[GitHub/mt8127/android_kernel_alcatel_ttab.git] / scripts / recordmcount.pl

#!/usr/bin/perl -w
# (c) 2008, Steven Rostedt <srostedt@redhat.com>
# Licensed under the terms of the GNU GPL License version 2
#
# recordmcount.pl - makes a section called __mcount_loc that holds
#                   all the offsets to the calls to mcount.
#
#
# What we want to end up with is a section in vmlinux called
# __mcount_loc that contains a list of pointers to all the
# call sites in the kernel that call mcount. Later on boot up, the kernel
# will read this list, save the locations and turn them into nops.
# When tracing or profiling is later enabled, these locations will then
# be converted back to pointers to some function.
#
# This is no easy feat. This script is called just after the original
# object is compiled and before it is linked.
#
# The references to the call sites are offsets from the section of text
# that the call site is in. Hence, all functions in a section that
# has a call site to mcount, will have the offset from the beginning of
# the section and not the beginning of the function.
#
# The trick is to find a way to record the beginning of the section.
# The way we do this is to look at the first function in the section
# which will also be the location of that section after final link.
# e.g.
#
#  .section ".text.sched"
#  .globl my_func
#  my_func:
#        [...]
#        call mcount  (offset: 0x5)
#        [...]
#        ret
#  other_func:
#        [...]
#        call mcount (offset: 0x1b)
#        [...]
#
# Both relocation offsets for the mcounts in the above example will be
# offset from .text.sched. If we make another file called tmp.s with:
#
#  .section __mcount_loc
#  .quad  my_func + 0x5
#  .quad  my_func + 0x1b
#
# We can then compile this tmp.s into tmp.o, and link it to the original
# object.
#
# But this gets hard if my_func is not globl (a static function).
# In such a case we have:
#
#  .section ".text.sched"
#  my_func:
#        [...]
#        call mcount  (offset: 0x5)
#        [...]
#        ret
#  .globl my_func
#  other_func:
#        [...]
#        call mcount (offset: 0x1b)
#        [...]
#
# If we make the tmp.s the same as above, when we link together with
# the original object, we will end up with two symbols for my_func:
# one local, one global.  After final compile, we will end up with
# an undefined reference to my_func.
#
# Since local objects can reference local variables, we need to find
# a way to make tmp.o reference the local objects of the original object
# file after it is linked together. To do this, we convert the my_func
# into a global symbol before linking tmp.o. Then after we link tmp.o
# we will only have a single symbol for my_func that is global.
# We can convert my_func back into a local symbol and we are done.
#
# Here are the steps we take:
#
# 1) Record all the local symbols by using 'nm'
# 2) Use objdump to find all the call site offsets and sections for
#    mcount.
# 3) Compile the list into its own object.
# 4) Do we have to deal with local functions? If not, go to step 8.
# 5) Make an object that converts these local functions to global symbols
#    with objcopy.
# 6) Link together this new object with the list object.
# 7) Convert the local functions back to local symbols and rename
#    the result as the original object.
#    End.
# 8) Link the object with the list object.
# 9) Move the result back to the original object.
#    End.
#

use strict;

my $P = $0;
$P =~ s@.*/@@g;

my $V = '0.1';

if ($#ARGV < 6) {
	print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
	print "version: $V\n";
	exit(1);
}

my ($arch, $bits, $objdump, $objcopy, $cc,
    $ld, $nm, $rm, $mv, $inputfile) = @ARGV;

# Acceptable sections to record.
my %text_sections = (
     ".text" => 1,
);

$objdump = "objdump" if ((length $objdump) == 0);
$objcopy = "objcopy" if ((length $objcopy) == 0);
$cc = "gcc" if ((length $cc) == 0);
$ld = "ld" if ((length $ld) == 0);
$nm = "nm" if ((length $nm) == 0);
$rm = "rm" if ((length $rm) == 0);
$mv = "mv" if ((length $mv) == 0);

