tools/perf/util/parse-events.l

   1
   2 %option reentrant
   3 %option bison-bridge
   4 %option prefix="parse_events_"
   5 %option stack
   6
   7 %{
   8 #include <errno.h>
   9 #include "../perf.h"
  10 #include "parse-events-bison.h"
  11 #include "parse-events.h"
  12
  13 char *parse_events_get_text(yyscan_t yyscanner);
  14 YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
  15
  16 static int __value(YYSTYPE *yylval, char *str, int base, int token)
  17 {
  18         u64 num;
  19
  20         errno = 0;
  21         num = strtoull(str, NULL, base);
  22         if (errno)
  23                 return PE_ERROR;
  24
  25         yylval->num = num;
  26         return token;
  27 }
  28
  29 static int value(yyscan_t scanner, int base)
  30 {
  31         YYSTYPE *yylval = parse_events_get_lval(scanner);
  32         char *text = parse_events_get_text(scanner);
  33
  34         return __value(yylval, text, base, PE_VALUE);
  35 }
  36
  37 static int raw(yyscan_t scanner)
  38 {
  39         YYSTYPE *yylval = parse_events_get_lval(scanner);
  40         char *text = parse_events_get_text(scanner);
  41
  42         return __value(yylval, text + 1, 16, PE_RAW);
  43 }
  44
  45 static int str(yyscan_t scanner, int token)
  46 {
  47         YYSTYPE *yylval = parse_events_get_lval(scanner);
  48         char *text = parse_events_get_text(scanner);
  49
  50         yylval->str = strdup(text);
  51         return token;
  52 }
  53
  54 static int sym(yyscan_t scanner, int type, int config)
  55 {
  56         YYSTYPE *yylval = parse_events_get_lval(scanner);
  57
  58         yylval->num = (type << 16) + config;
  59         return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
  60 }
  61
  62 static int term(yyscan_t scanner, int type)
  63 {
  64         YYSTYPE *yylval = parse_events_get_lval(scanner);
  65
  66         yylval->num = type;
  67         return PE_TERM;
  68 }
  69
  70 %}
  71
  72 %x mem
  73 %s config
  74 %x event
  75
  76 group           [^,{}/]*[{][^}]*[}][^,{}/]*
  77 event_pmu       [^,{}/]+[/][^/]*[/][^,{}/]*
  78 event           [^,{}/]+
  79
  80 num_dec         [0-9]+
  81 num_hex         0x[a-fA-F0-9]+
  82 num_raw_hex     [a-fA-F0-9]+
  83 name            [a-zA-Z_*?][a-zA-Z0-9_*?]*
  84 modifier_event  [ukhpGH]{1,8}
  85 modifier_bp     [rwx]{1,3}
  86
  87 %%
  88
  89 %{
  90         {
  91                 int start_token;
  92
  93                 start_token = parse_events_get_extra(yyscanner);
  94
  95                 if (start_token == PE_START_TERMS)
  96                         BEGIN(config);
  97                 else if (start_token == PE_START_EVENTS)
  98                         BEGIN(event);
  99
 100                 if (start_token) {
 101                         parse_events_set_extra(NULL, yyscanner);
 102                         return start_token;
 103                 }
 104          }
 105 %}
 106
 107 <event>{
 108
 109 {group}         {
 110                         BEGIN(INITIAL); yyless(0);
 111                 }
 112
 113 {event_pmu}     |
 114 {event}         {
 115                         str(yyscanner, PE_EVENT_NAME);
 116                         BEGIN(INITIAL); yyless(0);
 117                         return PE_EVENT_NAME;
 118                 }
 119
 120 .               |
 121 <<EOF>>         {
 122                         BEGIN(INITIAL); yyless(0);
 123                 }
 124
 125 }
 126
 127 cpu-cycles|cycles                               { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
 128 stalled-cycles-frontend|idle-cycles-frontend    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
 129 stalled-cycles-backend|idle-cycles-backend      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
 130 instructions                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
 131 cache-references                                { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
 132 cache-misses                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
 133 branch-instructions|branches                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
 134 branch-misses                                   { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
 135 bus-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
 136 ref-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
 137 cpu-clock                                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
 138 task-clock                                      { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
 139 page-faults|faults                              { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
 140 minor-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
 141 major-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
 142 context-switches|cs                             { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
 143 cpu-migrations|migrations                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
 144 alignment-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
 145 emulation-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
 146
 147 L1-dcache|l1-d|l1d|L1-data              |
 148 L1-icache|l1-i|l1i|L1-instruction       |
 149 LLC|L2                                  |
 150 dTLB|d-tlb|Data-TLB                     |
 151 iTLB|i-tlb|Instruction-TLB              |
 152 branch|branches|bpu|btb|bpc             |
 153 node                                    { return str(yyscanner, PE_NAME_CACHE_TYPE); }
 154
 155 load|loads|read                         |
 156 store|stores|write                      |
 157 prefetch|prefetches                     |
 158 speculative-read|speculative-load       |
 159 refs|Reference|ops|access               |
 160 misses|miss                             { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
 161
 162 <config>{
 163 config                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
 164 config1                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
 165 config2                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
 166 name                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
 167 period                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
 168 branch_type             { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
 169 ,                       { return ','; }
 170 "/"                     { BEGIN(INITIAL); return '/'; }
 171 }
 172
 173 mem:                    { BEGIN(mem); return PE_PREFIX_MEM; }
 174 r{num_raw_hex}          { return raw(yyscanner); }
 175 {num_dec}               { return value(yyscanner, 10); }
 176 {num_hex}               { return value(yyscanner, 16); }
 177
 178 {modifier_event}        { return str(yyscanner, PE_MODIFIER_EVENT); }
 179 {name}                  { return str(yyscanner, PE_NAME); }
 180 "/"                     { BEGIN(config); return '/'; }
 181 -                       { return '-'; }
 182 ,                       { BEGIN(event); return ','; }
 183 :                       { return ':'; }
 184 "{"                     { BEGIN(event); return '{'; }
 185 "}"                     { return '}'; }
 186 =                       { return '='; }
 187 \n                      { }
 188
 189 <mem>{
 190 {modifier_bp}           { return str(yyscanner, PE_MODIFIER_BP); }
 191 :                       { return ':'; }
 192 {num_dec}               { return value(yyscanner, 10); }
 193 {num_hex}               { return value(yyscanner, 16); }
 194         /*
 195          * We need to separate 'mem:' scanner part, in order to get specific
 196          * modifier bits parsed out. Otherwise we would need to handle PE_NAME
 197          * and we'd need to parse it manually. During the escape from <mem>
 198          * state we need to put the escaping char back, so we dont miss it.
 199          */
 200 .                       { unput(*yytext); BEGIN(INITIAL); }
 201         /*
 202          * We destroy the scanner after reaching EOF,
 203          * but anyway just to be sure get back to INIT state.
 204          */
 205 <<EOF>>                 { BEGIN(INITIAL); }
 206 }
 207
 208 %%
 209
 210 int parse_events_wrap(void *scanner __used)
 211 {
 212         return 1;
 213 }