index.cgi

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "1.7.10.4-Stricted";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "/usr/bin/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "/pub/git";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = 2007;
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "projects";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = ""
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "";
  90 # filename of html text to include at top of each page
  91 our $site_header = "";
  92 # html text to include at home page
  93 our $home_text = "indextext.html";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("static/gitweb.css");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "static/git-logo.png";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "static/git-favicon.png";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "static/gitweb.js";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # group projects by category on the projects list
 121 # (enabled if this variable evaluates to true)
 122 our $projects_list_group_categories = 0;
 123
 124 # default category if none specified
 125 # (leave the empty string for no category)
 126 our $project_list_default_category = "";
 127
 128 # default order of projects list
 129 # valid values are none, project, descr, owner, and age
 130 our $default_projects_order = "project";
 131
 132 # show repository only if this file exists
 133 # (only effective if this variable evaluates to true)
 134 our $export_ok = "";
 135
 136 # show repository only if this subroutine returns true
 137 # when given the path to the project, for example:
 138 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139 our $export_auth_hook = undef;
 140
 141 # only allow viewing of repositories also shown on the overview page
 142 our $strict_export = "";
 143
 144 # list of git base URLs used for URL to where fetch project from,
 145 # i.e. full URL is "$git_base_url/$project"
 146 our @git_base_url_list = grep { $_ ne '' } ("");
 147
 148 # default blob_plain mimetype and default charset for text/plain blob
 149 our $default_blob_plain_mimetype = 'text/plain';
 150 our $default_text_plain_charset  = undef;
 151
 152 # file to use for guessing MIME types before trying /etc/mime.types
 153 # (relative to the current git repository)
 154 our $mimetypes_file = undef;
 155
 156 # assume this charset if line contains non-UTF-8 characters;
 157 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 158 # for which encoding all byte sequences are valid, for example
 159 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160 # could be even 'utf-8' for the old behavior)
 161 our $fallback_encoding = 'iso-8859-1';
 162
 163 # rename detection options for git-diff and git-diff-tree
 164 # - default is '-M', with the cost proportional to
 165 #   (number of removed files) * (number of new files).
 166 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 167 #   (number of changed files + number of removed files) * (number of new files)
 168 # - even more costly is '-C', '--find-copies-harder' with cost
 169 #   (number of files in the original tree) * (number of new files)
 170 # - one might want to include '-B' option, e.g. '-B', '-M'
 171 our @diff_opts = ('-M'); # taken from git_commit
 172
 173 # Disables features that would allow repository owners to inject script into
 174 # the gitweb domain.
 175 our $prevent_xss = 0;
 176
 177 # Path to the highlight executable to use (must be the one from
 178 # http://www.andre-simon.de due to assumptions about parameters and output).
 179 # Useful if highlight is not installed on your webserver's PATH.
 180 # [Default: highlight]
 181 our $highlight_bin = "highlight";
 182
 183 # information about snapshot formats that gitweb is capable of serving
 184 our %known_snapshot_formats = (
 185         # name => {
 186         #       'display' => display name,
 187         #       'type' => mime type,
 188         #       'suffix' => filename suffix,
 189         #       'format' => --format for git-archive,
 190         #       'compressor' => [compressor command and arguments]
 191         #                       (array reference, optional)
 192         #       'disabled' => boolean (optional)}
 193         #
 194         'tgz' => {
 195                 'display' => 'tar.gz',
 196                 'type' => 'application/x-gzip',
 197                 'suffix' => '.tar.gz',
 198                 'format' => 'tar',
 199                 'compressor' => ['gzip', '-n']},
 200
 201         'tbz2' => {
 202                 'display' => 'tar.bz2',
 203                 'type' => 'application/x-bzip2',
 204                 'suffix' => '.tar.bz2',
 205                 'format' => 'tar',
 206                 'compressor' => ['bzip2']},
 207
 208         'txz' => {
 209                 'display' => 'tar.xz',
 210                 'type' => 'application/x-xz',
 211                 'suffix' => '.tar.xz',
 212                 'format' => 'tar',
 213                 'compressor' => ['xz'],
 214                 'disabled' => 1},
 215
 216         'zip' => {
 217                 'display' => 'zip',
 218                 'type' => 'application/x-zip',
 219                 'suffix' => '.zip',
 220                 'format' => 'zip'},
 221 );
 222
 223 # Aliases so we understand old gitweb.snapshot values in repository
 224 # configuration.
 225 our %known_snapshot_format_aliases = (
 226         'gzip'  => 'tgz',
 227         'bzip2' => 'tbz2',
 228         'xz'    => 'txz',
 229
 230         # backward compatibility: legacy gitweb config support
 231         'x-gzip' => undef, 'gz' => undef,
 232         'x-bzip2' => undef, 'bz2' => undef,
 233         'x-zip' => undef, '' => undef,
 234 );
 235
 236 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237 # are changed, it may be appropriate to change these values too via
 238 # $GITWEB_CONFIG.
 239 our %avatar_size = (
 240         'default' => 16,
 241         'double'  => 32
 242 );
 243
 244 # Used to set the maximum load that we will still respond to gitweb queries.
 245 # If server load exceed this value then return "503 server busy" error.
 246 # If gitweb cannot determined server load, it is taken to be 0.
 247 # Leave it undefined (or set to 'undef') to turn off load checking.
 248 our $maxload = 300;
 249
 250 # configuration for 'highlight' (http://www.andre-simon.de/)
 251 # match by basename
 252 our %highlight_basename = (
 253         #'Program' => 'py',
 254         #'Library' => 'py',
 255         'SConstruct' => 'py', # SCons equivalent of Makefile
 256         'Makefile' => 'make',
 257 );
 258 # match by extension
 259 our %highlight_ext = (
 260         # main extensions, defining name of syntax;
 261         # see files in /usr/share/highlight/langDefs/ directory
 262         map { $_ => $_ }
 263                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264         # alternate extensions, see /etc/highlight/filetypes.conf
 265         'h' => 'c',
 266         map { $_ => 'sh'  } qw(bash zsh ksh),
 267         map { $_ => 'cpp' } qw(cxx c++ cc),
 268         map { $_ => 'php' } qw(php3 php4 php5 phps),
 269         map { $_ => 'pl'  } qw(perl pm cgi),
 270         map { $_ => 'make'} qw(mak mk),
 271         map { $_ => 'xml' } qw(xhtml html htm),
 272 );
 273
 274 # You define site-wide feature defaults here; override them with
 275 # $GITWEB_CONFIG as necessary.
 276 our %feature = (
 277         # feature => {
 278         #       'sub' => feature-sub (subroutine),
 279         #       'override' => allow-override (boolean),
 280         #       'default' => [ default options...] (array reference)}
 281         #
 282         # if feature is overridable (it means that allow-override has true value),
 283         # then feature-sub will be called with default options as parameters;
 284         # return value of feature-sub indicates if to enable specified feature
 285         #
 286         # if there is no 'sub' key (no feature-sub), then feature cannot be
 287         # overridden
 288         #
 289         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291         # is enabled
 292
 293         # Enable the 'blame' blob view, showing the last commit that modified
 294         # each line in the file. This can be very CPU-intensive.
 295
 296         # To enable system wide have in $GITWEB_CONFIG
 297         # $feature{'blame'}{'default'} = [1];
 298         # To have project specific config enable override in $GITWEB_CONFIG
 299         # $feature{'blame'}{'override'} = 1;
 300         # and in project config gitweb.blame = 0|1;
 301         'blame' => {
 302                 'sub' => sub { feature_bool('blame', @_) },
 303                 'override' => 0,
 304                 'default' => [0]},
 305
 306         # Enable the 'snapshot' link, providing a compressed archive of any
 307         # tree. This can potentially generate high traffic if you have large
 308         # project.
 309
 310         # Value is a list of formats defined in %known_snapshot_formats that
 311         # you wish to offer.
 312         # To disable system wide have in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'default'} = [];
 314         # To have project specific config enable override in $GITWEB_CONFIG
 315         # $feature{'snapshot'}{'override'} = 1;
 316         # and in project config, a comma-separated list of formats or "none"
 317         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318         'snapshot' => {
 319                 'sub' => \&feature_snapshot,
 320                 'override' => 0,
 321                 'default' => ['tgz']},
 322
 323         # Enable text search, which will list the commits which match author,
 324         # committer or commit text to a given string.  Enabled by default.
 325         # Project specific override is not supported.
 326         #
 327         # Note that this controls all search features, which means that if
 328         # it is disabled, then 'grep' and 'pickaxe' search would also be
 329         # disabled.
 330         'search' => {
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable grep search, which will list the files in currently selected
 335         # tree containing the given string. Enabled by default. This can be
 336         # potentially CPU-intensive, of course.
 337         # Note that you need to have 'search' feature enabled too.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'grep'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'grep'}{'override'} = 1;
 343         # and in project config gitweb.grep = 0|1;
 344         'grep' => {
 345                 'sub' => sub { feature_bool('grep', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable the pickaxe search, which will list the commits that modified
 350         # a given string in a file. This can be practical and quite faster
 351         # alternative to 'blame', but still potentially CPU-intensive.
 352         # Note that you need to have 'search' feature enabled too.
 353
 354         # To enable system wide have in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'default'} = [1];
 356         # To have project specific config enable override in $GITWEB_CONFIG
 357         # $feature{'pickaxe'}{'override'} = 1;
 358         # and in project config gitweb.pickaxe = 0|1;
 359         'pickaxe' => {
 360                 'sub' => sub { feature_bool('pickaxe', @_) },
 361                 'override' => 0,
 362                 'default' => [1]},
 363
 364         # Enable showing size of blobs in a 'tree' view, in a separate
 365         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367         # To disable system wide have in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'default'} = [0];
 369         # To have project specific config enable override in $GITWEB_CONFIG
 370         # $feature{'show-sizes'}{'override'} = 1;
 371         # and in project config gitweb.showsizes = 0|1;
 372         'show-sizes' => {
 373                 'sub' => sub { feature_bool('showsizes', @_) },
 374                 'override' => 0,
 375                 'default' => [1]},
 376
 377         # Make gitweb use an alternative format of the URLs which can be
 378         # more readable and natural-looking: project name is embedded
 379         # directly in the path and the query string contains other
 380         # auxiliary information. All gitweb installations recognize
 381         # URL in either format; this configures in which formats gitweb
 382         # generates links.
 383
 384         # To enable system wide have in $GITWEB_CONFIG
 385         # $feature{'pathinfo'}{'default'} = [1];
 386         # Project specific override is not supported.
 387
 388         # Note that you will need to change the default location of CSS,
 389         # favicon, logo and possibly other files to an absolute URL. Also,
 390         # if gitweb.cgi serves as your indexfile, you will need to force
 391         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392         'pathinfo' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Make gitweb consider projects in project root subdirectories
 397         # to be forks of existing projects. Given project $projname.git,
 398         # projects matching $projname/*.git will not be shown in the main
 399         # projects list, instead a '+' mark will be added to $projname
 400         # there and a 'forks' view will be enabled for the project, listing
 401         # all the forks. If project list is taken from a file, forks have
 402         # to be listed after the main project.
 403
 404         # To enable system wide have in $GITWEB_CONFIG
 405         # $feature{'forks'}{'default'} = [1];
 406         # Project specific override is not supported.
 407         'forks' => {
 408                 'override' => 0,
 409                 'default' => [0]},
 410
 411         # Insert custom links to the action bar of all project pages.
 412         # This enables you mainly to link to third-party scripts integrating
 413         # into gitweb; e.g. git-browser for graphical history representation
 414         # or custom web-based repository administration interface.
 415
 416         # The 'default' value consists of a list of triplets in the form
 417         # (label, link, position) where position is the label after which
 418         # to insert the link and link is a format string where %n expands
 419         # to the project name, %f to the project path within the filesystem,
 420         # %h to the current hash (h gitweb parameter) and %b to the current
 421         # hash base (hb gitweb parameter); %% expands to %.
 422
 423         # To enable system wide have in $GITWEB_CONFIG e.g.
 424         # $feature{'actions'}{'default'} = [('graphiclog',
 425         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426         # Project specific override is not supported.
 427         'actions' => {
 428                 'override' => 0,
 429                 'default' => []},
 430
 431         # Allow gitweb scan project content tags of project repository,
 432         # and display the popular Web 2.0-ish "tag cloud" near the projects
 433         # list.  Note that this is something COMPLETELY different from the
 434         # normal Git tags.
 435
 436         # gitweb by itself can show existing tags, but it does not handle
 437         # tagging itself; you need to do it externally, outside gitweb.
 438         # The format is described in git_get_project_ctags() subroutine.
 439         # You may want to install the HTML::TagCloud Perl module to get
 440         # a pretty tag cloud instead of just a list of tags.
 441
 442         # To enable system wide have in $GITWEB_CONFIG
 443         # $feature{'ctags'}{'default'} = [1];
 444         # Project specific override is not supported.
 445
 446         # In the future whether ctags editing is enabled might depend
 447         # on the value, but using 1 should always mean no editing of ctags.
 448         'ctags' => {
 449                 'override' => 0,
 450                 'default' => [0]},
 451
 452         # The maximum number of patches in a patchset generated in patch
 453         # view. Set this to 0 or undef to disable patch view, or to a
 454         # negative number to remove any limit.
 455
 456         # To disable system wide have in $GITWEB_CONFIG
 457         # $feature{'patches'}{'default'} = [0];
 458         # To have project specific config enable override in $GITWEB_CONFIG
 459         # $feature{'patches'}{'override'} = 1;
 460         # and in project config gitweb.patches = 0|n;
 461         # where n is the maximum number of patches allowed in a patchset.
 462         'patches' => {
 463                 'sub' => \&feature_patches,
 464                 'override' => 0,
 465                 'default' => [16]},
 466
 467         # Avatar support. When this feature is enabled, views such as
 468         # shortlog or commit will display an avatar associated with
 469         # the email of the committer(s) and/or author(s).
 470
 471         # Currently available providers are gravatar and picon.
 472         # If an unknown provider is specified, the feature is disabled.
 473
 474         # Gravatar depends on Digest::MD5.
 475         # Picon currently relies on the indiana.edu database.
 476
 477         # To enable system wide have in $GITWEB_CONFIG
 478         # $feature{'avatar'}{'default'} = ['<provider>'];
 479         # where <provider> is either gravatar or picon.
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'avatar'}{'override'} = 1;
 482         # and in project config gitweb.avatar = <provider>;
 483         'avatar' => {
 484                 'sub' => \&feature_avatar,
 485                 'override' => 0,
 486                 'default' => ['']},
 487
 488         # Enable displaying how much time and how many git commands
 489         # it took to generate and display page.  Disabled by default.
 490         # Project specific override is not supported.
 491         'timed' => {
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable turning some links into links to actions which require
 496         # JavaScript to run (like 'blame_incremental').  Not enabled by
 497         # default.  Project specific override is currently not supported.
 498         'javascript-actions' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable and configure ability to change common timezone for dates
 503         # in gitweb output via JavaScript.  Enabled by default.
 504         # Project specific override is not supported.
 505         'javascript-timezone' => {
 506                 'override' => 0,
 507                 'default' => [
 508                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                      # or undef to turn off this feature
 510                         'gitweb_tz', # name of cookie where to store selected timezone
 511                         'datetime',  # CSS class used to mark up dates for manipulation
 512                 ]},
 513
 514         # Syntax highlighting support. This is based on Daniel Svensson's
 515         # and Sham Chukoury's work in gitweb-xmms2.git.
 516         # It requires the 'highlight' program present in $PATH,
 517         # and therefore is disabled by default.
 518
 519         # To enable system wide have in $GITWEB_CONFIG
 520         # $feature{'highlight'}{'default'} = [1];
 521         'highlight' => {
 522                 'sub' => sub { feature_bool('highlight', @_) },
 523                 'override' => 0,
 524                 'default' => [0]},
 525
 526         # Enable displaying of remote heads in the heads list
 527
 528         # To enable system wide have in $GITWEB_CONFIG
 529         # $feature{'remote_heads'}{'default'} = [1];
 530         # To have project specific config enable override in $GITWEB_CONFIG
 531         # $feature{'remote_heads'}{'override'} = 1;
 532         # and in project config gitweb.remote_heads = 0|1;
 533         'remote_heads' => {
 534                 'sub' => sub { feature_bool('remote_heads', @_) },
 535                 'override' => 0,
 536                 'default' => [0]},
 537 );
 538
 539 sub gitweb_get_feature {
 540         my ($name) = @_;
 541         return unless exists $feature{$name};
 542         my ($sub, $override, @defaults) = (
 543                 $feature{$name}{'sub'},
 544                 $feature{$name}{'override'},
 545                 @{$feature{$name}{'default'}});
 546         # project specific override is possible only if we have project
 547         our $git_dir; # global variable, declared later
 548         if (!$override || !defined $git_dir) {
 549                 return @defaults;
 550         }
 551         if (!defined $sub) {
 552                 warn "feature $name is not overridable";
 553                 return @defaults;
 554         }
 555         return $sub->(@defaults);
 556 }
 557
 558 # A wrapper to check if a given feature is enabled.
 559 # With this, you can say
 560 #
 561 #   my $bool_feat = gitweb_check_feature('bool_feat');
 562 #   gitweb_check_feature('bool_feat') or somecode;
 563 #
 564 # instead of
 565 #
 566 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 567 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 568 #
 569 sub gitweb_check_feature {
 570         return (gitweb_get_feature(@_))[0];
 571 }
 572
 573
 574 sub feature_bool {
 575         my $key = shift;
 576         my ($val) = git_get_project_config($key, '--bool');
 577
 578         if (!defined $val) {
 579                 return ($_[0]);
 580         } elsif ($val eq 'true') {
 581                 return (1);
 582         } elsif ($val eq 'false') {
 583                 return (0);
 584         }
 585 }
 586
 587 sub feature_snapshot {
 588         my (@fmts) = @_;
 589
 590         my ($val) = git_get_project_config('snapshot');
 591
 592         if ($val) {
 593                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 594         }
 595
 596         return @fmts;
 597 }
 598
 599 sub feature_patches {
 600         my @val = (git_get_project_config('patches', '--int'));
 601
 602         if (@val) {
 603                 return @val;
 604         }
 605
 606         return ($_[0]);
 607 }
 608
 609 sub feature_avatar {
 610         my @val = (git_get_project_config('avatar'));
 611
 612         return @val ? @val : @_;
 613 }
 614
 615 # checking HEAD file with -e is fragile if the repository was
 616 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 617 # and then pruned.
 618 sub check_head_link {
 619         my ($dir) = @_;
 620         my $headfile = "$dir/HEAD";
 621         return ((-e $headfile) ||
 622                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 623 }
 624
 625 sub check_export_ok {
 626         my ($dir) = @_;
 627         return (check_head_link($dir) &&
 628                 (!$export_ok || -e "$dir/$export_ok") &&
 629                 (!$export_auth_hook || $export_auth_hook->($dir)));
 630 }
 631
 632 # process alternate names for backward compatibility
 633 # filter out unsupported (unknown) snapshot formats
 634 sub filter_snapshot_fmts {
 635         my @fmts = @_;
 636
 637         @fmts = map {
 638                 exists $known_snapshot_format_aliases{$_} ?
 639                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 640         @fmts = grep {
 641                 exists $known_snapshot_formats{$_} &&
 642                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 643 }
 644
 645 # If it is set to code reference, it is code that it is to be run once per
 646 # request, allowing updating configurations that change with each request,
 647 # while running other code in config file only once.
 648 #
 649 # Otherwise, if it is false then gitweb would process config file only once;
 650 # if it is true then gitweb config would be run for each request.
 651 our $per_request_config = 1;
 652
 653 # read and parse gitweb config file given by its parameter.
 654 # returns true on success, false on recoverable error, allowing
 655 # to chain this subroutine, using first file that exists.
 656 # dies on errors during parsing config file, as it is unrecoverable.
 657 sub read_config_file {
 658         my $filename = shift;
 659         return unless defined $filename;
 660         # die if there are errors parsing config file
 661         if (-e $filename) {
 662                 do $filename;
 663                 die $@ if $@;
 664                 return 1;
 665         }
 666         return;
 667 }
 668
 669 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 670 sub evaluate_gitweb_config {
 671         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "gitweb_config.perl";
 672         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "/etc/gitweb.conf";
 673         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "/etc/gitweb-common.conf";
 674
 675         # Protect agains duplications of file names, to not read config twice.
 676         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 677         # there possibility of duplication of filename there doesn't matter.
 678         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 679         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 680
 681         # Common system-wide settings for convenience.
 682         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 683         read_config_file($GITWEB_CONFIG_COMMON);
 684
 685         # Use first config file that exists.  This means use the per-instance
 686         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 687         read_config_file($GITWEB_CONFIG) and return;
 688         read_config_file($GITWEB_CONFIG_SYSTEM);
 689 }
 690
 691 # Get loadavg of system, to compare against $maxload.
 692 # Currently it requires '/proc/loadavg' present to get loadavg;
 693 # if it is not present it returns 0, which means no load checking.
 694 sub get_loadavg {
 695         if( -e '/proc/loadavg' ){
 696                 open my $fd, '<', '/proc/loadavg'
 697                         or return 0;
 698                 my @load = split(/\s+/, scalar <$fd>);
 699                 close $fd;
 700
 701                 # The first three columns measure CPU and IO utilization of the last one,
 702                 # five, and 10 minute periods.  The fourth column shows the number of
 703                 # currently running processes and the total number of processes in the m/n
 704                 # format.  The last column displays the last process ID used.
 705                 return $load[0] || 0;
 706         }
 707         # additional checks for load average should go here for things that don't export
 708         # /proc/loadavg
 709
 710         return 0;
 711 }
 712
 713 # version of the core git binary
 714 our $git_version;
 715 sub evaluate_git_version {
 716         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 717         $number_of_git_cmds++;
 718 }
 719
 720 sub check_loadavg {
 721         if (defined $maxload && get_loadavg() > $maxload) {
 722                 die_error(503, "The load average on the server is too high");
 723         }
 724 }
 725
 726 # ======================================================================
 727 # input validation and dispatch
 728
 729 # input parameters can be collected from a variety of sources (presently, CGI
 730 # and PATH_INFO), so we define an %input_params hash that collects them all
 731 # together during validation: this allows subsequent uses (e.g. href()) to be
 732 # agnostic of the parameter origin
 733
 734 our %input_params = ();
 735
 736 # input parameters are stored with the long parameter name as key. This will
 737 # also be used in the href subroutine to convert parameters to their CGI
 738 # equivalent, and since the href() usage is the most frequent one, we store
 739 # the name -> CGI key mapping here, instead of the reverse.
 740 #
 741 # XXX: Warning: If you touch this, check the search form for updating,
 742 # too.
 743
 744 our @cgi_param_mapping = (
 745         project => "p",
 746         action => "a",
 747         file_name => "f",
 748         file_parent => "fp",
 749         hash => "h",
 750         hash_parent => "hp",
 751         hash_base => "hb",
 752         hash_parent_base => "hpb",
 753         page => "pg",
 754         order => "o",
 755         searchtext => "s",
 756         searchtype => "st",
 757         snapshot_format => "sf",
 758         extra_options => "opt",
 759         search_use_regexp => "sr",
 760         ctag => "by_tag",
 761         diff_style => "ds",
 762         project_filter => "pf",
 763         # this must be last entry (for manipulation from JavaScript)
 764         javascript => "js"
 765 );
 766 our %cgi_param_mapping = @cgi_param_mapping;
 767
 768 # we will also need to know the possible actions, for validation
 769 our %actions = (
 770         "blame" => \&git_blame,
 771         "blame_incremental" => \&git_blame_incremental,
 772         "blame_data" => \&git_blame_data,
 773         "blobdiff" => \&git_blobdiff,
 774         "blobdiff_plain" => \&git_blobdiff_plain,
 775         "blob" => \&git_blob,
 776         "blob_plain" => \&git_blob_plain,
 777         "commitdiff" => \&git_commitdiff,
 778         "commitdiff_plain" => \&git_commitdiff_plain,
 779         "commit" => \&git_commit,
 780         "forks" => \&git_forks,
 781         "heads" => \&git_heads,
 782         "history" => \&git_history,
 783         "log" => \&git_log,
 784         "patch" => \&git_patch,
 785         "patches" => \&git_patches,
 786         "remotes" => \&git_remotes,
 787         "rss" => \&git_rss,
 788         "atom" => \&git_atom,
 789         "search" => \&git_search,
 790         "search_help" => \&git_search_help,
 791         "shortlog" => \&git_shortlog,
 792         "summary" => \&git_summary,
 793         "tag" => \&git_tag,
 794         "tags" => \&git_tags,
 795         "tree" => \&git_tree,
 796         "snapshot" => \&git_snapshot,
 797         "object" => \&git_object,
 798         # those below don't need $project
 799         "opml" => \&git_opml,
 800         "project_list" => \&git_project_list,
 801         "project_index" => \&git_project_index,
 802 );
 803
 804 # finally, we have the hash of allowed extra_options for the commands that
 805 # allow them
 806 our %allowed_options = (
 807         "--no-merges" => [ qw(rss atom log shortlog history) ],
 808 );
 809
 810 # fill %input_params with the CGI parameters. All values except for 'opt'
 811 # should be single values, but opt can be an array. We should probably
 812 # build an array of parameters that can be multi-valued, but since for the time
 813 # being it's only this one, we just single it out
 814 sub evaluate_query_params {
 815         our $cgi;
 816
 817         while (my ($name, $symbol) = each %cgi_param_mapping) {
 818                 if ($symbol eq 'opt') {
 819                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 820                 } else {
 821                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 822                 }
 823         }
 824 }
 825
 826 # now read PATH_INFO and update the parameter list for missing parameters
 827 sub evaluate_path_info {
 828         return if defined $input_params{'project'};
 829         return if !$path_info;
 830         $path_info =~ s,^/+,,;
 831         return if !$path_info;
 832
 833         # find which part of PATH_INFO is project
 834         my $project = $path_info;
 835         $project =~ s,/+$,,;
 836         while ($project && !check_head_link("$projectroot/$project")) {
 837                 $project =~ s,/*[^/]*$,,;
 838         }
 839         return unless $project;
 840         $input_params{'project'} = $project;
 841
 842         # do not change any parameters if an action is given using the query string
 843         return if $input_params{'action'};
 844         $path_info =~ s,^\Q$project\E/*,,;
 845
 846         # next, check if we have an action
 847         my $action = $path_info;
 848         $action =~ s,/.*$,,;
 849         if (exists $actions{$action}) {
 850                 $path_info =~ s,^$action/*,,;
 851                 $input_params{'action'} = $action;
 852         }
 853
 854         # list of actions that want hash_base instead of hash, but can have no
 855         # pathname (f) parameter
 856         my @wants_base = (
 857                 'tree',
 858                 'history',
 859         );
 860
 861         # we want to catch, among others
 862         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 863         my ($parentrefname, $parentpathname, $refname, $pathname) =
 864                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 865
 866         # first, analyze the 'current' part
 867         if (defined $pathname) {
 868                 # we got "branch:filename" or "branch:dir/"
 869                 # we could use git_get_type(branch:pathname), but:
 870                 # - it needs $git_dir
 871                 # - it does a git() call
 872                 # - the convention of terminating directories with a slash
 873                 #   makes it superfluous
 874                 # - embedding the action in the PATH_INFO would make it even
 875                 #   more superfluous
 876                 $pathname =~ s,^/+,,;
 877                 if (!$pathname || substr($pathname, -1) eq "/") {
 878                         $input_params{'action'} ||= "tree";
 879                         $pathname =~ s,/$,,;
 880                 } else {
 881                         # the default action depends on whether we had parent info
 882                         # or not
 883                         if ($parentrefname) {
 884                                 $input_params{'action'} ||= "blobdiff_plain";
 885                         } else {
 886                                 $input_params{'action'} ||= "blob_plain";
 887                         }
 888                 }
 889                 $input_params{'hash_base'} ||= $refname;
 890                 $input_params{'file_name'} ||= $pathname;
 891         } elsif (defined $refname) {
 892                 # we got "branch". In this case we have to choose if we have to
 893                 # set hash or hash_base.
 894                 #
 895                 # Most of the actions without a pathname only want hash to be
 896                 # set, except for the ones specified in @wants_base that want
 897                 # hash_base instead. It should also be noted that hand-crafted
 898                 # links having 'history' as an action and no pathname or hash
 899                 # set will fail, but that happens regardless of PATH_INFO.
 900                 if (defined $parentrefname) {
 901                         # if there is parent let the default be 'shortlog' action
 902                         # (for http://git.example.com/repo.git/A..B links); if there
 903                         # is no parent, dispatch will detect type of object and set
 904                         # action appropriately if required (if action is not set)
 905                         $input_params{'action'} ||= "shortlog";
 906                 }
 907                 if ($input_params{'action'} &&
 908                     grep { $_ eq $input_params{'action'} } @wants_base) {
 909                         $input_params{'hash_base'} ||= $refname;
 910                 } else {
 911                         $input_params{'hash'} ||= $refname;
 912                 }
 913         }
 914
 915         # next, handle the 'parent' part, if present
 916         if (defined $parentrefname) {
 917                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 918                 # someproject/blobdiff/oldrev..newrev:/filename
 919                 if ($parentpathname) {
 920                         $parentpathname =~ s,^/+,,;
 921                         $parentpathname =~ s,/$,,;
 922                         $input_params{'file_parent'} ||= $parentpathname;
 923                 } else {
 924                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 925                 }
 926                 # we assume that hash_parent_base is wanted if a path was specified,
 927                 # or if the action wants hash_base instead of hash
 928                 if (defined $input_params{'file_parent'} ||
 929                         grep { $_ eq $input_params{'action'} } @wants_base) {
 930                         $input_params{'hash_parent_base'} ||= $parentrefname;
 931                 } else {
 932                         $input_params{'hash_parent'} ||= $parentrefname;
 933                 }
 934         }
 935
 936         # for the snapshot action, we allow URLs in the form
 937         # $project/snapshot/$hash.ext
 938         # where .ext determines the snapshot and gets removed from the
 939         # passed $refname to provide the $hash.
 940         #
 941         # To be able to tell that $refname includes the format extension, we
 942         # require the following two conditions to be satisfied:
 943         # - the hash input parameter MUST have been set from the $refname part
 944         #   of the URL (i.e. they must be equal)
 945         # - the snapshot format MUST NOT have been defined already (e.g. from
 946         #   CGI parameter sf)
 947         # It's also useless to try any matching unless $refname has a dot,
 948         # so we check for that too
 949         if (defined $input_params{'action'} &&
 950                 $input_params{'action'} eq 'snapshot' &&
 951                 defined $refname && index($refname, '.') != -1 &&
 952                 $refname eq $input_params{'hash'} &&
 953                 !defined $input_params{'snapshot_format'}) {
 954                 # We loop over the known snapshot formats, checking for
 955                 # extensions. Allowed extensions are both the defined suffix
 956                 # (which includes the initial dot already) and the snapshot
 957                 # format key itself, with a prepended dot
 958                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 959                         my $hash = $refname;
 960                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 961                                 next;
 962                         }
 963                         my $sfx = $1;
 964                         # a valid suffix was found, so set the snapshot format
 965                         # and reset the hash parameter
 966                         $input_params{'snapshot_format'} = $fmt;
 967                         $input_params{'hash'} = $hash;
 968                         # we also set the format suffix to the one requested
 969                         # in the URL: this way a request for e.g. .tgz returns
 970                         # a .tgz instead of a .tar.gz
 971                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 972                         last;
 973                 }
 974         }
 975 }
 976
 977 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 978      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 979      $searchtext, $search_regexp, $project_filter);
 980 sub evaluate_and_validate_params {
 981         our $action = $input_params{'action'};
 982         if (defined $action) {
 983                 if (!validate_action($action)) {
 984                         die_error(400, "Invalid action parameter");
 985                 }
 986         }
 987
 988         # parameters which are pathnames
 989         our $project = $input_params{'project'};
 990         if (defined $project) {
 991                 if (!validate_project($project)) {
 992                         undef $project;
 993                         die_error(404, "No such project");
 994                 }
 995         }
 996
 997         our $project_filter = $input_params{'project_filter'};
 998         if (defined $project_filter) {
 999                 if (!validate_pathname($project_filter)) {
1000                         die_error(404, "Invalid project_filter parameter");
1001                 }
1002         }
1003
1004         our $file_name = $input_params{'file_name'};
1005         if (defined $file_name) {
1006                 if (!validate_pathname($file_name)) {
1007                         die_error(400, "Invalid file parameter");
1008                 }
1009         }
1010
1011         our $file_parent = $input_params{'file_parent'};
1012         if (defined $file_parent) {
1013                 if (!validate_pathname($file_parent)) {
1014                         die_error(400, "Invalid file parent parameter");
1015                 }
1016         }
1017
1018         # parameters which are refnames
1019         our $hash = $input_params{'hash'};
1020         if (defined $hash) {
1021                 if (!validate_refname($hash)) {
1022                         die_error(400, "Invalid hash parameter");
1023                 }
1024         }
1025
1026         our $hash_parent = $input_params{'hash_parent'};
1027         if (defined $hash_parent) {
1028                 if (!validate_refname($hash_parent)) {
1029                         die_error(400, "Invalid hash parent parameter");
1030                 }
1031         }
1032
1033         our $hash_base = $input_params{'hash_base'};
1034         if (defined $hash_base) {
1035                 if (!validate_refname($hash_base)) {
1036                         die_error(400, "Invalid hash base parameter");
1037                 }
1038         }
1039
1040         our @extra_options = @{$input_params{'extra_options'}};
1041         # @extra_options is always defined, since it can only be (currently) set from
1042         # CGI, and $cgi->param() returns the empty array in array context if the param
1043         # is not set
1044         foreach my $opt (@extra_options) {
1045                 if (not exists $allowed_options{$opt}) {
1046                         die_error(400, "Invalid option parameter");
1047                 }
1048                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1049                         die_error(400, "Invalid option parameter for this action");
1050                 }
1051         }
1052
1053         our $hash_parent_base = $input_params{'hash_parent_base'};
1054         if (defined $hash_parent_base) {
1055                 if (!validate_refname($hash_parent_base)) {
1056                         die_error(400, "Invalid hash parent base parameter");
1057                 }
1058         }
1059
1060         # other parameters
1061         our $page = $input_params{'page'};
1062         if (defined $page) {
1063                 if ($page =~ m/[^0-9]/) {
1064                         die_error(400, "Invalid page parameter");
1065                 }
1066         }
1067
1068         our $searchtype = $input_params{'searchtype'};
1069         if (defined $searchtype) {
1070                 if ($searchtype =~ m/[^a-z]/) {
1071                         die_error(400, "Invalid searchtype parameter");
1072                 }
1073         }
1074
1075         our $search_use_regexp = $input_params{'search_use_regexp'};
1076
1077         our $searchtext = $input_params{'searchtext'};
1078         our $search_regexp;
1079         if (defined $searchtext) {
1080                 if (length($searchtext) < 2) {
1081                         die_error(403, "At least two characters are required for search parameter");
1082                 }
1083                 if ($search_use_regexp) {
1084                         $search_regexp = $searchtext;
1085                         if (!eval { qr/$search_regexp/; 1; }) {
1086                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1087                                 die_error(400, "Invalid search regexp '$search_regexp'",
1088                                           esc_html($error));
1089                         }
1090                 } else {
1091                         $search_regexp = quotemeta $searchtext;
1092                 }
1093         }
1094 }
1095
1096 # path to the current git repository
1097 our $git_dir;
1098 sub evaluate_git_dir {
1099         our $git_dir = "$projectroot/$project" if $project;
1100 }
1101
1102 our (@snapshot_fmts, $git_avatar);
1103 sub configure_gitweb_features {
1104         # list of supported snapshot formats
1105         our @snapshot_fmts = gitweb_get_feature('snapshot');
1106         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1107
1108         # check that the avatar feature is set to a known provider name,
1109         # and for each provider check if the dependencies are satisfied.
1110         # if the provider name is invalid or the dependencies are not met,
1111         # reset $git_avatar to the empty string.
1112         our ($git_avatar) = gitweb_get_feature('avatar');
1113         if ($git_avatar eq 'gravatar') {
1114                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1115         } elsif ($git_avatar eq 'picon') {
1116                 # no dependencies
1117         } else {
1118                 $git_avatar = '';
1119         }
1120 }
1121
1122 # custom error handler: 'die <message>' is Internal Server Error
1123 sub handle_errors_html {
1124         my $msg = shift; # it is already HTML escaped
1125
1126         # to avoid infinite loop where error occurs in die_error,
1127         # change handler to default handler, disabling handle_errors_html
1128         set_message("Error occured when inside die_error:\n$msg");
1129
1130         # you cannot jump out of die_error when called as error handler;
1131         # the subroutine set via CGI::Carp::set_message is called _after_
1132         # HTTP headers are already written, so it cannot write them itself
1133         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1134 }
1135 set_message(\&handle_errors_html);
1136
1137 # dispatch
1138 sub dispatch {
1139         if (!defined $action) {
1140                 if (defined $hash) {
1141                         $action = git_get_type($hash);
1142                         $action or die_error(404, "Object does not exist");
1143                 } elsif (defined $hash_base && defined $file_name) {
1144                         $action = git_get_type("$hash_base:$file_name");
1145                         $action or die_error(404, "File or directory does not exist");
1146                 } elsif (defined $project) {
1147                         $action = 'summary';
1148                 } else {
1149                         $action = 'project_list';
1150                 }
1151         }
1152         if (!defined($actions{$action})) {
1153                 die_error(400, "Unknown action");
1154         }
1155         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1156             !$project) {
1157                 die_error(400, "Project needed");
1158         }
1159         $actions{$action}->();
1160 }
1161
1162 sub reset_timer {
1163         our $t0 = [ gettimeofday() ]
1164                 if defined $t0;
1165         our $number_of_git_cmds = 0;
1166 }
1167
1168 our $first_request = 1;
1169 sub run_request {
1170         reset_timer();
1171
1172         evaluate_uri();
1173         if ($first_request) {
1174                 evaluate_gitweb_config();
1175                 evaluate_git_version();
1176         }
1177         if ($per_request_config) {
1178                 if (ref($per_request_config) eq 'CODE') {
1179                         $per_request_config->();
1180                 } elsif (!$first_request) {
1181                         evaluate_gitweb_config();
1182                 }
1183         }
1184         check_loadavg();
1185
1186         # $projectroot and $projects_list might be set in gitweb config file
1187         $projects_list ||= $projectroot;
1188
1189         evaluate_query_params();
1190         evaluate_path_info();
1191         evaluate_and_validate_params();
1192         evaluate_git_dir();
1193
1194         configure_gitweb_features();
1195
1196         dispatch();
1197 }
1198
1199 our $is_last_request = sub { 1 };
1200 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1201 our $CGI = 'CGI';
1202 our $cgi;
1203 sub configure_as_fcgi {
1204         require CGI::Fast;
1205         our $CGI = 'CGI::Fast';
1206
1207         my $request_number = 0;
1208         # let each child service 100 requests
1209         our $is_last_request = sub { ++$request_number > 100 };
1210 }
1211 sub evaluate_argv {
1212         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1213         configure_as_fcgi()
1214                 if $script_name =~ /\.fcgi$/;
1215
1216         return unless (@ARGV);
1217
1218         require Getopt::Long;
1219         Getopt::Long::GetOptions(
1220                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1221                 'nproc|n=i' => sub {
1222                         my ($arg, $val) = @_;
1223                         return unless eval { require FCGI::ProcManager; 1; };
1224                         my $proc_manager = FCGI::ProcManager->new({
1225                                 n_processes => $val,
1226                         });
1227                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1228                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1229                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1230                 },
1231         );
1232 }
1233
1234 sub run {
1235         evaluate_argv();
1236
1237         $first_request = 1;
1238         $pre_listen_hook->()
1239                 if $pre_listen_hook;
1240
1241  REQUEST:
1242         while ($cgi = $CGI->new()) {
1243                 $pre_dispatch_hook->()
1244                         if $pre_dispatch_hook;
1245
1246                 run_request();
1247
1248                 $post_dispatch_hook->()
1249                         if $post_dispatch_hook;
1250                 $first_request = 0;
1251
1252                 last REQUEST if ($is_last_request->());
1253         }
1254
1255  DONE_GITWEB:
1256         1;
1257 }
1258
1259 run();
1260
1261 if (defined caller) {
1262         # wrapped in a subroutine processing requests,
1263         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1264         return;
1265 } else {
1266         # pure CGI script, serving single request
1267         exit;
1268 }
1269
1270 ## ======================================================================
1271 ## action links
1272
1273 # possible values of extra options
1274 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1275 # -replay => 1      - start from a current view (replay with modifications)
1276 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1277 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1278 sub href {
1279         my %params = @_;
1280         # default is to use -absolute url() i.e. $my_uri
1281         my $href = $params{-full} ? $my_url : $my_uri;
1282
1283         # implicit -replay, must be first of implicit params
1284         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1285
1286         $params{'project'} = $project unless exists $params{'project'};
1287
1288         if ($params{-replay}) {
1289                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1290                         if (!exists $params{$name}) {
1291                                 $params{$name} = $input_params{$name};
1292                         }
1293                 }
1294         }
1295
1296         my $use_pathinfo = gitweb_check_feature('pathinfo');
1297         if (defined $params{'project'} &&
1298             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1299                 # try to put as many parameters as possible in PATH_INFO:
1300                 #   - project name
1301                 #   - action
1302                 #   - hash_parent or hash_parent_base:/file_parent
1303                 #   - hash or hash_base:/filename
1304                 #   - the snapshot_format as an appropriate suffix
1305
1306                 # When the script is the root DirectoryIndex for the domain,
1307                 # $href here would be something like http://gitweb.example.com/
1308                 # Thus, we strip any trailing / from $href, to spare us double
1309                 # slashes in the final URL
1310                 $href =~ s,/$,,;
1311
1312                 # Then add the project name, if present
1313                 $href .= "/".esc_path_info($params{'project'});
1314                 delete $params{'project'};
1315
1316                 # since we destructively absorb parameters, we keep this
1317                 # boolean that remembers if we're handling a snapshot
1318                 my $is_snapshot = $params{'action'} eq 'snapshot';
1319
1320                 # Summary just uses the project path URL, any other action is
1321                 # added to the URL
1322                 if (defined $params{'action'}) {
1323                         $href .= "/".esc_path_info($params{'action'})
1324                                 unless $params{'action'} eq 'summary';
1325                         delete $params{'action'};
1326                 }
1327
1328                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1329                 # stripping nonexistent or useless pieces
1330                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1331                         || $params{'hash_parent'} || $params{'hash'});
1332                 if (defined $params{'hash_base'}) {
1333                         if (defined $params{'hash_parent_base'}) {
1334                                 $href .= esc_path_info($params{'hash_parent_base'});
1335                                 # skip the file_parent if it's the same as the file_name
1336                                 if (defined $params{'file_parent'}) {
1337                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1338                                                 delete $params{'file_parent'};
1339                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1340                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1341                                                 delete $params{'file_parent'};
1342                                         }
1343                                 }
1344                                 $href .= "..";
1345                                 delete $params{'hash_parent'};
1346                                 delete $params{'hash_parent_base'};
1347                         } elsif (defined $params{'hash_parent'}) {
1348                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1349                                 delete $params{'hash_parent'};
1350                         }
1351
1352                         $href .= esc_path_info($params{'hash_base'});
1353                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1354                                 $href .= ":/".esc_path_info($params{'file_name'});
1355                                 delete $params{'file_name'};
1356                         }
1357                         delete $params{'hash'};
1358                         delete $params{'hash_base'};
1359                 } elsif (defined $params{'hash'}) {
1360                         $href .= esc_path_info($params{'hash'});
1361                         delete $params{'hash'};
1362                 }
1363
1364                 # If the action was a snapshot, we can absorb the
1365                 # snapshot_format parameter too
1366                 if ($is_snapshot) {
1367                         my $fmt = $params{'snapshot_format'};
1368                         # snapshot_format should always be defined when href()
1369                         # is called, but just in case some code forgets, we
1370                         # fall back to the default
1371                         $fmt ||= $snapshot_fmts[0];
1372                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1373                         delete $params{'snapshot_format'};
1374                 }
1375         }
1376
1377         # now encode the parameters explicitly
1378         my @result = ();
1379         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1380                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1381                 if (defined $params{$name}) {
1382                         if (ref($params{$name}) eq "ARRAY") {
1383                                 foreach my $par (@{$params{$name}}) {
1384                                         push @result, $symbol . "=" . esc_param($par);
1385                                 }
1386                         } else {
1387                                 push @result, $symbol . "=" . esc_param($params{$name});
1388                         }
1389                 }
1390         }
1391         $href .= "?" . join(';', @result) if scalar @result;
1392
1393         # final transformation: trailing spaces must be escaped (URI-encoded)
1394         $href =~ s/(\s+)$/CGI::escape($1)/e;
1395
1396         if ($params{-anchor}) {
1397                 $href .= "#".esc_param($params{-anchor});
1398         }
1399
1400         return $href;
1401 }
1402
1403
1404 ## ======================================================================
1405 ## validation, quoting/unquoting and escaping
1406
1407 sub validate_action {
1408         my $input = shift || return undef;
1409         return undef unless exists $actions{$input};
1410         return $input;
1411 }
1412
1413 sub validate_project {
1414         my $input = shift || return undef;
1415         if (!validate_pathname($input) ||
1416                 !(-d "$projectroot/$input") ||
1417                 !check_export_ok("$projectroot/$input") ||
1418                 ($strict_export && !project_in_list($input))) {
1419                 return undef;
1420         } else {
1421                 return $input;
1422         }
1423 }
1424
1425 sub validate_pathname {
1426         my $input = shift || return undef;
1427
1428         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1429         # at the beginning, at the end, and between slashes.
1430         # also this catches doubled slashes
1431         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1432                 return undef;
1433         }
1434         # no null characters
1435         if ($input =~ m!\0!) {
1436                 return undef;
1437         }
1438         return $input;
1439 }
1440
1441 sub validate_refname {
1442         my $input = shift || return undef;
1443
1444         # textual hashes are O.K.
1445         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1446                 return $input;
1447         }
1448         # it must be correct pathname
1449         $input = validate_pathname($input)
1450                 or return undef;
1451         # restrictions on ref name according to git-check-ref-format
1452         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1453                 return undef;
1454         }
1455         return $input;
1456 }
1457
1458 # decode sequences of octets in utf8 into Perl's internal form,
1459 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1460 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1461 sub to_utf8 {
1462         my $str = shift;
1463         return undef unless defined $str;
1464
1465         if (utf8::is_utf8($str) || utf8::decode($str)) {
1466                 return $str;
1467         } else {
1468                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1469         }
1470 }
1471
1472 # quote unsafe chars, but keep the slash, even when it's not
1473 # correct, but quoted slashes look too horrible in bookmarks
1474 sub esc_param {
1475         my $str = shift;
1476         return undef unless defined $str;
1477         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1478         $str =~ s/ /\+/g;
1479         return $str;
1480 }
1481
1482 # the quoting rules for path_info fragment are slightly different
1483 sub esc_path_info {
1484         my $str = shift;
1485         return undef unless defined $str;
1486
1487         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1488         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1489
1490         return $str;
1491 }
1492
1493 # quote unsafe chars in whole URL, so some characters cannot be quoted
1494 sub esc_url {
1495         my $str = shift;
1496         return undef unless defined $str;
1497         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1498         $str =~ s/ /\+/g;
1499         return $str;
1500 }
1501
1502 # quote unsafe characters in HTML attributes
1503 sub esc_attr {
1504
1505         # for XHTML conformance escaping '"' to '&quot;' is not enough
1506         return esc_html(@_);
1507 }
1508
1509 # replace invalid utf8 character with SUBSTITUTION sequence
1510 sub esc_html {
1511         my $str = shift;
1512         my %opts = @_;
1513
1514         return undef unless defined $str;
1515
1516         $str = to_utf8($str);
1517         $str = $cgi->escapeHTML($str);
1518         if ($opts{'-nbsp'}) {
1519                 $str =~ s/ /&nbsp;/g;
1520         }
1521         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1522         return $str;
1523 }
1524
1525 # quote control characters and escape filename to HTML
1526 sub esc_path {
1527         my $str = shift;
1528         my %opts = @_;
1529
1530         return undef unless defined $str;
1531
1532         $str = to_utf8($str);
1533         $str = $cgi->escapeHTML($str);
1534         if ($opts{'-nbsp'}) {
1535                 $str =~ s/ /&nbsp;/g;
1536         }
1537         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1538         return $str;
1539 }
1540
1541 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1542 sub sanitize {
1543         my $str = shift;
1544
1545         return undef unless defined $str;
1546
1547         $str = to_utf8($str);
1548         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1549         return $str;
1550 }
1551
1552 # Make control characters "printable", using character escape codes (CEC)
1553 sub quot_cec {
1554         my $cntrl = shift;
1555         my %opts = @_;
1556         my %es = ( # character escape codes, aka escape sequences
1557                 "\t" => '\t',   # tab            (HT)
1558                 "\n" => '\n',   # line feed      (LF)
1559                 "\r" => '\r',   # carrige return (CR)
1560                 "\f" => '\f',   # form feed      (FF)
1561                 "\b" => '\b',   # backspace      (BS)
1562                 "\a" => '\a',   # alarm (bell)   (BEL)
1563                 "\e" => '\e',   # escape         (ESC)
1564                 "\013" => '\v', # vertical tab   (VT)
1565                 "\000" => '\0', # nul character  (NUL)
1566         );
1567         my $chr = ( (exists $es{$cntrl})
1568                     ? $es{$cntrl}
1569                     : sprintf('\%2x', ord($cntrl)) );
1570         if ($opts{-nohtml}) {
1571                 return $chr;
1572         } else {
1573                 return "<span class=\"cntrl\">$chr</span>";
1574         }
1575 }
1576
1577 # Alternatively use unicode control pictures codepoints,
1578 # Unicode "printable representation" (PR)
1579 sub quot_upr {
1580         my $cntrl = shift;
1581         my %opts = @_;
1582
1583         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1584         if ($opts{-nohtml}) {
1585                 return $chr;
1586         } else {
1587                 return "<span class=\"cntrl\">$chr</span>";
1588         }
1589 }
1590
1591 # git may return quoted and escaped filenames
1592 sub unquote {
1593         my $str = shift;
1594
1595         sub unq {
1596                 my $seq = shift;
1597                 my %es = ( # character escape codes, aka escape sequences
1598                         't' => "\t",   # tab            (HT, TAB)
1599                         'n' => "\n",   # newline        (NL)
1600                         'r' => "\r",   # return         (CR)
1601                         'f' => "\f",   # form feed      (FF)
1602                         'b' => "\b",   # backspace      (BS)
1603                         'a' => "\a",   # alarm (bell)   (BEL)
1604                         'e' => "\e",   # escape         (ESC)
1605                         'v' => "\013", # vertical tab   (VT)
1606                 );
1607
1608                 if ($seq =~ m/^[0-7]{1,3}$/) {
1609                         # octal char sequence
1610                         return chr(oct($seq));
1611                 } elsif (exists $es{$seq}) {
1612                         # C escape sequence, aka character escape code
1613                         return $es{$seq};
1614                 }
1615                 # quoted ordinary character
1616                 return $seq;
1617         }
1618
1619         if ($str =~ m/^"(.*)"$/) {
1620                 # needs unquoting
1621                 $str = $1;
1622                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1623         }
1624         return $str;
1625 }
1626
1627 # escape tabs (convert tabs to spaces)
1628 sub untabify {
1629         my $line = shift;
1630
1631         while ((my $pos = index($line, "\t")) != -1) {
1632                 if (my $count = (8 - ($pos % 8))) {
1633                         my $spaces = ' ' x $count;
1634                         $line =~ s/\t/$spaces/;
1635                 }
1636         }
1637
1638         return $line;
1639 }
1640
1641 sub project_in_list {
1642         my $project = shift;
1643         my @list = git_get_projects_list();
1644         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1645 }
1646
1647 ## ----------------------------------------------------------------------
1648 ## HTML aware string manipulation
1649
1650 # Try to chop given string on a word boundary between position
1651 # $len and $len+$add_len. If there is no word boundary there,
1652 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1653 # (marking chopped part) would be longer than given string.
1654 sub chop_str {
1655         my $str = shift;
1656         my $len = shift;
1657         my $add_len = shift || 10;
1658         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1659
1660         # Make sure perl knows it is utf8 encoded so we don't
1661         # cut in the middle of a utf8 multibyte char.
1662         $str = to_utf8($str);
1663
1664         # allow only $len chars, but don't cut a word if it would fit in $add_len
1665         # if it doesn't fit, cut it if it's still longer than the dots we would add
1666         # remove chopped character entities entirely
1667
1668         # when chopping in the middle, distribute $len into left and right part
1669         # return early if chopping wouldn't make string shorter
1670         if ($where eq 'center') {
1671                 return $str if ($len + 5 >= length($str)); # filler is length 5
1672                 $len = int($len/2);
1673         } else {
1674                 return $str if ($len + 4 >= length($str)); # filler is length 4
1675         }
1676
1677         # regexps: ending and beginning with word part up to $add_len
1678         my $endre = qr/.{$len}\w{0,$add_len}/;
1679         my $begre = qr/\w{0,$add_len}.{$len}/;
1680
1681         if ($where eq 'left') {
1682                 $str =~ m/^(.*?)($begre)$/;
1683                 my ($lead, $body) = ($1, $2);
1684                 if (length($lead) > 4) {
1685                         $lead = " ...";
1686                 }
1687                 return "$lead$body";
1688
1689         } elsif ($where eq 'center') {
1690                 $str =~ m/^($endre)(.*)$/;
1691                 my ($left, $str)  = ($1, $2);
1692                 $str =~ m/^(.*?)($begre)$/;
1693                 my ($mid, $right) = ($1, $2);
1694                 if (length($mid) > 5) {
1695                         $mid = " ... ";
1696                 }
1697                 return "$left$mid$right";
1698
1699         } else {
1700                 $str =~ m/^($endre)(.*)$/;
1701                 my $body = $1;
1702                 my $tail = $2;
1703                 if (length($tail) > 4) {
1704                         $tail = "... ";
1705                 }
1706                 return "$body$tail";
1707         }
1708 }
1709
1710 # takes the same arguments as chop_str, but also wraps a <span> around the
1711 # result with a title attribute if it does get chopped. Additionally, the
1712 # string is HTML-escaped.
1713 sub chop_and_escape_str {
1714         my ($str) = @_;
1715
1716         my $chopped = chop_str(@_);
1717         $str = to_utf8($str);
1718         if ($chopped eq $str) {
1719                 return esc_html($chopped);
1720         } else {
1721                 $str =~ s/[[:cntrl:]]/?/g;
1722                 return $cgi->span({-title=>$str}, esc_html($chopped));
1723         }
1724 }
1725
1726 # Highlight selected fragments of string, using given CSS class,
1727 # and escape HTML.  It is assumed that fragments do not overlap.
1728 # Regions are passed as list of pairs (array references).
1729 #
1730 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1731 # '<span class="mark">foo</span>bar'
1732 sub esc_html_hl_regions {
1733         my ($str, $css_class, @sel) = @_;
1734         return esc_html($str) unless @sel;
1735
1736         my $out = '';
1737         my $pos = 0;
1738
1739         for my $s (@sel) {
1740                 $out .= esc_html(substr($str, $pos, $s->[0] - $pos))
1741                         if ($s->[0] - $pos > 0);
1742                 $out .= $cgi->span({-class => $css_class},
1743                                    esc_html(substr($str, $s->[0], $s->[1] - $s->[0])));
1744
1745                 $pos = $s->[1];
1746         }
1747         $out .= esc_html(substr($str, $pos))
1748                 if ($pos < length($str));
1749
1750         return $out;
1751 }
1752
1753 # return positions of beginning and end of each match
1754 sub matchpos_list {
1755         my ($str, $regexp) = @_;
1756         return unless (defined $str && defined $regexp);
1757
1758         my @matches;
1759         while ($str =~ /$regexp/g) {
1760                 push @matches, [$-[0], $+[0]];
1761         }
1762         return @matches;
1763 }
1764
1765 # highlight match (if any), and escape HTML
1766 sub esc_html_match_hl {
1767         my ($str, $regexp) = @_;
1768         return esc_html($str) unless defined $regexp;
1769
1770         my @matches = matchpos_list($str, $regexp);
1771         return esc_html($str) unless @matches;
1772
1773         return esc_html_hl_regions($str, 'match', @matches);
1774 }
1775
1776
1777 # highlight match (if any) of shortened string, and escape HTML
1778 sub esc_html_match_hl_chopped {
1779         my ($str, $chopped, $regexp) = @_;
1780         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1781
1782         my @matches = matchpos_list($str, $regexp);
1783         return esc_html($chopped) unless @matches;
1784
1785         # filter matches so that we mark chopped string
1786         my $tail = "... "; # see chop_str
1787         unless ($chopped =~ s/\Q$tail\E$//) {
1788                 $tail = '';
1789         }
1790         my $chop_len = length($chopped);
1791         my $tail_len = length($tail);
1792         my @filtered;
1793
1794         for my $m (@matches) {
1795                 if ($m->[0] > $chop_len) {
1796                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1797                         last;
1798                 } elsif ($m->[1] > $chop_len) {
1799                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1800                         last;
1801                 }
1802                 push @filtered, $m;
1803         }
1804
1805         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1806 }
1807
1808 ## ----------------------------------------------------------------------
1809 ## functions returning short strings
1810
1811 # CSS class for given age value (in seconds)
1812 sub age_class {
1813         my $age = shift;
1814
1815         if (!defined $age) {
1816                 return "noage";
1817         } elsif ($age < 60*60*2) {
1818                 return "age0";
1819         } elsif ($age < 60*60*24*2) {
1820                 return "age1";
1821         } else {
1822                 return "age2";
1823         }
1824 }
1825
1826 # convert age in seconds to "nn units ago" string
1827 sub age_string {
1828         my $age = shift;
1829         my $age_str;
1830
1831         if ($age > 60*60*24*365*2) {
1832                 $age_str = (int $age/60/60/24/365);
1833                 $age_str .= " years ago";
1834         } elsif ($age > 60*60*24*(365/12)*2) {
1835                 $age_str = int $age/60/60/24/(365/12);
1836                 $age_str .= " months ago";
1837         } elsif ($age > 60*60*24*7*2) {
1838                 $age_str = int $age/60/60/24/7;
1839                 $age_str .= " weeks ago";
1840         } elsif ($age > 60*60*24*2) {
1841                 $age_str = int $age/60/60/24;
1842                 $age_str .= " days ago";
1843         } elsif ($age > 60*60*2) {
1844                 $age_str = int $age/60/60;
1845                 $age_str .= " hours ago";
1846         } elsif ($age > 60*2) {
1847                 $age_str = int $age/60;
1848                 $age_str .= " min ago";
1849         } elsif ($age > 2) {
1850                 $age_str = int $age;
1851                 $age_str .= " sec ago";
1852         } else {
1853                 $age_str .= " right now";
1854         }
1855         return $age_str;
1856 }
1857
1858 use constant {
1859         S_IFINVALID => 0030000,
1860         S_IFGITLINK => 0160000,
1861 };
1862
1863 # submodule/subproject, a commit object reference
1864 sub S_ISGITLINK {
1865         my $mode = shift;
1866
1867         return (($mode & S_IFMT) == S_IFGITLINK)
1868 }
1869
1870 # convert file mode in octal to symbolic file mode string
1871 sub mode_str {
1872         my $mode = oct shift;
1873
1874         if (S_ISGITLINK($mode)) {
1875                 return 'm---------';
1876         } elsif (S_ISDIR($mode & S_IFMT)) {
1877                 return 'drwxr-xr-x';
1878         } elsif (S_ISLNK($mode)) {
1879                 return 'lrwxrwxrwx';
1880         } elsif (S_ISREG($mode)) {
1881                 # git cares only about the executable bit
1882                 if ($mode & S_IXUSR) {
1883                         return '-rwxr-xr-x';
1884                 } else {
1885                         return '-rw-r--r--';
1886                 };
1887         } else {
1888                 return '----------';
1889         }
1890 }
1891
1892 # convert file mode in octal to file type string
1893 sub file_type {
1894         my $mode = shift;
1895
1896         if ($mode !~ m/^[0-7]+$/) {
1897                 return $mode;
1898         } else {
1899                 $mode = oct $mode;
1900         }
1901
1902         if (S_ISGITLINK($mode)) {
1903                 return "submodule";
1904         } elsif (S_ISDIR($mode & S_IFMT)) {
1905                 return "directory";
1906         } elsif (S_ISLNK($mode)) {
1907                 return "symlink";
1908         } elsif (S_ISREG($mode)) {
1909                 return "file";
1910         } else {
1911                 return "unknown";
1912         }
1913 }
1914
1915 # convert file mode in octal to file type description string
1916 sub file_type_long {
1917         my $mode = shift;
1918
1919         if ($mode !~ m/^[0-7]+$/) {
1920                 return $mode;
1921         } else {
1922                 $mode = oct $mode;
1923         }
1924
1925         if (S_ISGITLINK($mode)) {
1926                 return "submodule";
1927         } elsif (S_ISDIR($mode & S_IFMT)) {
1928                 return "directory";
1929         } elsif (S_ISLNK($mode)) {
1930                 return "symlink";
1931         } elsif (S_ISREG($mode)) {
1932                 if ($mode & S_IXUSR) {
1933                         return "executable";
1934                 } else {
1935                         return "file";
1936                 };
1937         } else {
1938                 return "unknown";
1939         }
1940 }
1941
1942
1943 ## ----------------------------------------------------------------------
1944 ## functions returning short HTML fragments, or transforming HTML fragments
1945 ## which don't belong to other sections
1946
1947 # format line of commit message.
1948 sub format_log_line_html {
1949         my $line = shift;
1950
1951         $line = esc_html($line, -nbsp=>1);
1952         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1953                 $cgi->a({-href => href(action=>"object", hash=>$1),
1954                                         -class => "text"}, $1);
1955         }eg;
1956
1957         return $line;
1958 }
1959
1960 # format marker of refs pointing to given object
1961
1962 # the destination action is chosen based on object type and current context:
1963 # - for annotated tags, we choose the tag view unless it's the current view
1964 #   already, in which case we go to shortlog view
1965 # - for other refs, we keep the current view if we're in history, shortlog or
1966 #   log view, and select shortlog otherwise
1967 sub format_ref_marker {
1968         my ($refs, $id) = @_;
1969         my $markers = '';
1970
1971         if (defined $refs->{$id}) {
1972                 foreach my $ref (@{$refs->{$id}}) {
1973                         # this code exploits the fact that non-lightweight tags are the
1974                         # only indirect objects, and that they are the only objects for which
1975                         # we want to use tag instead of shortlog as action
1976                         my ($type, $name) = qw();
1977                         my $indirect = ($ref =~ s/\^\{\}$//);
1978                         # e.g. tags/v2.6.11 or heads/next
1979                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1980                                 $type = $1;
1981                                 $name = $2;
1982                         } else {
1983                                 $type = "ref";
1984                                 $name = $ref;
1985                         }
1986
1987                         my $class = $type;
1988                         $class .= " indirect" if $indirect;
1989
1990                         my $dest_action = "shortlog";
1991
1992                         if ($indirect) {
1993                                 $dest_action = "tag" unless $action eq "tag";
1994                         } elsif ($action =~ /^(history|(short)?log)$/) {
1995                                 $dest_action = $action;
1996                         }
1997
1998                         my $dest = "";
1999                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2000                         $dest .= $ref;
2001
2002                         my $link = $cgi->a({
2003                                 -href => href(
2004                                         action=>$dest_action,
2005                                         hash=>$dest
2006                                 )}, $name);
2007
2008                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2009                                 $link . "</span>";
2010                 }
2011         }
2012
2013         if ($markers) {
2014                 return ' <span class="refs">'. $markers . '</span>';
2015         } else {
2016                 return "";
2017         }
2018 }
2019
2020 # format, perhaps shortened and with markers, title line
2021 sub format_subject_html {
2022         my ($long, $short, $href, $extra) = @_;
2023         $extra = '' unless defined($extra);
2024
2025         if (length($short) < length($long)) {
2026                 $long =~ s/[[:cntrl:]]/?/g;
2027                 return $cgi->a({-href => $href, -class => "list subject",
2028                                 -title => to_utf8($long)},
2029                        esc_html($short)) . $extra;
2030         } else {
2031                 return $cgi->a({-href => $href, -class => "list subject"},
2032                        esc_html($long)) . $extra;
2033         }
2034 }
2035
2036 # Rather than recomputing the url for an email multiple times, we cache it
2037 # after the first hit. This gives a visible benefit in views where the avatar
2038 # for the same email is used repeatedly (e.g. shortlog).
2039 # The cache is shared by all avatar engines (currently gravatar only), which
2040 # are free to use it as preferred. Since only one avatar engine is used for any
2041 # given page, there's no risk for cache conflicts.
2042 our %avatar_cache = ();
2043
2044 # Compute the picon url for a given email, by using the picon search service over at
2045 # http://www.cs.indiana.edu/picons/search.html
2046 sub picon_url {
2047         my $email = lc shift;
2048         if (!$avatar_cache{$email}) {
2049                 my ($user, $domain) = split('@', $email);
2050                 $avatar_cache{$email} =
2051                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2052                         "$domain/$user/" .
2053                         "users+domains+unknown/up/single";
2054         }
2055         return $avatar_cache{$email};
2056 }
2057
2058 # Compute the gravatar url for a given email, if it's not in the cache already.
2059 # Gravatar stores only the part of the URL before the size, since that's the
2060 # one computationally more expensive. This also allows reuse of the cache for
2061 # different sizes (for this particular engine).
2062 sub gravatar_url {
2063         my $email = lc shift;
2064         my $size = shift;
2065         $avatar_cache{$email} ||=
2066                 "http://www.gravatar.com/avatar/" .
2067                         Digest::MD5::md5_hex($email) . "?s=";
2068         return $avatar_cache{$email} . $size;
2069 }
2070
2071 # Insert an avatar for the given $email at the given $size if the feature
2072 # is enabled.
2073 sub git_get_avatar {
2074         my ($email, %opts) = @_;
2075         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2076         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2077         $opts{-size} ||= 'default';
2078         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2079         my $url = "";
2080         if ($git_avatar eq 'gravatar') {
2081                 $url = gravatar_url($email, $size);
2082         } elsif ($git_avatar eq 'picon') {
2083                 $url = picon_url($email);
2084         }
2085         # Other providers can be added by extending the if chain, defining $url
2086         # as needed. If no variant puts something in $url, we assume avatars
2087         # are completely disabled/unavailable.
2088         if ($url) {
2089                 return $pre_white .
2090                        "<img width=\"$size\" " .
2091                             "class=\"avatar\" " .
2092                             "src=\"".esc_url($url)."\" " .
2093                             "alt=\"\" " .
2094                        "/>" . $post_white;
2095         } else {
2096                 return "";
2097         }
2098 }
2099
2100 sub format_search_author {
2101         my ($author, $searchtype, $displaytext) = @_;
2102         my $have_search = gitweb_check_feature('search');
2103
2104         if ($have_search) {
2105                 my $performed = "";
2106                 if ($searchtype eq 'author') {
2107                         $performed = "authored";
2108                 } elsif ($searchtype eq 'committer') {
2109                         $performed = "committed";
2110                 }
2111
2112                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2113                                 searchtext=>$author,
2114                                 searchtype=>$searchtype), class=>"list",
2115                                 title=>"Search for commits $performed by $author"},
2116                                 $displaytext);
2117
2118         } else {
2119                 return $displaytext;
2120         }
2121 }
2122
2123 # format the author name of the given commit with the given tag
2124 # the author name is chopped and escaped according to the other
2125 # optional parameters (see chop_str).
2126 sub format_author_html {
2127         my $tag = shift;
2128         my $co = shift;
2129         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2130         return "<$tag class=\"author\">" .
2131                format_search_author($co->{'author_name'}, "author",
2132                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2133                        $author) .
2134                "</$tag>";
2135 }
2136
2137 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2138 sub format_git_diff_header_line {
2139         my $line = shift;
2140         my $diffinfo = shift;
2141         my ($from, $to) = @_;
2142
2143         if ($diffinfo->{'nparents'}) {
2144                 # combined diff
2145                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2146                 if ($to->{'href'}) {
2147                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2148                                          esc_path($to->{'file'}));
2149                 } else { # file was deleted (no href)
2150                         $line .= esc_path($to->{'file'});
2151                 }
2152         } else {
2153                 # "ordinary" diff
2154                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2155                 if ($from->{'href'}) {
2156                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2157                                          'a/' . esc_path($from->{'file'}));
2158                 } else { # file was added (no href)
2159                         $line .= 'a/' . esc_path($from->{'file'});
2160                 }
2161                 $line .= ' ';
2162                 if ($to->{'href'}) {
2163                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2164                                          'b/' . esc_path($to->{'file'}));
2165                 } else { # file was deleted
2166                         $line .= 'b/' . esc_path($to->{'file'});
2167                 }
2168         }
2169
2170         return "<div class=\"diff header\">$line</div>\n";
2171 }
2172
2173 # format extended diff header line, before patch itself
2174 sub format_extended_diff_header_line {
2175         my $line = shift;
2176         my $diffinfo = shift;
2177         my ($from, $to) = @_;
2178
2179         # match <path>
2180         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2181                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2182                                        esc_path($from->{'file'}));
2183         }
2184         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2185                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2186                                  esc_path($to->{'file'}));
2187         }
2188         # match single <mode>
2189         if ($line =~ m/\s(\d{6})$/) {
2190                 $line .= '<span class="info"> (' .
2191                          file_type_long($1) .
2192                          ')</span>';
2193         }
2194         # match <hash>
2195         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2196                 # can match only for combined diff
2197                 $line = 'index ';
2198                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2199                         if ($from->{'href'}[$i]) {
2200                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2201                                                   -class=>"hash"},
2202                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2203                         } else {
2204                                 $line .= '0' x 7;
2205                         }
2206                         # separator
2207                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2208                 }
2209                 $line .= '..';
2210                 if ($to->{'href'}) {
2211                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2212                                          substr($diffinfo->{'to_id'},0,7));
2213                 } else {
2214                         $line .= '0' x 7;
2215                 }
2216
2217         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2218                 # can match only for ordinary diff
2219                 my ($from_link, $to_link);
2220                 if ($from->{'href'}) {
2221                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2222                                              substr($diffinfo->{'from_id'},0,7));
2223                 } else {
2224                         $from_link = '0' x 7;
2225                 }
2226                 if ($to->{'href'}) {
2227                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2228                                            substr($diffinfo->{'to_id'},0,7));
2229                 } else {
2230                         $to_link = '0' x 7;
2231                 }
2232                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2233                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2234         }
2235
2236         return $line . "<br/>\n";
2237 }
2238
2239 # format from-file/to-file diff header
2240 sub format_diff_from_to_header {
2241         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2242         my $line;
2243         my $result = '';
2244
2245         $line = $from_line;
2246         #assert($line =~ m/^---/) if DEBUG;
2247         # no extra formatting for "^--- /dev/null"
2248         if (! $diffinfo->{'nparents'}) {
2249                 # ordinary (single parent) diff
2250                 if ($line =~ m!^--- "?a/!) {
2251                         if ($from->{'href'}) {
2252                                 $line = '--- a/' .
2253                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2254                                                 esc_path($from->{'file'}));
2255                         } else {
2256                                 $line = '--- a/' .
2257                                         esc_path($from->{'file'});
2258                         }
2259                 }
2260                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2261
2262         } else {
2263                 # combined diff (merge commit)
2264                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2265                         if ($from->{'href'}[$i]) {
2266                                 $line = '--- ' .
2267                                         $cgi->a({-href=>href(action=>"blobdiff",
2268                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2269                                                              hash_parent_base=>$parents[$i],
2270                                                              file_parent=>$from->{'file'}[$i],
2271                                                              hash=>$diffinfo->{'to_id'},
2272                                                              hash_base=>$hash,
2273                                                              file_name=>$to->{'file'}),
2274                                                  -class=>"path",
2275                                                  -title=>"diff" . ($i+1)},
2276                                                 $i+1) .
2277                                         '/' .
2278                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2279                                                 esc_path($from->{'file'}[$i]));
2280                         } else {
2281                                 $line = '--- /dev/null';
2282                         }
2283                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2284                 }
2285         }
2286
2287         $line = $to_line;
2288         #assert($line =~ m/^\+\+\+/) if DEBUG;
2289         # no extra formatting for "^+++ /dev/null"
2290         if ($line =~ m!^\+\+\+ "?b/!) {
2291                 if ($to->{'href'}) {
2292                         $line = '+++ b/' .
2293                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2294                                         esc_path($to->{'file'}));
2295                 } else {
2296                         $line = '+++ b/' .
2297                                 esc_path($to->{'file'});
2298                 }
2299         }
2300         $result .= qq!<div class="diff to_file">$line</div>\n!;
2301
2302         return $result;
2303 }
2304
2305 # create note for patch simplified by combined diff
2306 sub format_diff_cc_simplified {
2307         my ($diffinfo, @parents) = @_;
2308         my $result = '';
2309
2310         $result .= "<div class=\"diff header\">" .
2311                    "diff --cc ";
2312         if (!is_deleted($diffinfo)) {
2313                 $result .= $cgi->a({-href => href(action=>"blob",
2314                                                   hash_base=>$hash,
2315                                                   hash=>$diffinfo->{'to_id'},
2316                                                   file_name=>$diffinfo->{'to_file'}),
2317                                     -class => "path"},
2318                                    esc_path($diffinfo->{'to_file'}));
2319         } else {
2320                 $result .= esc_path($diffinfo->{'to_file'});
2321         }
2322         $result .= "</div>\n" . # class="diff header"
2323                    "<div class=\"diff nodifferences\">" .
2324                    "Simple merge" .
2325                    "</div>\n"; # class="diff nodifferences"
2326
2327         return $result;
2328 }
2329
2330 sub diff_line_class {
2331         my ($line, $from, $to) = @_;
2332
2333         # ordinary diff
2334         my $num_sign = 1;
2335         # combined diff
2336         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2337                 $num_sign = scalar @{$from->{'href'}};
2338         }
2339
2340         my @diff_line_classifier = (
2341                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2342                 { regexp => qr/^\\/,               class => "incomplete"  },
2343                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2344                 # classifier for context must come before classifier add/rem,
2345                 # or we would have to use more complicated regexp, for example
2346                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2347                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2348                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2349         );
2350         for my $clsfy (@diff_line_classifier) {
2351                 return $clsfy->{'class'}
2352                         if ($line =~ $clsfy->{'regexp'});
2353         }
2354
2355         # fallback
2356         return "";
2357 }
2358
2359 # assumes that $from and $to are defined and correctly filled,
2360 # and that $line holds a line of chunk header for unified diff
2361 sub format_unidiff_chunk_header {
2362         my ($line, $from, $to) = @_;
2363
2364         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2365                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2366
2367         $from_lines = 0 unless defined $from_lines;
2368         $to_lines   = 0 unless defined $to_lines;
2369
2370         if ($from->{'href'}) {
2371                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2372                                      -class=>"list"}, $from_text);
2373         }
2374         if ($to->{'href'}) {
2375                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2376                                      -class=>"list"}, $to_text);
2377         }
2378         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2379                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2380         return $line;
2381 }
2382
2383 # assumes that $from and $to are defined and correctly filled,
2384 # and that $line holds a line of chunk header for combined diff
2385 sub format_cc_diff_chunk_header {
2386         my ($line, $from, $to) = @_;
2387
2388         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2389         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2390
2391         @from_text = split(' ', $ranges);
2392         for (my $i = 0; $i < @from_text; ++$i) {
2393                 ($from_start[$i], $from_nlines[$i]) =
2394                         (split(',', substr($from_text[$i], 1)), 0);
2395         }
2396
2397         $to_text   = pop @from_text;
2398         $to_start  = pop @from_start;
2399         $to_nlines = pop @from_nlines;
2400
2401         $line = "<span class=\"chunk_info\">$prefix ";
2402         for (my $i = 0; $i < @from_text; ++$i) {
2403                 if ($from->{'href'}[$i]) {
2404                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2405                                           -class=>"list"}, $from_text[$i]);
2406                 } else {
2407                         $line .= $from_text[$i];
2408                 }
2409                 $line .= " ";
2410         }
2411         if ($to->{'href'}) {
2412                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2413                                   -class=>"list"}, $to_text);
2414         } else {
2415                 $line .= $to_text;
2416         }
2417         $line .= " $prefix</span>" .
2418                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2419         return $line;
2420 }
2421
2422 # process patch (diff) line (not to be used for diff headers),
2423 # returning class and HTML-formatted (but not wrapped) line
2424 sub process_diff_line {
2425         my $line = shift;
2426         my ($from, $to) = @_;
2427
2428         my $diff_class = diff_line_class($line, $from, $to);
2429
2430         chomp $line;
2431         $line = untabify($line);
2432
2433         if ($from && $to && $line =~ m/^\@{2} /) {
2434                 $line = format_unidiff_chunk_header($line, $from, $to);
2435                 return $diff_class, $line;
2436
2437         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2438                 $line = format_cc_diff_chunk_header($line, $from, $to);
2439                 return $diff_class, $line;
2440
2441         }
2442         return $diff_class, esc_html($line, -nbsp=>1);
2443 }
2444
2445 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2446 # linked.  Pass the hash of the tree/commit to snapshot.
2447 sub format_snapshot_links {
2448         my ($hash) = @_;
2449         my $num_fmts = @snapshot_fmts;
2450         if ($num_fmts > 1) {
2451                 # A parenthesized list of links bearing format names.
2452                 # e.g. "snapshot (_tar.gz_ _zip_)"
2453                 return "snapshot (" . join(' ', map
2454                         $cgi->a({
2455                                 -href => href(
2456                                         action=>"snapshot",
2457                                         hash=>$hash,
2458                                         snapshot_format=>$_
2459                                 )
2460                         }, $known_snapshot_formats{$_}{'display'})
2461                 , @snapshot_fmts) . ")";
2462         } elsif ($num_fmts == 1) {
2463                 # A single "snapshot" link whose tooltip bears the format name.
2464                 # i.e. "_snapshot_"
2465                 my ($fmt) = @snapshot_fmts;
2466                 return
2467                         $cgi->a({
2468                                 -href => href(
2469                                         action=>"snapshot",
2470                                         hash=>$hash,
2471                                         snapshot_format=>$fmt
2472                                 ),
2473                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2474                         }, "snapshot");
2475         } else { # $num_fmts == 0
2476                 return undef;
2477         }
2478 }
2479
2480 ## ......................................................................
2481 ## functions returning values to be passed, perhaps after some
2482 ## transformation, to other functions; e.g. returning arguments to href()
2483
2484 # returns hash to be passed to href to generate gitweb URL
2485 # in -title key it returns description of link
2486 sub get_feed_info {
2487         my $format = shift || 'Atom';
2488         my %res = (action => lc($format));
2489
2490         # feed links are possible only for project views
2491         return unless (defined $project);
2492         # some views should link to OPML, or to generic project feed,
2493         # or don't have specific feed yet (so they should use generic)
2494         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2495
2496         my $branch;
2497         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2498         # from tag links; this also makes possible to detect branch links
2499         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2500             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2501                 $branch = $1;
2502         }
2503         # find log type for feed description (title)
2504         my $type = 'log';
2505         if (defined $file_name) {
2506                 $type  = "history of $file_name";
2507                 $type .= "/" if ($action eq 'tree');
2508                 $type .= " on '$branch'" if (defined $branch);
2509         } else {
2510                 $type = "log of $branch" if (defined $branch);
2511         }
2512
2513         $res{-title} = $type;
2514         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2515         $res{'file_name'} = $file_name;
2516
2517         return %res;
2518 }
2519
2520 ## ----------------------------------------------------------------------
2521 ## git utility subroutines, invoking git commands
2522
2523 # returns path to the core git executable and the --git-dir parameter as list
2524 sub git_cmd {
2525         $number_of_git_cmds++;
2526         return $GIT, '--git-dir='.$git_dir;
2527 }
2528
2529 # quote the given arguments for passing them to the shell
2530 # quote_command("command", "arg 1", "arg with ' and ! characters")
2531 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2532 # Try to avoid using this function wherever possible.
2533 sub quote_command {
2534         return join(' ',
2535                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2536 }
2537
2538 # get HEAD ref of given project as hash
2539 sub git_get_head_hash {
2540         return git_get_full_hash(shift, 'HEAD');
2541 }
2542
2543 sub git_get_full_hash {
2544         return git_get_hash(@_);
2545 }
2546
2547 sub git_get_short_hash {
2548         return git_get_hash(@_, '--short=7');
2549 }
2550
2551 sub git_get_hash {
2552         my ($project, $hash, @options) = @_;
2553         my $o_git_dir = $git_dir;
2554         my $retval = undef;
2555         $git_dir = "$projectroot/$project";
2556         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2557             '--verify', '-q', @options, $hash) {
2558                 $retval = <$fd>;
2559                 chomp $retval if defined $retval;
2560                 close $fd;
2561         }
2562         if (defined $o_git_dir) {
2563                 $git_dir = $o_git_dir;
2564         }
2565         return $retval;
2566 }
2567
2568 # get type of given object
2569 sub git_get_type {
2570         my $hash = shift;
2571
2572         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2573         my $type = <$fd>;
2574         close $fd or return;
2575         chomp $type;
2576         return $type;
2577 }
2578
2579 # repository configuration
2580 our $config_file = '';
2581 our %config;
2582
2583 # store multiple values for single key as anonymous array reference
2584 # single values stored directly in the hash, not as [ <value> ]
2585 sub hash_set_multi {
2586         my ($hash, $key, $value) = @_;
2587
2588         if (!exists $hash->{$key}) {
2589                 $hash->{$key} = $value;
2590         } elsif (!ref $hash->{$key}) {
2591                 $hash->{$key} = [ $hash->{$key}, $value ];
2592         } else {
2593                 push @{$hash->{$key}}, $value;
2594         }
2595 }
2596
2597 # return hash of git project configuration
2598 # optionally limited to some section, e.g. 'gitweb'
2599 sub git_parse_project_config {
2600         my $section_regexp = shift;
2601         my %config;
2602
2603         local $/ = "\0";
2604
2605         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2606                 or return;
2607
2608         while (my $keyval = <$fh>) {
2609                 chomp $keyval;
2610                 my ($key, $value) = split(/\n/, $keyval, 2);
2611
2612                 hash_set_multi(\%config, $key, $value)
2613                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2614         }
2615         close $fh;
2616
2617         return %config;
2618 }
2619
2620 # convert config value to boolean: 'true' or 'false'
2621 # no value, number > 0, 'true' and 'yes' values are true
2622 # rest of values are treated as false (never as error)
2623 sub config_to_bool {
2624         my $val = shift;
2625
2626         return 1 if !defined $val;             # section.key
2627
2628         # strip leading and trailing whitespace
2629         $val =~ s/^\s+//;
2630         $val =~ s/\s+$//;
2631
2632         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2633                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2634 }
2635
2636 # convert config value to simple decimal number
2637 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2638 # to be multiplied by 1024, 1048576, or 1073741824
2639 sub config_to_int {
2640         my $val = shift;
2641
2642         # strip leading and trailing whitespace
2643         $val =~ s/^\s+//;
2644         $val =~ s/\s+$//;
2645
2646         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2647                 $unit = lc($unit);
2648                 # unknown unit is treated as 1
2649                 return $num * ($unit eq 'g' ? 1073741824 :
2650                                $unit eq 'm' ?    1048576 :
2651                                $unit eq 'k' ?       1024 : 1);
2652         }
2653         return $val;
2654 }
2655
2656 # convert config value to array reference, if needed
2657 sub config_to_multi {
2658         my $val = shift;
2659
2660         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2661 }
2662
2663 sub git_get_project_config {
2664         my ($key, $type) = @_;
2665
2666         return unless defined $git_dir;
2667
2668         # key sanity check
2669         return unless ($key);
2670         # only subsection, if exists, is case sensitive,
2671         # and not lowercased by 'git config -z -l'
2672         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2673                 $key = join(".", lc($hi), $mi, lc($lo));
2674         } else {
2675                 $key = lc($key);
2676         }
2677         $key =~ s/^gitweb\.//;
2678         return if ($key =~ m/\W/);
2679
2680         # type sanity check
2681         if (defined $type) {
2682                 $type =~ s/^--//;
2683                 $type = undef
2684                         unless ($type eq 'bool' || $type eq 'int');
2685         }
2686
2687         # get config
2688         if (!defined $config_file ||
2689             $config_file ne "$git_dir/config") {
2690                 %config = git_parse_project_config('gitweb');
2691                 $config_file = "$git_dir/config";
2692         }
2693
2694         # check if config variable (key) exists
2695         return unless exists $config{"gitweb.$key"};
2696
2697         # ensure given type
2698         if (!defined $type) {
2699                 return $config{"gitweb.$key"};
2700         } elsif ($type eq 'bool') {
2701                 # backward compatibility: 'git config --bool' returns true/false
2702                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2703         } elsif ($type eq 'int') {
2704                 return config_to_int($config{"gitweb.$key"});
2705         }
2706         return $config{"gitweb.$key"};
2707 }
2708
2709 # get hash of given path at given ref
2710 sub git_get_hash_by_path {
2711         my $base = shift;
2712         my $path = shift || return undef;
2713         my $type = shift;
2714
2715         $path =~ s,/+$,,;
2716
2717         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2718                 or die_error(500, "Open git-ls-tree failed");
2719         my $line = <$fd>;
2720         close $fd or return undef;
2721
2722         if (!defined $line) {
2723                 # there is no tree or hash given by $path at $base
2724                 return undef;
2725         }
2726
2727         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2728         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2729         if (defined $type && $type ne $2) {
2730                 # type doesn't match
2731                 return undef;
2732         }
2733         return $3;
2734 }
2735
2736 # get path of entry with given hash at given tree-ish (ref)
2737 # used to get 'from' filename for combined diff (merge commit) for renames
2738 sub git_get_path_by_hash {
2739         my $base = shift || return;
2740         my $hash = shift || return;
2741
2742         local $/ = "\0";
2743
2744         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2745                 or return undef;
2746         while (my $line = <$fd>) {
2747                 chomp $line;
2748
2749                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2750                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2751                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2752                         close $fd;
2753                         return $1;
2754                 }
2755         }
2756         close $fd;
2757         return undef;
2758 }
2759
2760 ## ......................................................................
2761 ## git utility functions, directly accessing git repository
2762
2763 # get the value of config variable either from file named as the variable
2764 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2765 # configuration variable in the repository config file.
2766 sub git_get_file_or_project_config {
2767         my ($path, $name) = @_;
2768
2769         $git_dir = "$projectroot/$path";
2770         open my $fd, '<', "$git_dir/$name"
2771                 or return git_get_project_config($name);
2772         my $conf = <$fd>;
2773         close $fd;
2774         if (defined $conf) {
2775                 chomp $conf;
2776         }
2777         return $conf;
2778 }
2779
2780 sub git_get_project_description {
2781         my $path = shift;
2782         return git_get_file_or_project_config($path, 'description');
2783 }
2784
2785 sub git_get_project_category {
2786         my $path = shift;
2787         return git_get_file_or_project_config($path, 'category');
2788 }
2789
2790
2791 # supported formats:
2792 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2793 #   - if its contents is a number, use it as tag weight,
2794 #   - otherwise add a tag with weight 1
2795 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2796 #   the same value multiple times increases tag weight
2797 # * `gitweb.ctag' multi-valued repo config variable
2798 sub git_get_project_ctags {
2799         my $project = shift;
2800         my $ctags = {};
2801
2802         $git_dir = "$projectroot/$project";
2803         if (opendir my $dh, "$git_dir/ctags") {
2804                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2805                 foreach my $tagfile (@files) {
2806                         open my $ct, '<', $tagfile
2807                                 or next;
2808                         my $val = <$ct>;
2809                         chomp $val if $val;
2810                         close $ct;
2811
2812                         (my $ctag = $tagfile) =~ s#.*/##;
2813                         if ($val =~ /^\d+$/) {
2814                                 $ctags->{$ctag} = $val;
2815                         } else {
2816                                 $ctags->{$ctag} = 1;
2817                         }
2818                 }
2819                 closedir $dh;
2820
2821         } elsif (open my $fh, '<', "$git_dir/ctags") {
2822                 while (my $line = <$fh>) {
2823                         chomp $line;
2824                         $ctags->{$line}++ if $line;
2825                 }
2826                 close $fh;
2827
2828         } else {
2829                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2830                 foreach my $tag (@$taglist) {
2831                         $ctags->{$tag}++;
2832                 }
2833         }
2834
2835         return $ctags;
2836 }
2837
2838 # return hash, where keys are content tags ('ctags'),
2839 # and values are sum of weights of given tag in every project
2840 sub git_gather_all_ctags {
2841         my $projects = shift;
2842         my $ctags = {};
2843
2844         foreach my $p (@$projects) {
2845                 foreach my $ct (keys %{$p->{'ctags'}}) {
2846                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2847                 }
2848         }
2849
2850         return $ctags;
2851 }
2852
2853 sub git_populate_project_tagcloud {
2854         my $ctags = shift;
2855
2856         # First, merge different-cased tags; tags vote on casing
2857         my %ctags_lc;
2858         foreach (keys %$ctags) {
2859                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2860                 if (not $ctags_lc{lc $_}->{topcount}
2861                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2862                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2863                         $ctags_lc{lc $_}->{topname} = $_;
2864                 }
2865         }
2866
2867         my $cloud;
2868         my $matched = $input_params{'ctag'};
2869         if (eval { require HTML::TagCloud; 1; }) {
2870                 $cloud = HTML::TagCloud->new;
2871                 foreach my $ctag (sort keys %ctags_lc) {
2872                         # Pad the title with spaces so that the cloud looks
2873                         # less crammed.
2874                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2875                         $title =~ s/ /&nbsp;/g;
2876                         $title =~ s/^/&nbsp;/g;
2877                         $title =~ s/$/&nbsp;/g;
2878                         if (defined $matched && $matched eq $ctag) {
2879                                 $title = qq(<span class="match">$title</span>);
2880                         }
2881                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2882                                     $ctags_lc{$ctag}->{count});
2883                 }
2884         } else {
2885                 $cloud = {};
2886                 foreach my $ctag (keys %ctags_lc) {
2887                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2888                         if (defined $matched && $matched eq $ctag) {
2889                                 $title = qq(<span class="match">$title</span>);
2890                         }
2891                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2892                         $cloud->{$ctag}{ctag} =
2893                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2894                 }
2895         }
2896         return $cloud;
2897 }
2898
2899 sub git_show_project_tagcloud {
2900         my ($cloud, $count) = @_;
2901         if (ref $cloud eq 'HTML::TagCloud') {
2902                 return $cloud->html_and_css($count);
2903         } else {
2904                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2905                 return
2906                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2907                         join (', ', map {
2908                                 $cloud->{$_}->{'ctag'}
2909                         } splice(@tags, 0, $count)) .
2910                         '</div>';
2911         }
2912 }
2913
2914 sub git_get_project_url_list {
2915         my $path = shift;
2916
2917         $git_dir = "$projectroot/$path";
2918         open my $fd, '<', "$git_dir/cloneurl"
2919                 or return wantarray ?
2920                 @{ config_to_multi(git_get_project_config('url')) } :
2921                    config_to_multi(git_get_project_config('url'));
2922         my @git_project_url_list = map { chomp; $_ } <$fd>;
2923         close $fd;
2924
2925         return wantarray ? @git_project_url_list : \@git_project_url_list;
2926 }
2927
2928 sub git_get_projects_list {
2929         my $filter = shift || '';
2930         my $paranoid = shift;
2931         my @list;
2932
2933         if (-d $projects_list) {
2934                 # search in directory
2935                 my $dir = $projects_list;
2936                 # remove the trailing "/"
2937                 $dir =~ s!/+$!!;
2938                 my $pfxlen = length("$dir");
2939                 my $pfxdepth = ($dir =~ tr!/!!);
2940                 # when filtering, search only given subdirectory
2941                 if ($filter && !$paranoid) {
2942                         $dir .= "/$filter";
2943                         $dir =~ s!/+$!!;
2944                 }
2945
2946                 File::Find::find({
2947                         follow_fast => 1, # follow symbolic links
2948                         follow_skip => 2, # ignore duplicates
2949                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2950                         wanted => sub {
2951                                 # global variables
2952                                 our $project_maxdepth;
2953                                 our $projectroot;
2954                                 # skip project-list toplevel, if we get it.
2955                                 return if (m!^[/.]$!);
2956                                 # only directories can be git repositories
2957                                 return unless (-d $_);
2958                                 # don't traverse too deep (Find is super slow on os x)
2959                                 # $project_maxdepth excludes depth of $projectroot
2960                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2961                                         $File::Find::prune = 1;
2962                                         return;
2963                                 }
2964
2965                                 my $path = substr($File::Find::name, $pfxlen + 1);
2966                                 # paranoidly only filter here
2967                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2968                                         next;
2969                                 }
2970                                 # we check related file in $projectroot
2971                                 if (check_export_ok("$projectroot/$path")) {
2972                                         push @list, { path => $path };
2973                                         $File::Find::prune = 1;
2974                                 }
2975                         },
2976                 }, "$dir");
2977
2978         } elsif (-f $projects_list) {
2979                 # read from file(url-encoded):
2980                 # 'git%2Fgit.git Linus+Torvalds'
2981                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2982                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2983                 open my $fd, '<', $projects_list or return;
2984         PROJECT:
2985                 while (my $line = <$fd>) {
2986                         chomp $line;
2987                         my ($path, $owner) = split ' ', $line;
2988                         $path = unescape($path);
2989                         $owner = unescape($owner);
2990                         if (!defined $path) {
2991                                 next;
2992                         }
2993                         # if $filter is rpovided, check if $path begins with $filter
2994                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2995                                 next;
2996                         }
2997                         if (check_export_ok("$projectroot/$path")) {
2998                                 my $pr = {
2999                                         path => $path,
3000                                         owner => to_utf8($owner),
3001                                 };
3002                                 push @list, $pr;
3003                         }
3004                 }
3005                 close $fd;
3006         }
3007         return @list;
3008 }
3009
3010 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3011 # as side effects it sets 'forks' field to list of forks for forked projects
3012 sub filter_forks_from_projects_list {
3013         my $projects = shift;
3014
3015         my %trie; # prefix tree of directories (path components)
3016         # generate trie out of those directories that might contain forks
3017         foreach my $pr (@$projects) {
3018                 my $path = $pr->{'path'};
3019                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3020                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3021                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3022                 next unless (-d "$projectroot/$path"); # containing directory exists
3023                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3024
3025                 # add to trie
3026                 my @dirs = split('/', $path);
3027                 # walk the trie, until either runs out of components or out of trie
3028                 my $ref = \%trie;
3029                 while (scalar @dirs &&
3030                        exists($ref->{$dirs[0]})) {
3031                         $ref = $ref->{shift @dirs};
3032                 }
3033                 # create rest of trie structure from rest of components
3034                 foreach my $dir (@dirs) {
3035                         $ref = $ref->{$dir} = {};
3036                 }
3037                 # create end marker, store $pr as a data
3038                 $ref->{''} = $pr if (!exists $ref->{''});
3039         }
3040
3041         # filter out forks, by finding shortest prefix match for paths
3042         my @filtered;
3043  PROJECT:
3044         foreach my $pr (@$projects) {
3045                 # trie lookup
3046                 my $ref = \%trie;
3047         DIR:
3048                 foreach my $dir (split('/', $pr->{'path'})) {
3049                         if (exists $ref->{''}) {
3050                                 # found [shortest] prefix, is a fork - skip it
3051                                 push @{$ref->{''}{'forks'}}, $pr;
3052                                 next PROJECT;
3053                         }
3054                         if (!exists $ref->{$dir}) {
3055                                 # not in trie, cannot have prefix, not a fork
3056                                 push @filtered, $pr;
3057                                 next PROJECT;
3058                         }
3059                         # If the dir is there, we just walk one step down the trie.
3060                         $ref = $ref->{$dir};
3061                 }
3062                 # we ran out of trie
3063                 # (shouldn't happen: it's either no match, or end marker)
3064                 push @filtered, $pr;
3065         }
3066
3067         return @filtered;
3068 }
3069
3070 # note: fill_project_list_info must be run first,
3071 # for 'descr_long' and 'ctags' to be filled
3072 sub search_projects_list {
3073         my ($projlist, %opts) = @_;
3074         my $tagfilter  = $opts{'tagfilter'};
3075         my $search_re = $opts{'search_regexp'};
3076
3077         return @$projlist
3078                 unless ($tagfilter || $search_re);
3079
3080         # searching projects require filling to be run before it;
3081         fill_project_list_info($projlist,
3082                                $tagfilter  ? 'ctags' : (),
3083                                $search_re ? ('path', 'descr') : ());
3084         my @projects;
3085  PROJECT:
3086         foreach my $pr (@$projlist) {
3087
3088                 if ($tagfilter) {
3089                         next unless ref($pr->{'ctags'}) eq 'HASH';
3090                         next unless
3091                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3092                 }
3093
3094                 if ($search_re) {
3095                         next unless
3096                                 $pr->{'path'} =~ /$search_re/ ||
3097                                 $pr->{'descr_long'} =~ /$search_re/;
3098                 }
3099
3100                 push @projects, $pr;
3101         }
3102
3103         return @projects;
3104 }
3105
3106 our $gitweb_project_owner = undef;
3107 sub git_get_project_list_from_file {
3108
3109         return if (defined $gitweb_project_owner);
3110
3111         $gitweb_project_owner = {};
3112         # read from file (url-encoded):
3113         # 'git%2Fgit.git Linus+Torvalds'
3114         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3115         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3116         if (-f $projects_list) {
3117                 open(my $fd, '<', $projects_list);
3118                 while (my $line = <$fd>) {
3119                         chomp $line;
3120                         my ($pr, $ow) = split ' ', $line;
3121                         $pr = unescape($pr);
3122                         $ow = unescape($ow);
3123                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3124                 }
3125                 close $fd;
3126         }
3127 }
3128
3129 sub git_get_project_owner {
3130         my $project = shift;
3131         my $owner;
3132
3133         return undef unless $project;
3134         $git_dir = "$projectroot/$project";
3135
3136         if (!defined $gitweb_project_owner) {
3137                 git_get_project_list_from_file();
3138         }
3139
3140         if (exists $gitweb_project_owner->{$project}) {
3141                 $owner = $gitweb_project_owner->{$project};
3142         }
3143         if (!defined $owner){
3144                 $owner = git_get_project_config('owner');
3145         }
3146         if (!defined $owner) {
3147                 $owner = get_file_owner("$git_dir");
3148         }
3149
3150         return $owner;
3151 }
3152
3153 sub git_get_last_activity {
3154         my ($path) = @_;
3155         my $fd;
3156
3157         $git_dir = "$projectroot/$path";
3158         open($fd, "-|", git_cmd(), 'for-each-ref',
3159              '--format=%(committer)',
3160              '--sort=-committerdate',
3161              '--count=1',
3162              'refs/heads') or return;
3163         my $most_recent = <$fd>;
3164         close $fd or return;
3165         if (defined $most_recent &&
3166             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3167                 my $timestamp = $1;
3168                 my $age = time - $timestamp;
3169                 return ($age, age_string($age));
3170         }
3171         return (undef, undef);
3172 }
3173
3174 # Implementation note: when a single remote is wanted, we cannot use 'git
3175 # remote show -n' because that command always work (assuming it's a remote URL
3176 # if it's not defined), and we cannot use 'git remote show' because that would
3177 # try to make a network roundtrip. So the only way to find if that particular
3178 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3179 # and when we find what we want.
3180 sub git_get_remotes_list {
3181         my $wanted = shift;
3182         my %remotes = ();
3183
3184         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3185         return unless $fd;
3186         while (my $remote = <$fd>) {
3187                 chomp $remote;
3188                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3189                 next if $wanted and not $remote eq $wanted;
3190                 my ($url, $key) = ($1, $2);
3191
3192                 $remotes{$remote} ||= { 'heads' => () };
3193                 $remotes{$remote}{$key} = $url;
3194         }
3195         close $fd or return;
3196         return wantarray ? %remotes : \%remotes;
3197 }
3198
3199 # Takes a hash of remotes as first parameter and fills it by adding the
3200 # available remote heads for each of the indicated remotes.
3201 sub fill_remote_heads {
3202         my $remotes = shift;
3203         my @heads = map { "remotes/$_" } keys %$remotes;
3204         my @remoteheads = git_get_heads_list(undef, @heads);
3205         foreach my $remote (keys %$remotes) {
3206                 $remotes->{$remote}{'heads'} = [ grep {
3207                         $_->{'name'} =~ s!^$remote/!!
3208                         } @remoteheads ];
3209         }
3210 }
3211
3212 sub git_get_references {
3213         my $type = shift || "";
3214         my %refs;
3215         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3216         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3217         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3218                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3219                 or return;
3220
3221         while (my $line = <$fd>) {
3222                 chomp $line;
3223                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3224                         if (defined $refs{$1}) {
3225                                 push @{$refs{$1}}, $2;
3226                         } else {
3227                                 $refs{$1} = [ $2 ];
3228                         }
3229                 }
3230         }
3231         close $fd or return;
3232         return \%refs;
3233 }
3234
3235 sub git_get_rev_name_tags {
3236         my $hash = shift || return undef;
3237
3238         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3239                 or return;
3240         my $name_rev = <$fd>;
3241         close $fd;
3242
3243         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3244                 return $1;
3245         } else {
3246                 # catches also '$hash undefined' output
3247                 return undef;
3248         }
3249 }
3250
3251 ## ----------------------------------------------------------------------
3252 ## parse to hash functions
3253
3254 sub parse_date {
3255         my $epoch = shift;
3256         my $tz = shift || "-0000";
3257
3258         my %date;
3259         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3260         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3261         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3262         $date{'hour'} = $hour;
3263         $date{'minute'} = $min;
3264         $date{'mday'} = $mday;
3265         $date{'day'} = $days[$wday];
3266         $date{'month'} = $months[$mon];
3267         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3268                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3269         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3270                              $mday, $months[$mon], $hour ,$min;
3271         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3272                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3273
3274         my ($tz_sign, $tz_hour, $tz_min) =
3275                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3276         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3277         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3278         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3279         $date{'hour_local'} = $hour;
3280         $date{'minute_local'} = $min;
3281         $date{'tz_local'} = $tz;
3282         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3283                                   1900+$year, $mon+1, $mday,
3284                                   $hour, $min, $sec, $tz);
3285         return %date;
3286 }
3287
3288 sub parse_tag {
3289         my $tag_id = shift;
3290         my %tag;
3291         my @comment;
3292
3293         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3294         $tag{'id'} = $tag_id;
3295         while (my $line = <$fd>) {
3296                 chomp $line;
3297                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3298                         $tag{'object'} = $1;
3299                 } elsif ($line =~ m/^type (.+)$/) {
3300                         $tag{'type'} = $1;
3301                 } elsif ($line =~ m/^tag (.+)$/) {
3302                         $tag{'name'} = $1;
3303                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3304                         $tag{'author'} = $1;
3305                         $tag{'author_epoch'} = $2;
3306                         $tag{'author_tz'} = $3;
3307                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3308                                 $tag{'author_name'}  = $1;
3309                                 $tag{'author_email'} = $2;
3310                         } else {
3311                                 $tag{'author_name'} = $tag{'author'};
3312                         }
3313                 } elsif ($line =~ m/--BEGIN/) {
3314                         push @comment, $line;
3315                         last;
3316                 } elsif ($line eq "") {
3317                         last;
3318                 }
3319         }
3320         push @comment, <$fd>;
3321         $tag{'comment'} = \@comment;
3322         close $fd or return;
3323         if (!defined $tag{'name'}) {
3324                 return
3325         };
3326         return %tag
3327 }
3328
3329 sub parse_commit_text {
3330         my ($commit_text, $withparents) = @_;
3331         my @commit_lines = split '\n', $commit_text;
3332         my %co;
3333
3334         pop @commit_lines; # Remove '\0'
3335
3336         if (! @commit_lines) {
3337                 return;
3338         }
3339
3340         my $header = shift @commit_lines;
3341         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3342                 return;
3343         }
3344         ($co{'id'}, my @parents) = split ' ', $header;
3345         while (my $line = shift @commit_lines) {
3346                 last if $line eq "\n";
3347                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3348                         $co{'tree'} = $1;
3349                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3350                         push @parents, $1;
3351                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3352                         $co{'author'} = to_utf8($1);
3353                         $co{'author_epoch'} = $2;
3354                         $co{'author_tz'} = $3;
3355                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3356                                 $co{'author_name'}  = $1;
3357                                 $co{'author_email'} = $2;
3358                         } else {
3359                                 $co{'author_name'} = $co{'author'};
3360                         }
3361                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3362                         $co{'committer'} = to_utf8($1);
3363                         $co{'committer_epoch'} = $2;
3364                         $co{'committer_tz'} = $3;
3365                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3366                                 $co{'committer_name'}  = $1;
3367                                 $co{'committer_email'} = $2;
3368                         } else {
3369                                 $co{'committer_name'} = $co{'committer'};
3370                         }
3371                 }
3372         }
3373         if (!defined $co{'tree'}) {
3374                 return;
3375         };
3376         $co{'parents'} = \@parents;
3377         $co{'parent'} = $parents[0];
3378
3379         foreach my $title (@commit_lines) {
3380                 $title =~ s/^    //;
3381                 if ($title ne "") {
3382                         $co{'title'} = chop_str($title, 80, 5);
3383                         # remove leading stuff of merges to make the interesting part visible
3384                         if (length($title) > 50) {
3385                                 $title =~ s/^Automatic //;
3386                                 $title =~ s/^merge (of|with) /Merge ... /i;
3387                                 if (length($title) > 50) {
3388                                         $title =~ s/(http|rsync):\/\///;
3389                                 }
3390                                 if (length($title) > 50) {
3391                                         $title =~ s/(master|www|rsync)\.//;
3392                                 }
3393                                 if (length($title) > 50) {
3394                                         $title =~ s/kernel.org:?//;
3395                                 }
3396                                 if (length($title) > 50) {
3397                                         $title =~ s/\/pub\/scm//;
3398                                 }
3399                         }
3400                         $co{'title_short'} = chop_str($title, 50, 5);
3401                         last;
3402                 }
3403         }
3404         if (! defined $co{'title'} || $co{'title'} eq "") {
3405                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3406         }
3407         # remove added spaces
3408         foreach my $line (@commit_lines) {
3409                 $line =~ s/^    //;
3410         }
3411         $co{'comment'} = \@commit_lines;
3412
3413         my $age = time - $co{'committer_epoch'};
3414         $co{'age'} = $age;
3415         $co{'age_string'} = age_string($age);
3416         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3417         if ($age > 60*60*24*7*2) {
3418                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3419                 $co{'age_string_age'} = $co{'age_string'};
3420         } else {
3421                 $co{'age_string_date'} = $co{'age_string'};
3422                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3423         }
3424         return %co;
3425 }
3426
3427 sub parse_commit {
3428         my ($commit_id) = @_;
3429         my %co;
3430
3431         local $/ = "\0";
3432
3433         open my $fd, "-|", git_cmd(), "rev-list",
3434                 "--parents",
3435                 "--header",
3436                 "--max-count=1",
3437                 $commit_id,
3438                 "--",
3439                 or die_error(500, "Open git-rev-list failed");
3440         %co = parse_commit_text(<$fd>, 1);
3441         close $fd;
3442
3443         return %co;
3444 }
3445
3446 sub parse_commits {
3447         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3448         my @cos;
3449
3450         $maxcount ||= 1;
3451         $skip ||= 0;
3452
3453         local $/ = "\0";
3454
3455         open my $fd, "-|", git_cmd(), "rev-list",
3456                 "--header",
3457                 @args,
3458                 ("--max-count=" . $maxcount),
3459                 ("--skip=" . $skip),
3460                 @extra_options,
3461                 $commit_id,
3462                 "--",
3463                 ($filename ? ($filename) : ())
3464                 or die_error(500, "Open git-rev-list failed");
3465         while (my $line = <$fd>) {
3466                 my %co = parse_commit_text($line);
3467                 push @cos, \%co;
3468         }
3469         close $fd;
3470
3471         return wantarray ? @cos : \@cos;
3472 }
3473
3474 # parse line of git-diff-tree "raw" output
3475 sub parse_difftree_raw_line {
3476         my $line = shift;
3477         my %res;
3478
3479         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3480         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3481         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3482                 $res{'from_mode'} = $1;
3483                 $res{'to_mode'} = $2;
3484                 $res{'from_id'} = $3;
3485                 $res{'to_id'} = $4;
3486                 $res{'status'} = $5;
3487                 $res{'similarity'} = $6;
3488                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3489                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3490                 } else {
3491                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3492                 }
3493         }
3494         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3495         # combined diff (for merge commit)
3496         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3497                 $res{'nparents'}  = length($1);
3498                 $res{'from_mode'} = [ split(' ', $2) ];
3499                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3500                 $res{'from_id'} = [ split(' ', $3) ];
3501                 $res{'to_id'} = pop @{$res{'from_id'}};
3502                 $res{'status'} = [ split('', $4) ];
3503                 $res{'to_file'} = unquote($5);
3504         }
3505         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3506         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3507                 $res{'commit'} = $1;
3508         }
3509
3510         return wantarray ? %res : \%res;
3511 }
3512
3513 # wrapper: return parsed line of git-diff-tree "raw" output
3514 # (the argument might be raw line, or parsed info)
3515 sub parsed_difftree_line {
3516         my $line_or_ref = shift;
3517
3518         if (ref($line_or_ref) eq "HASH") {
3519                 # pre-parsed (or generated by hand)
3520                 return $line_or_ref;
3521         } else {
3522                 return parse_difftree_raw_line($line_or_ref);
3523         }
3524 }
3525
3526 # parse line of git-ls-tree output
3527 sub parse_ls_tree_line {
3528         my $line = shift;
3529         my %opts = @_;
3530         my %res;
3531
3532         if ($opts{'-l'}) {
3533                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3534                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3535
3536                 $res{'mode'} = $1;
3537                 $res{'type'} = $2;
3538                 $res{'hash'} = $3;
3539                 $res{'size'} = $4;
3540                 if ($opts{'-z'}) {
3541                         $res{'name'} = $5;
3542                 } else {
3543                         $res{'name'} = unquote($5);
3544                 }
3545         } else {
3546                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3547                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3548
3549                 $res{'mode'} = $1;
3550                 $res{'type'} = $2;
3551                 $res{'hash'} = $3;
3552                 if ($opts{'-z'}) {
3553                         $res{'name'} = $4;
3554                 } else {
3555                         $res{'name'} = unquote($4);
3556                 }
3557         }
3558
3559         return wantarray ? %res : \%res;
3560 }
3561
3562 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3563 sub parse_from_to_diffinfo {
3564         my ($diffinfo, $from, $to, @parents) = @_;
3565
3566         if ($diffinfo->{'nparents'}) {
3567                 # combined diff
3568                 $from->{'file'} = [];
3569                 $from->{'href'} = [];
3570                 fill_from_file_info($diffinfo, @parents)
3571                         unless exists $diffinfo->{'from_file'};
3572                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3573                         $from->{'file'}[$i] =
3574                                 defined $diffinfo->{'from_file'}[$i] ?
3575                                         $diffinfo->{'from_file'}[$i] :
3576                                         $diffinfo->{'to_file'};
3577                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3578                                 $from->{'href'}[$i] = href(action=>"blob",
3579                                                            hash_base=>$parents[$i],
3580                                                            hash=>$diffinfo->{'from_id'}[$i],
3581                                                            file_name=>$from->{'file'}[$i]);
3582                         } else {
3583                                 $from->{'href'}[$i] = undef;
3584                         }
3585                 }
3586         } else {
3587                 # ordinary (not combined) diff
3588                 $from->{'file'} = $diffinfo->{'from_file'};
3589                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3590                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3591                                                hash=>$diffinfo->{'from_id'},
3592                                                file_name=>$from->{'file'});
3593                 } else {
3594                         delete $from->{'href'};
3595                 }
3596         }
3597
3598         $to->{'file'} = $diffinfo->{'to_file'};
3599         if (!is_deleted($diffinfo)) { # file exists in result
3600                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3601                                      hash=>$diffinfo->{'to_id'},
3602                                      file_name=>$to->{'file'});
3603         } else {
3604                 delete $to->{'href'};
3605         }
3606 }
3607
3608 ## ......................................................................
3609 ## parse to array of hashes functions
3610
3611 sub git_get_heads_list {
3612         my ($limit, @classes) = @_;
3613         @classes = ('heads') unless @classes;
3614         my @patterns = map { "refs/$_" } @classes;
3615         my @headslist;
3616
3617         open my $fd, '-|', git_cmd(), 'for-each-ref',
3618                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3619                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3620                 @patterns
3621                 or return;
3622         while (my $line = <$fd>) {
3623                 my %ref_item;
3624
3625                 chomp $line;
3626                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3627                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3628                 my ($committer, $epoch, $tz) =
3629                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3630                 $ref_item{'fullname'}  = $name;
3631                 $name =~ s!^refs/(?:head|remote)s/!!;
3632
3633                 $ref_item{'name'}  = $name;
3634                 $ref_item{'id'}    = $hash;
3635                 $ref_item{'title'} = $title || '(no commit message)';
3636                 $ref_item{'epoch'} = $epoch;
3637                 if ($epoch) {
3638                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3639                 } else {
3640                         $ref_item{'age'} = "unknown";
3641                 }
3642
3643                 push @headslist, \%ref_item;
3644         }
3645         close $fd;
3646
3647         return wantarray ? @headslist : \@headslist;
3648 }
3649
3650 sub git_get_tags_list {
3651         my $limit = shift;
3652         my @tagslist;
3653
3654         open my $fd, '-|', git_cmd(), 'for-each-ref',
3655                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3656                 '--format=%(objectname) %(objecttype) %(refname) '.
3657                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3658                 'refs/tags'
3659                 or return;
3660         while (my $line = <$fd>) {
3661                 my %ref_item;
3662
3663                 chomp $line;
3664                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3665                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3666                 my ($creator, $epoch, $tz) =
3667                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3668                 $ref_item{'fullname'} = $name;
3669                 $name =~ s!^refs/tags/!!;
3670
3671                 $ref_item{'type'} = $type;
3672                 $ref_item{'id'} = $id;
3673                 $ref_item{'name'} = $name;
3674                 if ($type eq "tag") {
3675                         $ref_item{'subject'} = $title;
3676                         $ref_item{'reftype'} = $reftype;
3677                         $ref_item{'refid'}   = $refid;
3678                 } else {
3679                         $ref_item{'reftype'} = $type;
3680                         $ref_item{'refid'}   = $id;
3681                 }
3682
3683                 if ($type eq "tag" || $type eq "commit") {
3684                         $ref_item{'epoch'} = $epoch;
3685                         if ($epoch) {
3686                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3687                         } else {
3688                                 $ref_item{'age'} = "unknown";
3689                         }
3690                 }
3691
3692                 push @tagslist, \%ref_item;
3693         }
3694         close $fd;
3695
3696         return wantarray ? @tagslist : \@tagslist;
3697 }
3698
3699 ## ----------------------------------------------------------------------
3700 ## filesystem-related functions
3701
3702 sub get_file_owner {
3703         my $path = shift;
3704
3705         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3706         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3707         if (!defined $gcos) {
3708                 return undef;
3709         }
3710         my $owner = $gcos;
3711         $owner =~ s/[,;].*$//;
3712         return to_utf8($owner);
3713 }
3714
3715 # assume that file exists
3716 sub insert_file {
3717         my $filename = shift;
3718
3719         open my $fd, '<', $filename;
3720         print map { to_utf8($_) } <$fd>;
3721         close $fd;
3722 }
3723
3724 ## ......................................................................
3725 ## mimetype related functions
3726
3727 sub mimetype_guess_file {
3728         my $filename = shift;
3729         my $mimemap = shift;
3730         -r $mimemap or return undef;
3731
3732         my %mimemap;
3733         open(my $mh, '<', $mimemap) or return undef;
3734         while (<$mh>) {
3735                 next if m/^#/; # skip comments
3736                 my ($mimetype, @exts) = split(/\s+/);
3737                 foreach my $ext (@exts) {
3738                         $mimemap{$ext} = $mimetype;
3739                 }
3740         }
3741         close($mh);
3742
3743         $filename =~ /\.([^.]*)$/;
3744         return $mimemap{$1};
3745 }
3746
3747 sub mimetype_guess {
3748         my $filename = shift;
3749         my $mime;
3750         $filename =~ /\./ or return undef;
3751
3752         if ($mimetypes_file) {
3753                 my $file = $mimetypes_file;
3754                 if ($file !~ m!^/!) { # if it is relative path
3755                         # it is relative to project
3756                         $file = "$projectroot/$project/$file";
3757                 }
3758                 $mime = mimetype_guess_file($filename, $file);
3759         }
3760         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3761         return $mime;
3762 }
3763
3764 sub blob_mimetype {
3765         my $fd = shift;
3766         my $filename = shift;
3767
3768         if ($filename) {
3769                 my $mime = mimetype_guess($filename);
3770                 $mime and return $mime;
3771         }
3772
3773         # just in case
3774         return $default_blob_plain_mimetype unless $fd;
3775
3776         if (-T $fd) {
3777                 return 'text/plain';
3778         } elsif (! $filename) {
3779                 return 'application/octet-stream';
3780         } elsif ($filename =~ m/\.png$/i) {
3781                 return 'image/png';
3782         } elsif ($filename =~ m/\.gif$/i) {
3783                 return 'image/gif';
3784         } elsif ($filename =~ m/\.jpe?g$/i) {
3785                 return 'image/jpeg';
3786         } else {
3787                 return 'application/octet-stream';
3788         }
3789 }
3790
3791 sub blob_contenttype {
3792         my ($fd, $file_name, $type) = @_;
3793
3794         $type ||= blob_mimetype($fd, $file_name);
3795         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3796                 $type .= "; charset=$default_text_plain_charset";
3797         }
3798
3799         return $type;
3800 }
3801
3802 # guess file syntax for syntax highlighting; return undef if no highlighting
3803 # the name of syntax can (in the future) depend on syntax highlighter used
3804 sub guess_file_syntax {
3805         my ($highlight, $mimetype, $file_name) = @_;
3806         return undef unless ($highlight && defined $file_name);
3807         my $basename = basename($file_name, '.in');
3808         return $highlight_basename{$basename}
3809                 if exists $highlight_basename{$basename};
3810
3811         $basename =~ /\.([^.]*)$/;
3812         my $ext = $1 or return undef;
3813         return $highlight_ext{$ext}
3814                 if exists $highlight_ext{$ext};
3815
3816         return undef;
3817 }
3818
3819 # run highlighter and return FD of its output,
3820 # or return original FD if no highlighting
3821 sub run_highlighter {
3822         my ($fd, $highlight, $syntax) = @_;
3823         return $fd unless ($highlight && defined $syntax);
3824
3825         close $fd;
3826         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3827                   quote_command($highlight_bin).
3828                   " --replace-tabs=8 --fragment --syntax $syntax |"
3829                 or die_error(500, "Couldn't open file or run syntax highlighter");
3830         return $fd;
3831 }
3832
3833 ## ======================================================================
3834 ## functions printing HTML: header, footer, error page
3835
3836 sub get_page_title {
3837         my $title = to_utf8($site_name);
3838
3839         unless (defined $project) {
3840                 if (defined $project_filter) {
3841                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3842                 }
3843                 return $title;
3844         }
3845         $title .= " - " . to_utf8($project);
3846
3847         return $title unless (defined $action);
3848         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3849
3850         return $title unless (defined $file_name);
3851         $title .= " - " . esc_path($file_name);
3852         if ($action eq "tree" && $file_name !~ m|/$|) {
3853                 $title .= "/";
3854         }
3855
3856         return $title;
3857 }
3858
3859 sub get_content_type_html {
3860         # require explicit support from the UA if we are to send the page as
3861         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3862         # we have to do this because MSIE sometimes globs '*/*', pretending to
3863         # support xhtml+xml but choking when it gets what it asked for.
3864         if (defined $cgi->http('HTTP_ACCEPT') &&
3865             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3866             $cgi->Accept('application/xhtml+xml') != 0) {
3867                 return 'application/xhtml+xml';
3868         } else {
3869                 return 'text/html';
3870         }
3871 }
3872
3873 sub print_feed_meta {
3874         if (defined $project) {
3875                 my %href_params = get_feed_info();
3876                 if (!exists $href_params{'-title'}) {
3877                         $href_params{'-title'} = 'log';
3878                 }
3879
3880                 foreach my $format (qw(RSS Atom)) {
3881                         my $type = lc($format);
3882                         my %link_attr = (
3883                                 '-rel' => 'alternate',
3884                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3885                                 '-type' => "application/$type+xml"
3886                         );
3887
3888                         $href_params{'action'} = $type;
3889                         $link_attr{'-href'} = href(%href_params);
3890                         print "<link ".
3891                               "rel=\"$link_attr{'-rel'}\" ".
3892                               "title=\"$link_attr{'-title'}\" ".
3893                               "href=\"$link_attr{'-href'}\" ".
3894                               "type=\"$link_attr{'-type'}\" ".
3895                               "/>\n";
3896
3897                         $href_params{'extra_options'} = '--no-merges';
3898                         $link_attr{'-href'} = href(%href_params);
3899                         $link_attr{'-title'} .= ' (no merges)';
3900                         print "<link ".
3901                               "rel=\"$link_attr{'-rel'}\" ".
3902                               "title=\"$link_attr{'-title'}\" ".
3903                               "href=\"$link_attr{'-href'}\" ".
3904                               "type=\"$link_attr{'-type'}\" ".
3905                               "/>\n";
3906                 }
3907
3908         } else {
3909                 printf('<link rel="alternate" title="%s projects list" '.
3910                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3911                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3912                 printf('<link rel="alternate" title="%s projects feeds" '.
3913                        'href="%s" type="text/x-opml" />'."\n",
3914                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3915         }
3916 }
3917
3918 sub print_header_links {
3919         my $status = shift;
3920
3921         # print out each stylesheet that exist, providing backwards capability
3922         # for those people who defined $stylesheet in a config file
3923         if (defined $stylesheet) {
3924                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3925         } else {
3926                 foreach my $stylesheet (@stylesheets) {
3927                         next unless $stylesheet;
3928                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3929                 }
3930         }
3931         print_feed_meta()
3932                 if ($status eq '200 OK');
3933         if (defined $favicon) {
3934                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3935         }
3936 }
3937
3938 sub print_nav_breadcrumbs_path {
3939         my $dirprefix = undef;
3940         while (my $part = shift) {
3941                 $dirprefix .= "/" if defined $dirprefix;
3942                 $dirprefix .= $part;
3943                 print $cgi->a({-href => href(project => undef,
3944                                              project_filter => $dirprefix,
3945                                              action => "project_list")},
3946                               esc_html($part)) . " / ";
3947         }
3948 }
3949
3950 sub print_nav_breadcrumbs {
3951         my %opts = @_;
3952
3953         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3954         if (defined $project) {
3955                 my @dirname = split '/', $project;
3956                 my $projectbasename = pop @dirname;
3957                 print_nav_breadcrumbs_path(@dirname);
3958                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3959                 if (defined $action) {
3960                         my $action_print = $action ;
3961                         if (defined $opts{-action_extra}) {
3962                                 $action_print = $cgi->a({-href => href(action=>$action)},
3963                                         $action);
3964                         }
3965                         print " / $action_print";
3966                 }
3967                 if (defined $opts{-action_extra}) {
3968                         print " / $opts{-action_extra}";
3969                 }
3970                 print "\n";
3971         } elsif (defined $project_filter) {
3972                 print_nav_breadcrumbs_path(split '/', $project_filter);
3973         }
3974 }
3975
3976 sub print_search_form {
3977         if (!defined $searchtext) {
3978                 $searchtext = "";
3979         }
3980         my $search_hash;
3981         if (defined $hash_base) {
3982                 $search_hash = $hash_base;
3983         } elsif (defined $hash) {
3984                 $search_hash = $hash;
3985         } else {
3986                 $search_hash = "HEAD";
3987         }
3988         my $action = $my_uri;
3989         my $use_pathinfo = gitweb_check_feature('pathinfo');
3990         if ($use_pathinfo) {
3991                 $action .= "/".esc_url($project);
3992         }
3993         print $cgi->startform(-method => "get", -action => $action) .
3994               "<div class=\"search\">\n" .
3995               (!$use_pathinfo &&
3996               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3997               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3998               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3999               $cgi->popup_menu(-name => 'st', -default => 'commit',
4000                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4001               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4002               " search:\n",
4003               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4004               "<span title=\"Extended regular expression\">" .
4005               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4006                              -checked => $search_use_regexp) .
4007               "</span>" .
4008               "</div>" .
4009               $cgi->end_form() . "\n";
4010 }
4011
4012 sub git_header_html {
4013         my $status = shift || "200 OK";
4014         my $expires = shift;
4015         my %opts = @_;
4016
4017         my $title = get_page_title();
4018         my $content_type = get_content_type_html();
4019         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4020                            -status=> $status, -expires => $expires)
4021                 unless ($opts{'-no_http_header'});
4022         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4023         print <<EOF;
4024 <?xml version="1.0" encoding="utf-8"?>
4025 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4026 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4027 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4028 <!-- git core binaries version $git_version -->
4029 <head>
4030 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4031 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4032 <meta name="robots" content="index, nofollow"/>
4033 <title>$title</title>
4034 EOF
4035         # the stylesheet, favicon etc urls won't work correctly with path_info
4036         # unless we set the appropriate base URL
4037         if ($ENV{'PATH_INFO'}) {
4038                 print "<base href=\"".esc_url($base_url)."\" />\n";
4039         }
4040         print_header_links($status);
4041
4042         if (defined $site_html_head_string) {
4043                 print to_utf8($site_html_head_string);
4044         }
4045
4046         print "</head>\n" .
4047               "<body>\n";
4048
4049         if (defined $site_header && -f $site_header) {
4050                 insert_file($site_header);
4051         }
4052
4053         print "<div class=\"page_header\">\n";
4054         if (defined $logo) {
4055                 print $cgi->a({-href => esc_url($logo_url),
4056                                -title => $logo_label},
4057                               $cgi->img({-src => esc_url($logo),
4058                                          -width => 72, -height => 27,
4059                                          -alt => "git",
4060                                          -class => "logo"}));
4061         }
4062         print_nav_breadcrumbs(%opts);
4063         print "</div>\n";
4064
4065         my $have_search = gitweb_check_feature('search');
4066         if (defined $project && $have_search) {
4067                 print_search_form();
4068         }
4069 }
4070
4071 sub git_footer_html {
4072         my $feed_class = 'rss_logo';
4073
4074         print "<div class=\"page_footer\">\n";
4075         if (defined $project) {
4076                 my $descr = git_get_project_description($project);
4077                 if (defined $descr) {
4078                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4079                 }
4080
4081                 my %href_params = get_feed_info();
4082                 if (!%href_params) {
4083                         $feed_class .= ' generic';
4084                 }
4085                 $href_params{'-title'} ||= 'log';
4086
4087                 foreach my $format (qw(RSS Atom)) {
4088                         $href_params{'action'} = lc($format);
4089                         print $cgi->a({-href => href(%href_params),
4090                                       -title => "$href_params{'-title'} $format feed",
4091                                       -class => $feed_class}, $format)."\n";
4092                 }
4093
4094         } else {
4095                 print "<div class=\"page_footer_text\">Copyright &copy; 2013, <a href=\"http://nexus-irc.de\">Nexus-IRC.de</a></div>\n";
4096                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4097                                              project_filter => $project_filter),
4098                               -class => $feed_class}, "OPML") . " ";
4099                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4100                                              project_filter => $project_filter),
4101                               -class => $feed_class}, "TXT") . "\n";
4102         }
4103         print "</div>\n"; # class="page_footer"
4104
4105         if (defined $t0 && gitweb_check_feature('timed')) {
4106                 print "<div id=\"generating_info\">\n";
4107                 print 'This page took '.
4108                       '<span id="generating_time" class="time_span">'.
4109                       tv_interval($t0, [ gettimeofday() ]).
4110                       ' seconds </span>'.
4111                       ' and '.
4112                       '<span id="generating_cmd">'.
4113                       $number_of_git_cmds.
4114                       '</span> git commands '.
4115                       " to generate.\n";
4116                 print "</div>\n"; # class="page_footer"
4117         }
4118
4119         if (defined $site_footer && -f $site_footer) {
4120                 insert_file($site_footer);
4121         }
4122
4123         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4124         if (defined $action &&
4125             $action eq 'blame_incremental') {
4126                 print qq!<script type="text/javascript">\n!.
4127                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4128                       qq!           "!. href() .qq!");\n!.
4129                       qq!</script>\n!;
4130         } else {
4131                 my ($jstimezone, $tz_cookie, $datetime_class) =
4132                         gitweb_get_feature('javascript-timezone');
4133
4134                 print qq!<script type="text/javascript">\n!.
4135                       qq!window.onload = function () {\n!;
4136                 if (gitweb_check_feature('javascript-actions')) {
4137                         print qq!       fixLinks();\n!;
4138                 }
4139                 if ($jstimezone && $tz_cookie && $datetime_class) {
4140                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4141                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4142                 }
4143                 print qq!};\n!.
4144                       qq!</script>\n!;
4145         }
4146
4147         print "</body>\n" .
4148               "</html>";
4149 }
4150
4151 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4152 # Example: die_error(404, 'Hash not found')
4153 # By convention, use the following status codes (as defined in RFC 2616):
4154 # 400: Invalid or missing CGI parameters, or
4155 #      requested object exists but has wrong type.
4156 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4157 #      this server or project.
4158 # 404: Requested object/revision/project doesn't exist.
4159 # 500: The server isn't configured properly, or
4160 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4161 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4162 # 503: The server is currently unavailable (because it is overloaded,
4163 #      or down for maintenance).  Generally, this is a temporary state.
4164 sub die_error {
4165         my $status = shift || 500;
4166         my $error = esc_html(shift) || "Internal Server Error";
4167         my $extra = shift;
4168         my %opts = @_;
4169
4170         my %http_responses = (
4171                 400 => '400 Bad Request',
4172                 403 => '403 Forbidden',
4173                 404 => '404 Not Found',
4174                 500 => '500 Internal Server Error',
4175                 503 => '503 Service Unavailable',
4176         );
4177         git_header_html($http_responses{$status}, undef, %opts);
4178         print <<EOF;
4179 <div class="page_body">
4180 <br /><br />
4181 $status - $error
4182 <br />
4183 EOF
4184         if (defined $extra) {
4185                 print "<hr />\n" .
4186                       "$extra\n";
4187         }
4188         print "</div>\n";
4189
4190         git_footer_html();
4191         goto DONE_GITWEB
4192                 unless ($opts{'-error_handler'});
4193 }
4194
4195 ## ----------------------------------------------------------------------
4196 ## functions printing or outputting HTML: navigation
4197
4198 sub git_print_page_nav {
4199         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4200         $extra = '' if !defined $extra; # pager or formats
4201
4202         my @navs = qw(summary shortlog log commit commitdiff tree);
4203         if ($suppress) {
4204                 @navs = grep { $_ ne $suppress } @navs;
4205         }
4206
4207         my %arg = map { $_ => {action=>$_} } @navs;
4208         if (defined $head) {
4209                 for (qw(commit commitdiff)) {
4210                         $arg{$_}{'hash'} = $head;
4211                 }
4212                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4213                         for (qw(shortlog log)) {
4214                                 $arg{$_}{'hash'} = $head;
4215                         }
4216                 }
4217         }
4218
4219         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4220         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4221
4222         my @actions = gitweb_get_feature('actions');
4223         my %repl = (
4224                 '%' => '%',
4225                 'n' => $project,         # project name
4226                 'f' => $git_dir,         # project path within filesystem
4227                 'h' => $treehead || '',  # current hash ('h' parameter)
4228                 'b' => $treebase || '',  # hash base ('hb' parameter)
4229         );
4230         while (@actions) {
4231                 my ($label, $link, $pos) = splice(@actions,0,3);
4232                 # insert
4233                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4234                 # munch munch
4235                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4236                 $arg{$label}{'_href'} = $link;
4237         }
4238
4239         print "<div class=\"page_nav\">\n" .
4240                 (join " | ",
4241                  map { $_ eq $current ?
4242                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4243                  } @navs);
4244         print "<br/>\n$extra<br/>\n" .
4245               "</div>\n";
4246 }
4247
4248 # returns a submenu for the nagivation of the refs views (tags, heads,
4249 # remotes) with the current view disabled and the remotes view only
4250 # available if the feature is enabled
4251 sub format_ref_views {
4252         my ($current) = @_;
4253         my @ref_views = qw{tags heads};
4254         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4255         return join " | ", map {
4256                 $_ eq $current ? $_ :
4257                 $cgi->a({-href => href(action=>$_)}, $_)
4258         } @ref_views
4259 }
4260
4261 sub format_paging_nav {
4262         my ($action, $page, $has_next_link) = @_;
4263         my $paging_nav;
4264
4265
4266         if ($page > 0) {
4267                 $paging_nav .=
4268                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4269                         " &sdot; " .
4270                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4271                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4272         } else {
4273                 $paging_nav .= "first &sdot; prev";
4274         }
4275
4276         if ($has_next_link) {
4277                 $paging_nav .= " &sdot; " .
4278                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4279                                  -accesskey => "n", -title => "Alt-n"}, "next");
4280         } else {
4281                 $paging_nav .= " &sdot; next";
4282         }
4283
4284         return $paging_nav;
4285 }
4286
4287 ## ......................................................................
4288 ## functions printing or outputting HTML: div
4289
4290 sub git_print_header_div {
4291         my ($action, $title, $hash, $hash_base) = @_;
4292         my %args = ();
4293
4294         $args{'action'} = $action;
4295         $args{'hash'} = $hash if $hash;
4296         $args{'hash_base'} = $hash_base if $hash_base;
4297
4298         print "<div class=\"header\">\n" .
4299               $cgi->a({-href => href(%args), -class => "title"},
4300               $title ? $title : $action) .
4301               "\n</div>\n";
4302 }
4303
4304 sub format_repo_url {
4305         my ($name, $url) = @_;
4306         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4307 }
4308
4309 # Group output by placing it in a DIV element and adding a header.
4310 # Options for start_div() can be provided by passing a hash reference as the
4311 # first parameter to the function.
4312 # Options to git_print_header_div() can be provided by passing an array
4313 # reference. This must follow the options to start_div if they are present.
4314 # The content can be a scalar, which is output as-is, a scalar reference, which
4315 # is output after html escaping, an IO handle passed either as *handle or
4316 # *handle{IO}, or a function reference. In the latter case all following
4317 # parameters will be taken as argument to the content function call.
4318 sub git_print_section {
4319         my ($div_args, $header_args, $content);
4320         my $arg = shift;
4321         if (ref($arg) eq 'HASH') {
4322                 $div_args = $arg;
4323                 $arg = shift;
4324         }
4325         if (ref($arg) eq 'ARRAY') {
4326                 $header_args = $arg;
4327                 $arg = shift;
4328         }
4329         $content = $arg;
4330
4331         print $cgi->start_div($div_args);
4332         git_print_header_div(@$header_args);
4333
4334         if (ref($content) eq 'CODE') {
4335                 $content->(@_);
4336         } elsif (ref($content) eq 'SCALAR') {
4337                 print esc_html($$content);
4338         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4339                 print <$content>;
4340         } elsif (!ref($content) && defined($content)) {
4341                 print $content;
4342         }
4343
4344         print $cgi->end_div;
4345 }
4346
4347 sub format_timestamp_html {
4348         my $date = shift;
4349         my $strtime = $date->{'rfc2822'};
4350
4351         my (undef, undef, $datetime_class) =
4352                 gitweb_get_feature('javascript-timezone');
4353         if ($datetime_class) {
4354                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4355         }
4356
4357         my $localtime_format = '(%02d:%02d %s)';
4358         if ($date->{'hour_local'} < 6) {
4359                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4360         }
4361         $strtime .= ' ' .
4362                     sprintf($localtime_format,
4363                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4364
4365         return $strtime;
4366 }
4367
4368 # Outputs the author name and date in long form
4369 sub git_print_authorship {
4370         my $co = shift;
4371         my %opts = @_;
4372         my $tag = $opts{-tag} || 'div';
4373         my $author = $co->{'author_name'};
4374
4375         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4376         print "<$tag class=\"author_date\">" .
4377               format_search_author($author, "author", esc_html($author)) .
4378               " [".format_timestamp_html(\%ad)."]".
4379               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4380               "</$tag>\n";
4381 }
4382
4383 # Outputs table rows containing the full author or committer information,
4384 # in the format expected for 'commit' view (& similar).
4385 # Parameters are a commit hash reference, followed by the list of people
4386 # to output information for. If the list is empty it defaults to both
4387 # author and committer.
4388 sub git_print_authorship_rows {
4389         my $co = shift;
4390         # too bad we can't use @people = @_ || ('author', 'committer')
4391         my @people = @_;
4392         @people = ('author', 'committer') unless @people;
4393         foreach my $who (@people) {
4394                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4395                 print "<tr><td>$who</td><td>" .
4396                       format_search_author($co->{"${who}_name"}, $who,
4397                                            esc_html($co->{"${who}_name"})) . " " .
4398                       format_search_author($co->{"${who}_email"}, $who,
4399                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4400                       "</td><td rowspan=\"2\">" .
4401                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4402                       "</td></tr>\n" .
4403                       "<tr>" .
4404                       "<td></td><td>" .
4405                       format_timestamp_html(\%wd) .
4406                       "</td>" .
4407                       "</tr>\n";
4408         }
4409 }
4410
4411 sub git_print_page_path {
4412         my $name = shift;
4413         my $type = shift;
4414         my $hb = shift;
4415
4416
4417         print "<div class=\"page_path\">";
4418         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4419                       -title => 'tree root'}, to_utf8("[$project]"));
4420         print " / ";
4421         if (defined $name) {
4422                 my @dirname = split '/', $name;
4423                 my $basename = pop @dirname;
4424                 my $fullname = '';
4425
4426                 foreach my $dir (@dirname) {
4427                         $fullname .= ($fullname ? '/' : '') . $dir;
4428                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4429                                                      hash_base=>$hb),
4430                                       -title => $fullname}, esc_path($dir));
4431                         print " / ";
4432                 }
4433                 if (defined $type && $type eq 'blob') {
4434                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4435                                                      hash_base=>$hb),
4436                                       -title => $name}, esc_path($basename));
4437                 } elsif (defined $type && $type eq 'tree') {
4438                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4439                                                      hash_base=>$hb),
4440                                       -title => $name}, esc_path($basename));
4441                         print " / ";
4442                 } else {
4443                         print esc_path($basename);
4444                 }
4445         }
4446         print "<br/></div>\n";
4447 }
4448
4449 sub git_print_log {
4450         my $log = shift;
4451         my %opts = @_;
4452
4453         if ($opts{'-remove_title'}) {
4454                 # remove title, i.e. first line of log
4455                 shift @$log;
4456         }
4457         # remove leading empty lines
4458         while (defined $log->[0] && $log->[0] eq "") {
4459                 shift @$log;
4460         }
4461
4462         # print log
4463         my $signoff = 0;
4464         my $empty = 0;
4465         foreach my $line (@$log) {
4466                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4467                         $signoff = 1;
4468                         $empty = 0;
4469                         if (! $opts{'-remove_signoff'}) {
4470                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4471                                 next;
4472                         } else {
4473                                 # remove signoff lines
4474                                 next;
4475                         }
4476                 } else {
4477                         $signoff = 0;
4478                 }
4479
4480                 # print only one empty line
4481                 # do not print empty line after signoff
4482                 if ($line eq "") {
4483                         next if ($empty || $signoff);
4484                         $empty = 1;
4485                 } else {
4486                         $empty = 0;
4487                 }
4488
4489                 print format_log_line_html($line) . "<br/>\n";
4490         }
4491
4492         if ($opts{'-final_empty_line'}) {
4493                 # end with single empty line
4494                 print "<br/>\n" unless $empty;
4495         }
4496 }
4497
4498 # return link target (what link points to)
4499 sub git_get_link_target {
4500         my $hash = shift;
4501         my $link_target;
4502
4503         # read link
4504         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4505                 or return;
4506         {
4507                 local $/ = undef;
4508                 $link_target = <$fd>;
4509         }
4510         close $fd
4511                 or return;
4512
4513         return $link_target;
4514 }
4515
4516 # given link target, and the directory (basedir) the link is in,
4517 # return target of link relative to top directory (top tree);
4518 # return undef if it is not possible (including absolute links).
4519 sub normalize_link_target {
4520         my ($link_target, $basedir) = @_;
4521
4522         # absolute symlinks (beginning with '/') cannot be normalized
4523         return if (substr($link_target, 0, 1) eq '/');
4524
4525         # normalize link target to path from top (root) tree (dir)
4526         my $path;
4527         if ($basedir) {
4528                 $path = $basedir . '/' . $link_target;
4529         } else {
4530                 # we are in top (root) tree (dir)
4531                 $path = $link_target;
4532         }
4533
4534         # remove //, /./, and /../
4535         my @path_parts;
4536         foreach my $part (split('/', $path)) {
4537                 # discard '.' and ''
4538                 next if (!$part || $part eq '.');
4539                 # handle '..'
4540                 if ($part eq '..') {
4541                         if (@path_parts) {
4542                                 pop @path_parts;
4543                         } else {
4544                                 # link leads outside repository (outside top dir)
4545                                 return;
4546                         }
4547                 } else {
4548                         push @path_parts, $part;
4549                 }
4550         }
4551         $path = join('/', @path_parts);
4552
4553         return $path;
4554 }
4555
4556 # print tree entry (row of git_tree), but without encompassing <tr> element
4557 sub git_print_tree_entry {
4558         my ($t, $basedir, $hash_base, $have_blame) = @_;
4559
4560         my %base_key = ();
4561         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4562
4563         # The format of a table row is: mode list link.  Where mode is
4564         # the mode of the entry, list is the name of the entry, an href,
4565         # and link is the action links of the entry.
4566
4567         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4568         if (exists $t->{'size'}) {
4569                 print "<td class=\"size\">$t->{'size'}</td>\n";
4570         }
4571         if ($t->{'type'} eq "blob") {
4572                 print "<td class=\"list\">" .
4573                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4574                                                file_name=>"$basedir$t->{'name'}", %base_key),
4575                                 -class => "list"}, esc_path($t->{'name'}));
4576                 if (S_ISLNK(oct $t->{'mode'})) {
4577                         my $link_target = git_get_link_target($t->{'hash'});
4578                         if ($link_target) {
4579                                 my $norm_target = normalize_link_target($link_target, $basedir);
4580                                 if (defined $norm_target) {
4581                                         print " -> " .
4582                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4583                                                                      file_name=>$norm_target),
4584                                                        -title => $norm_target}, esc_path($link_target));
4585                                 } else {
4586                                         print " -> " . esc_path($link_target);
4587                                 }
4588                         }
4589                 }
4590                 print "</td>\n";
4591                 print "<td class=\"link\">";
4592                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4593                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4594                               "blob");
4595                 if ($have_blame) {
4596                         print " | " .
4597                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4598                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4599                                       "blame");
4600                 }
4601                 if (defined $hash_base) {
4602                         print " | " .
4603                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4604                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4605                                       "history");
4606                 }
4607                 print " | " .
4608                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4609                                                file_name=>"$basedir$t->{'name'}")},
4610                                 "raw");
4611                 print "</td>\n";
4612
4613         } elsif ($t->{'type'} eq "tree") {
4614                 print "<td class=\"list\">";
4615                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4616                                              file_name=>"$basedir$t->{'name'}",
4617                                              %base_key)},
4618                               esc_path($t->{'name'}));
4619                 print "</td>\n";
4620                 print "<td class=\"link\">";
4621                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4622                                              file_name=>"$basedir$t->{'name'}",
4623                                              %base_key)},
4624                               "tree");
4625                 if (defined $hash_base) {
4626                         print " | " .
4627                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4628                                                      file_name=>"$basedir$t->{'name'}")},
4629                                       "history");
4630                 }
4631                 print "</td>\n";
4632         } else {
4633                 # unknown object: we can only present history for it
4634                 # (this includes 'commit' object, i.e. submodule support)
4635                 print "<td class=\"list\">" .
4636                       esc_path($t->{'name'}) .
4637                       "</td>\n";
4638                 print "<td class=\"link\">";
4639                 if (defined $hash_base) {
4640                         print $cgi->a({-href => href(action=>"history",
4641                                                      hash_base=>$hash_base,
4642                                                      file_name=>"$basedir$t->{'name'}")},
4643                                       "history");
4644                 }
4645                 print "</td>\n";
4646         }
4647 }
4648
4649 ## ......................................................................
4650 ## functions printing large fragments of HTML
4651
4652 # get pre-image filenames for merge (combined) diff
4653 sub fill_from_file_info {
4654         my ($diff, @parents) = @_;
4655
4656         $diff->{'from_file'} = [ ];
4657         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4658         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4659                 if ($diff->{'status'}[$i] eq 'R' ||
4660                     $diff->{'status'}[$i] eq 'C') {
4661                         $diff->{'from_file'}[$i] =
4662                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4663                 }
4664         }
4665
4666         return $diff;
4667 }
4668
4669 # is current raw difftree line of file deletion
4670 sub is_deleted {
4671         my $diffinfo = shift;
4672
4673         return $diffinfo->{'to_id'} eq ('0' x 40);
4674 }
4675
4676 # does patch correspond to [previous] difftree raw line
4677 # $diffinfo  - hashref of parsed raw diff format
4678 # $patchinfo - hashref of parsed patch diff format
4679 #              (the same keys as in $diffinfo)
4680 sub is_patch_split {
4681         my ($diffinfo, $patchinfo) = @_;
4682
4683         return defined $diffinfo && defined $patchinfo
4684                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4685 }
4686
4687
4688 sub git_difftree_body {
4689         my ($difftree, $hash, @parents) = @_;
4690         my ($parent) = $parents[0];
4691         my $have_blame = gitweb_check_feature('blame');
4692         print "<div class=\"list_head\">\n";
4693         if ($#{$difftree} > 10) {
4694                 print(($#{$difftree} + 1) . " files changed:\n");
4695         }
4696         print "</div>\n";
4697
4698         print "<table class=\"" .
4699               (@parents > 1 ? "combined " : "") .
4700               "diff_tree\">\n";
4701
4702         # header only for combined diff in 'commitdiff' view
4703         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4704         if ($has_header) {
4705                 # table header
4706                 print "<thead><tr>\n" .
4707                        "<th></th><th></th>\n"; # filename, patchN link
4708                 for (my $i = 0; $i < @parents; $i++) {
4709                         my $par = $parents[$i];
4710                         print "<th>" .
4711                               $cgi->a({-href => href(action=>"commitdiff",
4712                                                      hash=>$hash, hash_parent=>$par),
4713                                        -title => 'commitdiff to parent number ' .
4714                                                   ($i+1) . ': ' . substr($par,0,7)},
4715                                       $i+1) .
4716                               "&nbsp;</th>\n";
4717                 }
4718                 print "</tr></thead>\n<tbody>\n";
4719         }
4720
4721         my $alternate = 1;
4722         my $patchno = 0;
4723         foreach my $line (@{$difftree}) {
4724                 my $diff = parsed_difftree_line($line);
4725
4726                 if ($alternate) {
4727                         print "<tr class=\"dark\">\n";
4728                 } else {
4729                         print "<tr class=\"light\">\n";
4730                 }
4731                 $alternate ^= 1;
4732
4733                 if (exists $diff->{'nparents'}) { # combined diff
4734
4735                         fill_from_file_info($diff, @parents)
4736                                 unless exists $diff->{'from_file'};
4737
4738                         if (!is_deleted($diff)) {
4739                                 # file exists in the result (child) commit
4740                                 print "<td>" .
4741                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4742                                                              file_name=>$diff->{'to_file'},
4743                                                              hash_base=>$hash),
4744                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4745                                       "</td>\n";
4746                         } else {
4747                                 print "<td>" .
4748                                       esc_path($diff->{'to_file'}) .
4749                                       "</td>\n";
4750                         }
4751
4752                         if ($action eq 'commitdiff') {
4753                                 # link to patch
4754                                 $patchno++;
4755                                 print "<td class=\"link\">" .
4756                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4757                                               "patch") .
4758                                       " | " .
4759                                       "</td>\n";
4760                         }
4761
4762                         my $has_history = 0;
4763                         my $not_deleted = 0;
4764                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4765                                 my $hash_parent = $parents[$i];
4766                                 my $from_hash = $diff->{'from_id'}[$i];
4767                                 my $from_path = $diff->{'from_file'}[$i];
4768                                 my $status = $diff->{'status'}[$i];
4769
4770                                 $has_history ||= ($status ne 'A');
4771                                 $not_deleted ||= ($status ne 'D');
4772
4773                                 if ($status eq 'A') {
4774                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4775                                 } elsif ($status eq 'D') {
4776                                         print "<td class=\"link\">" .
4777                                               $cgi->a({-href => href(action=>"blob",
4778                                                                      hash_base=>$hash,
4779                                                                      hash=>$from_hash,
4780                                                                      file_name=>$from_path)},
4781                                                       "blob" . ($i+1)) .
4782                                               " | </td>\n";
4783                                 } else {
4784                                         if ($diff->{'to_id'} eq $from_hash) {
4785                                                 print "<td class=\"link nochange\">";
4786                                         } else {
4787                                                 print "<td class=\"link\">";
4788                                         }
4789                                         print $cgi->a({-href => href(action=>"blobdiff",
4790                                                                      hash=>$diff->{'to_id'},
4791                                                                      hash_parent=>$from_hash,
4792                                                                      hash_base=>$hash,
4793                                                                      hash_parent_base=>$hash_parent,
4794                                                                      file_name=>$diff->{'to_file'},
4795                                                                      file_parent=>$from_path)},
4796                                                       "diff" . ($i+1)) .
4797                                               " | </td>\n";
4798                                 }
4799                         }
4800
4801                         print "<td class=\"link\">";
4802                         if ($not_deleted) {
4803                                 print $cgi->a({-href => href(action=>"blob",
4804                                                              hash=>$diff->{'to_id'},
4805                                                              file_name=>$diff->{'to_file'},
4806                                                              hash_base=>$hash)},
4807                                               "blob");
4808                                 print " | " if ($has_history);
4809                         }
4810                         if ($has_history) {
4811                                 print $cgi->a({-href => href(action=>"history",
4812                                                              file_name=>$diff->{'to_file'},
4813                                                              hash_base=>$hash)},
4814                                               "history");
4815                         }
4816                         print "</td>\n";
4817
4818                         print "</tr>\n";
4819                         next; # instead of 'else' clause, to avoid extra indent
4820                 }
4821                 # else ordinary diff
4822
4823                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4824                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4825                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4826                         $to_mode_oct = oct $diff->{'to_mode'};
4827                         if (S_ISREG($to_mode_oct)) { # only for regular file
4828                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4829                         }
4830                         $to_file_type = file_type($diff->{'to_mode'});
4831                 }
4832                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4833                         $from_mode_oct = oct $diff->{'from_mode'};
4834                         if (S_ISREG($from_mode_oct)) { # only for regular file
4835                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4836                         }
4837                         $from_file_type = file_type($diff->{'from_mode'});
4838                 }
4839
4840                 if ($diff->{'status'} eq "A") { # created
4841                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4842                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4843                         $mode_chng   .= "]</span>";
4844                         print "<td>";
4845                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4846                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4847                                       -class => "list"}, esc_path($diff->{'file'}));
4848                         print "</td>\n";
4849                         print "<td>$mode_chng</td>\n";
4850                         print "<td class=\"link\">";
4851                         if ($action eq 'commitdiff') {
4852                                 # link to patch
4853                                 $patchno++;
4854                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4855                                               "patch") .
4856                                       " | ";
4857                         }
4858                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4859                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4860                                       "blob");
4861                         print "</td>\n";
4862
4863                 } elsif ($diff->{'status'} eq "D") { # deleted
4864                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4865                         print "<td>";
4866                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4867                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4868                                        -class => "list"}, esc_path($diff->{'file'}));
4869                         print "</td>\n";
4870                         print "<td>$mode_chng</td>\n";
4871                         print "<td class=\"link\">";
4872                         if ($action eq 'commitdiff') {
4873                                 # link to patch
4874                                 $patchno++;
4875                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4876                                               "patch") .
4877                                       " | ";
4878                         }
4879                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4880                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4881                                       "blob") . " | ";
4882                         if ($have_blame) {
4883                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4884                                                              file_name=>$diff->{'file'})},
4885                                               "blame") . " | ";
4886                         }
4887                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4888                                                      file_name=>$diff->{'file'})},
4889                                       "history");
4890                         print "</td>\n";
4891
4892                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4893                         my $mode_chnge = "";
4894                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4895                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4896                                 if ($from_file_type ne $to_file_type) {
4897                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4898                                 }
4899                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4900                                         if ($from_mode_str && $to_mode_str) {
4901                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4902                                         } elsif ($to_mode_str) {
4903                                                 $mode_chnge .= " mode: $to_mode_str";
4904                                         }
4905                                 }
4906                                 $mode_chnge .= "]</span>\n";
4907                         }
4908                         print "<td>";
4909                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4910                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4911                                       -class => "list"}, esc_path($diff->{'file'}));
4912                         print "</td>\n";
4913                         print "<td>$mode_chnge</td>\n";
4914                         print "<td class=\"link\">";
4915                         if ($action eq 'commitdiff') {
4916                                 # link to patch
4917                                 $patchno++;
4918                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4919                                               "patch") .
4920                                       " | ";
4921                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4922                                 # "commit" view and modified file (not onlu mode changed)
4923                                 print $cgi->a({-href => href(action=>"blobdiff",
4924                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4925                                                              hash_base=>$hash, hash_parent_base=>$parent,
4926                                                              file_name=>$diff->{'file'})},
4927                                               "diff") .
4928                                       " | ";
4929                         }
4930                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4931                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4932                                        "blob") . " | ";
4933                         if ($have_blame) {
4934                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4935                                                              file_name=>$diff->{'file'})},
4936                                               "blame") . " | ";
4937                         }
4938                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4939                                                      file_name=>$diff->{'file'})},
4940                                       "history");
4941                         print "</td>\n";
4942
4943                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4944                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4945                         my $nstatus = $status_name{$diff->{'status'}};
4946                         my $mode_chng = "";
4947                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4948                                 # mode also for directories, so we cannot use $to_mode_str
4949                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4950                         }
4951                         print "<td>" .
4952                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4953                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4954                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4955                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4956                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4957                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4958                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4959                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4960                               "<td class=\"link\">";
4961                         if ($action eq 'commitdiff') {
4962                                 # link to patch
4963                                 $patchno++;
4964                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4965                                               "patch") .
4966                                       " | ";
4967                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4968                                 # "commit" view and modified file (not only pure rename or copy)
4969                                 print $cgi->a({-href => href(action=>"blobdiff",
4970                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4971                                                              hash_base=>$hash, hash_parent_base=>$parent,
4972                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4973                                               "diff") .
4974                                       " | ";
4975                         }
4976                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4977                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4978                                       "blob") . " | ";
4979                         if ($have_blame) {
4980                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4981                                                              file_name=>$diff->{'to_file'})},
4982                                               "blame") . " | ";
4983                         }
4984                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4985                                                     file_name=>$diff->{'to_file'})},
4986                                       "history");
4987                         print "</td>\n";
4988
4989                 } # we should not encounter Unmerged (U) or Unknown (X) status
4990                 print "</tr>\n";
4991         }
4992         print "</tbody>" if $has_header;
4993         print "</table>\n";
4994 }
4995
4996 sub print_sidebyside_diff_chunk {
4997         my @chunk = @_;
4998         my (@ctx, @rem, @add);
4999
5000         return unless @chunk;
5001
5002         # incomplete last line might be among removed or added lines,
5003         # or both, or among context lines: find which
5004         for (my $i = 1; $i < @chunk; $i++) {
5005                 if ($chunk[$i][0] eq 'incomplete') {
5006                         $chunk[$i][0] = $chunk[$i-1][0];
5007                 }
5008         }
5009
5010         # guardian
5011         push @chunk, ["", ""];
5012
5013         foreach my $line_info (@chunk) {
5014                 my ($class, $line) = @$line_info;
5015
5016                 # print chunk headers
5017                 if ($class && $class eq 'chunk_header') {
5018                         print $line;
5019                         next;
5020                 }
5021
5022                 ## print from accumulator when type of class of lines change
5023                 # empty contents block on start rem/add block, or end of chunk
5024                 if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
5025                         print join '',
5026                                 '<div class="chunk_block ctx">',
5027                                         '<div class="old">',
5028                                         @ctx,
5029                                         '</div>',
5030                                         '<div class="new">',
5031                                         @ctx,
5032                                         '</div>',
5033                                 '</div>';
5034                         @ctx = ();
5035                 }
5036                 # empty add/rem block on start context block, or end of chunk
5037                 if ((@rem || @add) && (!$class || $class eq 'ctx')) {
5038                         if (!@add) {
5039                                 # pure removal
5040                                 print join '',
5041                                         '<div class="chunk_block rem">',
5042                                                 '<div class="old">',
5043                                                 @rem,
5044                                                 '</div>',
5045                                         '</div>';
5046                         } elsif (!@rem) {
5047                                 # pure addition
5048                                 print join '',
5049                                         '<div class="chunk_block add">',
5050                                                 '<div class="new">',
5051                                                 @add,
5052                                                 '</div>',
5053                                         '</div>';
5054                         } else {
5055                                 # assume that it is change
5056                                 print join '',
5057                                         '<div class="chunk_block chg">',
5058                                                 '<div class="old">',
5059                                                 @rem,
5060                                                 '</div>',
5061                                                 '<div class="new">',
5062                                                 @add,
5063                                                 '</div>',
5064                                         '</div>';
5065                         }
5066                         @rem = @add = ();
5067                 }
5068
5069                 ## adding lines to accumulator
5070                 # guardian value
5071                 last unless $line;
5072                 # rem, add or change
5073                 if ($class eq 'rem') {
5074                         push @rem, $line;
5075                 } elsif ($class eq 'add') {
5076                         push @add, $line;
5077                 }
5078                 # context line
5079                 if ($class eq 'ctx') {
5080                         push @ctx, $line;
5081                 }
5082         }
5083 }
5084
5085 sub git_patchset_body {
5086         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5087         my ($hash_parent) = $hash_parents[0];
5088
5089         my $is_combined = (@hash_parents > 1);
5090         my $patch_idx = 0;
5091         my $patch_number = 0;
5092         my $patch_line;
5093         my $diffinfo;
5094         my $to_name;
5095         my (%from, %to);
5096         my @chunk; # for side-by-side diff
5097
5098         print "<div class=\"patchset\">\n";
5099
5100         # skip to first patch
5101         while ($patch_line = <$fd>) {
5102                 chomp $patch_line;
5103
5104                 last if ($patch_line =~ m/^diff /);
5105         }
5106
5107  PATCH:
5108         while ($patch_line) {
5109
5110                 # parse "git diff" header line
5111                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5112                         # $1 is from_name, which we do not use
5113                         $to_name = unquote($2);
5114                         $to_name =~ s!^b/!!;
5115                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5116                         # $1 is 'cc' or 'combined', which we do not use
5117                         $to_name = unquote($2);
5118                 } else {
5119                         $to_name = undef;
5120                 }
5121
5122                 # check if current patch belong to current raw line
5123                 # and parse raw git-diff line if needed
5124                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5125                         # this is continuation of a split patch
5126                         print "<div class=\"patch cont\">\n";
5127                 } else {
5128                         # advance raw git-diff output if needed
5129                         $patch_idx++ if defined $diffinfo;
5130
5131                         # read and prepare patch information
5132                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5133
5134                         # compact combined diff output can have some patches skipped
5135                         # find which patch (using pathname of result) we are at now;
5136                         if ($is_combined) {
5137                                 while ($to_name ne $diffinfo->{'to_file'}) {
5138                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5139                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5140                                               "</div>\n";  # class="patch"
5141
5142                                         $patch_idx++;
5143                                         $patch_number++;
5144
5145                                         last if $patch_idx > $#$difftree;
5146                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5147                                 }
5148                         }
5149
5150                         # modifies %from, %to hashes
5151                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5152
5153                         # this is first patch for raw difftree line with $patch_idx index
5154                         # we index @$difftree array from 0, but number patches from 1
5155                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5156                 }
5157
5158                 # git diff header
5159                 #assert($patch_line =~ m/^diff /) if DEBUG;
5160                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5161                 $patch_number++;
5162                 # print "git diff" header
5163                 print format_git_diff_header_line($patch_line, $diffinfo,
5164                                                   \%from, \%to);
5165
5166                 # print extended diff header
5167                 print "<div class=\"diff extended_header\">\n";
5168         EXTENDED_HEADER:
5169                 while ($patch_line = <$fd>) {
5170                         chomp $patch_line;
5171
5172                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5173
5174                         print format_extended_diff_header_line($patch_line, $diffinfo,
5175                                                                \%from, \%to);
5176                 }
5177                 print "</div>\n"; # class="diff extended_header"
5178
5179                 # from-file/to-file diff header
5180                 if (! $patch_line) {
5181                         print "</div>\n"; # class="patch"
5182                         last PATCH;
5183                 }
5184                 next PATCH if ($patch_line =~ m/^diff /);
5185                 #assert($patch_line =~ m/^---/) if DEBUG;
5186
5187                 my $last_patch_line = $patch_line;
5188                 $patch_line = <$fd>;
5189                 chomp $patch_line;
5190                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5191
5192                 print format_diff_from_to_header($last_patch_line, $patch_line,
5193                                                  $diffinfo, \%from, \%to,
5194                                                  @hash_parents);
5195
5196                 # the patch itself
5197         LINE:
5198                 while ($patch_line = <$fd>) {
5199                         chomp $patch_line;
5200
5201                         next PATCH if ($patch_line =~ m/^diff /);
5202
5203                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5204                         my $diff_classes = "diff";
5205                         $diff_classes .= " $class" if ($class);
5206                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5207
5208                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5209                                 if ($class eq 'chunk_header') {
5210                                         print_sidebyside_diff_chunk(@chunk);
5211                                         @chunk = ( [ $class, $line ] );
5212                                 } else {
5213                                         push @chunk, [ $class, $line ];
5214                                 }
5215                         } else {
5216                                 # default 'inline' style and unknown styles
5217                                 print $line;
5218                         }
5219                 }
5220
5221         } continue {
5222                 if (@chunk) {
5223                         print_sidebyside_diff_chunk(@chunk);
5224                         @chunk = ();
5225                 }
5226                 print "</div>\n"; # class="patch"
5227         }
5228
5229         # for compact combined (--cc) format, with chunk and patch simplification
5230         # the patchset might be empty, but there might be unprocessed raw lines
5231         for (++$patch_idx if $patch_number > 0;
5232              $patch_idx < @$difftree;
5233              ++$patch_idx) {
5234                 # read and prepare patch information
5235                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5236
5237                 # generate anchor for "patch" links in difftree / whatchanged part
5238                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5239                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5240                       "</div>\n";  # class="patch"
5241
5242                 $patch_number++;
5243         }
5244
5245         if ($patch_number == 0) {
5246                 if (@hash_parents > 1) {
5247                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5248                 } else {
5249                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5250                 }
5251         }
5252
5253         print "</div>\n"; # class="patchset"
5254 }
5255
5256 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5257
5258 sub git_project_search_form {
5259         my ($searchtext, $search_use_regexp) = @_;
5260
5261         my $limit = '';
5262         if ($project_filter) {
5263                 $limit = " in '$project_filter/'";
5264         }
5265
5266         print "<div class=\"projsearch\">\n";
5267         print $cgi->startform(-method => 'get', -action => $my_uri) .
5268               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5269         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5270                 if (defined $project_filter);
5271         print $cgi->textfield(-name => 's', -value => $searchtext,
5272                               -title => "Search project by name and description$limit",
5273                               -size => 20) . "\n" .
5274               "<span title=\"Extended regular expression\">" .
5275               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5276                              -checked => $search_use_regexp) .
5277               "</span>\n" .
5278               $cgi->submit(-name => 'btnS', -value => 'Search') .
5279               $cgi->end_form() . "\n" .
5280               $cgi->a({-href => href(project => undef, searchtext => undef,
5281                                      project_filter => $project_filter)},
5282                      ) . "<br />\n";
5283         print "</div>\n";
5284 }
5285
5286 # entry for given @keys needs filling if at least one of keys in list
5287 # is not present in %$project_info
5288 sub project_info_needs_filling {
5289         my ($project_info, @keys) = @_;
5290
5291         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5292         foreach my $key (@keys) {
5293                 if (!exists $project_info->{$key}) {
5294                         return 1;
5295                 }
5296         }
5297         return;
5298 }
5299
5300 # fills project list info (age, description, owner, category, forks, etc.)
5301 # for each project in the list, removing invalid projects from
5302 # returned list, or fill only specified info.
5303 #
5304 # Invalid projects are removed from the returned list if and only if you
5305 # ask 'age' or 'age_string' to be filled, because they are the only fields
5306 # that run unconditionally git command that requires repository, and
5307 # therefore do always check if project repository is invalid.
5308 #
5309 # USAGE:
5310 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5311 #   ensures that 'descr_long' and 'ctags' fields are filled
5312 # * @project_list = fill_project_list_info(\@project_list)
5313 #   ensures that all fields are filled (and invalid projects removed)
5314 #
5315 # NOTE: modifies $projlist, but does not remove entries from it
5316 sub fill_project_list_info {
5317         my ($projlist, @wanted_keys) = @_;
5318         my @projects;
5319         my $filter_set = sub { return @_; };
5320         if (@wanted_keys) {
5321                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5322                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5323         }
5324
5325         my $show_ctags = gitweb_check_feature('ctags');
5326  PROJECT:
5327         foreach my $pr (@$projlist) {
5328                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5329                         my (@activity) = git_get_last_activity($pr->{'path'});
5330                         unless (@activity) {
5331                                 next PROJECT;
5332                         }
5333                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5334                 }
5335                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5336                         my $descr = git_get_project_description($pr->{'path'}) || "";
5337                         $descr = to_utf8($descr);
5338                         $pr->{'descr_long'} = $descr;
5339                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5340                 }
5341                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5342                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5343                 }
5344                 if ($show_ctags &&
5345                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5346                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5347                 }
5348                 if ($projects_list_group_categories &&
5349                     project_info_needs_filling($pr, $filter_set->('category'))) {
5350                         my $cat = git_get_project_category($pr->{'path'}) ||
5351                                                            $project_list_default_category;
5352                         $pr->{'category'} = to_utf8($cat);
5353                 }
5354
5355                 push @projects, $pr;
5356         }
5357
5358         return @projects;
5359 }
5360
5361 sub sort_projects_list {
5362         my ($projlist, $order) = @_;
5363         my @projects;
5364
5365         my %order_info = (
5366                 project => { key => 'path', type => 'str' },
5367                 descr => { key => 'descr_long', type => 'str' },
5368                 owner => { key => 'owner', type => 'str' },
5369                 age => { key => 'age', type => 'num' }
5370         );
5371         my $oi = $order_info{$order};
5372         return @$projlist unless defined $oi;
5373         if ($oi->{'type'} eq 'str') {
5374                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5375         } else {
5376                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5377         }
5378
5379         return @projects;
5380 }
5381
5382 # returns a hash of categories, containing the list of project
5383 # belonging to each category
5384 sub build_projlist_by_category {
5385         my ($projlist, $from, $to) = @_;
5386         my %categories;
5387
5388         $from = 0 unless defined $from;
5389         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5390
5391         for (my $i = $from; $i <= $to; $i++) {
5392                 my $pr = $projlist->[$i];
5393                 push @{$categories{ $pr->{'category'} }}, $pr;
5394         }
5395
5396         return wantarray ? %categories : \%categories;
5397 }
5398
5399 # print 'sort by' <th> element, generating 'sort by $name' replay link
5400 # if that order is not selected
5401 sub print_sort_th {
5402         print format_sort_th(@_);
5403 }
5404
5405 sub format_sort_th {
5406         my ($name, $order, $header) = @_;
5407         my $sort_th = "";
5408         $header ||= ucfirst($name);
5409
5410         if ($order eq $name) {
5411                 $sort_th .= "<th>$header</th>\n";
5412         } else {
5413                 $sort_th .= "<th>" .
5414                             $cgi->a({-href => href(-replay=>1, order=>$name),
5415                                      -class => "header"}, $header) .
5416                             "</th>\n";
5417         }
5418
5419         return $sort_th;
5420 }
5421
5422 sub git_project_list_rows {
5423         my ($projlist, $from, $to, $check_forks) = @_;
5424
5425         $from = 0 unless defined $from;
5426         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5427         my $count;
5428         my $alternate = 1;
5429         for (my $i = $from; $i <= $to; $i++) {
5430                 my $pr = $projlist->[$i];
5431                 $count++;
5432                 if ($alternate) {
5433                         print "<tr class=\"dark\">\n";
5434                 } else {
5435                         print "<tr class=\"light\">\n";
5436                 }
5437                 $alternate ^= 1;
5438
5439                 if ($check_forks) {
5440                         print "<td>";
5441                         if ($pr->{'forks'}) {
5442                                 my $nforks = scalar @{$pr->{'forks'}};
5443                                 if ($nforks > 0) {
5444                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5445                                                        -title => "$nforks forks"}, "+");
5446                                 } else {
5447                                         print $cgi->span({-title => "$nforks forks"}, "+");
5448                                 }
5449                         }
5450                         print "</td>\n";
5451                 }
5452                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5453                                         -class => "list"},
5454                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5455                       "</td>\n" .
5456                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5457                                         -class => "list",
5458                                         -title => $pr->{'descr_long'}},
5459                                         $search_regexp
5460                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5461                                                                     $pr->{'descr'}, $search_regexp)
5462                                         : esc_html($pr->{'descr'})) .
5463                       "</td>\n" .
5464                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5465                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5466                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5467                       "<td class=\"link\">" .
5468                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5469                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5470                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5471                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5472                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5473                       "</td>\n" .
5474                       "</tr>\n";
5475         }
5476         print "<tr><td>&nbsp;</td><td>&nbsp;</td><td>".$count." projects found</td><td>&nbsp;</td><td>&nbsp;</td></tr>";
5477 }
5478
5479 sub git_project_list_body {
5480         # actually uses global variable $project
5481         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5482         my @projects = @$projlist;
5483
5484         my $check_forks = gitweb_check_feature('forks');
5485         my $show_ctags  = gitweb_check_feature('ctags');
5486         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5487         $check_forks = undef
5488                 if ($tagfilter || $search_regexp);
5489
5490         # filtering out forks before filling info allows to do less work
5491         @projects = filter_forks_from_projects_list(\@projects)
5492                 if ($check_forks);
5493         # search_projects_list pre-fills required info
5494         @projects = search_projects_list(\@projects,
5495                                          'search_regexp' => $search_regexp,
5496                                          'tagfilter'  => $tagfilter)
5497                 if ($tagfilter || $search_regexp);
5498         # fill the rest
5499         @projects = fill_project_list_info(\@projects);
5500
5501         $order ||= $default_projects_order;
5502         $from = 0 unless defined $from;
5503         $to = $#projects if (!defined $to || $#projects < $to);
5504
5505         # short circuit
5506         if ($from > $to) {
5507                 print "<center>\n".
5508                       "<b>No such projects found</b><br />\n".
5509                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5510                       "</center>\n<br />\n";
5511                 return;
5512         }
5513
5514         @projects = sort_projects_list(\@projects, $order);
5515
5516         if ($show_ctags) {
5517                 my $ctags = git_gather_all_ctags(\@projects);
5518                 my $cloud = git_populate_project_tagcloud($ctags);
5519                 print git_show_project_tagcloud($cloud, 64);
5520         }
5521
5522         print "<table class=\"project_list\">\n";
5523         unless ($no_header) {
5524                 print "<tr>\n";
5525                 if ($check_forks) {
5526                         print "<th></th>\n";
5527                 }
5528                 print_sort_th('project', $order, 'Project');
5529                 print_sort_th('descr', $order, 'Description');
5530                 print_sort_th('owner', $order, 'Owner');
5531                 print_sort_th('age', $order, 'Last Change');
5532                 print "<th></th>\n" . # for links
5533                       "</tr>\n";
5534         }
5535
5536         if ($projects_list_group_categories) {
5537                 # only display categories with projects in the $from-$to window
5538                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5539                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5540                 foreach my $cat (sort keys %categories) {
5541                         unless ($cat eq "") {
5542                                 print "<tr>\n";
5543                                 if ($check_forks) {
5544                                         print "<td></td>\n";
5545                                 }
5546                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5547                                 print "</tr>\n";
5548                         }
5549
5550                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5551                 }
5552         } else {
5553                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5554         }
5555
5556         if (defined $extra) {
5557                 print "<tr>\n";
5558                 if ($check_forks) {
5559                         print "<td></td>\n";
5560                 }
5561                 print "<td colspan=\"5\">$extra</td>\n" .
5562                       "</tr>\n";
5563         }
5564         print "</table>\n";
5565 }
5566
5567 sub git_log_body {
5568         # uses global variable $project
5569         my ($commitlist, $from, $to, $refs, $extra) = @_;
5570
5571         $from = 0 unless defined $from;
5572         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5573
5574         for (my $i = 0; $i <= $to; $i++) {
5575                 my %co = %{$commitlist->[$i]};
5576                 next if !%co;
5577                 my $commit = $co{'id'};
5578                 my $ref = format_ref_marker($refs, $commit);
5579                 git_print_header_div('commit',
5580                                "<span class=\"age\">$co{'age_string'}</span>" .
5581                                esc_html($co{'title'}) . $ref,
5582                                $commit);
5583                 print "<div class=\"title_text\">\n" .
5584                       "<div class=\"log_link\">\n" .
5585                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5586                       " | " .
5587                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5588                       " | " .
5589                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5590                       "<br/>\n" .
5591                       "</div>\n";
5592                       git_print_authorship(\%co, -tag => 'span');
5593                       print "<br/>\n</div>\n";
5594
5595                 print "<div class=\"log_body\">\n";
5596                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5597                 print "</div>\n";
5598         }
5599         if ($extra) {
5600                 print "<div class=\"page_nav\">\n";
5601                 print "$extra\n";
5602                 print "</div>\n";
5603         }
5604 }
5605
5606 sub git_shortlog_body {
5607         # uses global variable $project
5608         my ($commitlist, $from, $to, $refs, $extra, $file_name, $file_hash, $ftype, $allrefs) = @_;
5609
5610         $from = 0 unless defined $from;
5611         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5612
5613         print "<table class=\"shortlog\" cellspacing=\"0\" cellpadding=\"0\">\n";
5614         my $alternate = 1;
5615         my $graph_rand = int(rand(99999));
5616         my $head = git_get_head_hash($project);
5617         my $graph_hash;
5618         if (defined $allrefs && $allrefs == 1) {
5619                 $graph_hash = "all";
5620         }
5621         if (!defined $hash) {
5622                 $hash = $head;
5623         }
5624         if(!defined $graph_hash) {
5625                 $graph_hash = $hash;
5626         }
5627         if (!defined $page) {
5628                 $page = 0;
5629         }
5630         print "<tr class=\"header\">\n";
5631         print "<td colspan=\"2\"><img class=\"graph\" src=\"git_graph.php?r=".$graph_rand.";p=".$project.";h=".$graph_hash.";from=".($from + (100 * $page)).";to=".($to + (100 * $page)).";c=header\" /></td>\n";
5632         print "<td valign=\"bottom\"><b>Author</b></td>\n";
5633         print "<td valign=\"bottom\"><b>Commit</b></td>\n";
5634         print "<td></td>\n";
5635         print "</tr>\n";
5636
5637         for (my $i = $from; $i <= $to; $i++) {
5638                 my %co = %{$commitlist->[$i]};
5639                 my $commit = $co{'id'};
5640                 my $ref = format_ref_marker($refs, $commit);
5641                 if ($alternate) {
5642                         print "<tr class=\"dark\">\n";
5643                 } else {
5644                         print "<tr class=\"light\">\n";
5645                 }
5646                 $alternate ^= 1;
5647                 print "<td><img class=\"graph\" src=\"git_graph.php?r=".$graph_rand.";p=".$project.";h=".$graph_hash.";from=".($from + (100 * $page)).";to=".($to + (100 * $page)).";c=".$commit."\" /></td>";
5648                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5649                 print "<td class=\"". age_class($co{'age'}) . "\" title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5650                       format_author_html('td', \%co, 10) . "<td>";
5651                 print format_subject_html($co{'title'}, $co{'title_short'},
5652                                           href(action=>"commit", hash=>$commit), $ref);
5653                 print "</td>\n" .
5654                       "<td class=\"link\">" .
5655                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5656                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5657                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5658                 my $snapshot_links = format_snapshot_links($commit);
5659                 if (defined $snapshot_links) {
5660                         print " | " . $snapshot_links;
5661                 }
5662                 print "</td>\n" .
5663                       "</tr>\n";
5664         }
5665         if (defined $extra) {
5666                 print "<tr>\n" .
5667                       "<td colspan=\"4\">$extra</td>\n" .
5668                       "</tr>\n";
5669         }
5670         print "</table>\n";
5671 }
5672
5673 sub git_history_body {
5674         # Warning: assumes constant type (blob or tree) during history
5675         my ($commitlist, $from, $to, $refs, $extra,
5676             $file_name, $file_hash, $ftype) = @_;
5677
5678         $from = 0 unless defined $from;
5679         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5680
5681         print "<table class=\"history\">\n";
5682         my $alternate = 1;
5683         for (my $i = $from; $i <= $to; $i++) {
5684                 my %co = %{$commitlist->[$i]};
5685                 if (!%co) {
5686                         next;
5687                 }
5688                 my $commit = $co{'id'};
5689
5690                 my $ref = format_ref_marker($refs, $commit);
5691
5692                 if ($alternate) {
5693                         print "<tr class=\"dark\">\n";
5694                 } else {
5695                         print "<tr class=\"light\">\n";
5696                 }
5697                 $alternate ^= 1;
5698                 print "<td class=\"". age_class($co{'age'}) . "\" title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5699         # shortlog:   format_author_html('td', \%co, 10)
5700                       format_author_html('td', \%co, 15, 3) . "<td>";
5701                 # originally git_history used chop_str($co{'title'}, 50)
5702                 print format_subject_html($co{'title'}, $co{'title_short'},
5703                                           href(action=>"commit", hash=>$commit), $ref);
5704                 print "</td>\n" .
5705                       "<td class=\"link\">" .
5706                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5707                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5708
5709                 if ($ftype eq 'blob') {
5710                         my $blob_current = $file_hash;
5711                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5712                         if (defined $blob_current && defined $blob_parent &&
5713                                         $blob_current ne $blob_parent) {
5714                                 print " | " .
5715                                         $cgi->a({-href => href(action=>"blobdiff",
5716                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5717                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5718                                                                file_name=>$file_name)},
5719                                                 "diff to current");
5720                         }
5721                 }
5722                 print "</td>\n" .
5723                       "</tr>\n";
5724         }
5725         if (defined $extra) {
5726                 print "<tr>\n" .
5727                       "<td colspan=\"4\">$extra</td>\n" .
5728                       "</tr>\n";
5729         }
5730         print "</table>\n";
5731 }
5732
5733 sub git_tags_body {
5734         # uses global variable $project
5735         my ($taglist, $from, $to, $extra) = @_;
5736         $from = 0 unless defined $from;
5737         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5738
5739         print "<table class=\"tags\">\n";
5740         my $alternate = 1;
5741         for (my $i = $from; $i <= $to; $i++) {
5742                 my $entry = $taglist->[$i];
5743                 my %tag = %$entry;
5744                 my $comment = $tag{'subject'};
5745                 my $comment_short;
5746                 if (defined $comment) {
5747                         $comment_short = chop_str($comment, 30, 5);
5748                 }
5749                 if ($alternate) {
5750                         print "<tr class=\"dark\">\n";
5751                 } else {
5752                         print "<tr class=\"light\">\n";
5753                 }
5754                 $alternate ^= 1;
5755                 if (defined $tag{'age'}) {
5756                         print "<td><i>$tag{'age'}</i></td>\n";
5757                 } else {
5758                         print "<td></td>\n";
5759                 }
5760                 print "<td>" .
5761                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5762                                -class => "list name"}, esc_html($tag{'name'})) .
5763                       "</td>\n" .
5764                       "<td>";
5765                 if (defined $comment) {
5766                         print format_subject_html($comment, $comment_short,
5767                                                   href(action=>"tag", hash=>$tag{'id'}));
5768                 }
5769                 print "</td>\n" .
5770                       "<td class=\"selflink\">";
5771                 if ($tag{'type'} eq "tag") {
5772                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5773                 } else {
5774                         print "&nbsp;";
5775                 }
5776                 print "</td>\n" .
5777                       "<td class=\"link\">" . " | " .
5778                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5779                 if ($tag{'reftype'} eq "commit") {
5780                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5781                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5782                 } elsif ($tag{'reftype'} eq "blob") {
5783                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5784                 }
5785                 print "</td>\n" .
5786                       "</tr>";
5787         }
5788         if (defined $extra) {
5789                 print "<tr>\n" .
5790                       "<td colspan=\"5\">$extra</td>\n" .
5791                       "</tr>\n";
5792         }
5793         print "</table>\n";
5794 }
5795
5796 sub git_heads_body {
5797         # uses global variable $project
5798         my ($headlist, $head_at, $from, $to, $extra) = @_;
5799         $from = 0 unless defined $from;
5800         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5801
5802         print "<table class=\"heads\">\n";
5803         my $alternate = 1;
5804         for (my $i = $from; $i <= $to; $i++) {
5805                 my $entry = $headlist->[$i];
5806                 my %ref = %$entry;
5807                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5808                 if ($alternate) {
5809                         print "<tr class=\"dark\">\n";
5810                 } else {
5811                         print "<tr class=\"light\">\n";
5812                 }
5813                 $alternate ^= 1;
5814                 print "<td><i>$ref{'age'}</i></td>\n" .
5815                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5816                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5817                                -class => "list name"},esc_html($ref{'name'})) .
5818                       "</td>\n" .
5819                       "<td class=\"link\">" .
5820                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5821                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5822                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5823                       "</td>\n" .
5824                       "</tr>";
5825         }
5826         if (defined $extra) {
5827                 print "<tr>\n" .
5828                       "<td colspan=\"3\">$extra</td>\n" .
5829                       "</tr>\n";
5830         }
5831         print "</table>\n";
5832 }
5833
5834 # Display a single remote block
5835 sub git_remote_block {
5836         my ($remote, $rdata, $limit, $head) = @_;
5837
5838         my $heads = $rdata->{'heads'};
5839         my $fetch = $rdata->{'fetch'};
5840         my $push = $rdata->{'push'};
5841
5842         my $urls_table = "<table class=\"projects_list\">\n" ;
5843
5844         if (defined $fetch) {
5845                 if ($fetch eq $push) {
5846                         $urls_table .= format_repo_url("URL", $fetch);
5847                 } else {
5848                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5849                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5850                 }
5851         } elsif (defined $push) {
5852                 $urls_table .= format_repo_url("Push URL", $push);
5853         } else {
5854                 $urls_table .= format_repo_url("", "No remote URL");
5855         }
5856
5857         $urls_table .= "</table>\n";
5858
5859         my $dots;
5860         if (defined $limit && $limit < @$heads) {
5861                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5862         }
5863
5864         print $urls_table;
5865         git_heads_body($heads, $head, 0, $limit, $dots);
5866 }
5867
5868 # Display a list of remote names with the respective fetch and push URLs
5869 sub git_remotes_list {
5870         my ($remotedata, $limit) = @_;
5871         print "<table class=\"heads\">\n";
5872         my $alternate = 1;
5873         my @remotes = sort keys %$remotedata;
5874
5875         my $limited = $limit && $limit < @remotes;
5876
5877         $#remotes = $limit - 1 if $limited;
5878
5879         while (my $remote = shift @remotes) {
5880                 my $rdata = $remotedata->{$remote};
5881                 my $fetch = $rdata->{'fetch'};
5882                 my $push = $rdata->{'push'};
5883                 if ($alternate) {
5884                         print "<tr class=\"dark\">\n";
5885                 } else {
5886                         print "<tr class=\"light\">\n";
5887                 }
5888                 $alternate ^= 1;
5889                 print "<td>" .
5890                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5891                                -class=> "list name"},esc_html($remote)) .
5892                       "</td>";
5893                 print "<td class=\"link\">" .
5894                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5895                       " | " .
5896                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5897                       "</td>";
5898
5899                 print "</tr>\n";
5900         }
5901
5902         if ($limited) {
5903                 print "<tr>\n" .
5904                       "<td colspan=\"3\">" .
5905                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5906                       "</td>\n" . "</tr>\n";
5907         }
5908
5909         print "</table>";
5910 }
5911
5912 # Display remote heads grouped by remote, unless there are too many
5913 # remotes, in which case we only display the remote names
5914 sub git_remotes_body {
5915         my ($remotedata, $limit, $head) = @_;
5916         if ($limit and $limit < keys %$remotedata) {
5917                 git_remotes_list($remotedata, $limit);
5918         } else {
5919                 fill_remote_heads($remotedata);
5920                 while (my ($remote, $rdata) = each %$remotedata) {
5921                         git_print_section({-class=>"remote", -id=>$remote},
5922                                 ["remotes", $remote, $remote], sub {
5923                                         git_remote_block($remote, $rdata, $limit, $head);
5924                                 });
5925                 }
5926         }
5927 }
5928
5929 sub git_search_message {
5930         my %co = @_;
5931
5932         my $greptype;
5933         if ($searchtype eq 'commit') {
5934                 $greptype = "--grep=";
5935         } elsif ($searchtype eq 'author') {
5936                 $greptype = "--author=";
5937         } elsif ($searchtype eq 'committer') {
5938                 $greptype = "--committer=";
5939         }
5940         $greptype .= $searchtext;
5941         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5942                                        $greptype, '--regexp-ignore-case',
5943                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5944
5945         my $paging_nav = '';
5946         if ($page > 0) {
5947                 $paging_nav .=
5948                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5949                                 "first") .
5950                         " &sdot; " .
5951                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5952                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5953         } else {
5954                 $paging_nav .= "first &sdot; prev";
5955         }
5956         my $next_link = '';
5957         if ($#commitlist >= 100) {
5958                 $next_link =
5959                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5960                                  -accesskey => "n", -title => "Alt-n"}, "next");
5961                 $paging_nav .= " &sdot; $next_link";
5962         } else {
5963                 $paging_nav .= " &sdot; next";
5964         }
5965
5966         git_header_html();
5967
5968         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5969         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5970         if ($page == 0 && !@commitlist) {
5971                 print "<p>No match.</p>\n";
5972         } else {
5973                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5974         }
5975
5976         git_footer_html();
5977 }
5978
5979 sub git_search_changes {
5980         my %co = @_;
5981
5982         local $/ = "\n";
5983         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5984                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5985                 ($search_use_regexp ? '--pickaxe-regex' : ())
5986                         or die_error(500, "Open git-log failed");
5987
5988         git_header_html();
5989
5990         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5991         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5992
5993         print "<table class=\"pickaxe search\">\n";
5994         my $alternate = 1;
5995         undef %co;
5996         my @files;
5997         while (my $line = <$fd>) {
5998                 chomp $line;
5999                 next unless $line;
6000
6001                 my %set = parse_difftree_raw_line($line);
6002                 if (defined $set{'commit'}) {
6003                         # finish previous commit
6004                         if (%co) {
6005                                 print "</td>\n" .
6006                                       "<td class=\"link\">" .
6007                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6008                                               "commit") .
6009                                       " | " .
6010                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6011                                                              hash_base=>$co{'id'})},
6012                                               "tree") .
6013                                       "</td>\n" .
6014                                       "</tr>\n";
6015                         }
6016
6017                         if ($alternate) {
6018                                 print "<tr class=\"dark\">\n";
6019                         } else {
6020                                 print "<tr class=\"light\">\n";
6021                         }
6022                         $alternate ^= 1;
6023                         %co = parse_commit($set{'commit'});
6024                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6025                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6026                               "<td><i>$author</i></td>\n" .
6027                               "<td>" .
6028                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6029                                       -class => "list subject"},
6030                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6031                 } elsif (defined $set{'to_id'}) {
6032                         next if ($set{'to_id'} =~ m/^0{40}$/);
6033
6034                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6035                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6036                                       -class => "list"},
6037                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6038                               "<br/>\n";
6039                 }
6040         }
6041         close $fd;
6042
6043         # finish last commit (warning: repetition!)
6044         if (%co) {
6045                 print "</td>\n" .
6046                       "<td class=\"link\">" .
6047                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6048                               "commit") .
6049                       " | " .
6050                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6051                                              hash_base=>$co{'id'})},
6052                               "tree") .
6053                       "</td>\n" .
6054                       "</tr>\n";
6055         }
6056
6057         print "</table>\n";
6058
6059         git_footer_html();
6060 }
6061
6062 sub git_search_files {
6063         my %co = @_;
6064
6065         local $/ = "\n";
6066         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6067                 $search_use_regexp ? ('-E', '-i') : '-F',
6068                 $searchtext, $co{'tree'}
6069                         or die_error(500, "Open git-grep failed");
6070
6071         git_header_html();
6072
6073         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6074         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6075
6076         print "<table class=\"grep_search\">\n";
6077         my $alternate = 1;
6078         my $matches = 0;
6079         my $lastfile = '';
6080         my $file_href;
6081         while (my $line = <$fd>) {
6082                 chomp $line;
6083                 my ($file, $lno, $ltext, $binary);
6084                 last if ($matches++ > 1000);
6085                 if ($line =~ /^Binary file (.+) matches$/) {
6086                         $file = $1;
6087                         $binary = 1;
6088                 } else {
6089                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6090                         $file =~ s/^$co{'tree'}://;
6091                 }
6092                 if ($file ne $lastfile) {
6093                         $lastfile and print "</td></tr>\n";
6094                         if ($alternate++) {
6095                                 print "<tr class=\"dark\">\n";
6096                         } else {
6097                                 print "<tr class=\"light\">\n";
6098                         }
6099                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6100                                           file_name=>$file);
6101                         print "<td class=\"list\">".
6102                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6103                         print "</td><td>\n";
6104                         $lastfile = $file;
6105                 }
6106                 if ($binary) {
6107                         print "<div class=\"binary\">Binary file</div>\n";
6108                 } else {
6109                         $ltext = untabify($ltext);
6110                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6111                                 $ltext = esc_html($1, -nbsp=>1);
6112                                 $ltext .= '<span class="match">';
6113                                 $ltext .= esc_html($2, -nbsp=>1);
6114                                 $ltext .= '</span>';
6115                                 $ltext .= esc_html($3, -nbsp=>1);
6116                         } else {
6117                                 $ltext = esc_html($ltext, -nbsp=>1);
6118                         }
6119                         print "<div class=\"pre\">" .
6120                                 $cgi->a({-href => $file_href.'#l'.$lno,
6121                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6122                                 ' ' .  $ltext . "</div>\n";
6123                 }
6124         }
6125         if ($lastfile) {
6126                 print "</td></tr>\n";
6127                 if ($matches > 1000) {
6128                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6129                 }
6130         } else {
6131                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6132         }
6133         close $fd;
6134
6135         print "</table>\n";
6136
6137         git_footer_html();
6138 }
6139
6140 sub git_search_grep_body {
6141         my ($commitlist, $from, $to, $extra) = @_;
6142         $from = 0 unless defined $from;
6143         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6144
6145         print "<table class=\"commit_search\">\n";
6146         my $alternate = 1;
6147         for (my $i = $from; $i <= $to; $i++) {
6148                 my %co = %{$commitlist->[$i]};
6149                 if (!%co) {
6150                         next;
6151                 }
6152                 my $commit = $co{'id'};
6153                 if ($alternate) {
6154                         print "<tr class=\"dark\">\n";
6155                 } else {
6156                         print "<tr class=\"light\">\n";
6157                 }
6158                 $alternate ^= 1;
6159                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6160                       format_author_html('td', \%co, 15, 5) .
6161                       "<td>" .
6162                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6163                                -class => "list subject"},
6164                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6165                 my $comment = $co{'comment'};
6166                 foreach my $line (@$comment) {
6167                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6168                                 my ($lead, $match, $trail) = ($1, $2, $3);
6169                                 $match = chop_str($match, 70, 5, 'center');
6170                                 my $contextlen = int((80 - length($match))/2);
6171                                 $contextlen = 30 if ($contextlen > 30);
6172                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6173                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6174
6175                                 $lead  = esc_html($lead);
6176                                 $match = esc_html($match);
6177                                 $trail = esc_html($trail);
6178
6179                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6180                         }
6181                 }
6182                 print "</td>\n" .
6183                       "<td class=\"link\">" .
6184                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6185                       " | " .
6186                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6187                       " | " .
6188                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6189                 print "</td>\n" .
6190                       "</tr>\n";
6191         }
6192         if (defined $extra) {
6193                 print "<tr>\n" .
6194                       "<td colspan=\"3\">$extra</td>\n" .
6195                       "</tr>\n";
6196         }
6197         print "</table>\n";
6198 }
6199
6200 ## ======================================================================
6201 ## ======================================================================
6202 ## actions
6203
6204 sub git_project_list {
6205         my $order = $input_params{'order'};
6206         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6207                 die_error(400, "Unknown order parameter");
6208         }
6209
6210         my @list = git_get_projects_list($project_filter, $strict_export);
6211         if (!@list) {
6212                 die_error(404, "No projects found");
6213         }
6214
6215         git_header_html();
6216         if (defined $home_text && -f $home_text) {
6217                 print "<div class=\"index_include\">\n";
6218                 insert_file($home_text);
6219                 print "</div>\n";
6220         }
6221
6222         git_project_search_form($searchtext, $search_use_regexp);
6223         git_project_list_body(\@list, $order);
6224         git_footer_html();
6225 }
6226
6227 sub git_forks {
6228         my $order = $input_params{'order'};
6229         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6230                 die_error(400, "Unknown order parameter");
6231         }
6232
6233         my $filter = $project;
6234         $filter =~ s/\.git$//;
6235         my @list = git_get_projects_list($filter);
6236         if (!@list) {
6237                 die_error(404, "No forks found");
6238         }
6239
6240         git_header_html();
6241         git_print_page_nav('','');
6242         git_print_header_div('summary', "$project forks");
6243         git_project_list_body(\@list, $order);
6244         git_footer_html();
6245 }
6246
6247 sub git_project_index {
6248         my @projects = git_get_projects_list($project_filter, $strict_export);
6249         if (!@projects) {
6250                 die_error(404, "No projects found");
6251         }
6252
6253         print $cgi->header(
6254                 -type => 'text/plain',
6255                 -charset => 'utf-8',
6256                 -content_disposition => 'inline; filename="index.aux"');
6257
6258         foreach my $pr (@projects) {
6259                 if (!exists $pr->{'owner'}) {
6260                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6261                 }
6262
6263                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6264                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6265                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6266                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6267                 $path  =~ s/ /\+/g;
6268                 $owner =~ s/ /\+/g;
6269
6270                 print "$path $owner\n";
6271         }
6272 }
6273
6274 sub git_summary {
6275         my $descr = git_get_project_description($project) || "none";
6276         my %co = parse_commit("HEAD");
6277         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6278         my $head = $co{'id'};
6279         my $remote_heads = gitweb_check_feature('remote_heads');
6280
6281         my $owner = git_get_project_owner($project);
6282
6283         my $refs = git_get_references();
6284         # These get_*_list functions return one more to allow us to see if
6285         # there are more ...
6286         my @taglist  = git_get_tags_list(16);
6287         my @headlist = git_get_heads_list(16);
6288         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6289         my @forklist;
6290         my $check_forks = gitweb_check_feature('forks');
6291
6292         if ($check_forks) {
6293                 # find forks of a project
6294                 my $filter = $project;
6295                 $filter =~ s/\.git$//;
6296                 @forklist = git_get_projects_list($filter);
6297                 # filter out forks of forks
6298                 @forklist = filter_forks_from_projects_list(\@forklist)
6299                         if (@forklist);
6300         }
6301
6302         git_header_html();
6303         git_print_page_nav('summary','', $head);
6304
6305         print "<div class=\"title\">&nbsp;</div>\n";
6306         print "<table class=\"projects_list\">\n" .
6307               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6308               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6309         if (defined $cd{'rfc2822'}) {
6310                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6311                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6312         }
6313
6314         # use per project git URL list in $projectroot/$project/cloneurl
6315         # or make project git URL from git base URL and project name
6316         my $url_tag = "URL";
6317         my @url_list = git_get_project_url_list($project);
6318         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6319         foreach my $git_url (@url_list) {
6320                 next unless $git_url;
6321                 print format_repo_url($url_tag, $git_url);
6322                 $url_tag = "";
6323         }
6324
6325         # Tag cloud
6326         my $show_ctags = gitweb_check_feature('ctags');
6327         if ($show_ctags) {
6328                 my $ctags = git_get_project_ctags($project);
6329                 if (%$ctags) {
6330                         # without ability to add tags, don't show if there are none
6331                         my $cloud = git_populate_project_tagcloud($ctags);
6332                         print "<tr id=\"metadata_ctags\">" .
6333                               "<td>content tags</td>" .
6334                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6335                               "</tr>\n";
6336                 }
6337         }
6338
6339         print "</table>\n";
6340
6341         # If XSS prevention is on, we don't include README.html.
6342         # TODO: Allow a readme in some safe format.
6343         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6344                 print "<div class=\"title\">readme</div>\n" .
6345                       "<div class=\"readme\">\n";
6346                 insert_file("$projectroot/$project/README.html");
6347                 print "\n</div>\n"; # class="readme"
6348         }
6349
6350         # we need to request one more than 16 (0..15) to check if
6351         # those 16 are all
6352         my @commitlist = $head ? parse_commits("--all", 17) : ();
6353         if (@commitlist) {
6354                 git_print_header_div('shortlog');
6355                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6356                                   $#commitlist <=  15 ? undef :
6357                                   $cgi->a({-href => href(action=>"shortlog")}, "..."), 0, 0, 0, 1);
6358         }
6359
6360         if (@taglist) {
6361                 git_print_header_div('tags');
6362                 git_tags_body(\@taglist, 0, 15,
6363                               $#taglist <=  15 ? undef :
6364                               $cgi->a({-href => href(action=>"tags")}, "..."));
6365         }
6366
6367         if (@headlist) {
6368                 git_print_header_div('heads');
6369                 git_heads_body(\@headlist, $head, 0, 15,
6370                                $#headlist <= 15 ? undef :
6371                                $cgi->a({-href => href(action=>"heads")}, "..."));
6372         }
6373
6374         if (%remotedata) {
6375                 git_print_header_div('remotes');
6376                 git_remotes_body(\%remotedata, 15, $head);
6377         }
6378
6379         if (@forklist) {
6380                 git_print_header_div('forks');
6381                 git_project_list_body(\@forklist, 'age', 0, 15,
6382                                       $#forklist <= 15 ? undef :
6383                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6384                                       'no_header');
6385         }
6386
6387         git_footer_html();
6388 }
6389
6390 sub git_tag {
6391         my %tag = parse_tag($hash);
6392
6393         if (! %tag) {
6394                 die_error(404, "Unknown tag object");
6395         }
6396
6397         my $head = git_get_head_hash($project);
6398         git_header_html();
6399         git_print_page_nav('','', $head,undef,$head);
6400         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6401         print "<div class=\"title_text\">\n" .
6402               "<table class=\"object_header\">\n" .
6403               "<tr>\n" .
6404               "<td>object</td>\n" .
6405               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6406                                $tag{'object'}) . "</td>\n" .
6407               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6408                                               $tag{'type'}) . "</td>\n" .
6409               "</tr>\n";
6410         if (defined($tag{'author'})) {
6411                 git_print_authorship_rows(\%tag, 'author');
6412         }
6413         print "</table>\n\n" .
6414               "</div>\n";
6415         print "<div class=\"page_body\">";
6416         my $comment = $tag{'comment'};
6417         foreach my $line (@$comment) {
6418                 chomp $line;
6419                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6420         }
6421         print "</div>\n";
6422         git_footer_html();
6423 }
6424
6425 sub git_blame_common {
6426         my $format = shift || 'porcelain';
6427         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6428                 $format = 'incremental';
6429                 $action = 'blame_incremental'; # for page title etc
6430         }
6431
6432         # permissions
6433         gitweb_check_feature('blame')
6434                 or die_error(403, "Blame view not allowed");
6435
6436         # error checking
6437         die_error(400, "No file name given") unless $file_name;
6438         $hash_base ||= git_get_head_hash($project);
6439         die_error(404, "Couldn't find base commit") unless $hash_base;
6440         my %co = parse_commit($hash_base)
6441                 or die_error(404, "Commit not found");
6442         my $ftype = "blob";
6443         if (!defined $hash) {
6444                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6445                         or die_error(404, "Error looking up file");
6446         } else {
6447                 $ftype = git_get_type($hash);
6448                 if ($ftype !~ "blob") {
6449                         die_error(400, "Object is not a blob");
6450                 }
6451         }
6452
6453         my $fd;
6454         if ($format eq 'incremental') {
6455                 # get file contents (as base)
6456                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6457                         or die_error(500, "Open git-cat-file failed");
6458         } elsif ($format eq 'data') {
6459                 # run git-blame --incremental
6460                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6461                         $hash_base, "--", $file_name
6462                         or die_error(500, "Open git-blame --incremental failed");
6463         } else {
6464                 # run git-blame --porcelain
6465                 open $fd, "-|", git_cmd(), "blame", '-p',
6466                         $hash_base, '--', $file_name
6467                         or die_error(500, "Open git-blame --porcelain failed");
6468         }
6469
6470         # incremental blame data returns early
6471         if ($format eq 'data') {
6472                 print $cgi->header(
6473                         -type=>"text/plain", -charset => "utf-8",
6474                         -status=> "200 OK");
6475                 local $| = 1; # output autoflush
6476                 while (my $line = <$fd>) {
6477                         print to_utf8($line);
6478                 }
6479                 close $fd
6480                         or print "ERROR $!\n";
6481
6482                 print 'END';
6483                 if (defined $t0 && gitweb_check_feature('timed')) {
6484                         print ' '.
6485                               tv_interval($t0, [ gettimeofday() ]).
6486                               ' '.$number_of_git_cmds;
6487                 }
6488                 print "\n";
6489
6490                 return;
6491         }
6492
6493         # page header
6494         git_header_html();
6495         my $formats_nav =
6496                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6497                         "blob") .
6498                 " | ";
6499         if ($format eq 'incremental') {
6500                 $formats_nav .=
6501                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6502                                 "blame") . " (non-incremental)";
6503         } else {
6504                 $formats_nav .=
6505                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6506                                 "blame") . " (incremental)";
6507         }
6508         $formats_nav .=
6509                 " | " .
6510                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6511                         "history") .
6512                 " | " .
6513                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6514                         "HEAD");
6515         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6516         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6517         git_print_page_path($file_name, $ftype, $hash_base);
6518
6519         # page body
6520         if ($format eq 'incremental') {
6521                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6522                       "This page requires JavaScript to run.\n Use ".
6523                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6524                               'this page').
6525                       " instead.\n".
6526                       "</b></center></div>\n</noscript>\n";
6527
6528                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6529         }
6530
6531         print qq!<div class="page_body">\n!;
6532         print qq!<div id="progress_info">... / ...</div>\n!
6533                 if ($format eq 'incremental');
6534         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6535               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6536               qq!<thead>\n!.
6537               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6538               qq!</thead>\n!.
6539               qq!<tbody>\n!;
6540
6541         my @rev_color = qw(light dark);
6542         my $num_colors = scalar(@rev_color);
6543         my $current_color = 0;
6544
6545         if ($format eq 'incremental') {
6546                 my $color_class = $rev_color[$current_color];
6547
6548                 #contents of a file
6549                 my $linenr = 0;
6550         LINE:
6551                 while (my $line = <$fd>) {
6552                         chomp $line;
6553                         $linenr++;
6554
6555                         print qq!<tr id="l$linenr" class="$color_class">!.
6556                               qq!<td class="sha1"><a href=""> </a></td>!.
6557                               qq!<td class="linenr">!.
6558                               qq!<a class="linenr" href="">$linenr</a></td>!;
6559                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6560                         print qq!</tr>\n!;
6561                 }
6562
6563         } else { # porcelain, i.e. ordinary blame
6564                 my %metainfo = (); # saves information about commits
6565
6566                 # blame data
6567         LINE:
6568                 while (my $line = <$fd>) {
6569                         chomp $line;
6570                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6571                         # no <lines in group> for subsequent lines in group of lines
6572                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6573                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6574                         if (!exists $metainfo{$full_rev}) {
6575                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6576                         }
6577                         my $meta = $metainfo{$full_rev};
6578                         my $data;
6579                         while ($data = <$fd>) {
6580                                 chomp $data;
6581                                 last if ($data =~ s/^\t//); # contents of line
6582                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6583                                         $meta->{$1} = $2 unless exists $meta->{$1};
6584                                 }
6585                                 if ($data =~ /^previous /) {
6586                                         $meta->{'nprevious'}++;
6587                                 }
6588                         }
6589                         my $short_rev = substr($full_rev, 0, 8);
6590                         my $author = $meta->{'author'};
6591                         my %date =
6592                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6593                         my $date = $date{'iso-tz'};
6594                         if ($group_size) {
6595                                 $current_color = ($current_color + 1) % $num_colors;
6596                         }
6597                         my $tr_class = $rev_color[$current_color];
6598                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6599                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6600                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6601                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6602                         if ($group_size) {
6603                                 print "<td class=\"sha1\"";
6604                                 print " title=\"". esc_html($author) . ", $date\"";
6605                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6606                                 print ">";
6607                                 print $cgi->a({-href => href(action=>"commit",
6608                                                              hash=>$full_rev,
6609                                                              file_name=>$file_name)},
6610                                               esc_html($short_rev));
6611                                 if ($group_size >= 2) {
6612                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6613                                         if (@author_initials) {
6614                                                 print "<br />" .
6615                                                       esc_html(join('', @author_initials));
6616                                                 #           or join('.', ...)
6617                                         }
6618                                 }
6619                                 print "</td>\n";
6620                         }
6621                         # 'previous' <sha1 of parent commit> <filename at commit>
6622                         if (exists $meta->{'previous'} &&
6623                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6624                                 $meta->{'parent'} = $1;
6625                                 $meta->{'file_parent'} = unquote($2);
6626                         }
6627                         my $linenr_commit =
6628                                 exists($meta->{'parent'}) ?
6629                                 $meta->{'parent'} : $full_rev;
6630                         my $linenr_filename =
6631                                 exists($meta->{'file_parent'}) ?
6632                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6633                         my $blamed = href(action => 'blame',
6634                                           file_name => $linenr_filename,
6635                                           hash_base => $linenr_commit);
6636                         print "<td class=\"linenr\">";
6637                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6638                                         -class => "linenr" },
6639                                       esc_html($lineno));
6640                         print "</td>";
6641                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6642                         print "</tr>\n";
6643                 } # end while
6644
6645         }
6646
6647         # footer
6648         print "</tbody>\n".
6649               "</table>\n"; # class="blame"
6650         print "</div>\n";   # class="blame_body"
6651         close $fd
6652                 or print "Reading blob failed\n";
6653
6654         git_footer_html();
6655 }
6656
6657 sub git_blame {
6658         git_blame_common();
6659 }
6660
6661 sub git_blame_incremental {
6662         git_blame_common('incremental');
6663 }
6664
6665 sub git_blame_data {
6666         git_blame_common('data');
6667 }
6668
6669 sub git_tags {
6670         my $head = git_get_head_hash($project);
6671         git_header_html();
6672         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6673         git_print_header_div('summary', $project);
6674
6675         my @tagslist = git_get_tags_list();
6676         if (@tagslist) {
6677                 git_tags_body(\@tagslist);
6678         }
6679         git_footer_html();
6680 }
6681
6682 sub git_heads {
6683         my $head = git_get_head_hash($project);
6684         git_header_html();
6685         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6686         git_print_header_div('summary', $project);
6687
6688         my @headslist = git_get_heads_list();
6689         if (@headslist) {
6690                 git_heads_body(\@headslist, $head);
6691         }
6692         git_footer_html();
6693 }
6694
6695 # used both for single remote view and for list of all the remotes
6696 sub git_remotes {
6697         gitweb_check_feature('remote_heads')
6698                 or die_error(403, "Remote heads view is disabled");
6699
6700         my $head = git_get_head_hash($project);
6701         my $remote = $input_params{'hash'};
6702
6703         my $remotedata = git_get_remotes_list($remote);
6704         die_error(500, "Unable to get remote information") unless defined $remotedata;
6705
6706         unless (%$remotedata) {
6707                 die_error(404, defined $remote ?
6708                         "Remote $remote not found" :
6709                         "No remotes found");
6710         }
6711
6712         git_header_html(undef, undef, -action_extra => $remote);
6713         git_print_page_nav('', '',  $head, undef, $head,
6714                 format_ref_views($remote ? '' : 'remotes'));
6715
6716         fill_remote_heads($remotedata);
6717         if (defined $remote) {
6718                 git_print_header_div('remotes', "$remote remote for $project");
6719                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6720         } else {
6721                 git_print_header_div('summary', "$project remotes");
6722                 git_remotes_body($remotedata, undef, $head);
6723         }
6724
6725         git_footer_html();
6726 }
6727
6728 sub git_blob_plain {
6729         my $type = shift;
6730         my $expires;
6731
6732         if (!defined $hash) {
6733                 if (defined $file_name) {
6734                         my $base = $hash_base || git_get_head_hash($project);
6735                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6736                                 or die_error(404, "Cannot find file");
6737                 } else {
6738                         die_error(400, "No file name defined");
6739                 }
6740         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6741                 # blobs defined by non-textual hash id's can be cached
6742                 $expires = "+1d";
6743         }
6744
6745         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6746                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6747
6748         # content-type (can include charset)
6749         $type = blob_contenttype($fd, $file_name, $type);
6750
6751         # "save as" filename, even when no $file_name is given
6752         my $save_as = "$hash";
6753         if (defined $file_name) {
6754                 $save_as = $file_name;
6755         } elsif ($type =~ m/^text\//) {
6756                 $save_as .= '.txt';
6757         }
6758
6759         # With XSS prevention on, blobs of all types except a few known safe
6760         # ones are served with "Content-Disposition: attachment" to make sure
6761         # they don't run in our security domain.  For certain image types,
6762         # blob view writes an <img> tag referring to blob_plain view, and we
6763         # want to be sure not to break that by serving the image as an
6764         # attachment (though Firefox 3 doesn't seem to care).
6765         my $sandbox = $prevent_xss &&
6766                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6767
6768         # serve text/* as text/plain
6769         if ($prevent_xss &&
6770             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6771              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6772                 my $rest = $1;
6773                 $rest = defined $rest ? $rest : '';
6774                 $type = "text/plain$rest";
6775         }
6776
6777         print $cgi->header(
6778                 -type => $type,
6779                 -expires => $expires,
6780                 -content_disposition =>
6781                         ($sandbox ? 'attachment' : 'inline')
6782                         . '; filename="' . $save_as . '"');
6783         local $/ = undef;
6784         binmode STDOUT, ':raw';
6785         print <$fd>;
6786         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6787         close $fd;
6788 }
6789
6790 sub git_blob {
6791         my $expires;
6792
6793         if (!defined $hash) {
6794                 if (defined $file_name) {
6795                         my $base = $hash_base || git_get_head_hash($project);
6796                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6797                                 or die_error(404, "Cannot find file");
6798                 } else {
6799                         die_error(400, "No file name defined");
6800                 }
6801         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6802                 # blobs defined by non-textual hash id's can be cached
6803                 $expires = "+1d";
6804         }
6805
6806         my $have_blame = gitweb_check_feature('blame');
6807         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6808                 or die_error(500, "Couldn't cat $file_name, $hash");
6809         my $mimetype = blob_mimetype($fd, $file_name);
6810         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6811         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6812                 close $fd;
6813                 return git_blob_plain($mimetype);
6814         }
6815         # we can have blame only for text/* mimetype
6816         $have_blame &&= ($mimetype =~ m!^text/!);
6817
6818         my $highlight = gitweb_check_feature('highlight');
6819         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6820         $fd = run_highlighter($fd, $highlight, $syntax)
6821                 if $syntax;
6822
6823         git_header_html(undef, $expires);
6824         my $formats_nav = '';
6825         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6826                 if (defined $file_name) {
6827                         if ($have_blame) {
6828                                 $formats_nav .=
6829                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6830                                                 "blame") .
6831                                         " | ";
6832                         }
6833                         $formats_nav .=
6834                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6835                                         "history") .
6836                                 " | " .
6837                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6838                                         "raw") .
6839                                 " | " .
6840                                 $cgi->a({-href => href(action=>"blob",
6841                                                        hash_base=>"HEAD", file_name=>$file_name)},
6842                                         "HEAD");
6843                 } else {
6844                         $formats_nav .=
6845                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6846                                         "raw");
6847                 }
6848                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6849                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6850         } else {
6851                 print "<div class=\"page_nav\">\n" .
6852                       "<br/><br/></div>\n" .
6853                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6854         }
6855         git_print_page_path($file_name, "blob", $hash_base);
6856         print "<div class=\"page_body\">\n";
6857         if ($mimetype =~ m!^image/!) {
6858                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6859                 if ($file_name) {
6860                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6861                 }
6862                 print qq! src="! .
6863                       href(action=>"blob_plain", hash=>$hash,
6864                            hash_base=>$hash_base, file_name=>$file_name) .
6865                       qq!" />\n!;
6866         } else {
6867                 my $nr;
6868                 while (my $line = <$fd>) {
6869                         chomp $line;
6870                         $nr++;
6871                         $line = untabify($line);
6872                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6873                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6874                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6875                 }
6876         }
6877         close $fd
6878                 or print "Reading blob failed.\n";
6879         print "</div>";
6880         git_footer_html();
6881 }
6882
6883 sub git_tree {
6884         if (!defined $hash_base) {
6885                 $hash_base = "HEAD";
6886         }
6887         if (!defined $hash) {
6888                 if (defined $file_name) {
6889                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6890                 } else {
6891                         $hash = $hash_base;
6892                 }
6893         }
6894         die_error(404, "No such tree") unless defined($hash);
6895
6896         my $show_sizes = gitweb_check_feature('show-sizes');
6897         my $have_blame = gitweb_check_feature('blame');
6898
6899         my @entries = ();
6900         {
6901                 local $/ = "\0";
6902                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6903                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6904                         or die_error(500, "Open git-ls-tree failed");
6905                 @entries = map { chomp; $_ } <$fd>;
6906                 close $fd
6907                         or die_error(404, "Reading tree failed");
6908         }
6909
6910         my $refs = git_get_references();
6911         my $ref = format_ref_marker($refs, $hash_base);
6912         git_header_html();
6913         my $basedir = '';
6914         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6915                 my @views_nav = ();
6916                 if (defined $file_name) {
6917                         push @views_nav,
6918                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6919                                         "history"),
6920                                 $cgi->a({-href => href(action=>"tree",
6921                                                        hash_base=>"HEAD", file_name=>$file_name)},
6922                                         "HEAD"),
6923                 }
6924                 my $snapshot_links = format_snapshot_links($hash);
6925                 if (defined $snapshot_links) {
6926                         # FIXME: Should be available when we have no hash base as well.
6927                         push @views_nav, $snapshot_links;
6928                 }
6929                 git_print_page_nav('tree','', $hash_base, undef, undef,
6930                                    join(' | ', @views_nav));
6931                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6932         } else {
6933                 undef $hash_base;
6934                 print "<div class=\"page_nav\">\n";
6935                 print "<br/><br/></div>\n";
6936                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6937         }
6938         if (defined $file_name) {
6939                 $basedir = $file_name;
6940                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6941                         $basedir .= '/';
6942                 }
6943                 git_print_page_path($file_name, 'tree', $hash_base);
6944         }
6945         print "<div class=\"page_body\">\n";
6946         print "<table class=\"tree\">\n";
6947         my $alternate = 1;
6948         # '..' (top directory) link if possible
6949         if (defined $hash_base &&
6950             defined $file_name && $file_name =~ m![^/]+$!) {
6951                 if ($alternate) {
6952                         print "<tr class=\"dark\">\n";
6953                 } else {
6954                         print "<tr class=\"light\">\n";
6955                 }
6956                 $alternate ^= 1;
6957
6958                 my $up = $file_name;
6959                 $up =~ s!/?[^/]+$!!;
6960                 undef $up unless $up;
6961                 # based on git_print_tree_entry
6962                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6963                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6964                 print '<td class="list">';
6965                 print $cgi->a({-href => href(action=>"tree",
6966                                              hash_base=>$hash_base,
6967                                              file_name=>$up)},
6968                               "..");
6969                 print "</td>\n";
6970                 print "<td class=\"link\"></td>\n";
6971
6972                 print "</tr>\n";
6973         }
6974         foreach my $line (@entries) {
6975                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6976
6977                 if ($alternate) {
6978                         print "<tr class=\"dark\">\n";
6979                 } else {
6980                         print "<tr class=\"light\">\n";
6981                 }
6982                 $alternate ^= 1;
6983
6984                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6985
6986                 print "</tr>\n";
6987         }
6988         print "</table>\n" .
6989               "</div>";
6990         git_footer_html();
6991 }
6992
6993 sub snapshot_name {
6994         my ($project, $hash) = @_;
6995
6996         # path/to/project.git  -> project
6997         # path/to/project/.git -> project
6998         my $name = to_utf8($project);
6999         $name =~ s,([^/])/*\.git$,$1,;
7000         $name = basename($name);
7001         # sanitize name
7002         $name =~ s/[[:cntrl:]]/?/g;
7003
7004         my $ver = $hash;
7005         if ($hash =~ /^[0-9a-fA-F]+$/) {
7006                 # shorten SHA-1 hash
7007                 my $full_hash = git_get_full_hash($project, $hash);
7008                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7009                         $ver = git_get_short_hash($project, $hash);
7010                 }
7011         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7012                 # tags don't need shortened SHA-1 hash
7013                 $ver = $1;
7014         } else {
7015                 # branches and other need shortened SHA-1 hash
7016                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
7017                         $ver = $1;
7018                 }
7019                 $ver .= '-' . git_get_short_hash($project, $hash);
7020         }
7021         # in case of hierarchical branch names
7022         $ver =~ s!/!.!g;
7023
7024         # name = project-version_string
7025         $name = "$name-$ver";
7026
7027         return wantarray ? ($name, $name) : $name;
7028 }
7029
7030 sub git_snapshot {
7031         my $format = $input_params{'snapshot_format'};
7032         if (!@snapshot_fmts) {
7033                 die_error(403, "Snapshots not allowed");
7034         }
7035         # default to first supported snapshot format
7036         $format ||= $snapshot_fmts[0];
7037         if ($format !~ m/^[a-z0-9]+$/) {
7038                 die_error(400, "Invalid snapshot format parameter");
7039         } elsif (!exists($known_snapshot_formats{$format})) {
7040                 die_error(400, "Unknown snapshot format");
7041         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7042                 die_error(403, "Snapshot format not allowed");
7043         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7044                 die_error(403, "Unsupported snapshot format");
7045         }
7046
7047         my $type = git_get_type("$hash^{}");
7048         if (!$type) {
7049                 die_error(404, 'Object does not exist');
7050         }  elsif ($type eq 'blob') {
7051                 die_error(400, 'Object is not a tree-ish');
7052         }
7053
7054         my ($name, $prefix) = snapshot_name($project, $hash);
7055         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7056         my $cmd = quote_command(
7057                 git_cmd(), 'archive',
7058                 "--format=$known_snapshot_formats{$format}{'format'}",
7059                 "--prefix=$prefix/", $hash);
7060         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7061                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7062         }
7063
7064         $filename =~ s/(["\\])/\\$1/g;
7065         print $cgi->header(
7066                 -type => $known_snapshot_formats{$format}{'type'},
7067                 -content_disposition => 'inline; filename="' . $filename . '"',
7068                 -status => '200 OK');
7069
7070         open my $fd, "-|", $cmd
7071                 or die_error(500, "Execute git-archive failed");
7072         binmode STDOUT, ':raw';
7073         print <$fd>;
7074         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7075         close $fd;
7076 }
7077
7078 sub git_log_generic {
7079         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7080
7081         my $head = git_get_head_hash($project);
7082     my $allrefs;
7083         if (!defined $base) {
7084                 $base = $head;
7085         $allrefs = 1;
7086         }
7087         if (!defined $page) {
7088                 $page = 0;
7089         }
7090         my $refs = git_get_references();
7091
7092         my $commit_hash = $base;
7093     if (defined $allrefs) {
7094         $commit_hash = "--all";
7095     }
7096     if (defined $parent) {
7097                 $commit_hash = "$parent..$base";
7098         }
7099         my @commitlist =
7100                 parse_commits($commit_hash, 101, (100 * $page),
7101                               defined $file_name ? ($file_name, "--full-history") : ());
7102
7103         my $ftype;
7104         if (!defined $file_hash && defined $file_name) {
7105                 # some commits could have deleted file in question,
7106                 # and not have it in tree, but one of them has to have it
7107                 for (my $i = 0; $i < @commitlist; $i++) {
7108                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7109                         last if defined $file_hash;
7110                 }
7111         }
7112         if (defined $file_hash) {
7113                 $ftype = git_get_type($file_hash);
7114         }
7115         if (defined $file_name && !defined $ftype) {
7116                 die_error(500, "Unknown type of object");
7117         }
7118         my %co;
7119         if (defined $file_name) {
7120                 %co = parse_commit($base)
7121                         or die_error(404, "Unknown commit object");
7122         }
7123
7124
7125         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7126         my $next_link = '';
7127         if ($#commitlist >= 100) {
7128                 $next_link =
7129                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7130                                  -accesskey => "n", -title => "Alt-n"}, "next");
7131         }
7132         my $patch_max = gitweb_get_feature('patches');
7133         if ($patch_max && !defined $file_name) {
7134                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7135                         $paging_nav .= " &sdot; " .
7136                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7137                                         "patches");
7138                 }
7139         }
7140
7141         git_header_html();
7142         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7143         if (defined $file_name) {
7144                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7145         } else {
7146                 git_print_header_div('summary', $project)
7147         }
7148         git_print_page_path($file_name, $ftype, $hash_base)
7149                 if (defined $file_name);
7150
7151         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7152                      $file_name, $file_hash, $ftype, $allrefs);
7153
7154         git_footer_html();
7155 }
7156
7157 sub git_log {
7158         git_log_generic('log', \&git_log_body,
7159                         $hash, $hash_parent);
7160 }
7161
7162 sub git_commit {
7163         $hash ||= $hash_base || "HEAD";
7164         my %co = parse_commit($hash)
7165             or die_error(404, "Unknown commit object");
7166
7167         my $parent  = $co{'parent'};
7168         my $parents = $co{'parents'}; # listref
7169
7170         # we need to prepare $formats_nav before any parameter munging
7171         my $formats_nav;
7172         if (!defined $parent) {
7173                 # --root commitdiff
7174                 $formats_nav .= '(initial)';
7175         } elsif (@$parents == 1) {
7176                 # single parent commit
7177                 $formats_nav .=
7178                         '(parent: ' .
7179                         $cgi->a({-href => href(action=>"commit",
7180                                                hash=>$parent)},
7181                                 esc_html(substr($parent, 0, 7))) .
7182                         ')';
7183         } else {
7184                 # merge commit
7185                 $formats_nav .=
7186                         '(merge: ' .
7187                         join(' ', map {
7188                                 $cgi->a({-href => href(action=>"commit",
7189                                                        hash=>$_)},
7190                                         esc_html(substr($_, 0, 7)));
7191                         } @$parents ) .
7192                         ')';
7193         }
7194         if (gitweb_check_feature('patches') && @$parents <= 1) {
7195                 $formats_nav .= " | " .
7196                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7197                                 "patch");
7198         }
7199
7200         if (!defined $parent) {
7201                 $parent = "--root";
7202         }
7203         my @difftree;
7204         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7205                 @diff_opts,
7206                 (@$parents <= 1 ? $parent : '-c'),
7207                 $hash, "--"
7208                 or die_error(500, "Open git-diff-tree failed");
7209         @difftree = map { chomp; $_ } <$fd>;
7210         close $fd or die_error(404, "Reading git-diff-tree failed");
7211
7212         # non-textual hash id's can be cached
7213         my $expires;
7214         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7215                 $expires = "+1d";
7216         }
7217         my $refs = git_get_references();
7218         my $ref = format_ref_marker($refs, $co{'id'});
7219
7220         git_header_html(undef, $expires);
7221         git_print_page_nav('commit', '',
7222                            $hash, $co{'tree'}, $hash,
7223                            $formats_nav);
7224
7225         if (defined $co{'parent'}) {
7226                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7227         } else {
7228                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7229         }
7230         print "<div class=\"title_text\">\n" .
7231               "<table class=\"object_header\">\n";
7232         git_print_authorship_rows(\%co);
7233         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7234         print "<tr>" .
7235               "<td>tree</td>" .
7236               "<td class=\"sha1\">" .
7237               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7238                        class => "list"}, $co{'tree'}) .
7239               "</td>" .
7240               "<td class=\"link\">" .
7241               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7242                       "tree");
7243         my $snapshot_links = format_snapshot_links($hash);
7244         if (defined $snapshot_links) {
7245                 print " | " . $snapshot_links;
7246         }
7247         print "</td>" .
7248               "</tr>\n";
7249
7250         foreach my $par (@$parents) {
7251                 print "<tr>" .
7252                       "<td>parent</td>" .
7253                       "<td class=\"sha1\">" .
7254                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7255                                class => "list"}, $par) .
7256                       "</td>" .
7257                       "<td class=\"link\">" .
7258                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7259                       " | " .
7260                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7261                       "</td>" .
7262                       "</tr>\n";
7263         }
7264         print "</table>".
7265               "</div>\n";
7266
7267         print "<div class=\"page_body\">\n";
7268         git_print_log($co{'comment'});
7269         print "</div>\n";
7270
7271         git_difftree_body(\@difftree, $hash, @$parents);
7272
7273         git_footer_html();
7274 }
7275
7276 sub git_object {
7277         # object is defined by:
7278         # - hash or hash_base alone
7279         # - hash_base and file_name
7280         my $type;
7281
7282         # - hash or hash_base alone
7283         if ($hash || ($hash_base && !defined $file_name)) {
7284                 my $object_id = $hash || $hash_base;
7285
7286                 open my $fd, "-|", quote_command(
7287                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7288                         or die_error(404, "Object does not exist");
7289                 $type = <$fd>;
7290                 chomp $type;
7291                 close $fd
7292                         or die_error(404, "Object does not exist");
7293
7294         # - hash_base and file_name
7295         } elsif ($hash_base && defined $file_name) {
7296                 $file_name =~ s,/+$,,;
7297
7298                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7299                         or die_error(404, "Base object does not exist");
7300
7301                 # here errors should not hapen
7302                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7303                         or die_error(500, "Open git-ls-tree failed");
7304                 my $line = <$fd>;
7305                 close $fd;
7306
7307                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7308                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7309                         die_error(404, "File or directory for given base does not exist");
7310                 }
7311                 $type = $2;
7312                 $hash = $3;
7313         } else {
7314                 die_error(400, "Not enough information to find object");
7315         }
7316
7317         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7318                                           hash=>$hash, hash_base=>$hash_base,
7319                                           file_name=>$file_name),
7320                              -status => '302 Found');
7321 }
7322
7323 sub git_blobdiff {
7324         my $format = shift || 'html';
7325         my $diff_style = $input_params{'diff_style'} || 'inline';
7326
7327         my $fd;
7328         my @difftree;
7329         my %diffinfo;
7330         my $expires;
7331
7332         # preparing $fd and %diffinfo for git_patchset_body
7333         # new style URI
7334         if (defined $hash_base && defined $hash_parent_base) {
7335                 if (defined $file_name) {
7336                         # read raw output
7337                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7338                                 $hash_parent_base, $hash_base,
7339                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7340                                 or die_error(500, "Open git-diff-tree failed");
7341                         @difftree = map { chomp; $_ } <$fd>;
7342                         close $fd
7343                                 or die_error(404, "Reading git-diff-tree failed");
7344                         @difftree
7345                                 or die_error(404, "Blob diff not found");
7346
7347                 } elsif (defined $hash &&
7348                          $hash =~ /[0-9a-fA-F]{40}/) {
7349                         # try to find filename from $hash
7350
7351                         # read filtered raw output
7352                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7353                                 $hash_parent_base, $hash_base, "--"
7354                                 or die_error(500, "Open git-diff-tree failed");
7355                         @difftree =
7356                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7357                                 # $hash == to_id
7358                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7359                                 map { chomp; $_ } <$fd>;
7360                         close $fd
7361                                 or die_error(404, "Reading git-diff-tree failed");
7362                         @difftree
7363                                 or die_error(404, "Blob diff not found");
7364
7365                 } else {
7366                         die_error(400, "Missing one of the blob diff parameters");
7367                 }
7368
7369                 if (@difftree > 1) {
7370                         die_error(400, "Ambiguous blob diff specification");
7371                 }
7372
7373                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7374                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7375                 $file_name   ||= $diffinfo{'to_file'};
7376
7377                 $hash_parent ||= $diffinfo{'from_id'};
7378                 $hash        ||= $diffinfo{'to_id'};
7379
7380                 # non-textual hash id's can be cached
7381                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7382                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7383                         $expires = '+1d';
7384                 }
7385
7386                 # open patch output
7387                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7388                         '-p', ($format eq 'html' ? "--full-index" : ()),
7389                         $hash_parent_base, $hash_base,
7390                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7391                         or die_error(500, "Open git-diff-tree failed");
7392         }
7393
7394         # old/legacy style URI -- not generated anymore since 1.4.3.
7395         if (!%diffinfo) {
7396                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7397         }
7398
7399         # header
7400         if ($format eq 'html') {
7401                 my $formats_nav =
7402                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7403                                 "raw");
7404                 $formats_nav .= diff_style_nav($diff_style);
7405                 git_header_html(undef, $expires);
7406                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7407                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7408                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7409                 } else {
7410                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7411                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7412                 }
7413                 if (defined $file_name) {
7414                         git_print_page_path($file_name, "blob", $hash_base);
7415                 } else {
7416                         print "<div class=\"page_path\"></div>\n";
7417                 }
7418
7419         } elsif ($format eq 'plain') {
7420                 print $cgi->header(
7421                         -type => 'text/plain',
7422                         -charset => 'utf-8',
7423                         -expires => $expires,
7424                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7425
7426                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7427
7428         } else {
7429                 die_error(400, "Unknown blobdiff format");
7430         }
7431
7432         # patch
7433         if ($format eq 'html') {
7434                 print "<div class=\"page_body\">\n";
7435
7436                 git_patchset_body($fd, $diff_style,
7437                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7438                 close $fd;
7439
7440                 print "</div>\n"; # class="page_body"
7441                 git_footer_html();
7442
7443         } else {
7444                 while (my $line = <$fd>) {
7445                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7446                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7447
7448                         print $line;
7449
7450                         last if $line =~ m!^\+\+\+!;
7451                 }
7452                 local $/ = undef;
7453                 print <$fd>;
7454                 close $fd;
7455         }
7456 }
7457
7458 sub git_blobdiff_plain {
7459         git_blobdiff('plain');
7460 }
7461
7462 # assumes that it is added as later part of already existing navigation,
7463 # so it returns "| foo | bar" rather than just "foo | bar"
7464 sub diff_style_nav {
7465         my ($diff_style, $is_combined) = @_;
7466         $diff_style ||= 'inline';
7467
7468         return "" if ($is_combined);
7469
7470         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7471         my %styles = @styles;
7472         @styles =
7473                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7474
7475         return join '',
7476                 map { " | ".$_ }
7477                 map {
7478                         $_ eq $diff_style ? $styles{$_} :
7479                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7480                 } @styles;
7481 }
7482
7483 sub git_commitdiff {
7484         my %params = @_;
7485         my $format = $params{-format} || 'html';
7486         my $diff_style = $input_params{'diff_style'} || 'inline';
7487
7488         my ($patch_max) = gitweb_get_feature('patches');
7489         if ($format eq 'patch') {
7490                 die_error(403, "Patch view not allowed") unless $patch_max;
7491         }
7492
7493         $hash ||= $hash_base || "HEAD";
7494         my %co = parse_commit($hash)
7495             or die_error(404, "Unknown commit object");
7496
7497         # choose format for commitdiff for merge
7498         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7499                 $hash_parent = '--cc';
7500         }
7501         # we need to prepare $formats_nav before almost any parameter munging
7502         my $formats_nav;
7503         if ($format eq 'html') {
7504                 $formats_nav =
7505                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7506                                 "raw");
7507                 if ($patch_max && @{$co{'parents'}} <= 1) {
7508                         $formats_nav .= " | " .
7509                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7510                                         "patch");
7511                 }
7512                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7513
7514                 if (defined $hash_parent &&
7515                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7516                         # commitdiff with two commits given
7517                         my $hash_parent_short = $hash_parent;
7518                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7519                                 $hash_parent_short = substr($hash_parent, 0, 7);
7520                         }
7521                         $formats_nav .=
7522                                 ' (from';
7523                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7524                                 if ($co{'parents'}[$i] eq $hash_parent) {
7525                                         $formats_nav .= ' parent ' . ($i+1);
7526                                         last;
7527                                 }
7528                         }
7529                         $formats_nav .= ': ' .
7530                                 $cgi->a({-href => href(-replay=>1,
7531                                                        hash=>$hash_parent, hash_base=>undef)},
7532                                         esc_html($hash_parent_short)) .
7533                                 ')';
7534                 } elsif (!$co{'parent'}) {
7535                         # --root commitdiff
7536                         $formats_nav .= ' (initial)';
7537                 } elsif (scalar @{$co{'parents'}} == 1) {
7538                         # single parent commit
7539                         $formats_nav .=
7540                                 ' (parent: ' .
7541                                 $cgi->a({-href => href(-replay=>1,
7542                                                        hash=>$co{'parent'}, hash_base=>undef)},
7543                                         esc_html(substr($co{'parent'}, 0, 7))) .
7544                                 ')';
7545                 } else {
7546                         # merge commit
7547                         if ($hash_parent eq '--cc') {
7548                                 $formats_nav .= ' | ' .
7549                                         $cgi->a({-href => href(-replay=>1,
7550                                                                hash=>$hash, hash_parent=>'-c')},
7551                                                 'combined');
7552                         } else { # $hash_parent eq '-c'
7553                                 $formats_nav .= ' | ' .
7554                                         $cgi->a({-href => href(-replay=>1,
7555                                                                hash=>$hash, hash_parent=>'--cc')},
7556                                                 'compact');
7557                         }
7558                         $formats_nav .=
7559                                 ' (merge: ' .
7560                                 join(' ', map {
7561                                         $cgi->a({-href => href(-replay=>1,
7562                                                                hash=>$_, hash_base=>undef)},
7563                                                 esc_html(substr($_, 0, 7)));
7564                                 } @{$co{'parents'}} ) .
7565                                 ')';
7566                 }
7567         }
7568
7569         my $hash_parent_param = $hash_parent;
7570         if (!defined $hash_parent_param) {
7571                 # --cc for multiple parents, --root for parentless
7572                 $hash_parent_param =
7573                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7574         }
7575
7576         # read commitdiff
7577         my $fd;
7578         my @difftree;
7579         if ($format eq 'html') {
7580                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7581                         "--no-commit-id", "--patch-with-raw", "--full-index",
7582                         $hash_parent_param, $hash, "--"
7583                         or die_error(500, "Open git-diff-tree failed");
7584
7585                 while (my $line = <$fd>) {
7586                         chomp $line;
7587                         # empty line ends raw part of diff-tree output
7588                         last unless $line;
7589                         push @difftree, scalar parse_difftree_raw_line($line);
7590                 }
7591
7592         } elsif ($format eq 'plain') {
7593                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7594                         '-p', $hash_parent_param, $hash, "--"
7595                         or die_error(500, "Open git-diff-tree failed");
7596         } elsif ($format eq 'patch') {
7597                 # For commit ranges, we limit the output to the number of
7598                 # patches specified in the 'patches' feature.
7599                 # For single commits, we limit the output to a single patch,
7600                 # diverging from the git-format-patch default.
7601                 my @commit_spec = ();
7602                 if ($hash_parent) {
7603                         if ($patch_max > 0) {
7604                                 push @commit_spec, "-$patch_max";
7605                         }
7606                         push @commit_spec, '-n', "$hash_parent..$hash";
7607                 } else {
7608                         if ($params{-single}) {
7609                                 push @commit_spec, '-1';
7610                         } else {
7611                                 if ($patch_max > 0) {
7612                                         push @commit_spec, "-$patch_max";
7613                                 }
7614                                 push @commit_spec, "-n";
7615                         }
7616                         push @commit_spec, '--root', $hash;
7617                 }
7618                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7619                         '--encoding=utf8', '--stdout', @commit_spec
7620                         or die_error(500, "Open git-format-patch failed");
7621         } else {
7622                 die_error(400, "Unknown commitdiff format");
7623         }
7624
7625         # non-textual hash id's can be cached
7626         my $expires;
7627         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7628                 $expires = "+1d";
7629         }
7630
7631         # write commit message
7632         if ($format eq 'html') {
7633                 my $refs = git_get_references();
7634                 my $ref = format_ref_marker($refs, $co{'id'});
7635
7636                 git_header_html(undef, $expires);
7637                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7638                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7639                 print "<div class=\"title_text\">\n" .
7640                       "<table class=\"object_header\">\n";
7641                 git_print_authorship_rows(\%co);
7642                 print "</table>".
7643                       "</div>\n";
7644                 print "<div class=\"page_body\">\n";
7645                 if (@{$co{'comment'}} > 1) {
7646                         print "<div class=\"log\">\n";
7647                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7648                         print "</div>\n"; # class="log"
7649                 }
7650
7651         } elsif ($format eq 'plain') {
7652                 my $refs = git_get_references("tags");
7653                 my $tagname = git_get_rev_name_tags($hash);
7654                 my $filename = basename($project) . "-$hash.patch";
7655
7656                 print $cgi->header(
7657                         -type => 'text/plain',
7658                         -charset => 'utf-8',
7659                         -expires => $expires,
7660                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7661                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7662                 print "From: " . to_utf8($co{'author'}) . "\n";
7663                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7664                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7665
7666                 print "X-Git-Tag: $tagname\n" if $tagname;
7667                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7668
7669                 foreach my $line (@{$co{'comment'}}) {
7670                         print to_utf8($line) . "\n";
7671                 }
7672                 print "---\n\n";
7673         } elsif ($format eq 'patch') {
7674                 my $filename = basename($project) . "-$hash.patch";
7675
7676                 print $cgi->header(
7677                         -type => 'text/plain',
7678                         -charset => 'utf-8',
7679                         -expires => $expires,
7680                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7681         }
7682
7683         # write patch
7684         if ($format eq 'html') {
7685                 my $use_parents = !defined $hash_parent ||
7686                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7687                 git_difftree_body(\@difftree, $hash,
7688                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7689                 print "<br/>\n";
7690
7691                 git_patchset_body($fd, $diff_style,
7692                                   \@difftree, $hash,
7693                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7694                 close $fd;
7695                 print "</div>\n"; # class="page_body"
7696                 git_footer_html();
7697
7698         } elsif ($format eq 'plain') {
7699                 local $/ = undef;
7700                 print <$fd>;
7701                 close $fd
7702                         or print "Reading git-diff-tree failed\n";
7703         } elsif ($format eq 'patch') {
7704                 local $/ = undef;
7705                 print <$fd>;
7706                 close $fd
7707                         or print "Reading git-format-patch failed\n";
7708         }
7709 }
7710
7711 sub git_commitdiff_plain {
7712         git_commitdiff(-format => 'plain');
7713 }
7714
7715 # format-patch-style patches
7716 sub git_patch {
7717         git_commitdiff(-format => 'patch', -single => 1);
7718 }
7719
7720 sub git_patches {
7721         git_commitdiff(-format => 'patch');
7722 }
7723
7724 sub git_history {
7725         git_log_generic('history', \&git_history_body,
7726                         $hash_base, $hash_parent_base,
7727                         $file_name, $hash);
7728 }
7729
7730 sub git_search {
7731         $searchtype ||= 'commit';
7732
7733         # check if appropriate features are enabled
7734         gitweb_check_feature('search')
7735                 or die_error(403, "Search is disabled");
7736         if ($searchtype eq 'pickaxe') {
7737                 # pickaxe may take all resources of your box and run for several minutes
7738                 # with every query - so decide by yourself how public you make this feature
7739                 gitweb_check_feature('pickaxe')
7740                         or die_error(403, "Pickaxe search is disabled");
7741         }
7742         if ($searchtype eq 'grep') {
7743                 # grep search might be potentially CPU-intensive, too
7744                 gitweb_check_feature('grep')
7745                         or die_error(403, "Grep search is disabled");
7746         }
7747
7748         if (!defined $searchtext) {
7749                 die_error(400, "Text field is empty");
7750         }
7751         if (!defined $hash) {
7752                 $hash = git_get_head_hash($project);
7753         }
7754         my %co = parse_commit($hash);
7755         if (!%co) {
7756                 die_error(404, "Unknown commit object");
7757         }
7758         if (!defined $page) {
7759                 $page = 0;
7760         }
7761
7762         if ($searchtype eq 'commit' ||
7763             $searchtype eq 'author' ||
7764             $searchtype eq 'committer') {
7765                 git_search_message(%co);
7766         } elsif ($searchtype eq 'pickaxe') {
7767                 git_search_changes(%co);
7768         } elsif ($searchtype eq 'grep') {
7769                 git_search_files(%co);
7770         } else {
7771                 die_error(400, "Unknown search type");
7772         }
7773 }
7774
7775 sub git_search_help {
7776         git_header_html();
7777         git_print_page_nav('','', $hash,$hash,$hash);
7778         print <<EOT;
7779 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7780 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7781 the pattern entered is recognized as the POSIX extended
7782 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7783 insensitive).</p>
7784 <dl>
7785 <dt><b>commit</b></dt>
7786 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7787 EOT
7788         my $have_grep = gitweb_check_feature('grep');
7789         if ($have_grep) {
7790                 print <<EOT;
7791 <dt><b>grep</b></dt>
7792 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7793     a different one) are searched for the given pattern. On large trees, this search can take
7794 a while and put some strain on the server, so please use it with some consideration. Note that
7795 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7796 case-sensitive.</dd>
7797 EOT
7798         }
7799         print <<EOT;
7800 <dt><b>author</b></dt>
7801 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7802 <dt><b>committer</b></dt>
7803 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7804 EOT
7805         my $have_pickaxe = gitweb_check_feature('pickaxe');
7806         if ($have_pickaxe) {
7807                 print <<EOT;
7808 <dt><b>pickaxe</b></dt>
7809 <dd>All commits that caused the string to appear or disappear from any file (changes that
7810 added, removed or "modified" the string) will be listed. This search can take a while and
7811 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7812 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7813 EOT
7814         }
7815         print "</dl>\n";
7816         git_footer_html();
7817 }
7818
7819 sub git_shortlog {
7820         git_log_generic('shortlog', \&git_shortlog_body,
7821                         $hash, $hash_parent);
7822 }
7823
7824 ## ......................................................................
7825 ## feeds (RSS, Atom; OPML)
7826
7827 sub git_feed {
7828         my $format = shift || 'atom';
7829         my $have_blame = gitweb_check_feature('blame');
7830
7831         # Atom: http://www.atomenabled.org/developers/syndication/
7832         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7833         if ($format ne 'rss' && $format ne 'atom') {
7834                 die_error(400, "Unknown web feed format");
7835         }
7836
7837         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7838         my $head = $hash || 'HEAD';
7839         my @commitlist = parse_commits($head, 150, 0, $file_name);
7840
7841         my %latest_commit;
7842         my %latest_date;
7843         my $content_type = "application/$format+xml";
7844         if (defined $cgi->http('HTTP_ACCEPT') &&
7845                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7846                 # browser (feed reader) prefers text/xml
7847                 $content_type = 'text/xml';
7848         }
7849         if (defined($commitlist[0])) {
7850                 %latest_commit = %{$commitlist[0]};
7851                 my $latest_epoch = $latest_commit{'committer_epoch'};
7852                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7853                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7854                 if (defined $if_modified) {
7855                         my $since;
7856                         if (eval { require HTTP::Date; 1; }) {
7857                                 $since = HTTP::Date::str2time($if_modified);
7858                         } elsif (eval { require Time::ParseDate; 1; }) {
7859                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7860                         }
7861                         if (defined $since && $latest_epoch <= $since) {
7862                                 print $cgi->header(
7863                                         -type => $content_type,
7864                                         -charset => 'utf-8',
7865                                         -last_modified => $latest_date{'rfc2822'},
7866                                         -status => '304 Not Modified');
7867                                 return;
7868                         }
7869                 }
7870                 print $cgi->header(
7871                         -type => $content_type,
7872                         -charset => 'utf-8',
7873                         -last_modified => $latest_date{'rfc2822'});
7874         } else {
7875                 print $cgi->header(
7876                         -type => $content_type,
7877                         -charset => 'utf-8');
7878         }
7879
7880         # Optimization: skip generating the body if client asks only
7881         # for Last-Modified date.
7882         return if ($cgi->request_method() eq 'HEAD');
7883
7884         # header variables
7885         my $title = "$site_name - $project/$action";
7886         my $feed_type = 'log';
7887         if (defined $hash) {
7888                 $title .= " - '$hash'";
7889                 $feed_type = 'branch log';
7890                 if (defined $file_name) {
7891                         $title .= " :: $file_name";
7892                         $feed_type = 'history';
7893                 }
7894         } elsif (defined $file_name) {
7895                 $title .= " - $file_name";
7896                 $feed_type = 'history';
7897         }
7898         $title .= " $feed_type";
7899         my $descr = git_get_project_description($project);
7900         if (defined $descr) {
7901                 $descr = esc_html($descr);
7902         } else {
7903                 $descr = "$project " .
7904                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7905                          " feed";
7906         }
7907         my $owner = git_get_project_owner($project);
7908         $owner = esc_html($owner);
7909
7910         #header
7911         my $alt_url;
7912         if (defined $file_name) {
7913                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7914         } elsif (defined $hash) {
7915                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7916         } else {
7917                 $alt_url = href(-full=>1, action=>"summary");
7918         }
7919         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7920         if ($format eq 'rss') {
7921                 print <<XML;
7922 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7923 <channel>
7924 XML
7925                 print "<title>$title</title>\n" .
7926                       "<link>$alt_url</link>\n" .
7927                       "<description>$descr</description>\n" .
7928                       "<language>en</language>\n" .
7929                       # project owner is responsible for 'editorial' content
7930                       "<managingEditor>$owner</managingEditor>\n";
7931                 if (defined $logo || defined $favicon) {
7932                         # prefer the logo to the favicon, since RSS
7933                         # doesn't allow both
7934                         my $img = esc_url($logo || $favicon);
7935                         print "<image>\n" .
7936                               "<url>$img</url>\n" .
7937                               "<title>$title</title>\n" .
7938                               "<link>$alt_url</link>\n" .
7939                               "</image>\n";
7940                 }
7941                 if (%latest_date) {
7942                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7943                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7944                 }
7945                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7946         } elsif ($format eq 'atom') {
7947                 print <<XML;
7948 <feed xmlns="http://www.w3.org/2005/Atom">
7949 XML
7950                 print "<title>$title</title>\n" .
7951                       "<subtitle>$descr</subtitle>\n" .
7952                       '<link rel="alternate" type="text/html" href="' .
7953                       $alt_url . '" />' . "\n" .
7954                       '<link rel="self" type="' . $content_type . '" href="' .
7955                       $cgi->self_url() . '" />' . "\n" .
7956                       "<id>" . href(-full=>1) . "</id>\n" .
7957                       # use project owner for feed author
7958                       "<author><name>$owner</name></author>\n";
7959                 if (defined $favicon) {
7960                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7961                 }
7962                 if (defined $logo) {
7963                         # not twice as wide as tall: 72 x 27 pixels
7964                         print "<logo>" . esc_url($logo) . "</logo>\n";
7965                 }
7966                 if (! %latest_date) {
7967                         # dummy date to keep the feed valid until commits trickle in:
7968                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7969                 } else {
7970                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7971                 }
7972                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7973         }
7974
7975         # contents
7976         for (my $i = 0; $i <= $#commitlist; $i++) {
7977                 my %co = %{$commitlist[$i]};
7978                 my $commit = $co{'id'};
7979                 # we read 150, we always show 30 and the ones more recent than 48 hours
7980                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7981                         last;
7982                 }
7983                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7984
7985                 # get list of changed files
7986                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7987                         $co{'parent'} || "--root",
7988                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7989                         or next;
7990                 my @difftree = map { chomp; $_ } <$fd>;
7991                 close $fd
7992                         or next;
7993
7994                 # print element (entry, item)
7995                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7996                 if ($format eq 'rss') {
7997                         print "<item>\n" .
7998                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7999                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8000                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8001                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8002                               "<link>$co_url</link>\n" .
8003                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8004                               "<content:encoded>" .
8005                               "<![CDATA[\n";
8006                 } elsif ($format eq 'atom') {
8007                         print "<entry>\n" .
8008                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8009                               "<updated>$cd{'iso-8601'}</updated>\n" .
8010                               "<author>\n" .
8011                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8012                         if ($co{'author_email'}) {
8013                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8014                         }
8015                         print "</author>\n" .
8016                               # use committer for contributor
8017                               "<contributor>\n" .
8018                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8019                         if ($co{'committer_email'}) {
8020                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8021                         }
8022                         print "</contributor>\n" .
8023                               "<published>$cd{'iso-8601'}</published>\n" .
8024                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8025                               "<id>$co_url</id>\n" .
8026                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8027                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8028                 }
8029                 my $comment = $co{'comment'};
8030                 print "<pre>\n";
8031                 foreach my $line (@$comment) {
8032                         $line = esc_html($line);
8033                         print "$line\n";
8034                 }
8035                 print "</pre><ul>\n";
8036                 foreach my $difftree_line (@difftree) {
8037                         my %difftree = parse_difftree_raw_line($difftree_line);
8038                         next if !$difftree{'from_id'};
8039
8040                         my $file = $difftree{'file'} || $difftree{'to_file'};
8041
8042                         print "<li>" .
8043                               "[" .
8044                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8045                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8046                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8047                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8048                                       -title => "diff"}, 'D');
8049                         if ($have_blame) {
8050                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8051                                                              file_name=>$file, hash_base=>$commit),
8052                                               -title => "blame"}, 'B');
8053                         }
8054                         # if this is not a feed of a file history
8055                         if (!defined $file_name || $file_name ne $file) {
8056                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8057                                                              file_name=>$file, hash=>$commit),
8058                                               -title => "history"}, 'H');
8059                         }
8060                         $file = esc_path($file);
8061                         print "] ".
8062                               "$file</li>\n";
8063                 }
8064                 if ($format eq 'rss') {
8065                         print "</ul>]]>\n" .
8066                               "</content:encoded>\n" .
8067                               "</item>\n";
8068                 } elsif ($format eq 'atom') {
8069                         print "</ul>\n</div>\n" .
8070                               "</content>\n" .
8071                               "</entry>\n";
8072                 }
8073         }
8074
8075         # end of feed
8076         if ($format eq 'rss') {
8077                 print "</channel>\n</rss>\n";
8078         } elsif ($format eq 'atom') {
8079                 print "</feed>\n";
8080         }
8081 }
8082
8083 sub git_rss {
8084         git_feed('rss');
8085 }
8086
8087 sub git_atom {
8088         git_feed('atom');
8089 }
8090
8091 sub git_opml {
8092         my @list = git_get_projects_list($project_filter, $strict_export);
8093         if (!@list) {
8094                 die_error(404, "No projects found");
8095         }
8096
8097         print $cgi->header(
8098                 -type => 'text/xml',
8099                 -charset => 'utf-8',
8100                 -content_disposition => 'inline; filename="opml.xml"');
8101
8102         my $title = esc_html($site_name);
8103         my $filter = " within subdirectory ";
8104         if (defined $project_filter) {
8105                 $filter .= esc_html($project_filter);
8106         } else {
8107                 $filter = "";
8108         }
8109         print <<XML;
8110 <?xml version="1.0" encoding="utf-8"?>
8111 <opml version="1.0">
8112 <head>
8113   <title>$title OPML Export$filter</title>
8114 </head>
8115 <body>
8116 <outline text="git RSS feeds">
8117 XML
8118
8119         foreach my $pr (@list) {
8120                 my %proj = %$pr;
8121                 my $head = git_get_head_hash($proj{'path'});
8122                 if (!defined $head) {
8123                         next;
8124                 }
8125                 $git_dir = "$projectroot/$proj{'path'}";
8126                 my %co = parse_commit($head);
8127                 if (!%co) {
8128                         next;
8129                 }
8130
8131                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8132                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8133                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8134                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8135         }
8136         print <<XML;
8137 </outline>
8138 </body>
8139 </opml>
8140 XML
8141 }