x86: merge putuser asm functions.

putuser_32.S and putuser_64.S are merged into putuser.S.

Signed-off-by: Glauber Costa <gcosta@redhat.com>
Signed-off-by: H. Peter Anvin <hpa@zytor.com>
Signed-off-by: Ingo Molnar <mingo@elte.hu>

diff --git a/arch/x86/lib/Makefile b/arch/x86/lib/Makefile
index e92948203a5dfde38cb998078447ac338e280024..83226e0a7ce4e331aa1aac3277b1d6301bf025f8 100644 (file)
--- a/arch/x86/lib/Makefile
+++ b/arch/x86/lib/Makefile
@@ -5,7 +5,7 @@
 obj-$(CONFIG_SMP) := msr-on-cpu.o
 
 lib-y := delay.o
-lib-y += usercopy_$(BITS).o getuser.o putuser_$(BITS).o
+lib-y += usercopy_$(BITS).o getuser.o putuser.o
 lib-y += memcpy_$(BITS).o
 
 ifeq ($(CONFIG_X86_32),y)

diff --git a/arch/x86/lib/putuser.S b/arch/x86/lib/putuser.S
new file mode 100644 (file)
index 0000000..36b0d15
--- /dev/null
+++ b/arch/x86/lib/putuser.S
@@ -0,0 +1,97 @@
+/*
+ * __put_user functions.
+ *
+ * (C) Copyright 2005 Linus Torvalds
+ * (C) Copyright 2005 Andi Kleen
+ * (C) Copyright 2008 Glauber Costa
+ *
+ * These functions have a non-standard call interface
+ * to make them more efficient, especially as they
+ * return an error value in addition to the "real"
+ * return value.
+ */
+#include <linux/linkage.h>
+#include <asm/dwarf2.h>
+#include <asm/thread_info.h>
+#include <asm/errno.h>
+#include <asm/asm.h>
+
+
+/*
+ * __put_user_X
+ *
+ * Inputs:     %eax[:%edx] contains the data
+ *             %ecx contains the address
+ *
+ * Outputs:    %eax is error code (0 or -EFAULT)
+ *
+ * These functions should not modify any other registers,
+ * as they get called from within inline assembly.
+ */
+
+#define ENTER  CFI_STARTPROC ; \
+               GET_THREAD_INFO(%_ASM_BX)
+#define EXIT   ret ; \
+               CFI_ENDPROC
+
+.text
+ENTRY(__put_user_1)
+       ENTER
+       cmp TI_addr_limit(%_ASM_BX),%_ASM_CX
+       jae bad_put_user
+1:     movb %al,(%_ASM_CX)
+       xor %eax,%eax
+       EXIT
+ENDPROC(__put_user_1)
+
+ENTRY(__put_user_2)
+       ENTER
+       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
+       sub $1,%_ASM_BX
+       cmp %_ASM_BX,%_ASM_CX
+       jae bad_put_user
+2:     movw %ax,(%_ASM_CX)
+       xor %eax,%eax
+       EXIT
+ENDPROC(__put_user_2)
+
+ENTRY(__put_user_4)
+       ENTER
+       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
+       sub $3,%_ASM_BX
+       cmp %_ASM_BX,%_ASM_CX
+       jae bad_put_user
+3:     movl %eax,(%_ASM_CX)
+       xor %eax,%eax
+       EXIT
+ENDPROC(__put_user_4)
+
+ENTRY(__put_user_8)
+       ENTER
+       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
+       sub $7,%_ASM_BX
+       cmp %_ASM_BX,%_ASM_CX
+       jae bad_put_user
+4:     mov %_ASM_AX,(%_ASM_CX)
+#ifdef CONFIG_X86_32
+5:     movl %edx,4(%_ASM_CX)
+#endif
+       xor %eax,%eax
+       EXIT
+ENDPROC(__put_user_8)
+
+bad_put_user:
+       CFI_STARTPROC
+       movl $-EFAULT,%eax
+       EXIT
+END(bad_put_user)
+
+.section __ex_table,"a"
+       _ASM_PTR 1b,bad_put_user
+       _ASM_PTR 2b,bad_put_user
+       _ASM_PTR 3b,bad_put_user
+       _ASM_PTR 4b,bad_put_user
+#ifdef CONFIG_X86_32
+       _ASM_PTR 5b,bad_put_user
+#endif
+.previous

