scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with is a section in vmlinux called
  10 # __mcount_loc that contains a list of pointers to all the
  11 # call sites in the kernel that call mcount. Later on boot up, the kernel
  12 # will read this list, save the locations and turn them into nops.
  13 # When tracing or profiling is later enabled, these locations will then
  14 # be converted back to pointers to some function.
  15 #
  16 # This is no easy feat. This script is called just after the original
  17 # object is compiled and before it is linked.
  18 #
  19 # The references to the call sites are offsets from the section of text
  20 # that the call site is in. Hence, all functions in a section that
  21 # has a call site to mcount, will have the offset from the beginning of
  22 # the section and not the beginning of the function.
  23 #
  24 # The trick is to find a way to record the beginning of the section.
  25 # The way we do this is to look at the first function in the section
  26 # which will also be the location of that section after final link.
  27 # e.g.
  28 #
  29 #  .section ".text.sched"
  30 #  .globl my_func
  31 #  my_func:
  32 #        [...]
  33 #        call mcount  (offset: 0x5)
  34 #        [...]
  35 #        ret
  36 #  other_func:
  37 #        [...]
  38 #        call mcount (offset: 0x1b)
  39 #        [...]
  40 #
  41 # Both relocation offsets for the mcounts in the above example will be
  42 # offset from .text.sched. If we make another file called tmp.s with:
  43 #
  44 #  .section __mcount_loc
  45 #  .quad  my_func + 0x5
  46 #  .quad  my_func + 0x1b
  47 #
  48 # We can then compile this tmp.s into tmp.o, and link it to the original
  49 # object.
  50 #
  51 # But this gets hard if my_func is not globl (a static function).
  52 # In such a case we have:
  53 #
  54 #  .section ".text.sched"
  55 #  my_func:
  56 #        [...]
  57 #        call mcount  (offset: 0x5)
  58 #        [...]
  59 #        ret
  60 #  .globl my_func
  61 #  other_func:
  62 #        [...]
  63 #        call mcount (offset: 0x1b)
  64 #        [...]
  65 #
  66 # If we make the tmp.s the same as above, when we link together with
  67 # the original object, we will end up with two symbols for my_func:
  68 # one local, one global.  After final compile, we will end up with
  69 # an undefined reference to my_func.
  70 #
  71 # Since local objects can reference local variables, we need to find
  72 # a way to make tmp.o reference the local objects of the original object
  73 # file after it is linked together. To do this, we convert the my_func
  74 # into a global symbol before linking tmp.o. Then after we link tmp.o
  75 # we will only have a single symbol for my_func that is global.
  76 # We can convert my_func back into a local symbol and we are done.
  77 #
  78 # Here are the steps we take:
  79 #
  80 # 1) Record all the local symbols by using 'nm'
  81 # 2) Use objdump to find all the call site offsets and sections for
  82 #    mcount.
  83 # 3) Compile the list into its own object.
  84 # 4) Do we have to deal with local functions? If not, go to step 8.
  85 # 5) Make an object that converts these local functions to global symbols
  86 #    with objcopy.
  87 # 6) Link together this new object with the list object.
  88 # 7) Convert the local functions back to local symbols and rename
  89 #    the result as the original object.
  90 #    End.
  91 # 8) Link the object with the list object.
  92 # 9) Move the result back to the original object.
  93 #    End.
  94 #
  95
  96 use strict;
  97
  98 my $P = $0;
  99 $P =~ s@.*/@@g;
 100
 101 my $V = '0.1';
 102
 103 if ($#ARGV < 6) {
 104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
 105         print "version: $V\n";
 106         exit(1);
 107 }
 108
 109 my ($arch, $bits, $objdump, $objcopy, $cc,
 110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
 111
 112 # Acceptable sections to record.
 113 my %text_sections = (
 114      ".text" => 1,
 115 );
 116
 117 $objdump = "objdump" if ((length $objdump) == 0);
 118 $objcopy = "objcopy" if ((length $objcopy) == 0);
 119 $cc = "gcc" if ((length $cc) == 0);
 120 $ld = "ld" if ((length $ld) == 0);
 121 $nm = "nm" if ((length $nm) == 0);
 122 $rm = "rm" if ((length $rm) == 0);
 123 $mv = "mv" if ((length $mv) == 0);
 124
 125 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 126 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 127
 128 my %locals;             # List of local (static) functions
 129 my %weak;               # List of weak functions
 130 my %convert;            # List of local functions used that needs conversion
 131
 132 my $type;
 133 my $nm_regex;           # Find the local functions (return function)
 134 my $section_regex;      # Find the start of a section
 135 my $function_regex;     # Find the name of a function
 136                         #    (return offset and func name)
 137 my $mcount_regex;       # Find the call site to mcount (return offset)
 138 my $alignment;         # The .align value to use for $mcount_section
 139
 140 if ($arch eq "x86") {
 141     if ($bits == 64) {
 142         $arch = "x86_64";
 143     } else {
 144         $arch = "i386";
 145     }
 146 }
 147
 148 #
 149 # We base the defaults off of i386, the other archs may
 150 # feel free to change them in the below if statements.
 151 #
 152 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 153 $section_regex = "Disassembly of section\\s+(\\S+):";
 154 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 155 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 156 $type = ".long";
 157
 158 if ($arch eq "x86_64") {
 159     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 160     $type = ".quad";
 161     $alignment = 8;
 162
 163     # force flags for this arch
 164     $ld .= " -m elf_x86_64";
 165     $objdump .= " -M x86-64";
 166     $objcopy .= " -O elf64-x86-64";
 167     $cc .= " -m64";
 168
 169 } elsif ($arch eq "i386") {
 170     $alignment = 4;
 171
 172     # force flags for this arch
 173     $ld .= " -m elf_i386";
 174     $objdump .= " -M i386";
 175     $objcopy .= " -O elf32-i386";
 176     $cc .= " -m32";
 177
 178 } elsif ($arch eq "sh") {
 179
 180     # force flags for this arch
 181     $ld .= " -m shlelf_linux";
 182     $objcopy .= " -O elf32-sh-linux";
 183     $cc .= " -m32";
 184
 185 } elsif ($arch eq "powerpc") {
 186     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 187     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 188     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 189
 190     if ($bits == 64) {
 191         $type = ".quad";
 192     }
 193
 194 } else {
 195     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 196 }
 197
 198 my $text_found = 0;
 199 my $read_function = 0;
 200 my $opened = 0;
 201 my $mcount_section = "__mcount_loc";
 202
 203 my $dirname;
 204 my $filename;
 205 my $prefix;
 206 my $ext;
 207
 208 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 209     $dirname = $1;
 210     $filename = $2;
 211 } else {
 212     $dirname = ".";
 213     $filename = $inputfile;
 214 }
 215
 216 if ($filename =~ m,^(.*)(\.\S),) {
 217     $prefix = $1;
 218     $ext = $2;
 219 } else {
 220     $prefix = $filename;
 221     $ext = "";
 222 }
 223
 224 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 225 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 226
 227 #
 228 # --globalize-symbols came out in 2.17, we must test the version
 229 # of objcopy, and if it is less than 2.17, then we can not
 230 # record local functions.
 231 my $use_locals = 01;
 232 my $local_warn_once = 0;
 233 my $found_version = 0;
 234
 235 open (IN, "$objcopy --version |") || die "error running $objcopy";
 236 while (<IN>) {
 237     if (/objcopy.*\s(\d+)\.(\d+)/) {
 238         my $major = $1;
 239         my $minor = $2;
 240
 241         $found_version = 1;
 242         if ($major < 2 ||
 243             ($major == 2 && $minor < 17)) {
 244             $use_locals = 0;
 245         }
 246         last;
 247     }
 248 }
 249 close (IN);
 250
 251 if (!$found_version) {
 252     print STDERR "WARNING: could not find objcopy version.\n" .
 253         "\tDisabling local function references.\n";
 254 }
 255
 256
 257 #
 258 # Step 1: find all the local (static functions) and weak symbols.
 259 #        't' is local, 'w/W' is weak (we never use a weak function)
 260 #
 261 open (IN, "$nm $inputfile|") || die "error running $nm";
 262 while (<IN>) {
 263     if (/$nm_regex/) {
 264         $locals{$1} = 1;
 265     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
 266         $weak{$2} = $1;
 267     }
 268 }
 269 close(IN);
 270
 271 my @offsets;            # Array of offsets of mcount callers
 272 my $ref_func;           # reference function to use for offsets
 273 my $offset = 0;         # offset of ref_func to section beginning
 274
 275 ##
 276 # update_funcs - print out the current mcount callers
 277 #
 278 #  Go through the list of offsets to callers and write them to
 279 #  the output file in a format that can be read by an assembler.
 280 #
 281 sub update_funcs
 282 {
 283     return if ($#offsets < 0);
 284
 285     defined($ref_func) || die "No function to reference";
 286
 287     # A section only had a weak function, to represent it.
 288     # Unfortunately, a weak function may be overwritten by another
 289     # function of the same name, making all these offsets incorrect.
 290     # To be safe, we simply print a warning and bail.
 291     if (defined $weak{$ref_func}) {
 292         print STDERR
 293             "$inputfile: WARNING: referencing weak function" .
 294             " $ref_func for mcount\n";
 295         return;
 296     }
 297
 298     # is this function static? If so, note this fact.
 299     if (defined $locals{$ref_func}) {
 300
 301         # only use locals if objcopy supports globalize-symbols
 302         if (!$use_locals) {
 303             return;
 304         }
 305         $convert{$ref_func} = 1;
 306     }
 307
 308     # Loop through all the mcount caller offsets and print a reference
 309     # to the caller based from the ref_func.
 310     for (my $i=0; $i <= $#offsets; $i++) {
 311         if (!$opened) {
 312             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 313             $opened = 1;
 314             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
 315             print FILE "\t.align $alignment\n" if (defined($alignment));
 316         }
 317         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
 318     }
 319 }
 320
 321 #
 322 # Step 2: find the sections and mcount call sites
 323 #
 324 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
 325
 326 my $text;
 327
 328 while (<IN>) {
 329     # is it a section?
 330     if (/$section_regex/) {
 331
 332         # Only record text sections that we know are safe
 333         if (defined($text_sections{$1})) {
 334             $read_function = 1;
 335         } else {
 336             $read_function = 0;
 337         }
 338         # print out any recorded offsets
 339         update_funcs() if ($text_found);
 340
 341         # reset all markers and arrays
 342         $text_found = 0;
 343         undef($ref_func);
 344         undef(@offsets);
 345
 346     # section found, now is this a start of a function?
 347     } elsif ($read_function && /$function_regex/) {
 348         $text_found = 1;
 349         $offset = hex $1;
 350         $text = $2;
 351
 352         # if this is either a local function or a weak function
 353         # keep looking for functions that are global that
 354         # we can use safely.
 355         if (!defined($locals{$text}) && !defined($weak{$text})) {
 356             $ref_func = $text;
 357             $read_function = 0;
 358         } else {
 359             # if we already have a function, and this is weak, skip it
 360             if (!defined($ref_func) || !defined($weak{$text})) {
 361                 $ref_func = $text;
 362             }
 363         }
 364     }
 365
 366     # is this a call site to mcount? If so, record it to print later
 367     if ($text_found && /$mcount_regex/) {
 368         $offsets[$#offsets + 1] = hex $1;
 369     }
 370 }
 371
 372 # dump out anymore offsets that may have been found
 373 update_funcs() if ($text_found);
 374
 375 # If we did not find any mcount callers, we are done (do nothing).
 376 if (!$opened) {
 377     exit(0);
 378 }
 379
 380 close(FILE);
 381
 382 #
 383 # Step 3: Compile the file that holds the list of call sites to mcount.
 384 #
 385 `$cc -o $mcount_o -c $mcount_s`;
 386
 387 my @converts = keys %convert;
 388
 389 #
 390 # Step 4: Do we have sections that started with local functions?
 391 #
 392 if ($#converts >= 0) {
 393     my $globallist = "";
 394     my $locallist = "";
 395
 396     foreach my $con (@converts) {
 397         $globallist .= " --globalize-symbol $con";
 398         $locallist .= " --localize-symbol $con";
 399     }
 400
 401     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 402     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 403
 404     #
 405     # Step 5: set up each local function as a global
 406     #
 407     `$objcopy $globallist $inputfile $globalobj`;
 408
 409     #
 410     # Step 6: Link the global version to our list.
 411     #
 412     `$ld -r $globalobj $mcount_o -o $globalmix`;
 413
 414     #
 415     # Step 7: Convert the local functions back into local symbols
 416     #
 417     `$objcopy $locallist $globalmix $inputfile`;
 418
 419     # Remove the temp files
 420     `$rm $globalobj $globalmix`;
 421
 422 } else {
 423
 424     my $mix = $dirname . "/.tmp_mx_" . $filename;
 425
 426     #
 427     # Step 8: Link the object with our list of call sites object.
 428     #
 429     `$ld -r $inputfile $mcount_o -o $mix`;
 430
 431     #
 432     # Step 9: Move the result back to the original object.
 433     #
 434     `$mv $mix $inputfile`;
 435 }
 436
 437 # Clean up the temp files
 438 `$rm $mcount_o $mcount_s`;
 439
 440 exit(0);