arch/arm64/kernel/vdso32/vdso.lds.S

   1 /*
   2  * Adapted from arm64 version.
   3  *
   4  * GNU linker script for the VDSO library.
   5  *
   6  * Copyright (C) 2012 ARM Limited
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  *
  20  * Author: Will Deacon <will.deacon@arm.com>
  21  * Heavily based on the vDSO linker scripts for other archs.
  22  */
  23
  24 #include <linux/const.h>
  25 #include <asm/page.h>
  26 #include <asm/vdso.h>
  27
  28 OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
  29 OUTPUT_ARCH(arm)
  30
  31 SECTIONS
  32 {
  33         PROVIDE_HIDDEN(_vdso_data = . - PAGE_SIZE);
  34         . = VDSO_LBASE + SIZEOF_HEADERS;
  35
  36         .hash           : { *(.hash) }                  :text
  37         .gnu.hash       : { *(.gnu.hash) }
  38         .dynsym         : { *(.dynsym) }
  39         .dynstr         : { *(.dynstr) }
  40         .gnu.version    : { *(.gnu.version) }
  41         .gnu.version_d  : { *(.gnu.version_d) }
  42         .gnu.version_r  : { *(.gnu.version_r) }
  43
  44         .note           : { *(.note.*) }                :text   :note
  45
  46         .dynamic        : { *(.dynamic) }               :text   :dynamic
  47
  48         .rodata         : { *(.rodata*) }               :text
  49
  50         .text           : { *(.text*) }                 :text   =0xe7f001f2
  51
  52         .got            : { *(.got) }
  53         .rel.plt        : { *(.rel.plt) }
  54
  55         /DISCARD/       : {
  56                 *(.note.GNU-stack)
  57                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
  58                 *(.bss .sbss .dynbss .dynsbss)
  59         }
  60 }
  61
  62 /*
  63  * We must supply the ELF program headers explicitly to get just one
  64  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  65  */
  66 PHDRS
  67 {
  68         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
  69         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
  70         note            PT_NOTE         FLAGS(4);               /* PF_R */
  71 }
  72
  73 VERSION
  74 {
  75         LINUX_2.6 {
  76         global:
  77                 __vdso_clock_gettime;
  78                 __vdso_gettimeofday;
  79                 __vdso_clock_getres;
  80                 __vdso_time;
  81                 __kernel_sigreturn_arm;
  82                 __kernel_sigreturn_thumb;
  83                 __kernel_rt_sigreturn_arm;
  84                 __kernel_rt_sigreturn_thumb;
  85         local: *;
  86         };
  87 }
  88
  89 /*
  90  * Make the sigreturn code visible to the kernel.
  91  */
  92 VDSO_compat_sigreturn_arm       = __kernel_sigreturn_arm;
  93 VDSO_compat_sigreturn_thumb     = __kernel_sigreturn_thumb;
  94 VDSO_compat_rt_sigreturn_arm    = __kernel_rt_sigreturn_arm;
  95 VDSO_compat_rt_sigreturn_thumb  = __kernel_rt_sigreturn_thumb;