#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
#    "'$nm' '$rm' '$mv' '$inputfile'\n";

my %locals;		# List of local (static) functions
my %weak;		# List of weak functions
my %convert;		# List of local functions used that needs conversion

my $type;
my $nm_regex;		# Find the local functions (return function)
my $section_regex;	# Find the start of a section
my $function_regex;	# Find the name of a function
			#    (return offset and func name)
my $mcount_regex;	# Find the call site to mcount (return offset)
my $alignment;		# The .align value to use for $mcount_section
my $section_type;	# Section header plus possible alignment command

if ($arch eq "x86") {
    if ($bits == 64) {
	$arch = "x86_64";
    } else {
	$arch = "i386";
    }
}

#
# We base the defaults off of i386, the other archs may
# feel free to change them in the below if statements.
#
$nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
$section_regex = "Disassembly of section\\s+(\\S+):";
$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
$section_type = '@progbits';
$type = ".long";

if ($arch eq "x86_64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
    $type = ".quad";
    $alignment = 8;

    # force flags for this arch
    $ld .= " -m elf_x86_64";
    $objdump .= " -M x86-64";
    $objcopy .= " -O elf64-x86-64";
    $cc .= " -m64";

} elsif ($arch eq "i386") {
    $alignment = 4;

    # force flags for this arch
    $ld .= " -m elf_i386";
    $objdump .= " -M i386";
    $objcopy .= " -O elf32-i386";
    $cc .= " -m32";

} elsif ($arch eq "sh") {
    $alignment = 2;

    # force flags for this arch
    $ld .= " -m shlelf_linux";
    $objcopy .= " -O elf32-sh-linux";
    $cc .= " -m32";

} elsif ($arch eq "powerpc") {
    $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";

    if ($bits == 64) {
	$type = ".quad";
    }

} elsif ($arch eq "arm") {
    $alignment = 2;
    $section_type = '%progbits';

} else {
    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
}

my $text_found = 0;
my $read_function = 0;
my $opened = 0;
my $mcount_section = "__mcount_loc";

my $dirname;
my $filename;
my $prefix;
my $ext;

if ($inputfile =~ m,^(.*)/([^/]*)$,) {
    $dirname = $1;
    $filename = $2;
} else {
    $dirname = ".";
    $filename = $inputfile;
}

if ($filename =~ m,^(.*)(\.\S),) {
    $prefix = $1;
    $ext = $2;
} else {
    $prefix = $filename;
    $ext = "";
}

my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";

#
# --globalize-symbols came out in 2.17, we must test the version
# of objcopy, and if it is less than 2.17, then we can not
# record local functions.
my $use_locals = 01;
my $local_warn_once = 0;
my $found_version = 0;

open (IN, "$objcopy --version |") || die "error running $objcopy";
while (<IN>) {
    if (/objcopy.*\s(\d+)\.(\d+)/) {
	my $major = $1;
	my $minor = $2;

	$found_version = 1;
	if ($major < 2 ||
	    ($major == 2 && $minor < 17)) {
	    $use_locals = 0;
	}
	last;
    }
}
close (IN);

if (!$found_version) {
    print STDERR "WARNING: could not find objcopy version.\n" .
	"\tDisabling local function references.\n";
}


#
# Step 1: find all the local (static functions) and weak symbols.
#        't' is local, 'w/W' is weak (we never use a weak function)
#
open (IN, "$nm $inputfile|") || die "error running $nm";
while (<IN>) {
    if (/$nm_regex/) {
	$locals{$1} = 1;
    } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
	$weak{$2} = $1;
    }
}
close(IN);

my @offsets;		# Array of offsets of mcount callers
my $ref_func;		# reference function to use for offsets
my $offset = 0;		# offset of ref_func to section beginning