diff --git a/arch/x86/lib/putuser_32.S b/arch/x86/lib/putuser_32.S
deleted file mode 100644 (file)
index e7eda34..0000000
--- a/arch/x86/lib/putuser_32.S
+++ /dev/null
@@ -1,90 +0,0 @@
-/*
- * __put_user functions.
- *
- * (C) Copyright 2005 Linus Torvalds
- *
- * These functions have a non-standard call interface
- * to make them more efficient, especially as they
- * return an error value in addition to the "real"
- * return value.
- */
-#include <linux/linkage.h>
-#include <asm/dwarf2.h>
-#include <asm/thread_info.h>
-#include <asm/asm.h>
-
-
-/*
- * __put_user_X
- *
- * Inputs:     %eax[:%edx] contains the data
- *             %ecx contains the address
- *
- * Outputs:    %eax is error code (0 or -EFAULT)
- *
- * These functions should not modify any other registers,
- * as they get called from within inline assembly.
- */
-
-#define ENTER  CFI_STARTPROC ; \
-               GET_THREAD_INFO(%_ASM_BX)
-#define EXIT   ret ; \
-               CFI_ENDPROC
-
-.text
-ENTRY(__put_user_1)
-       ENTER
-       cmp TI_addr_limit(%_ASM_BX),%_ASM_CX
-       jae bad_put_user
-1:     movb %al,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_1)
-
-ENTRY(__put_user_2)
-       ENTER
-       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
-       sub $1,%_ASM_BX
-       cmp %_ASM_BX,%_ASM_CX
-       jae bad_put_user
-2:     movw %ax,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_2)
-
-ENTRY(__put_user_4)
-       ENTER
-       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
-       sub $3,%_ASM_BX
-       cmp %_ASM_BX,%_ASM_CX
-       jae bad_put_user
-3:     movl %eax,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_4)
-
-ENTRY(__put_user_8)
-       ENTER
-       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
-       sub $7,%_ASM_BX
-       cmp %_ASM_BX,%_ASM_CX
-       jae bad_put_user
-4:     movl %_ASM_AX,(%_ASM_CX)
-5:     movl %edx,4(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_8)
-
-bad_put_user:
-       CFI_STARTPROC
-       movl $-14,%eax
-       EXIT
-END(bad_put_user)
-
-.section __ex_table,"a"
-       _ASM_PTR 1b,bad_put_user
-       _ASM_PTR 2b,bad_put_user
-       _ASM_PTR 3b,bad_put_user
-       _ASM_PTR 4b,bad_put_user
-       _ASM_PTR 5b,bad_put_user
-.previous

diff --git a/arch/x86/lib/putuser_64.S b/arch/x86/lib/putuser_64.S
deleted file mode 100644 (file)
index d496cc8..0000000
--- a/arch/x86/lib/putuser_64.S
+++ /dev/null
@@ -1,94 +0,0 @@
-/*
- * __put_user functions.
- *
- * (C) Copyright 1998 Linus Torvalds
- * (C) Copyright 2005 Andi Kleen
- *
- * These functions have a non-standard call interface
- * to make them more efficient, especially as they
- * return an error value in addition to the "real"
- * return value.
- */
-
-/*
- * __put_user_X
- *
- * Inputs:     %rcx contains the address
- *             %rdx contains new value
- *
- * Outputs:    %rax is error code (0 or -EFAULT)
- *
- * %rbx is destroyed.
- *
- * These functions should not modify any other registers,
- * as they get called from within inline assembly.
- */
-
-#include <linux/linkage.h>
-#include <asm/dwarf2.h>
-#include <asm/page.h>
-#include <asm/errno.h>
-#include <asm/asm-offsets.h>
-#include <asm/thread_info.h>
-#include <asm/asm.h>
-
-#define ENTER   CFI_STARTPROC ; \
-                GET_THREAD_INFO(%_ASM_BX)
-#define EXIT    ret ; \
-                CFI_ENDPROC
-
-       .text
-ENTRY(__put_user_1)
-       ENTER
-       cmp TI_addr_limit(%_ASM_BX),%_ASM_CX
-       jae bad_put_user
-1:     movb %al,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_1)
-
-ENTRY(__put_user_2)
-       ENTER
-       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
-       sub  $1, %_ASM_BX
-       cmp %_ASM_BX ,%_ASM_CX
-       jae  bad_put_user
-2:     movw %ax,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_2)
-
-ENTRY(__put_user_4)
-       ENTER
-       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
-       sub  $3, %_ASM_BX
-       cmp  %_ASM_BX, %_ASM_CX
-       jae bad_put_user
-3:     movl %eax,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_4)
-
-ENTRY(__put_user_8)
-       ENTER
-       mov TI_addr_limit(%_ASM_BX),%_ASM_BX
-       sub  $7, %_ASM_BX
-       cmp  %_ASM_BX, %_ASM_CX
-       jae bad_put_user
-4:     movq %_ASM_AX,(%_ASM_CX)
-       xor %eax,%eax
-       EXIT
-ENDPROC(__put_user_8)
-
-bad_put_user:
-       CFI_STARTPROC
-       mov $(-EFAULT),%eax
-       EXIT
-END(bad_put_user)
-
-.section __ex_table,"a"
-       _ASM_PTR 1b,bad_put_user
-       _ASM_PTR 2b,bad_put_user
-       _ASM_PTR 3b,bad_put_user
-       _ASM_PTR 4b,bad_put_user
-.previous