arch/arm/mm/proc-v7-3level.S

   1 /*
   2  * arch/arm/mm/proc-v7-3level.S
   3  *
   4  * Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  * Copyright (C) 2011 ARM Ltd.
   6  * Author: Catalin Marinas <catalin.marinas@arm.com>
   7  *   based on arch/arm/mm/proc-v7-2level.S
   8  *
   9  * This program is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License version 2 as
  11  * published by the Free Software Foundation.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
  21  */
  22
  23 #define TTB_IRGN_NC     (0 << 8)
  24 #define TTB_IRGN_WBWA   (1 << 8)
  25 #define TTB_IRGN_WT     (2 << 8)
  26 #define TTB_IRGN_WB     (3 << 8)
  27 #define TTB_RGN_NC      (0 << 10)
  28 #define TTB_RGN_OC_WBWA (1 << 10)
  29 #define TTB_RGN_OC_WT   (2 << 10)
  30 #define TTB_RGN_OC_WB   (3 << 10)
  31 #define TTB_S           (3 << 12)
  32 #define TTB_EAE         (1 << 31)
  33
  34 /* PTWs cacheable, inner WB not shareable, outer WB not shareable */
  35 #define TTB_FLAGS_UP    (TTB_IRGN_WB|TTB_RGN_OC_WB)
  36 #define PMD_FLAGS_UP    (PMD_SECT_WB)
  37
  38 /* PTWs cacheable, inner WBWA shareable, outer WBWA not shareable */
  39 #define TTB_FLAGS_SMP   (TTB_IRGN_WBWA|TTB_S|TTB_RGN_OC_WBWA)
  40 #define PMD_FLAGS_SMP   (PMD_SECT_WBWA|PMD_SECT_S)
  41
  42 /*
  43  * cpu_v7_switch_mm(pgd_phys, tsk)
  44  *
  45  * Set the translation table base pointer to be pgd_phys (physical address of
  46  * the new TTB).
  47  */
  48 ENTRY(cpu_v7_switch_mm)
  49 #ifdef CONFIG_MMU
  50         mmid    r1, r1                          @ get mm->context.id
  51         asid    r3, r1
  52         mov     r3, r3, lsl #(48 - 32)          @ ASID
  53         mcrr    p15, 0, r0, r3, c2              @ set TTB 0
  54         isb
  55 #endif
  56         mov     pc, lr
  57 ENDPROC(cpu_v7_switch_mm)
  58
  59 #ifdef __ARMEB__
  60 #define rl r3
  61 #define rh r2
  62 #else
  63 #define rl r2
  64 #define rh r3
  65 #endif
  66
  67 /*
  68  * cpu_v7_set_pte_ext(ptep, pte)
  69  *
  70  * Set a level 2 translation table entry.
  71  * - ptep - pointer to level 3 translation table entry
  72  * - pte - PTE value to store (64-bit in r2 and r3)
  73  */
  74 ENTRY(cpu_v7_set_pte_ext)
  75 #ifdef CONFIG_MMU
  76         tst     rl, #L_PTE_VALID
  77         beq     1f
  78         tst     rh, #1 << (57 - 32)             @ L_PTE_NONE
  79         bicne   rl, #L_PTE_VALID
  80         bne     1f
  81         tst     rh, #1 << (55 - 32)             @ L_PTE_DIRTY
  82         orreq   rl, #L_PTE_RDONLY
  83 1:      strd    r2, r3, [r0]
  84         ALT_SMP(W(nop))
  85 #ifdef CONFIG_ARM_ERRATA_824069
  86         ALT_UP (mcr     p15, 0, r0, c7, c14, 1)         @ flush_pte
  87 #else
  88         ALT_UP (mcr     p15, 0, r0, c7, c10, 1)         @ flush_pte
  89 #endif
  90 #endif
  91         mov     pc, lr
  92 ENDPROC(cpu_v7_set_pte_ext)
  93
  94         /*
  95          * Memory region attributes for LPAE (defined in pgtable-3level.h):
  96          *
  97          *   n = AttrIndx[2:0]
  98          *
  99          *                      n       MAIR
 100          *   UNCACHED           000     00000000
 101          *   BUFFERABLE         001     01000100
 102          *   DEV_WC             001     01000100
 103          *   WRITETHROUGH       010     10101010
 104          *   WRITEBACK          011     11101110
 105          *   DEV_CACHED         011     11101110
 106          *   DEV_SHARED         100     00000100
 107          *   DEV_NONSHARED      100     00000100
 108          *   unused             101
 109          *   unused             110
 110          *   WRITEALLOC         111     11111111
 111          */
 112 .equ    PRRR,   0xeeaa4400                      @ MAIR0
 113 .equ    NMRR,   0xff000004                      @ MAIR1
 114
 115         /*
 116          * Macro for setting up the TTBRx and TTBCR registers.
 117          * - \ttbr1 updated.
 118          */
 119         .macro  v7_ttb_setup, zero, ttbr0, ttbr1, tmp
 120         ldr     \tmp, =swapper_pg_dir           @ swapper_pg_dir virtual address
 121         cmp     \ttbr1, \tmp                    @ PHYS_OFFSET > PAGE_OFFSET? (branch below)
 122         mrc     p15, 0, \tmp, c2, c0, 2         @ TTB control register
 123         orr     \tmp, \tmp, #TTB_EAE
 124         ALT_SMP(orr     \tmp, \tmp, #TTB_FLAGS_SMP)
 125         ALT_UP(orr      \tmp, \tmp, #TTB_FLAGS_UP)
 126         ALT_SMP(orr     \tmp, \tmp, #TTB_FLAGS_SMP << 16)
 127         ALT_UP(orr      \tmp, \tmp, #TTB_FLAGS_UP << 16)
 128         /*
 129          * TTBR0/TTBR1 split (PAGE_OFFSET):
 130          *   0x40000000: T0SZ = 2, T1SZ = 0 (not used)
 131          *   0x80000000: T0SZ = 0, T1SZ = 1
 132          *   0xc0000000: T0SZ = 0, T1SZ = 2
 133          *
 134          * Only use this feature if PHYS_OFFSET <= PAGE_OFFSET, otherwise
 135          * booting secondary CPUs would end up using TTBR1 for the identity
 136          * mapping set up in TTBR0.
 137          */
 138         bhi     9001f                           @ PHYS_OFFSET > PAGE_OFFSET?
 139         orr     \tmp, \tmp, #(((PAGE_OFFSET >> 30) - 1) << 16) @ TTBCR.T1SZ
 140 #if defined CONFIG_VMSPLIT_2G
 141         /* PAGE_OFFSET == 0x80000000, T1SZ == 1 */
 142         add     \ttbr1, \ttbr1, #1 << 4         @ skip two L1 entries
 143 #elif defined CONFIG_VMSPLIT_3G
 144         /* PAGE_OFFSET == 0xc0000000, T1SZ == 2 */
 145         add     \ttbr1, \ttbr1, #4096 * (1 + 3) @ only L2 used, skip pgd+3*pmd
 146 #endif
 147         /* CONFIG_VMSPLIT_1G does not need TTBR1 adjustment */
 148 9001:   mcr     p15, 0, \tmp, c2, c0, 2         @ TTB control register
 149         mcrr    p15, 1, \ttbr1, \zero, c2       @ load TTBR1
 150         .endm
 151
 152         __CPUINIT
 153
 154         /*
 155          *   AT
 156          *  TFR   EV X F   IHD LR    S
 157          * .EEE ..EE PUI. .TAT 4RVI ZWRS BLDP WCAM
 158          * rxxx rrxx xxx0 0101 xxxx xxxx x111 xxxx < forced
 159          *   11    0 110    1  0011 1100 .111 1101 < we want
 160          */
 161         .align  2
 162         .type   v7_crval, #object
 163 v7_crval:
 164         crval   clear=0x0120c302, mmuset=0x30c23c7d, ucset=0x00c01c7c
 165
 166         .previous