scripts/kconfig/streamline_config.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2005-2009 - Steven Rostedt
   4 # Licensed under the terms of the GNU GPL License version 2
   5 #
   6 #  It's simple enough to figure out how this works.
   7 #  If not, then you can ask me at stripconfig@goodmis.org
   8 #
   9 # What it does?
  10 #
  11 #   If you have installed a Linux kernel from a distribution
  12 #   that turns on way too many modules than you need, and
  13 #   you only want the modules you use, then this program
  14 #   is perfect for you.
  15 #
  16 #   It gives you the ability to turn off all the modules that are
  17 #   not loaded on your system.
  18 #
  19 # Howto:
  20 #
  21 #  1. Boot up the kernel that you want to stream line the config on.
  22 #  2. Change directory to the directory holding the source of the
  23 #       kernel that you just booted.
  24 #  3. Copy the configuraton file to this directory as .config
  25 #  4. Have all your devices that you need modules for connected and
  26 #      operational (make sure that their corresponding modules are loaded)
  27 #  5. Run this script redirecting the output to some other file
  28 #       like config_strip.
  29 #  6. Back up your old config (if you want too).
  30 #  7. copy the config_strip file to .config
  31 #  8. Run "make oldconfig"
  32 #
  33 #  Now your kernel is ready to be built with only the modules that
  34 #  are loaded.
  35 #
  36 # Here's what I did with my Debian distribution.
  37 #
  38 #    cd /usr/src/linux-2.6.10
  39 #    cp /boot/config-2.6.10-1-686-smp .config
  40 #    ~/bin/streamline_config > config_strip
  41 #    mv .config config_sav
  42 #    mv config_strip .config
  43 #    make oldconfig
  44 #
  45 use strict;
  46 use Getopt::Long;
  47
  48 # set the environment variable LOCALMODCONFIG_DEBUG to get
  49 # debug output.
  50 my $debugprint = 0;
  51 $debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
  52
  53 sub dprint {
  54     return if (!$debugprint);
  55     print STDERR @_;
  56 }
  57
  58 my $config = ".config";
  59
  60 my $uname = `uname -r`;
  61 chomp $uname;
  62
  63 my @searchconfigs = (
  64         {
  65             "file" => ".config",
  66             "exec" => "cat",
  67         },
  68         {
  69             "file" => "/proc/config.gz",
  70             "exec" => "zcat",
  71         },
  72         {
  73             "file" => "/boot/config-$uname",
  74             "exec" => "cat",
  75         },
  76         {
  77             "file" => "/boot/vmlinuz-$uname",
  78             "exec" => "scripts/extract-ikconfig",
  79             "test" => "scripts/extract-ikconfig",
  80         },
  81         {
  82             "file" => "vmlinux",
  83             "exec" => "scripts/extract-ikconfig",
  84             "test" => "scripts/extract-ikconfig",
  85         },
  86         {
  87             "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
  88             "exec" => "scripts/extract-ikconfig",
  89             "test" => "scripts/extract-ikconfig",
  90         },
  91         {
  92             "file" => "kernel/configs.ko",
  93             "exec" => "scripts/extract-ikconfig",
  94             "test" => "scripts/extract-ikconfig",
  95         },
  96         {
  97             "file" => "kernel/configs.o",
  98             "exec" => "scripts/extract-ikconfig",
  99             "test" => "scripts/extract-ikconfig",
 100         },
 101 );
 102
 103 sub read_config {
 104     foreach my $conf (@searchconfigs) {
 105         my $file = $conf->{"file"};
 106
 107         next if ( ! -f "$file");
 108
 109         if (defined($conf->{"test"})) {
 110             `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
 111             next if ($?);
 112         }
 113
 114         my $exec = $conf->{"exec"};
 115
 116         print STDERR "using config: '$file'\n";
 117
 118         open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
 119         my @x = <$infile>;
 120         close $infile;
 121         return @x;
 122     }
 123     die "No config file found";
 124 }
 125
 126 my @config_file = read_config;
 127
 128 # Parse options
 129 my $localmodconfig = 0;
 130 my $localyesconfig = 0;
 131
 132 GetOptions("localmodconfig" => \$localmodconfig,
 133            "localyesconfig" => \$localyesconfig);
 134
 135 # Get the build source and top level Kconfig file (passed in)
 136 my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
 137 my $kconfig = $ARGV[1];
 138 my $lsmod_file = $ENV{'LSMOD'};
 139
 140 my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
 141 chomp @makefiles;
 142
 143 my %depends;
 144 my %selects;
 145 my %prompts;
 146 my %objects;
 147 my $var;
 148 my $iflevel = 0;
 149 my @ifdeps;
 150
 151 # prevent recursion
 152 my %read_kconfigs;
 153
 154 sub read_kconfig {
 155     my ($kconfig) = @_;
 156
 157     my $state = "NONE";
 158     my $config;
 159
 160     my $cont = 0;
 161     my $line;
 162
 163     my $source = "$ksource/$kconfig";
 164     my $last_source = "";
 165
 166     # Check for any environment variables used
 167     while ($source =~ /\$(\w+)/ && $last_source ne $source) {
 168         my $env = $1;
 169         $last_source = $source;
 170         $source =~ s/\$$env/$ENV{$env}/;
 171     }
 172
 173     open(my $kinfile, '<', $source) || die "Can't open $kconfig";
 174     while (<$kinfile>) {
 175         chomp;
 176
 177         # Make sure that lines ending with \ continue
 178         if ($cont) {
 179             $_ = $line . " " . $_;
 180         }
 181
 182         if (s/\\$//) {
 183             $cont = 1;
 184             $line = $_;
 185             next;
 186         }
 187
 188         $cont = 0;
 189
 190         # collect any Kconfig sources
 191         if (/^source\s*"(.*)"/) {
 192             my $kconfig = $1;
 193             # prevent reading twice.
 194             if (!defined($read_kconfigs{$kconfig})) {
 195                 $read_kconfigs{$kconfig} = 1;
 196                 read_kconfig($kconfig);
 197             }
 198             next;
 199         }
 200
 201         # configs found
 202         if (/^\s*(menu)?config\s+(\S+)\s*$/) {
 203             $state = "NEW";
 204             $config = $2;
 205
 206             # Add depends for 'if' nesting
 207             for (my $i = 0; $i < $iflevel; $i++) {
 208                 if ($i) {
 209                     $depends{$config} .= " " . $ifdeps[$i];
 210                 } else {
 211                     $depends{$config} = $ifdeps[$i];
 212                 }
 213                 $state = "DEP";
 214             }
 215
 216         # collect the depends for the config
 217         } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
 218             $state = "DEP";
 219             $depends{$config} = $1;
 220         } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
 221             $depends{$config} .= " " . $1;
 222
 223         # Get the configs that select this config
 224         } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
 225             my $conf = $1;
 226             if (defined($selects{$conf})) {
 227                 $selects{$conf} .= " " . $config;
 228             } else {
 229                 $selects{$conf} = $config;
 230             }
 231
 232         # configs without prompts must be selected
 233         } elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
 234             # note if the config has a prompt
 235             $prompts{$config} = 1;
 236
 237         # Check for if statements
 238         } elsif (/^if\s+(.*\S)\s*$/) {
 239             my $deps = $1;
 240             # remove beginning and ending non text
 241             $deps =~ s/^[^a-zA-Z0-9_]*//;
 242             $deps =~ s/[^a-zA-Z0-9_]*$//;
 243
 244             my @deps = split /[^a-zA-Z0-9_]+/, $deps;
 245
 246             $ifdeps[$iflevel++] = join ':', @deps;
 247
 248         } elsif (/^endif/) {
 249
 250             $iflevel-- if ($iflevel);
 251
 252         # stop on "help"
 253         } elsif (/^\s*help\s*$/) {
 254             $state = "NONE";
 255         }
 256     }
 257     close($kinfile);
 258 }
 259
 260 if ($kconfig) {
 261     read_kconfig($kconfig);
 262 }
 263
 264 # Makefiles can use variables to define their dependencies
 265 sub convert_vars {
 266     my ($line, %vars) = @_;
 267
 268     my $process = "";
 269
 270     while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
 271         my $start = $1;
 272         my $variable = $2;
 273         my $var = $3;
 274
 275         if (defined($vars{$var})) {
 276             $process .= $start . $vars{$var};
 277         } else {
 278             $process .= $start . $variable;
 279         }
 280     }
 281
 282     $process .= $line;
 283
 284     return $process;
 285 }
 286
 287 # Read all Makefiles to map the configs to the objects
 288 foreach my $makefile (@makefiles) {
 289
 290     my $line = "";
 291     my %make_vars;
 292
 293     open(my $infile, '<', $makefile) || die "Can't open $makefile";
 294     while (<$infile>) {
 295         # if this line ends with a backslash, continue
 296         chomp;
 297         if (/^(.*)\\$/) {
 298             $line .= $1;
 299             next;
 300         }
 301
 302         $line .= $_;
 303         $_ = $line;
 304         $line = "";
 305
 306         my $objs;
 307
 308         # Convert variables in a line (could define configs)
 309         $_ = convert_vars($_, %make_vars);
 310
 311         # collect objects after obj-$(CONFIG_FOO_BAR)
 312         if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
 313             $var = $1;
 314             $objs = $2;
 315
 316         # check if variables are set
 317         } elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
 318             $make_vars{$1} = $2;
 319         }
 320         if (defined($objs)) {
 321             foreach my $obj (split /\s+/,$objs) {
 322                 $obj =~ s/-/_/g;
 323                 if ($obj =~ /(.*)\.o$/) {
 324                     # Objects may be enabled by more than one config.
 325                     # Store configs in an array.
 326                     my @arr;
 327
 328                     if (defined($objects{$1})) {
 329                         @arr = @{$objects{$1}};
 330                     }
 331
 332                     $arr[$#arr+1] = $var;
 333
 334                     # The objects have a hash mapping to a reference
 335                     # of an array of configs.
 336                     $objects{$1} = \@arr;
 337                 }
 338             }
 339         }
 340     }
 341     close($infile);
 342 }
 343
 344 my %modules;
 345 my $linfile;
 346
 347 if (defined($lsmod_file)) {
 348     if ( ! -f $lsmod_file) {
 349         if ( -f $ENV{'objtree'}."/".$lsmod_file) {
 350             $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
 351         } else {
 352                 die "$lsmod_file not found";
 353         }
 354     }
 355
 356     my $otype = ( -x $lsmod_file) ? '-|' : '<';
 357     open($linfile, $otype, $lsmod_file);
 358
 359 } else {
 360
 361     # see what modules are loaded on this system
 362     my $lsmod;
 363
 364     foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
 365         if ( -x "$dir/lsmod" ) {
 366             $lsmod = "$dir/lsmod";
 367             last;
 368         }
 369 }
 370     if (!defined($lsmod)) {
 371         # try just the path
 372         $lsmod = "lsmod";
 373     }
 374
 375     open($linfile, '-|', $lsmod) || die "Can not call lsmod with $lsmod";
 376 }
 377
 378 while (<$linfile>) {
 379         next if (/^Module/);  # Skip the first line.
 380         if (/^(\S+)/) {
 381                 $modules{$1} = 1;
 382         }
 383 }
 384 close ($linfile);
 385
 386 # add to the configs hash all configs that are needed to enable
 387 # a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
 388 # where we know we need bar.o so we add FOO to the list.
 389 my %configs;
 390 foreach my $module (keys(%modules)) {
 391     if (defined($objects{$module})) {
 392         my @arr = @{$objects{$module}};
 393         foreach my $conf (@arr) {
 394             $configs{$conf} = $module;
 395             dprint "$conf added by direct ($module)\n";
 396             if ($debugprint) {
 397                 my $c=$conf;
 398                 $c =~ s/^CONFIG_//;
 399                 if (defined($depends{$c})) {
 400                     dprint " deps = $depends{$c}\n";
 401                 } else {
 402                     dprint " no deps\n";
 403                 }
 404             }
 405         }
 406     } else {
 407         # Most likely, someone has a custom (binary?) module loaded.
 408         print STDERR "$module config not found!!\n";
 409     }
 410 }
 411
 412 # Read the current config, and see what is enabled. We want to
 413 # ignore configs that we would not enable anyway.
 414
 415 my %orig_configs;
 416 my $valid = "A-Za-z_0-9";
 417
 418 foreach my $line (@config_file) {
 419     $_ = $line;
 420
 421     if (/(CONFIG_[$valid]*)=(m|y)/) {
 422         $orig_configs{$1} = $2;
 423     }
 424 }
 425
 426 my $repeat = 1;
 427
 428 my $depconfig;
 429
 430 #
 431 # Note, we do not care about operands (like: &&, ||, !) we want to add any
 432 # config that is in the depend list of another config. This script does
 433 # not enable configs that are not already enabled. If we come across a
 434 # config A that depends on !B, we can still add B to the list of depends
 435 # to keep on. If A was on in the original config, B would not have been
 436 # and B would not be turned on by this script.
 437 #
 438 sub parse_config_depends
 439 {
 440     my ($p) = @_;
 441
 442     while ($p =~ /[$valid]/) {
 443
 444         if ($p =~ /^[^$valid]*([$valid]+)/) {
 445             my $conf = "CONFIG_" . $1;
 446
 447             $p =~ s/^[^$valid]*[$valid]+//;
 448
 449             # We only need to process if the depend config is a module
 450             if (!defined($orig_configs{$conf}) || !$orig_configs{conf} eq "m") {
 451                 next;
 452             }
 453
 454             if (!defined($configs{$conf})) {
 455                 # We must make sure that this config has its
 456                 # dependencies met.
 457                 $repeat = 1; # do again
 458                 dprint "$conf selected by depend $depconfig\n";
 459                 $configs{$conf} = 1;
 460             }
 461         } else {
 462             die "this should never happen";
 463         }
 464     }
 465 }
 466
 467 # Select is treated a bit differently than depends. We call this
 468 # when a config has no prompt and requires another config to be
 469 # selected. We use to just select all configs that selected this
 470 # config, but found that that can balloon into enabling hundreds
 471 # of configs that we do not care about.
 472 #
 473 # The idea is we look at all the configs that select it. If one
 474 # is already in our list of configs to enable, then there's nothing
 475 # else to do. If there isn't, we pick the first config that was
 476 # enabled in the orignal config and use that.
 477 sub parse_config_selects
 478 {
 479     my ($config, $p) = @_;
 480
 481     my $next_config;
 482
 483     while ($p =~ /[$valid]/) {
 484
 485         if ($p =~ /^[^$valid]*([$valid]+)/) {
 486             my $conf = "CONFIG_" . $1;
 487
 488             $p =~ s/^[^$valid]*[$valid]+//;
 489
 490             # Make sure that this config exists in the current .config file
 491             if (!defined($orig_configs{$conf})) {
 492                 dprint "$conf not set for $config select\n";
 493                 next;
 494             }
 495
 496             # Check if something other than a module selects this config
 497             if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
 498                 dprint "$conf (non module) selects config, we are good\n";
 499                 # we are good with this
 500                 return;
 501             }
 502             if (defined($configs{$conf})) {
 503                 dprint "$conf selects $config so we are good\n";
 504                 # A set config selects this config, we are good
 505                 return;
 506             }
 507             # Set this config to be selected
 508             if (!defined($next_config)) {
 509                 $next_config = $conf;
 510             }
 511         } else {
 512             die "this should never happen";
 513         }
 514     }
 515
 516     # If no possible config selected this, then something happened.
 517     if (!defined($next_config)) {
 518         print STDERR "WARNING: $config is required, but nothing in the\n";
 519         print STDERR "  current config selects it.\n";
 520         return;
 521     }
 522
 523     # If we are here, then we found no config that is set and
 524     # selects this config. Repeat.
 525     $repeat = 1;
 526     # Make this config need to be selected
 527     $configs{$next_config} = 1;
 528     dprint "$next_config selected by select $config\n";
 529 }
 530
 531 my %process_selects;
 532
 533 # loop through all configs, select their dependencies.
 534 sub loop_depend {
 535     $repeat = 1;
 536
 537     while ($repeat) {
 538         $repeat = 0;
 539
 540       forloop:
 541         foreach my $config (keys %configs) {
 542
 543             # If this config is not a module, we do not need to process it
 544             if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
 545                 next forloop;
 546             }
 547
 548             $config =~ s/^CONFIG_//;
 549             $depconfig = $config;
 550
 551             if (defined($depends{$config})) {
 552                 # This config has dependencies. Make sure they are also included
 553                 parse_config_depends $depends{$config};
 554             }
 555
 556             # If the config has no prompt, then we need to check if a config
 557             # that is enabled selected it. Or if we need to enable one.
 558             if (!defined($prompts{$config}) && defined($selects{$config})) {
 559                 $process_selects{$config} = 1;
 560             }
 561         }
 562     }
 563 }
 564
 565 sub loop_select {
 566
 567     foreach my $config (keys %process_selects) {
 568         $config =~ s/^CONFIG_//;
 569
 570         dprint "Process select $config\n";
 571
 572         # config has no prompt and must be selected.
 573         parse_config_selects $config, $selects{$config};
 574     }
 575 }
 576
 577 while ($repeat) {
 578     # Get the first set of configs and their dependencies.
 579     loop_depend;
 580
 581     $repeat = 0;
 582
 583     # Now we need to see if we have to check selects;
 584     loop_select;
 585 }
 586
 587 my %setconfigs;
 588
 589 # Finally, read the .config file and turn off any module enabled that
 590 # we could not find a reason to keep enabled.
 591 foreach my $line (@config_file) {
 592     $_ = $line;
 593
 594     if (/CONFIG_IKCONFIG/) {
 595         if (/# CONFIG_IKCONFIG is not set/) {
 596             # enable IKCONFIG at least as a module
 597             print "CONFIG_IKCONFIG=m\n";
 598             # don't ask about PROC
 599             print "# CONFIG_IKCONFIG_PROC is not set\n";
 600         } else {
 601             print;
 602         }
 603         next;
 604     }
 605
 606     if (/^(CONFIG.*)=(m|y)/) {
 607         if (defined($configs{$1})) {
 608             if ($localyesconfig) {
 609                 $setconfigs{$1} = 'y';
 610                 print "$1=y\n";
 611                 next;
 612             } else {
 613                 $setconfigs{$1} = $2;
 614             }
 615         } elsif ($2 eq "m") {
 616             print "# $1 is not set\n";
 617             next;
 618         }
 619     }
 620     print;
 621 }
 622
 623 # Integrity check, make sure all modules that we want enabled do
 624 # indeed have their configs set.
 625 loop:
 626 foreach my $module (keys(%modules)) {
 627     if (defined($objects{$module})) {
 628         my @arr = @{$objects{$module}};
 629         foreach my $conf (@arr) {
 630             if (defined($setconfigs{$conf})) {
 631                 next loop;
 632             }
 633         }
 634         print STDERR "module $module did not have configs";
 635         foreach my $conf (@arr) {
 636             print STDERR " " , $conf;
 637         }
 638         print STDERR "\n";
 639     }
 640 }