##
# update_funcs - print out the current mcount callers
#
#  Go through the list of offsets to callers and write them to
#  the output file in a format that can be read by an assembler.
#
sub update_funcs
{
    return if ($#offsets < 0);

    defined($ref_func) || die "No function to reference";

    # A section only had a weak function, to represent it.
    # Unfortunately, a weak function may be overwritten by another
    # function of the same name, making all these offsets incorrect.
    # To be safe, we simply print a warning and bail.
    if (defined $weak{$ref_func}) {
	print STDERR
	    "$inputfile: WARNING: referencing weak function" .
	    " $ref_func for mcount\n";
	return;
    }

    # is this function static? If so, note this fact.
    if (defined $locals{$ref_func}) {

	# only use locals if objcopy supports globalize-symbols
	if (!$use_locals) {
	    return;
	}
	$convert{$ref_func} = 1;
    }

    # Loop through all the mcount caller offsets and print a reference
    # to the caller based from the ref_func.
    for (my $i=0; $i <= $#offsets; $i++) {
	if (!$opened) {
	    open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
	    $opened = 1;
	    print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	    print FILE "\t.align $alignment\n" if (defined($alignment));
	}
	printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
    }
}

#
# Step 2: find the sections and mcount call sites
#
open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";

my $text;

while (<IN>) {
    # is it a section?
    if (/$section_regex/) {

	# Only record text sections that we know are safe
	if (defined($text_sections{$1})) {
	    $read_function = 1;
	} else {
	    $read_function = 0;
	}
	# print out any recorded offsets
	update_funcs() if ($text_found);

	# reset all markers and arrays
	$text_found = 0;
	undef($ref_func);
	undef(@offsets);

    # section found, now is this a start of a function?
    } elsif ($read_function && /$function_regex/) {
	$text_found = 1;
	$offset = hex $1;
	$text = $2;

	# if this is either a local function or a weak function
	# keep looking for functions that are global that
	# we can use safely.
	if (!defined($locals{$text}) && !defined($weak{$text})) {
	    $ref_func = $text;
	    $read_function = 0;
	} else {
	    # if we already have a function, and this is weak, skip it
	    if (!defined($ref_func) || !defined($weak{$text})) {
		$ref_func = $text;
	    }
	}
    }

    # is this a call site to mcount? If so, record it to print later
    if ($text_found && /$mcount_regex/) {
	$offsets[$#offsets + 1] = hex $1;
    }
}

# dump out anymore offsets that may have been found
update_funcs() if ($text_found);

# If we did not find any mcount callers, we are done (do nothing).
if (!$opened) {
    exit(0);
}

close(FILE);

#
# Step 3: Compile the file that holds the list of call sites to mcount.
#
`$cc -o $mcount_o -c $mcount_s`;

my @converts = keys %convert;

#
# Step 4: Do we have sections that started with local functions?
#
if ($#converts >= 0) {
    my $globallist = "";
    my $locallist = "";

    foreach my $con (@converts) {
	$globallist .= " --globalize-symbol $con";
	$locallist .= " --localize-symbol $con";
    }

    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
    my $globalmix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 5: set up each local function as a global
    #
    `$objcopy $globallist $inputfile $globalobj`;

    #
    # Step 6: Link the global version to our list.
    #
    `$ld -r $globalobj $mcount_o -o $globalmix`;

    #
    # Step 7: Convert the local functions back into local symbols
    #
    `$objcopy $locallist $globalmix $inputfile`;

    # Remove the temp files
    `$rm $globalobj $globalmix`;

} else {

    my $mix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 8: Link the object with our list of call sites object.
    #
    `$ld -r $inputfile $mcount_o -o $mix`;

    #
    # Step 9: Move the result back to the original object.
    #
    `$mv $mix $inputfile`;
}

# Clean up the temp files
`$rm $mcount_o $mcount_s`;

exit(0);
Commit	Line	Data
8da3821b SR	1	#!/usr/bin/perl -w
	2	# (c) 2008, Steven Rostedt <srostedt@redhat.com>
	3	# Licensed under the terms of the GNU GPL License version 2
	4	#
	5	# recordmcount.pl - makes a section called __mcount_loc that holds
	6	# all the offsets to the calls to mcount.
	7	#
	8	#
	9	# What we want to end up with is a section in vmlinux called
	10	# __mcount_loc that contains a list of pointers to all the
	11	# call sites in the kernel that call mcount. Later on boot up, the kernel
	12	# will read this list, save the locations and turn them into nops.
	13	# When tracing or profiling is later enabled, these locations will then
	14	# be converted back to pointers to some function.
	15	#
	16	# This is no easy feat. This script is called just after the original
	17	# object is compiled and before it is linked.
	18	#
	19	# The references to the call sites are offsets from the section of text
	20	# that the call site is in. Hence, all functions in a section that
	21	# has a call site to mcount, will have the offset from the beginning of
	22	# the section and not the beginning of the function.
	23	#
	24	# The trick is to find a way to record the beginning of the section.
	25	# The way we do this is to look at the first function in the section
	26	# which will also be the location of that section after final link.
	27	# e.g.
	28	#
	29	# .section ".text.sched"
	30	# .globl my_func
	31	# my_func:
	32	# [...]
	33	# call mcount (offset: 0x5)
	34	# [...]
	35	# ret
	36	# other_func:
	37	# [...]
	38	# call mcount (offset: 0x1b)
	39	# [...]
	40	#
	41	# Both relocation offsets for the mcounts in the above example will be
	42	# offset from .text.sched. If we make another file called tmp.s with:
	43	#
	44	# .section __mcount_loc
	45	# .quad my_func + 0x5
	46	# .quad my_func + 0x1b
	47	#
	48	# We can then compile this tmp.s into tmp.o, and link it to the original
	49	# object.
	50	#
	51	# But this gets hard if my_func is not globl (a static function).
	52	# In such a case we have:
	53	#
	54	# .section ".text.sched"
	55	# my_func:
	56	# [...]
	57	# call mcount (offset: 0x5)
	58	# [...]
	59	# ret
	60	# .globl my_func
	61	# other_func:
	62	# [...]
	63	# call mcount (offset: 0x1b)
	64	# [...]
65	#
66	# If we make the tmp.s the same as above, when we link together with
67	# the original object, we will end up with two symbols for my_func:
68	# one local, one global. After final compile, we will end up with
69	# an undefined reference to my_func.
70	#
71	# Since local objects can reference local variables, we need to find
72	# a way to make tmp.o reference the local objects of the original object
73	# file after it is linked together. To do this, we convert the my_func
74	# into a global symbol before linking tmp.o. Then after we link tmp.o
75	# we will only have a single symbol for my_func that is global.
76	# We can convert my_func back into a local symbol and we are done.
77	#
78	# Here are the steps we take:
79	#
80	# 1) Record all the local symbols by using 'nm'
81	# 2) Use objdump to find all the call site offsets and sections for
82	# mcount.
83	# 3) Compile the list into its own object.
84	# 4) Do we have to deal with local functions? If not, go to step 8.
85	# 5) Make an object that converts these local functions to global symbols
86	# with objcopy.
87	# 6) Link together this new object with the list object.
88	# 7) Convert the local functions back to local symbols and rename
89	# the result as the original object.
90	# End.
91	# 8) Link the object with the list object.
92	# 9) Move the result back to the original object.
93	# End.
94	#
95
96	use strict;
97
98	my $P = $0;
99	$P =~ s@.*/@@g;
100
101	my $V = '0.1';
102
103	if ($#ARGV < 6) {
104	print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
105	print "version: $V\n";
106	exit(1);
107	}
108
dce9d18a SR	109	my ($arch, $bits, $objdump, $objcopy, $cc,
dce9d18a SR	110	$ld, $nm, $rm, $mv, $inputfile) = @ARGV;
8da3821b	111
34698bcb SR	112	# Acceptable sections to record.
	113	my %text_sections = (
	114	".text" => 1,
	115	);
	116
8da3821b SR	117	$objdump = "objdump" if ((length $objdump) == 0);
	118	$objcopy = "objcopy" if ((length $objcopy) == 0);
	119	$cc = "gcc" if ((length $cc) == 0);
	120	$ld = "ld" if ((length $ld) == 0);
	121	$nm = "nm" if ((length $nm) == 0);
	122	$rm = "rm" if ((length $rm) == 0);
	123	$mv = "mv" if ((length $mv) == 0);
	124
	125	#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
	126	# "'$nm' '$rm' '$mv' '$inputfile'\n";
	127
8feff1ca SR	128	my %locals; # List of local (static) functions
	129	my %weak; # List of weak functions
	130	my %convert; # List of local functions used that needs conversion
8da3821b SR	131
8da3821b SR	132	my $type;
42e007d0	133	my $nm_regex; # Find the local functions (return function)
8da3821b	134	my $section_regex; # Find the start of a section
8feff1ca SR	135	my $function_regex; # Find the name of a function
8feff1ca SR	136	# (return offset and func name)
8da3821b	137	my $mcount_regex; # Find the call site to mcount (return offset)
3a3d04ae	138	my $alignment; # The .align value to use for $mcount_section
e58918ab	139	my $section_type; # Section header plus possible alignment command
8da3821b	140
dce9d18a SR	141	if ($arch eq "x86") {
	142	if ($bits == 64) {
	143	$arch = "x86_64";
	144	} else {
	145	$arch = "i386";
	146	}
	147	}
	148
c204f726 SR	149	#
	150	# We base the defaults off of i386, the other archs may
	151	# feel free to change them in the below if statements.
	152	#
	153	$nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
	154	$section_regex = "Disassembly of section\\s+(\\S+):";
	155	$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
	156	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount\$";
e58918ab	157	$section_type = '@progbits';
c204f726 SR	158	$type = ".long";
c204f726 SR	159
8da3821b	160	if ($arch eq "x86_64") {
8da3821b SR	161	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
8da3821b SR	162	$type = ".quad";
7d5222a6	163	$alignment = 8;
d74fcd1e SR	164
	165	# force flags for this arch
	166	$ld .= " -m elf_x86_64";
	167	$objdump .= " -M x86-64";
	168	$objcopy .= " -O elf64-x86-64";
	169	$cc .= " -m64";
	170
8da3821b	171	} elsif ($arch eq "i386") {
7d5222a6	172	$alignment = 4;
d74fcd1e SR	173
	174	# force flags for this arch
	175	$ld .= " -m elf_i386";
	176	$objdump .= " -M i386";
	177	$objcopy .= " -O elf32-i386";
	178	$cc .= " -m32";
	179
0da85c09	180	} elsif ($arch eq "sh") {
3a3d04ae	181	$alignment = 2;
0da85c09 MF	182
	183	# force flags for this arch
	184	$ld .= " -m shlelf_linux";
	185	$objcopy .= " -O elf32-sh-linux";
	186	$cc .= " -m32";
	187
42e007d0 SR	188	} elsif ($arch eq "powerpc") {
42e007d0 SR	189	$nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
42e007d0 SR	190	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
42e007d0 SR	191	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s\\.?_mcount\$";
c204f726	192
42e007d0 SR	193	if ($bits == 64) {
42e007d0 SR	194	$type = ".quad";
42e007d0 SR	195	}
42e007d0 SR	196
e58918ab JR	197	} elsif ($arch eq "arm") {
	198	$alignment = 2;
	199	$section_type = '%progbits';
	200
8da3821b SR	201	} else {
	202	die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
	203	}
	204
	205	my $text_found = 0;
	206	my $read_function = 0;
	207	my $opened = 0;
8da3821b SR	208	my $mcount_section = "__mcount_loc";
	209
	210	my $dirname;
	211	my $filename;
	212	my $prefix;
	213	my $ext;
	214
	215	if ($inputfile =~ m,^(.)/([^/])$,) {
	216	$dirname = $1;
	217	$filename = $2;
	218	} else {
	219	$dirname = ".";
	220	$filename = $inputfile;
	221	}
	222
	223	if ($filename =~ m,^(.*)(\.\S),) {
	224	$prefix = $1;
	225	$ext = $2;
	226	} else {
	227	$prefix = $filename;
	228	$ext = "";
	229	}
	230
	231	my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
	232	my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
	233
f2f8458e SR	234	#
	235	# --globalize-symbols came out in 2.17, we must test the version
	236	# of objcopy, and if it is less than 2.17, then we can not
	237	# record local functions.
	238	my $use_locals = 01;
	239	my $local_warn_once = 0;
	240	my $found_version = 0;
	241
	242	open (IN, "$objcopy --version \|") \|\| die "error running $objcopy";
	243	while (<IN>) {
	244	if (/objcopy.*\s(\d+)\.(\d+)/) {
	245	my $major = $1;
	246	my $minor = $2;
	247
	248	$found_version = 1;
	249	if ($major < 2 \|\|
	250	($major == 2 && $minor < 17)) {
	251	$use_locals = 0;
	252	}
	253	last;
	254	}
	255	}
	256	close (IN);
	257
	258	if (!$found_version) {
	259	print STDERR "WARNING: could not find objcopy version.\n" .
	260	"\tDisabling local function references.\n";
	261	}
	262
	263
8da3821b	264	#
8feff1ca SR	265	# Step 1: find all the local (static functions) and weak symbols.
8feff1ca SR	266	# 't' is local, 'w/W' is weak (we never use a weak function)
8da3821b SR	267	#
	268	open (IN, "$nm $inputfile\|") \|\| die "error running $nm";
	269	while (<IN>) {
42e007d0	270	if (/$nm_regex/) {
8da3821b	271	$locals{$1} = 1;
8feff1ca SR	272	} elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
8feff1ca SR	273	$weak{$2} = $1;
8da3821b SR	274	}
	275	}
	276	close(IN);
	277
8feff1ca SR	278	my @offsets; # Array of offsets of mcount callers
	279	my $ref_func; # reference function to use for offsets
	280	my $offset = 0; # offset of ref_func to section beginning
	281
	282	##
	283	# update_funcs - print out the current mcount callers
	284	#
	285	# Go through the list of offsets to callers and write them to
	286	# the output file in a format that can be read by an assembler.
	287	#
	288	sub update_funcs
	289	{
	290	return if ($#offsets < 0);
	291
	292	defined($ref_func) \|\| die "No function to reference";
	293
	294	# A section only had a weak function, to represent it.
	295	# Unfortunately, a weak function may be overwritten by another
	296	# function of the same name, making all these offsets incorrect.
	297	# To be safe, we simply print a warning and bail.
	298	if (defined $weak{$ref_func}) {
	299	print STDERR
	300	"$inputfile: WARNING: referencing weak function" .
	301	" $ref_func for mcount\n";
	302	return;
	303	}
	304
	305	# is this function static? If so, note this fact.
	306	if (defined $locals{$ref_func}) {
f2f8458e SR	307
	308	# only use locals if objcopy supports globalize-symbols
	309	if (!$use_locals) {
f2f8458e SR	310	return;
f2f8458e SR	311	}
8feff1ca SR	312	$convert{$ref_func} = 1;
	313	}
	314
	315	# Loop through all the mcount caller offsets and print a reference
	316	# to the caller based from the ref_func.
	317	for (my $i=0; $i <= $#offsets; $i++) {
	318	if (!$opened) {
	319	open(FILE, ">$mcount_s") \|\| die "can't create $mcount_s\n";
	320	$opened = 1;
e58918ab	321	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
42e007d0	322	print FILE "\t.align $alignment\n" if (defined($alignment));
8feff1ca SR	323	}
	324	printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
	325	}
	326	}
	327
8da3821b SR	328	#
	329	# Step 2: find the sections and mcount call sites
	330	#
	331	open(IN, "$objdump -dr $inputfile\|") \|\| die "error running $objdump";
	332
8feff1ca SR	333	my $text;
8feff1ca SR	334
8da3821b SR	335	while (<IN>) {
	336	# is it a section?
	337	if (/$section_regex/) {
34698bcb SR	338
	339	# Only record text sections that we know are safe
	340	if (defined($text_sections{$1})) {
	341	$read_function = 1;
	342	} else {
	343	$read_function = 0;
	344	}
8feff1ca SR	345	# print out any recorded offsets
	346	update_funcs() if ($text_found);
	347
	348	# reset all markers and arrays
8da3821b	349	$text_found = 0;
8feff1ca SR	350	undef($ref_func);
	351	undef(@offsets);
	352
8da3821b SR	353	# section found, now is this a start of a function?
8da3821b SR	354	} elsif ($read_function && /$function_regex/) {
8da3821b	355	$text_found = 1;
8feff1ca SR	356	$offset = hex $1;
	357	$text = $2;
	358
	359	# if this is either a local function or a weak function
	360	# keep looking for functions that are global that
	361	# we can use safely.
	362	if (!defined($locals{$text}) && !defined($weak{$text})) {
	363	$ref_func = $text;
	364	$read_function = 0;
	365	} else {
	366	# if we already have a function, and this is weak, skip it
	367	if (!defined($ref_func) \|\| !defined($weak{$text})) {
	368	$ref_func = $text;
	369	}
8da3821b	370	}
8feff1ca SR	371	}
	372
	373	# is this a call site to mcount? If so, record it to print later
	374	if ($text_found && /$mcount_regex/) {
	375	$offsets[$#offsets + 1] = hex $1;
8da3821b SR	376	}
	377	}
	378
8feff1ca SR	379	# dump out anymore offsets that may have been found
	380	update_funcs() if ($text_found);
	381
8da3821b SR	382	# If we did not find any mcount callers, we are done (do nothing).
	383	if (!$opened) {
	384	exit(0);
	385	}
	386
	387	close(FILE);
	388
	389	#
	390	# Step 3: Compile the file that holds the list of call sites to mcount.
	391	#
	392	`$cc -o $mcount_o -c $mcount_s`;
	393
	394	my @converts = keys %convert;
	395
	396	#
	397	# Step 4: Do we have sections that started with local functions?
	398	#
	399	if ($#converts >= 0) {
	400	my $globallist = "";
	401	my $locallist = "";
	402
	403	foreach my $con (@converts) {
	404	$globallist .= " --globalize-symbol $con";
	405	$locallist .= " --localize-symbol $con";
	406	}
	407
	408	my $globalobj = $dirname . "/.tmp_gl_" . $filename;
	409	my $globalmix = $dirname . "/.tmp_mx_" . $filename;
	410
	411	#
	412	# Step 5: set up each local function as a global
	413	#
	414	`$objcopy $globallist $inputfile $globalobj`;
	415
	416	#
	417	# Step 6: Link the global version to our list.
	418	#
	419	`$ld -r $globalobj $mcount_o -o $globalmix`;
	420
	421	#
	422	# Step 7: Convert the local functions back into local symbols
	423	#
	424	`$objcopy $locallist $globalmix $inputfile`;
	425
	426	# Remove the temp files
	427	`$rm $globalobj $globalmix`;
	428
	429	} else {
	430
	431	my $mix = $dirname . "/.tmp_mx_" . $filename;
	432
	433	#
	434	# Step 8: Link the object with our list of call sites object.
	435	#
	436	`$ld -r $inputfile $mcount_o -o $mix`;
	437
	438	#
	439	# Step 9: Move the result back to the original object.
	440	#
	441	`$mv $mix $inputfile`;
	442	}
	443
	444	# Clean up the temp files
	445	`$rm $mcount_o $mcount_s`;
446
447	exit(0);