arch/s390/kernel/entry.S

   1 /*
   2  *    S390 low-level entry points.
   3  *
   4  *    Copyright IBM Corp. 1999, 2012
   5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   6  *               Hartmut Penner (hp@de.ibm.com),
   7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
   9  */
  10
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/cache.h>
  14 #include <asm/errno.h>
  15 #include <asm/ptrace.h>
  16 #include <asm/thread_info.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/unistd.h>
  19 #include <asm/page.h>
  20 #include <asm/sigp.h>
  21
  22 __PT_R0      =  __PT_GPRS
  23 __PT_R1      =  __PT_GPRS + 4
  24 __PT_R2      =  __PT_GPRS + 8
  25 __PT_R3      =  __PT_GPRS + 12
  26 __PT_R4      =  __PT_GPRS + 16
  27 __PT_R5      =  __PT_GPRS + 20
  28 __PT_R6      =  __PT_GPRS + 24
  29 __PT_R7      =  __PT_GPRS + 28
  30 __PT_R8      =  __PT_GPRS + 32
  31 __PT_R9      =  __PT_GPRS + 36
  32 __PT_R10     =  __PT_GPRS + 40
  33 __PT_R11     =  __PT_GPRS + 44
  34 __PT_R12     =  __PT_GPRS + 48
  35 __PT_R13     =  __PT_GPRS + 524
  36 __PT_R14     =  __PT_GPRS + 56
  37 __PT_R15     =  __PT_GPRS + 60
  38
  39 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  40                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
  41 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  42                  _TIF_MCCK_PENDING)
  43 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  44                  _TIF_SYSCALL_TRACEPOINT)
  45
  46 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  47 STACK_SIZE  = 1 << STACK_SHIFT
  48
  49 #define BASED(name) name-system_call(%r13)
  50
  51         .macro  TRACE_IRQS_ON
  52 #ifdef CONFIG_TRACE_IRQFLAGS
  53         basr    %r2,%r0
  54         l       %r1,BASED(.Lhardirqs_on)
  55         basr    %r14,%r1                # call trace_hardirqs_on_caller
  56 #endif
  57         .endm
  58
  59         .macro  TRACE_IRQS_OFF
  60 #ifdef CONFIG_TRACE_IRQFLAGS
  61         basr    %r2,%r0
  62         l       %r1,BASED(.Lhardirqs_off)
  63         basr    %r14,%r1                # call trace_hardirqs_off_caller
  64 #endif
  65         .endm
  66
  67         .macro  LOCKDEP_SYS_EXIT
  68 #ifdef CONFIG_LOCKDEP
  69         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  70         jz      .+10
  71         l       %r1,BASED(.Llockdep_sys_exit)
  72         basr    %r14,%r1                # call lockdep_sys_exit
  73 #endif
  74         .endm
  75
  76         .macro  CHECK_STACK stacksize,savearea
  77 #ifdef CONFIG_CHECK_STACK
  78         tml     %r15,\stacksize - CONFIG_STACK_GUARD
  79         la      %r14,\savearea
  80         jz      stack_overflow
  81 #endif
  82         .endm
  83
  84         .macro  SWITCH_ASYNC savearea,stack,shift
  85         tmh     %r8,0x0001              # interrupting from user ?
  86         jnz     1f
  87         lr      %r14,%r9
  88         sl      %r14,BASED(.Lcritical_start)
  89         cl      %r14,BASED(.Lcritical_length)
  90         jhe     0f
  91         la      %r11,\savearea          # inside critical section, do cleanup
  92         bras    %r14,cleanup_critical
  93         tmh     %r8,0x0001              # retest problem state after cleanup
  94         jnz     1f
  95 0:      l       %r14,\stack             # are we already on the target stack?
  96         slr     %r14,%r15
  97         sra     %r14,\shift
  98         jnz     1f
  99         CHECK_STACK 1<<\shift,\savearea
 100         j       2f
 101 1:      l       %r15,\stack             # load target stack
 102 2:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 103         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 104         .endm
 105
 106         .macro  ADD64 high,low,timer
 107         al      \high,\timer
 108         al      \low,4+\timer
 109         brc     12,.+8
 110         ahi     \high,1
 111         .endm
 112
 113         .macro  SUB64 high,low,timer
 114         sl      \high,\timer
 115         sl      \low,4+\timer
 116         brc     3,.+8
 117         ahi     \high,-1
 118         .endm
 119
 120         .macro  UPDATE_VTIME high,low,enter_timer
 121         lm      \high,\low,__LC_EXIT_TIMER
 122         SUB64   \high,\low,\enter_timer
 123         ADD64   \high,\low,__LC_USER_TIMER
 124         stm     \high,\low,__LC_USER_TIMER
 125         lm      \high,\low,__LC_LAST_UPDATE_TIMER
 126         SUB64   \high,\low,__LC_EXIT_TIMER
 127         ADD64   \high,\low,__LC_SYSTEM_TIMER
 128         stm     \high,\low,__LC_SYSTEM_TIMER
 129         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 130         .endm
 131
 132         .macro REENABLE_IRQS
 133         st      %r8,__LC_RETURN_PSW
 134         ni      __LC_RETURN_PSW,0xbf
 135         ssm     __LC_RETURN_PSW
 136         .endm
 137
 138         .section .kprobes.text, "ax"
 139
 140 /*
 141  * Scheduler resume function, called by switch_to
 142  *  gpr2 = (task_struct *) prev
 143  *  gpr3 = (task_struct *) next
 144  * Returns:
 145  *  gpr2 = prev
 146  */
 147 ENTRY(__switch_to)
 148         stm     %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 149         st      %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 150         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
 151         l       %r5,__THREAD_info(%r3)          # get thread_info of next
 152         lr      %r15,%r5
 153         ahi     %r15,STACK_SIZE                 # end of kernel stack of next
 154         st      %r3,__LC_CURRENT                # store task struct of next
 155         st      %r5,__LC_THREAD_INFO            # store thread info of next
 156         st      %r15,__LC_KERNEL_STACK          # store end of kernel stack
 157         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 158         mvc     __LC_CURRENT_PID(4,%r0),__TASK_pid(%r3) # store pid of next
 159         l       %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 160         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
 161         jz      0f
 162         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 163         oi      __TI_flags+3(%r5),_TIF_MCCK_PENDING     # set it in next
 164 0:      lm      %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 165         br      %r14
 166
 167 __critical_start:
 168 /*
 169  * SVC interrupt handler routine. System calls are synchronous events and
 170  * are executed with interrupts enabled.
 171  */
 172
 173 ENTRY(system_call)
 174         stpt    __LC_SYNC_ENTER_TIMER
 175 sysc_stm:
 176         stm     %r8,%r15,__LC_SAVE_AREA_SYNC
 177         l       %r12,__LC_THREAD_INFO
 178         l       %r13,__LC_SVC_NEW_PSW+4
 179 sysc_per:
 180         l       %r15,__LC_KERNEL_STACK
 181         ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 182         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 183 sysc_vtime:
 184         UPDATE_VTIME %r8,%r9,__LC_SYNC_ENTER_TIMER
 185         stm     %r0,%r7,__PT_R0(%r11)
 186         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_SYNC
 187         mvc     __PT_PSW(8,%r11),__LC_SVC_OLD_PSW
 188         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 189 sysc_do_svc:
 190         oi      __TI_flags+3(%r12),_TIF_SYSCALL
 191         lh      %r8,__PT_INT_CODE+2(%r11)
 192         sla     %r8,2                           # shift and test for svc0
 193         jnz     sysc_nr_ok
 194         # svc 0: system call number in %r1
 195         cl      %r1,BASED(.Lnr_syscalls)
 196         jnl     sysc_nr_ok
 197         sth     %r1,__PT_INT_CODE+2(%r11)
 198         lr      %r8,%r1
 199         sla     %r8,2
 200 sysc_nr_ok:
 201         l       %r10,BASED(.Lsys_call_table)    # 31 bit system call table
 202         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 203         st      %r2,__PT_ORIG_GPR2(%r11)
 204         st      %r7,STACK_FRAME_OVERHEAD(%r15)
 205         l       %r9,0(%r8,%r10)                 # get system call addr.
 206         tm      __TI_flags+2(%r12),_TIF_TRACE >> 8
 207         jnz     sysc_tracesys
 208         basr    %r14,%r9                        # call sys_xxxx
 209         st      %r2,__PT_R2(%r11)               # store return value
 210
 211 sysc_return:
 212         LOCKDEP_SYS_EXIT
 213 sysc_tif:
 214         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
 215         jno     sysc_restore
 216         tm      __TI_flags+3(%r12),_TIF_WORK_SVC
 217         jnz     sysc_work                       # check for work
 218         ni      __TI_flags+3(%r12),255-_TIF_SYSCALL
 219 sysc_restore:
 220         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r11)
 221         stpt    __LC_EXIT_TIMER
 222         lm      %r0,%r15,__PT_R0(%r11)
 223         lpsw    __LC_RETURN_PSW
 224 sysc_done:
 225
 226 #
 227 # One of the work bits is on. Find out which one.
 228 #
 229 sysc_work:
 230         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 231         jo      sysc_mcck_pending
 232         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 233         jo      sysc_reschedule
 234         tm      __TI_flags+3(%r12),_TIF_PER_TRAP
 235         jo      sysc_singlestep
 236         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
 237         jo      sysc_sigpending
 238         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
 239         jo      sysc_notify_resume
 240         j       sysc_return             # beware of critical section cleanup
 241
 242 #
 243 # _TIF_NEED_RESCHED is set, call schedule
 244 #
 245 sysc_reschedule:
 246         l       %r1,BASED(.Lschedule)
 247         la      %r14,BASED(sysc_return)
 248         br      %r1                     # call schedule
 249
 250 #
 251 # _TIF_MCCK_PENDING is set, call handler
 252 #
 253 sysc_mcck_pending:
 254         l       %r1,BASED(.Lhandle_mcck)
 255         la      %r14,BASED(sysc_return)
 256         br      %r1                     # TIF bit will be cleared by handler
 257
 258 #
 259 # _TIF_SIGPENDING is set, call do_signal
 260 #
 261 sysc_sigpending:
 262         lr      %r2,%r11                # pass pointer to pt_regs
 263         l       %r1,BASED(.Ldo_signal)
 264         basr    %r14,%r1                # call do_signal
 265         tm      __TI_flags+3(%r12),_TIF_SYSCALL
 266         jno     sysc_return
 267         lm      %r2,%r7,__PT_R2(%r11)   # load svc arguments
 268         xr      %r8,%r8                 # svc 0 returns -ENOSYS
 269         clc     __PT_INT_CODE+2(2,%r11),BASED(.Lnr_syscalls+2)
 270         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
 271         lh      %r8,__PT_INT_CODE+2(%r11)       # load new svc number
 272         sla     %r8,2
 273         j       sysc_nr_ok              # restart svc
 274
 275 #
 276 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 277 #
 278 sysc_notify_resume:
 279         lr      %r2,%r11                # pass pointer to pt_regs
 280         l       %r1,BASED(.Ldo_notify_resume)
 281         la      %r14,BASED(sysc_return)
 282         br      %r1                     # call do_notify_resume
 283
 284 #
 285 # _TIF_PER_TRAP is set, call do_per_trap
 286 #
 287 sysc_singlestep:
 288         ni      __TI_flags+3(%r12),255-_TIF_PER_TRAP
 289         lr      %r2,%r11                # pass pointer to pt_regs
 290         l       %r1,BASED(.Ldo_per_trap)
 291         la      %r14,BASED(sysc_return)
 292         br      %r1                     # call do_per_trap
 293
 294 #
 295 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 296 # and after the system call
 297 #
 298 sysc_tracesys:
 299         l       %r1,BASED(.Ltrace_enter)
 300         lr      %r2,%r11                # pass pointer to pt_regs
 301         la      %r3,0
 302         xr      %r0,%r0
 303         icm     %r0,3,__PT_INT_CODE+2(%r11)
 304         st      %r0,__PT_R2(%r11)
 305         basr    %r14,%r1                # call do_syscall_trace_enter
 306         cl      %r2,BASED(.Lnr_syscalls)
 307         jnl     sysc_tracenogo
 308         lr      %r8,%r2
 309         sll     %r8,2
 310         l       %r9,0(%r8,%r10)
 311 sysc_tracego:
 312         lm      %r3,%r7,__PT_R3(%r11)
 313         st      %r7,STACK_FRAME_OVERHEAD(%r15)
 314         l       %r2,__PT_ORIG_GPR2(%r11)
 315         basr    %r14,%r9                # call sys_xxx
 316         st      %r2,__PT_R2(%r11)       # store return value
 317 sysc_tracenogo:
 318         tm      __TI_flags+2(%r12),_TIF_TRACE >> 8
 319         jz      sysc_return
 320         l       %r1,BASED(.Ltrace_exit)
 321         lr      %r2,%r11                # pass pointer to pt_regs
 322         la      %r14,BASED(sysc_return)
 323         br      %r1                     # call do_syscall_trace_exit
 324
 325 #
 326 # a new process exits the kernel with ret_from_fork
 327 #
 328 ENTRY(ret_from_fork)
 329         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 330         l       %r12,__LC_THREAD_INFO
 331         l       %r13,__LC_SVC_NEW_PSW+4
 332         l       %r1,BASED(.Lschedule_tail)
 333         basr    %r14,%r1                # call schedule_tail
 334         TRACE_IRQS_ON
 335         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 336         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 337         jne     sysc_tracenogo
 338         # it's a kernel thread
 339         lm      %r9,%r10,__PT_R9(%r11)  # load gprs
 340 ENTRY(kernel_thread_starter)
 341         la      %r2,0(%r10)
 342         basr    %r14,%r9
 343         j       sysc_tracenogo
 344
 345 /*
 346  * Program check handler routine
 347  */
 348
 349 ENTRY(pgm_check_handler)
 350         stpt    __LC_SYNC_ENTER_TIMER
 351         stm     %r8,%r15,__LC_SAVE_AREA_SYNC
 352         l       %r12,__LC_THREAD_INFO
 353         l       %r13,__LC_SVC_NEW_PSW+4
 354         lm      %r8,%r9,__LC_PGM_OLD_PSW
 355         tmh     %r8,0x0001              # test problem state bit
 356         jnz     1f                      # -> fault in user space
 357         tmh     %r8,0x4000              # PER bit set in old PSW ?
 358         jnz     0f                      # -> enabled, can't be a double fault
 359         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 360         jnz     pgm_svcper              # -> single stepped svc
 361 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 362         j       2f
 363 1:      UPDATE_VTIME %r14,%r15,__LC_SYNC_ENTER_TIMER
 364         l       %r15,__LC_KERNEL_STACK
 365 2:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 366         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 367         stm     %r0,%r7,__PT_R0(%r11)
 368         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_SYNC
 369         stm     %r8,%r9,__PT_PSW(%r11)
 370         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 371         mvc     __PT_INT_PARM_LONG(4,%r11),__LC_TRANS_EXC_CODE
 372         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 373         jz      0f
 374         l       %r1,__TI_task(%r12)
 375         tmh     %r8,0x0001              # kernel per event ?
 376         jz      pgm_kprobe
 377         oi      __TI_flags+3(%r12),_TIF_PER_TRAP
 378         mvc     __THREAD_per_address(4,%r1),__LC_PER_ADDRESS
 379         mvc     __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
 380         mvc     __THREAD_per_paid(1,%r1),__LC_PER_PAID
 381 0:      REENABLE_IRQS
 382         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 383         l       %r1,BASED(.Ljump_table)
 384         la      %r10,0x7f
 385         n       %r10,__PT_INT_CODE(%r11)
 386         je      sysc_return
 387         sll     %r10,2
 388         l       %r1,0(%r10,%r1)         # load address of handler routine
 389         lr      %r2,%r11                # pass pointer to pt_regs
 390         basr    %r14,%r1                # branch to interrupt-handler
 391         j       sysc_return
 392
 393 #
 394 # PER event in supervisor state, must be kprobes
 395 #
 396 pgm_kprobe:
 397         REENABLE_IRQS
 398         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 399         l       %r1,BASED(.Ldo_per_trap)
 400         lr      %r2,%r11                # pass pointer to pt_regs
 401         basr    %r14,%r1                # call do_per_trap
 402         j       sysc_return
 403
 404 #
 405 # single stepped system call
 406 #
 407 pgm_svcper:
 408         oi      __TI_flags+3(%r12),_TIF_PER_TRAP
 409         mvc     __LC_RETURN_PSW(4),__LC_SVC_NEW_PSW
 410         mvc     __LC_RETURN_PSW+4(4),BASED(.Lsysc_per)
 411         lpsw    __LC_RETURN_PSW         # branch to sysc_per and enable irqs
 412
 413 /*
 414  * IO interrupt handler routine
 415  */
 416
 417 ENTRY(io_int_handler)
 418         stck    __LC_INT_CLOCK
 419         stpt    __LC_ASYNC_ENTER_TIMER
 420         stm     %r8,%r15,__LC_SAVE_AREA_ASYNC
 421         l       %r12,__LC_THREAD_INFO
 422         l       %r13,__LC_SVC_NEW_PSW+4
 423         lm      %r8,%r9,__LC_IO_OLD_PSW
 424         tmh     %r8,0x0001              # interrupting from user ?
 425         jz      io_skip
 426         UPDATE_VTIME %r14,%r15,__LC_ASYNC_ENTER_TIMER
 427 io_skip:
 428         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 429         stm     %r0,%r7,__PT_R0(%r11)
 430         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_ASYNC
 431         stm     %r8,%r9,__PT_PSW(%r11)
 432         TRACE_IRQS_OFF
 433         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 434         l       %r1,BASED(.Ldo_IRQ)
 435         lr      %r2,%r11                # pass pointer to pt_regs
 436         basr    %r14,%r1                # call do_IRQ
 437 io_return:
 438         LOCKDEP_SYS_EXIT
 439         TRACE_IRQS_ON
 440 io_tif:
 441         tm      __TI_flags+3(%r12),_TIF_WORK_INT
 442         jnz     io_work                 # there is work to do (signals etc.)
 443 io_restore:
 444         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r11)
 445         stpt    __LC_EXIT_TIMER
 446         lm      %r0,%r15,__PT_R0(%r11)
 447         lpsw    __LC_RETURN_PSW
 448 io_done:
 449
 450 #
 451 # There is work todo, find out in which context we have been interrupted:
 452 # 1) if we return to user space we can do all _TIF_WORK_INT work
 453 # 2) if we return to kernel code and preemptive scheduling is enabled check
 454 #    the preemption counter and if it is zero call preempt_schedule_irq
 455 # Before any work can be done, a switch to the kernel stack is required.
 456 #
 457 io_work:
 458         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 459         jo      io_work_user            # yes -> do resched & signal
 460 #ifdef CONFIG_PREEMPT
 461         # check for preemptive scheduling
 462         icm     %r0,15,__TI_precount(%r12)
 463         jnz     io_restore              # preemption disabled
 464         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 465         jno     io_restore
 466         # switch to kernel stack
 467         l       %r1,__PT_R15(%r11)
 468         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 469         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 470         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
 471         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 472         lr      %r15,%r1
 473         # TRACE_IRQS_ON already done at io_return, call
 474         # TRACE_IRQS_OFF to keep things symmetrical
 475         TRACE_IRQS_OFF
 476         l       %r1,BASED(.Lpreempt_irq)
 477         basr    %r14,%r1                # call preempt_schedule_irq
 478         j       io_return
 479 #else
 480         j       io_restore
 481 #endif
 482
 483 #
 484 # Need to do work before returning to userspace, switch to kernel stack
 485 #
 486 io_work_user:
 487         l       %r1,__LC_KERNEL_STACK
 488         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 489         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 490         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
 491         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 492         lr      %r15,%r1
 493
 494 #
 495 # One of the work bits is on. Find out which one.
 496 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 497 #               and _TIF_MCCK_PENDING
 498 #
 499 io_work_tif:
 500         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 501         jo      io_mcck_pending
 502         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 503         jo      io_reschedule
 504         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
 505         jo      io_sigpending
 506         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
 507         jo      io_notify_resume
 508         j       io_return               # beware of critical section cleanup
 509
 510 #
 511 # _TIF_MCCK_PENDING is set, call handler
 512 #
 513 io_mcck_pending:
 514         # TRACE_IRQS_ON already done at io_return
 515         l       %r1,BASED(.Lhandle_mcck)
 516         basr    %r14,%r1                # TIF bit will be cleared by handler
 517         TRACE_IRQS_OFF
 518         j       io_return
 519
 520 #
 521 # _TIF_NEED_RESCHED is set, call schedule
 522 #
 523 io_reschedule:
 524         # TRACE_IRQS_ON already done at io_return
 525         l       %r1,BASED(.Lschedule)
 526         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 527         basr    %r14,%r1                # call scheduler
 528         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 529         TRACE_IRQS_OFF
 530         j       io_return
 531
 532 #
 533 # _TIF_SIGPENDING is set, call do_signal
 534 #
 535 io_sigpending:
 536         # TRACE_IRQS_ON already done at io_return
 537         l       %r1,BASED(.Ldo_signal)
 538         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 539         lr      %r2,%r11                # pass pointer to pt_regs
 540         basr    %r14,%r1                # call do_signal
 541         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 542         TRACE_IRQS_OFF
 543         j       io_return
 544
 545 #
 546 # _TIF_SIGPENDING is set, call do_signal
 547 #
 548 io_notify_resume:
 549         # TRACE_IRQS_ON already done at io_return
 550         l       %r1,BASED(.Ldo_notify_resume)
 551         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 552         lr      %r2,%r11                # pass pointer to pt_regs
 553         basr    %r14,%r1                # call do_notify_resume
 554         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 555         TRACE_IRQS_OFF
 556         j       io_return
 557
 558 /*
 559  * External interrupt handler routine
 560  */
 561
 562 ENTRY(ext_int_handler)
 563         stck    __LC_INT_CLOCK
 564         stpt    __LC_ASYNC_ENTER_TIMER
 565         stm     %r8,%r15,__LC_SAVE_AREA_ASYNC
 566         l       %r12,__LC_THREAD_INFO
 567         l       %r13,__LC_SVC_NEW_PSW+4
 568         lm      %r8,%r9,__LC_EXT_OLD_PSW
 569         tmh     %r8,0x0001              # interrupting from user ?
 570         jz      ext_skip
 571         UPDATE_VTIME %r14,%r15,__LC_ASYNC_ENTER_TIMER
 572 ext_skip:
 573         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
 574         stm     %r0,%r7,__PT_R0(%r11)
 575         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_ASYNC
 576         stm     %r8,%r9,__PT_PSW(%r11)
 577         TRACE_IRQS_OFF
 578         lr      %r2,%r11                # pass pointer to pt_regs
 579         l       %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
 580         l       %r4,__LC_EXT_PARAMS     # get external parameters
 581         l       %r1,BASED(.Ldo_extint)
 582         basr    %r14,%r1                # call do_extint
 583         j       io_return
 584
 585 /*
 586  * Load idle PSW. The second "half" of this function is in cleanup_idle.
 587  */
 588 ENTRY(psw_idle)
 589         st      %r3,__SF_EMPTY(%r15)
 590         basr    %r1,0
 591         la      %r1,psw_idle_lpsw+4-.(%r1)
 592         st      %r1,__SF_EMPTY+4(%r15)
 593         oi      __SF_EMPTY+4(%r15),0x80
 594         stck    __CLOCK_IDLE_ENTER(%r2)
 595         stpt    __TIMER_IDLE_ENTER(%r2)
 596 psw_idle_lpsw:
 597         lpsw    __SF_EMPTY(%r15)
 598         br      %r14
 599 psw_idle_end:
 600
 601 __critical_end:
 602
 603 /*
 604  * Machine check handler routines
 605  */
 606
 607 ENTRY(mcck_int_handler)
 608         stck    __LC_MCCK_CLOCK
 609         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
 610         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
 611         l       %r12,__LC_THREAD_INFO
 612         l       %r13,__LC_SVC_NEW_PSW+4
 613         lm      %r8,%r9,__LC_MCK_OLD_PSW
 614         tm      __LC_MCCK_CODE,0x80     # system damage?
 615         jo      mcck_panic              # yes -> rest of mcck code invalid
 616         la      %r14,__LC_CPU_TIMER_SAVE_AREA
 617         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 618         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 619         jo      3f
 620         la      %r14,__LC_SYNC_ENTER_TIMER
 621         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 622         jl      0f
 623         la      %r14,__LC_ASYNC_ENTER_TIMER
 624 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 625         jl      1f
 626         la      %r14,__LC_EXIT_TIMER
 627 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 628         jl      2f
 629         la      %r14,__LC_LAST_UPDATE_TIMER
 630 2:      spt     0(%r14)
 631         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 632 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 633         jno     mcck_panic              # no -> skip cleanup critical
 634         tm      %r8,0x0001              # interrupting from user ?
 635         jz      mcck_skip
 636         UPDATE_VTIME %r14,%r15,__LC_MCCK_ENTER_TIMER
 637 mcck_skip:
 638         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+32,__LC_PANIC_STACK,PAGE_SHIFT
 639         stm     %r0,%r7,__PT_R0(%r11)
 640         mvc     __PT_R8(32,%r11),__LC_GPREGS_SAVE_AREA+32
 641         stm     %r8,%r9,__PT_PSW(%r11)
 642         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 643         l       %r1,BASED(.Ldo_machine_check)
 644         lr      %r2,%r11                # pass pointer to pt_regs
 645         basr    %r14,%r1                # call s390_do_machine_check
 646         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 647         jno     mcck_return
 648         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
 649         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 650         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 651         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
 652         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 653         lr      %r15,%r1
 654         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
 655         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 656         jno     mcck_return
 657         TRACE_IRQS_OFF
 658         l       %r1,BASED(.Lhandle_mcck)
 659         basr    %r14,%r1                # call s390_handle_mcck
 660         TRACE_IRQS_ON
 661 mcck_return:
 662         mvc     __LC_RETURN_MCCK_PSW(8),__PT_PSW(%r11) # move return PSW
 663         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 664         jno     0f
 665         lm      %r0,%r15,__PT_R0(%r11)
 666         stpt    __LC_EXIT_TIMER
 667         lpsw    __LC_RETURN_MCCK_PSW
 668 0:      lm      %r0,%r15,__PT_R0(%r11)
 669         lpsw    __LC_RETURN_MCCK_PSW
 670
 671 mcck_panic:
 672         l       %r14,__LC_PANIC_STACK
 673         slr     %r14,%r15
 674         sra     %r14,PAGE_SHIFT
 675         jz      0f
 676         l       %r15,__LC_PANIC_STACK
 677 0:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 678         j       mcck_skip
 679
 680 #
 681 # PSW restart interrupt handler
 682 #
 683 ENTRY(restart_int_handler)
 684         st      %r15,__LC_SAVE_AREA_RESTART
 685         l       %r15,__LC_RESTART_STACK
 686         ahi     %r15,-__PT_SIZE                 # create pt_regs on stack
 687         xc      0(__PT_SIZE,%r15),0(%r15)
 688         stm     %r0,%r14,__PT_R0(%r15)
 689         mvc     __PT_R15(4,%r15),__LC_SAVE_AREA_RESTART
 690         mvc     __PT_PSW(8,%r15),__LC_RST_OLD_PSW # store restart old psw
 691         ahi     %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
 692         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
 693         l       %r1,__LC_RESTART_FN             # load fn, parm & source cpu
 694         l       %r2,__LC_RESTART_DATA
 695         l       %r3,__LC_RESTART_SOURCE
 696         ltr     %r3,%r3                         # test source cpu address
 697         jm      1f                              # negative -> skip source stop
 698 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
 699         brc     10,0b                           # wait for status stored
 700 1:      basr    %r14,%r1                        # call function
 701         stap    __SF_EMPTY(%r15)                # store cpu address
 702         lh      %r3,__SF_EMPTY(%r15)
 703 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
 704         brc     2,2b
 705 3:      j       3b
 706
 707         .section .kprobes.text, "ax"
 708
 709 #ifdef CONFIG_CHECK_STACK
 710 /*
 711  * The synchronous or the asynchronous stack overflowed. We are dead.
 712  * No need to properly save the registers, we are going to panic anyway.
 713  * Setup a pt_regs so that show_trace can provide a good call trace.
 714  */
 715 stack_overflow:
 716         l       %r15,__LC_PANIC_STACK   # change to panic stack
 717         ahi     %r15,-__PT_SIZE         # create pt_regs
 718         stm     %r0,%r7,__PT_R0(%r15)
 719         stm     %r8,%r9,__PT_PSW(%r15)
 720         mvc     __PT_R8(32,%r11),0(%r14)
 721         lr      %r15,%r11
 722         ahi     %r15,-STACK_FRAME_OVERHEAD
 723         l       %r1,BASED(1f)
 724         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 725         lr      %r2,%r11                # pass pointer to pt_regs
 726         br      %r1                     # branch to kernel_stack_overflow
 727 1:      .long   kernel_stack_overflow
 728 #endif
 729
 730 cleanup_table:
 731         .long   system_call + 0x80000000
 732         .long   sysc_do_svc + 0x80000000
 733         .long   sysc_tif + 0x80000000
 734         .long   sysc_restore + 0x80000000
 735         .long   sysc_done + 0x80000000
 736         .long   io_tif + 0x80000000
 737         .long   io_restore + 0x80000000
 738         .long   io_done + 0x80000000
 739         .long   psw_idle + 0x80000000
 740         .long   psw_idle_end + 0x80000000
 741
 742 cleanup_critical:
 743         cl      %r9,BASED(cleanup_table)        # system_call
 744         jl      0f
 745         cl      %r9,BASED(cleanup_table+4)      # sysc_do_svc
 746         jl      cleanup_system_call
 747         cl      %r9,BASED(cleanup_table+8)      # sysc_tif
 748         jl      0f
 749         cl      %r9,BASED(cleanup_table+12)     # sysc_restore
 750         jl      cleanup_sysc_tif
 751         cl      %r9,BASED(cleanup_table+16)     # sysc_done
 752         jl      cleanup_sysc_restore
 753         cl      %r9,BASED(cleanup_table+20)     # io_tif
 754         jl      0f
 755         cl      %r9,BASED(cleanup_table+24)     # io_restore
 756         jl      cleanup_io_tif
 757         cl      %r9,BASED(cleanup_table+28)     # io_done
 758         jl      cleanup_io_restore
 759         cl      %r9,BASED(cleanup_table+32)     # psw_idle
 760         jl      0f
 761         cl      %r9,BASED(cleanup_table+36)     # psw_idle_end
 762         jl      cleanup_idle
 763 0:      br      %r14
 764
 765 cleanup_system_call:
 766         # check if stpt has been executed
 767         cl      %r9,BASED(cleanup_system_call_insn)
 768         jh      0f
 769         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 770         chi     %r11,__LC_SAVE_AREA_ASYNC
 771         je      0f
 772         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 773 0:      # check if stm has been executed
 774         cl      %r9,BASED(cleanup_system_call_insn+4)
 775         jh      0f
 776         mvc     __LC_SAVE_AREA_SYNC(32),0(%r11)
 777 0:      # set up saved registers r12, and r13
 778         st      %r12,16(%r11)           # r12 thread-info pointer
 779         st      %r13,20(%r11)           # r13 literal-pool pointer
 780         # check if the user time calculation has been done
 781         cl      %r9,BASED(cleanup_system_call_insn+8)
 782         jh      0f
 783         l       %r10,__LC_EXIT_TIMER
 784         l       %r15,__LC_EXIT_TIMER+4
 785         SUB64   %r10,%r15,__LC_SYNC_ENTER_TIMER
 786         ADD64   %r10,%r15,__LC_USER_TIMER
 787         st      %r10,__LC_USER_TIMER
 788         st      %r15,__LC_USER_TIMER+4
 789 0:      # check if the system time calculation has been done
 790         cl      %r9,BASED(cleanup_system_call_insn+12)
 791         jh      0f
 792         l       %r10,__LC_LAST_UPDATE_TIMER
 793         l       %r15,__LC_LAST_UPDATE_TIMER+4
 794         SUB64   %r10,%r15,__LC_EXIT_TIMER
 795         ADD64   %r10,%r15,__LC_SYSTEM_TIMER
 796         st      %r10,__LC_SYSTEM_TIMER
 797         st      %r15,__LC_SYSTEM_TIMER+4
 798 0:      # update accounting time stamp
 799         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 800         # set up saved register 11
 801         l       %r15,__LC_KERNEL_STACK
 802         ahi     %r15,-__PT_SIZE
 803         st      %r15,12(%r11)           # r11 pt_regs pointer
 804         # fill pt_regs
 805         mvc     __PT_R8(32,%r15),__LC_SAVE_AREA_SYNC
 806         stm     %r0,%r7,__PT_R0(%r15)
 807         mvc     __PT_PSW(8,%r15),__LC_SVC_OLD_PSW
 808         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
 809         # setup saved register 15
 810         ahi     %r15,-STACK_FRAME_OVERHEAD
 811         st      %r15,28(%r11)           # r15 stack pointer
 812         # set new psw address and exit
 813         l       %r9,BASED(cleanup_table+4)      # sysc_do_svc + 0x80000000
 814         br      %r14
 815 cleanup_system_call_insn:
 816         .long   system_call + 0x80000000
 817         .long   sysc_stm + 0x80000000
 818         .long   sysc_vtime + 0x80000000 + 36
 819         .long   sysc_vtime + 0x80000000 + 76
 820
 821 cleanup_sysc_tif:
 822         l       %r9,BASED(cleanup_table+8)      # sysc_tif + 0x80000000
 823         br      %r14
 824
 825 cleanup_sysc_restore:
 826         cl      %r9,BASED(cleanup_sysc_restore_insn)
 827         jhe     0f
 828         l       %r9,12(%r11)            # get saved pointer to pt_regs
 829         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r9)
 830         mvc     0(32,%r11),__PT_R8(%r9)
 831         lm      %r0,%r7,__PT_R0(%r9)
 832 0:      lm      %r8,%r9,__LC_RETURN_PSW
 833         br      %r14
 834 cleanup_sysc_restore_insn:
 835         .long   sysc_done - 4 + 0x80000000
 836
 837 cleanup_io_tif:
 838         l       %r9,BASED(cleanup_table+20)     # io_tif + 0x80000000
 839         br      %r14
 840
 841 cleanup_io_restore:
 842         cl      %r9,BASED(cleanup_io_restore_insn)
 843         jhe     0f
 844         l       %r9,12(%r11)            # get saved r11 pointer to pt_regs
 845         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r9)
 846         mvc     0(32,%r11),__PT_R8(%r9)
 847         lm      %r0,%r7,__PT_R0(%r9)
 848 0:      lm      %r8,%r9,__LC_RETURN_PSW
 849         br      %r14
 850 cleanup_io_restore_insn:
 851         .long   io_done - 4 + 0x80000000
 852
 853 cleanup_idle:
 854         # copy interrupt clock & cpu timer
 855         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
 856         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
 857         chi     %r11,__LC_SAVE_AREA_ASYNC
 858         je      0f
 859         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
 860         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
 861 0:      # check if stck has been executed
 862         cl      %r9,BASED(cleanup_idle_insn)
 863         jhe     1f
 864         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
 865         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r3)
 866 1:      # account system time going idle
 867         lm      %r9,%r10,__LC_STEAL_TIMER
 868         ADD64   %r9,%r10,__CLOCK_IDLE_ENTER(%r2)
 869         SUB64   %r9,%r10,__LC_LAST_UPDATE_CLOCK
 870         stm     %r9,%r10,__LC_STEAL_TIMER
 871         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
 872         lm      %r9,%r10,__LC_SYSTEM_TIMER
 873         ADD64   %r9,%r10,__LC_LAST_UPDATE_TIMER
 874         SUB64   %r9,%r10,__TIMER_IDLE_ENTER(%r2)
 875         stm     %r9,%r10,__LC_SYSTEM_TIMER
 876         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
 877         # prepare return psw
 878         n       %r8,BASED(cleanup_idle_wait)    # clear wait state bit
 879         l       %r9,24(%r11)                    # return from psw_idle
 880         br      %r14
 881 cleanup_idle_insn:
 882         .long   psw_idle_lpsw + 0x80000000
 883 cleanup_idle_wait:
 884         .long   0xfffdffff
 885
 886 /*
 887  * Integer constants
 888  */
 889         .align  4
 890 .Lnr_syscalls:
 891         .long   NR_syscalls
 892 .Lvtimer_max:
 893         .quad   0x7fffffffffffffff
 894
 895 /*
 896  * Symbol constants
 897  */
 898 .Ldo_machine_check:     .long   s390_do_machine_check
 899 .Lhandle_mcck:          .long   s390_handle_mcck
 900 .Ldo_IRQ:               .long   do_IRQ
 901 .Ldo_extint:            .long   do_extint
 902 .Ldo_signal:            .long   do_signal
 903 .Ldo_notify_resume:     .long   do_notify_resume
 904 .Ldo_per_trap:          .long   do_per_trap
 905 .Ljump_table:           .long   pgm_check_table
 906 .Lschedule:             .long   schedule
 907 #ifdef CONFIG_PREEMPT
 908 .Lpreempt_irq:          .long   preempt_schedule_irq
 909 #endif
 910 .Ltrace_enter:          .long   do_syscall_trace_enter
 911 .Ltrace_exit:           .long   do_syscall_trace_exit
 912 .Lschedule_tail:        .long   schedule_tail
 913 .Lsys_call_table:       .long   sys_call_table
 914 .Lsysc_per:             .long   sysc_per + 0x80000000
 915 #ifdef CONFIG_TRACE_IRQFLAGS
 916 .Lhardirqs_on:          .long   trace_hardirqs_on_caller
 917 .Lhardirqs_off:         .long   trace_hardirqs_off_caller
 918 #endif
 919 #ifdef CONFIG_LOCKDEP
 920 .Llockdep_sys_exit:     .long   lockdep_sys_exit
 921 #endif
 922 .Lcritical_start:       .long   __critical_start + 0x80000000
 923 .Lcritical_length:      .long   __critical_end - __critical_start
 924
 925                 .section .rodata, "a"
 926 #define SYSCALL(esa,esame,emu)  .long esa
 927         .globl  sys_call_table
 928 sys_call_table:
 929 #include "syscalls.S"
 930 #undef SYSCALL