projects / GitHub / mt8127 / android_kernel_alcatel_ttab.git / blob
? search:


c5fe01bca6c0e9b69a6255487143e0d6f4f6ec4f
[GitHub/mt8127/android_kernel_alcatel_ttab.git] / arch / x86 / kernel / entry_32.S
1 /*
2 *
3 * Copyright (C) 1991, 1992 Linus Torvalds
4 */
5
6 /*
7 * entry.S contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all interrupts
9 * and faults that can result in a task-switch.
10 *
11 * NOTE: This code handles signal-recognition, which happens every time
12 * after a timer-interrupt and after each system call.
13 *
14 * I changed all the .align's to 4 (16 byte alignment), as that's faster
15 * on a 486.
16 *
17 * Stack layout in 'syscall_exit':
18 * ptrace needs to have all regs on the stack.
19 * if the order here is changed, it needs to be
20 * updated in fork.c:copy_process, signal.c:do_signal,
21 * ptrace.c and ptrace.h
22 *
23 * 0(%esp) - %ebx
24 * 4(%esp) - %ecx
25 * 8(%esp) - %edx
26 * C(%esp) - %esi
27 * 10(%esp) - %edi
28 * 14(%esp) - %ebp
29 * 18(%esp) - %eax
30 * 1C(%esp) - %ds
31 * 20(%esp) - %es
32 * 24(%esp) - %fs
33 * 28(%esp) - orig_eax
34 * 2C(%esp) - %eip
35 * 30(%esp) - %cs
36 * 34(%esp) - %eflags
37 * 38(%esp) - %oldesp
38 * 3C(%esp) - %oldss
39 *
40 * "current" is in register %ebx during any slow entries.
41 */
42
43 #include <linux/linkage.h>
44 #include <asm/thread_info.h>
45 #include <asm/irqflags.h>
46 #include <asm/errno.h>
47 #include <asm/segment.h>
48 #include <asm/smp.h>
49 #include <asm/page.h>
50 #include <asm/desc.h>
51 #include <asm/percpu.h>
52 #include <asm/dwarf2.h>
53 #include <asm/processor-flags.h>
54 #include <asm/ftrace.h>
55 #include <asm/irq_vectors.h>
56
57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
58 #include <linux/elf-em.h>
59 #define AUDIT_ARCH_I386 (EM_386|__AUDIT_ARCH_LE)
60 #define __AUDIT_ARCH_LE 0x40000000
61
62 #ifndef CONFIG_AUDITSYSCALL
63 #define sysenter_audit syscall_trace_entry
64 #define sysexit_audit syscall_exit_work
65 #endif
66
67 /*
68 * We use macros for low-level operations which need to be overridden
69 * for paravirtualization. The following will never clobber any registers:
70 * INTERRUPT_RETURN (aka. "iret")
71 * GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
72 * ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
73 *
74 * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
75 * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
76 * Allowing a register to be clobbered can shrink the paravirt replacement
77 * enough to patch inline, increasing performance.
78 */
79
80 #define nr_syscalls ((syscall_table_size)/4)
81
82 #ifdef CONFIG_PREEMPT
83 #define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
84 #else
85 #define preempt_stop(clobbers)
86 #define resume_kernel restore_nocheck
87 #endif
88
89 .macro TRACE_IRQS_IRET
90 #ifdef CONFIG_TRACE_IRQFLAGS
91 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off?
92 jz 1f
93 TRACE_IRQS_ON
94 1:
95 #endif
96 .endm
97
98 #ifdef CONFIG_VM86
99 #define resume_userspace_sig check_userspace
100 #else
101 #define resume_userspace_sig resume_userspace
102 #endif
103
104 #define SAVE_ALL \
105 cld; \
106 pushl %fs; \
107 CFI_ADJUST_CFA_OFFSET 4;\
108 /*CFI_REL_OFFSET fs, 0;*/\
109 pushl %es; \
110 CFI_ADJUST_CFA_OFFSET 4;\
111 /*CFI_REL_OFFSET es, 0;*/\
112 pushl %ds; \
113 CFI_ADJUST_CFA_OFFSET 4;\
114 /*CFI_REL_OFFSET ds, 0;*/\
115 pushl %eax; \
116 CFI_ADJUST_CFA_OFFSET 4;\
117 CFI_REL_OFFSET eax, 0;\
118 pushl %ebp; \
119 CFI_ADJUST_CFA_OFFSET 4;\
120 CFI_REL_OFFSET ebp, 0;\
121 pushl %edi; \
122 CFI_ADJUST_CFA_OFFSET 4;\
123 CFI_REL_OFFSET edi, 0;\
124 pushl %esi; \
125 CFI_ADJUST_CFA_OFFSET 4;\
126 CFI_REL_OFFSET esi, 0;\
127 pushl %edx; \
128 CFI_ADJUST_CFA_OFFSET 4;\
129 CFI_REL_OFFSET edx, 0;\
130 pushl %ecx; \
131 CFI_ADJUST_CFA_OFFSET 4;\
132 CFI_REL_OFFSET ecx, 0;\
133 pushl %ebx; \
134 CFI_ADJUST_CFA_OFFSET 4;\
135 CFI_REL_OFFSET ebx, 0;\
136 movl $(__USER_DS), %edx; \
137 movl %edx, %ds; \
138 movl %edx, %es; \
139 movl $(__KERNEL_PERCPU), %edx; \
140 movl %edx, %fs
141
142 #define RESTORE_INT_REGS \
143 popl %ebx; \
144 CFI_ADJUST_CFA_OFFSET -4;\
145 CFI_RESTORE ebx;\
146 popl %ecx; \
147 CFI_ADJUST_CFA_OFFSET -4;\
148 CFI_RESTORE ecx;\
149 popl %edx; \
150 CFI_ADJUST_CFA_OFFSET -4;\
151 CFI_RESTORE edx;\
152 popl %esi; \
153 CFI_ADJUST_CFA_OFFSET -4;\
154 CFI_RESTORE esi;\
155 popl %edi; \
156 CFI_ADJUST_CFA_OFFSET -4;\
157 CFI_RESTORE edi;\
158 popl %ebp; \
159 CFI_ADJUST_CFA_OFFSET -4;\
160 CFI_RESTORE ebp;\
161 popl %eax; \
162 CFI_ADJUST_CFA_OFFSET -4;\
163 CFI_RESTORE eax
164
165 #define RESTORE_REGS \
166 RESTORE_INT_REGS; \
167 1: popl %ds; \
168 CFI_ADJUST_CFA_OFFSET -4;\
169 /*CFI_RESTORE ds;*/\
170 2: popl %es; \
171 CFI_ADJUST_CFA_OFFSET -4;\
172 /*CFI_RESTORE es;*/\
173 3: popl %fs; \
174 CFI_ADJUST_CFA_OFFSET -4;\
175 /*CFI_RESTORE fs;*/\
176 .pushsection .fixup,"ax"; \
177 4: movl $0,(%esp); \
178 jmp 1b; \
179 5: movl $0,(%esp); \
180 jmp 2b; \
181 6: movl $0,(%esp); \
182 jmp 3b; \
183 .section __ex_table,"a";\
184 .align 4; \
185 .long 1b,4b; \
186 .long 2b,5b; \
187 .long 3b,6b; \
188 .popsection
189
190 #define RING0_INT_FRAME \
191 CFI_STARTPROC simple;\
192 CFI_SIGNAL_FRAME;\
193 CFI_DEF_CFA esp, 3*4;\
194 /*CFI_OFFSET cs, -2*4;*/\
195 CFI_OFFSET eip, -3*4
196
197 #define RING0_EC_FRAME \
198 CFI_STARTPROC simple;\
199 CFI_SIGNAL_FRAME;\
200 CFI_DEF_CFA esp, 4*4;\
201 /*CFI_OFFSET cs, -2*4;*/\
202 CFI_OFFSET eip, -3*4
203
204 #define RING0_PTREGS_FRAME \
205 CFI_STARTPROC simple;\
206 CFI_SIGNAL_FRAME;\
207 CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
208 /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
209 CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
210 /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
211 /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
212 CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
213 CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
214 CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
215 CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
216 CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
217 CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
218 CFI_OFFSET ebx, PT_EBX-PT_OLDESP
219
220 ENTRY(ret_from_fork)
221 CFI_STARTPROC
222 pushl %eax
223 CFI_ADJUST_CFA_OFFSET 4
224 call schedule_tail
225 GET_THREAD_INFO(%ebp)
226 popl %eax
227 CFI_ADJUST_CFA_OFFSET -4
228 pushl $0x0202 # Reset kernel eflags
229 CFI_ADJUST_CFA_OFFSET 4
230 popfl
231 CFI_ADJUST_CFA_OFFSET -4
232 jmp syscall_exit
233 CFI_ENDPROC
234 END(ret_from_fork)
235
236 /*
237 * Return to user mode is not as complex as all this looks,
238 * but we want the default path for a system call return to
239 * go as quickly as possible which is why some of this is
240 * less clear than it otherwise should be.
241 */
242
243 # userspace resumption stub bypassing syscall exit tracing
244 ALIGN
245 RING0_PTREGS_FRAME
246 ret_from_exception:
247 preempt_stop(CLBR_ANY)
248 ret_from_intr:
249 GET_THREAD_INFO(%ebp)
250 check_userspace:
251 movl PT_EFLAGS(%esp), %eax # mix EFLAGS and CS
252 movb PT_CS(%esp), %al
253 andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
254 cmpl $USER_RPL, %eax
255 jb resume_kernel # not returning to v8086 or userspace
256
257 ENTRY(resume_userspace)
258 LOCKDEP_SYS_EXIT
259 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
260 # setting need_resched or sigpending
261 # between sampling and the iret
262 TRACE_IRQS_OFF
263 movl TI_flags(%ebp), %ecx
264 andl $_TIF_WORK_MASK, %ecx # is there any work to be done on
265 # int/exception return?
266 jne work_pending
267 jmp restore_all
268 END(ret_from_exception)
269
270 #ifdef CONFIG_PREEMPT
271 ENTRY(resume_kernel)
272 DISABLE_INTERRUPTS(CLBR_ANY)
273 cmpl $0,TI_preempt_count(%ebp) # non-zero preempt_count ?
274 jnz restore_nocheck
275 need_resched:
276 movl TI_flags(%ebp), %ecx # need_resched set ?
277 testb $_TIF_NEED_RESCHED, %cl
278 jz restore_all
279 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off (exception path) ?
280 jz restore_all
281 call preempt_schedule_irq
282 jmp need_resched
283 END(resume_kernel)
284 #endif
285 CFI_ENDPROC
286
287 /* SYSENTER_RETURN points to after the "sysenter" instruction in
288 the vsyscall page. See vsyscall-sysentry.S, which defines the symbol. */
289
290 # sysenter call handler stub
291 ENTRY(ia32_sysenter_target)
292 CFI_STARTPROC simple
293 CFI_SIGNAL_FRAME
294 CFI_DEF_CFA esp, 0
295 CFI_REGISTER esp, ebp
296 movl TSS_sysenter_sp0(%esp),%esp
297 sysenter_past_esp:
298 /*
299 * Interrupts are disabled here, but we can't trace it until
300 * enough kernel state to call TRACE_IRQS_OFF can be called - but
301 * we immediately enable interrupts at that point anyway.
302 */
303 pushl $(__USER_DS)
304 CFI_ADJUST_CFA_OFFSET 4
305 /*CFI_REL_OFFSET ss, 0*/
306 pushl %ebp
307 CFI_ADJUST_CFA_OFFSET 4
308 CFI_REL_OFFSET esp, 0
309 pushfl
310 orl $X86_EFLAGS_IF, (%esp)
311 CFI_ADJUST_CFA_OFFSET 4
312 pushl $(__USER_CS)
313 CFI_ADJUST_CFA_OFFSET 4
314 /*CFI_REL_OFFSET cs, 0*/
315 /*
316 * Push current_thread_info()->sysenter_return to the stack.
317 * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
318 * pushed above; +8 corresponds to copy_thread's esp0 setting.
319 */
320 pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
321 CFI_ADJUST_CFA_OFFSET 4
322 CFI_REL_OFFSET eip, 0
323
324 pushl %eax
325 CFI_ADJUST_CFA_OFFSET 4
326 SAVE_ALL
327 ENABLE_INTERRUPTS(CLBR_NONE)
328
329 /*
330 * Load the potential sixth argument from user stack.
331 * Careful about security.
332 */
333 cmpl $__PAGE_OFFSET-3,%ebp
334 jae syscall_fault
335 1: movl (%ebp),%ebp
336 movl %ebp,PT_EBP(%esp)
337 .section __ex_table,"a"
338 .align 4
339 .long 1b,syscall_fault
340 .previous
341
342 GET_THREAD_INFO(%ebp)
343
344 /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
345 testw $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
346 jnz sysenter_audit
347 sysenter_do_call:
348 cmpl $(nr_syscalls), %eax
349 jae syscall_badsys
350 call *sys_call_table(,%eax,4)
351 movl %eax,PT_EAX(%esp)
352 LOCKDEP_SYS_EXIT
353 DISABLE_INTERRUPTS(CLBR_ANY)
354 TRACE_IRQS_OFF
355 movl TI_flags(%ebp), %ecx
356 testw $_TIF_ALLWORK_MASK, %cx
357 jne sysexit_audit
358 sysenter_exit:
359 /* if something modifies registers it must also disable sysexit */
360 movl PT_EIP(%esp), %edx
361 movl PT_OLDESP(%esp), %ecx
362 xorl %ebp,%ebp
363 TRACE_IRQS_ON
364 1: mov PT_FS(%esp), %fs
365 ENABLE_INTERRUPTS_SYSEXIT
366
367 #ifdef CONFIG_AUDITSYSCALL
368 sysenter_audit:
369 testw $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
370 jnz syscall_trace_entry
371 addl $4,%esp
372 CFI_ADJUST_CFA_OFFSET -4
373 /* %esi already in 8(%esp) 6th arg: 4th syscall arg */
374 /* %edx already in 4(%esp) 5th arg: 3rd syscall arg */
375 /* %ecx already in 0(%esp) 4th arg: 2nd syscall arg */
376 movl %ebx,%ecx /* 3rd arg: 1st syscall arg */
377 movl %eax,%edx /* 2nd arg: syscall number */
378 movl $AUDIT_ARCH_I386,%eax /* 1st arg: audit arch */
379 call audit_syscall_entry
380 pushl %ebx
381 CFI_ADJUST_CFA_OFFSET 4
382 movl PT_EAX(%esp),%eax /* reload syscall number */
383 jmp sysenter_do_call
384
385 sysexit_audit:
386 testw $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %cx
387 jne syscall_exit_work
388 TRACE_IRQS_ON
389 ENABLE_INTERRUPTS(CLBR_ANY)
390 movl %eax,%edx /* second arg, syscall return value */
391 cmpl $0,%eax /* is it < 0? */
392 setl %al /* 1 if so, 0 if not */
393 movzbl %al,%eax /* zero-extend that */
394 inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
395 call audit_syscall_exit
396 DISABLE_INTERRUPTS(CLBR_ANY)
397 TRACE_IRQS_OFF
398 movl TI_flags(%ebp), %ecx
399 testw $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %cx
400 jne syscall_exit_work
401 movl PT_EAX(%esp),%eax /* reload syscall return value */
402 jmp sysenter_exit
403 #endif
404
405 CFI_ENDPROC
406 .pushsection .fixup,"ax"
407 2: movl $0,PT_FS(%esp)
408 jmp 1b
409 .section __ex_table,"a"
410 .align 4
411 .long 1b,2b
412 .popsection
413 ENDPROC(ia32_sysenter_target)
414
415 # system call handler stub
416 ENTRY(system_call)
417 RING0_INT_FRAME # can't unwind into user space anyway
418 pushl %eax # save orig_eax
419 CFI_ADJUST_CFA_OFFSET 4
420 SAVE_ALL
421 GET_THREAD_INFO(%ebp)
422 # system call tracing in operation / emulation
423 /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
424 testw $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
425 jnz syscall_trace_entry
426 cmpl $(nr_syscalls), %eax
427 jae syscall_badsys
428 syscall_call:
429 call *sys_call_table(,%eax,4)
430 movl %eax,PT_EAX(%esp) # store the return value
431 syscall_exit:
432 LOCKDEP_SYS_EXIT
433 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
434 # setting need_resched or sigpending
435 # between sampling and the iret
436 TRACE_IRQS_OFF
437 movl TI_flags(%ebp), %ecx
438 testw $_TIF_ALLWORK_MASK, %cx # current->work
439 jne syscall_exit_work
440
441 restore_all:
442 movl PT_EFLAGS(%esp), %eax # mix EFLAGS, SS and CS
443 # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
444 # are returning to the kernel.
445 # See comments in process.c:copy_thread() for details.
446 movb PT_OLDSS(%esp), %ah
447 movb PT_CS(%esp), %al
448 andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
449 cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
450 CFI_REMEMBER_STATE
451 je ldt_ss # returning to user-space with LDT SS
452 restore_nocheck:
453 TRACE_IRQS_IRET
454 restore_nocheck_notrace:
455 RESTORE_REGS
456 addl $4, %esp # skip orig_eax/error_code
457 CFI_ADJUST_CFA_OFFSET -4
458 irq_return:
459 INTERRUPT_RETURN
460 .section .fixup,"ax"
461 ENTRY(iret_exc)
462 pushl $0 # no error code
463 pushl $do_iret_error
464 jmp error_code
465 .previous
466 .section __ex_table,"a"
467 .align 4
468 .long irq_return,iret_exc
469 .previous
470
471 CFI_RESTORE_STATE
472 ldt_ss:
473 larl PT_OLDSS(%esp), %eax
474 jnz restore_nocheck
475 testl $0x00400000, %eax # returning to 32bit stack?
476 jnz restore_nocheck # allright, normal return
477
478 #ifdef CONFIG_PARAVIRT
479 /*
480 * The kernel can't run on a non-flat stack if paravirt mode
481 * is active. Rather than try to fixup the high bits of
482 * ESP, bypass this code entirely. This may break DOSemu
483 * and/or Wine support in a paravirt VM, although the option
484 * is still available to implement the setting of the high
485 * 16-bits in the INTERRUPT_RETURN paravirt-op.
486 */
487 cmpl $0, pv_info+PARAVIRT_enabled
488 jne restore_nocheck
489 #endif
490
491 /* If returning to userspace with 16bit stack,
492 * try to fix the higher word of ESP, as the CPU
493 * won't restore it.
494 * This is an "official" bug of all the x86-compatible
495 * CPUs, which we can try to work around to make
496 * dosemu and wine happy. */
497 movl PT_OLDESP(%esp), %eax
498 movl %esp, %edx
499 call patch_espfix_desc
500 pushl $__ESPFIX_SS
501 CFI_ADJUST_CFA_OFFSET 4
502 pushl %eax
503 CFI_ADJUST_CFA_OFFSET 4
504 DISABLE_INTERRUPTS(CLBR_EAX)
505 TRACE_IRQS_OFF
506 lss (%esp), %esp
507 CFI_ADJUST_CFA_OFFSET -8
508 jmp restore_nocheck
509 CFI_ENDPROC
510 ENDPROC(system_call)
511
512 # perform work that needs to be done immediately before resumption
513 ALIGN
514 RING0_PTREGS_FRAME # can't unwind into user space anyway
515 work_pending:
516 testb $_TIF_NEED_RESCHED, %cl
517 jz work_notifysig
518 work_resched:
519 call schedule
520 LOCKDEP_SYS_EXIT
521 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
522 # setting need_resched or sigpending
523 # between sampling and the iret
524 TRACE_IRQS_OFF
525 movl TI_flags(%ebp), %ecx
526 andl $_TIF_WORK_MASK, %ecx # is there any work to be done other
527 # than syscall tracing?
528 jz restore_all
529 testb $_TIF_NEED_RESCHED, %cl
530 jnz work_resched
531
532 work_notifysig: # deal with pending signals and
533 # notify-resume requests
534 #ifdef CONFIG_VM86
535 testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
536 movl %esp, %eax
537 jne work_notifysig_v86 # returning to kernel-space or
538 # vm86-space
539 xorl %edx, %edx
540 call do_notify_resume
541 jmp resume_userspace_sig
542
543 ALIGN
544 work_notifysig_v86:
545 pushl %ecx # save ti_flags for do_notify_resume
546 CFI_ADJUST_CFA_OFFSET 4
547 call save_v86_state # %eax contains pt_regs pointer
548 popl %ecx
549 CFI_ADJUST_CFA_OFFSET -4
550 movl %eax, %esp
551 #else
552 movl %esp, %eax
553 #endif
554 xorl %edx, %edx
555 call do_notify_resume
556 jmp resume_userspace_sig
557 END(work_pending)
558
559 # perform syscall exit tracing
560 ALIGN
561 syscall_trace_entry:
562 movl $-ENOSYS,PT_EAX(%esp)
563 movl %esp, %eax
564 call syscall_trace_enter
565 /* What it returned is what we'll actually use. */
566 cmpl $(nr_syscalls), %eax
567 jnae syscall_call
568 jmp syscall_exit
569 END(syscall_trace_entry)
570
571 # perform syscall exit tracing
572 ALIGN
573 syscall_exit_work:
574 testb $_TIF_WORK_SYSCALL_EXIT, %cl
575 jz work_pending
576 TRACE_IRQS_ON
577 ENABLE_INTERRUPTS(CLBR_ANY) # could let syscall_trace_leave() call
578 # schedule() instead
579 movl %esp, %eax
580 call syscall_trace_leave
581 jmp resume_userspace
582 END(syscall_exit_work)
583 CFI_ENDPROC
584
585 RING0_INT_FRAME # can't unwind into user space anyway
586 syscall_fault:
587 GET_THREAD_INFO(%ebp)
588 movl $-EFAULT,PT_EAX(%esp)
589 jmp resume_userspace
590 END(syscall_fault)
591
592 syscall_badsys:
593 movl $-ENOSYS,PT_EAX(%esp)
594 jmp resume_userspace
595 END(syscall_badsys)
596 CFI_ENDPROC
597
598 #define FIXUP_ESPFIX_STACK \
599 /* since we are on a wrong stack, we cant make it a C code :( */ \
600 PER_CPU(gdt_page, %ebx); \
601 GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
602 addl %esp, %eax; \
603 pushl $__KERNEL_DS; \
604 CFI_ADJUST_CFA_OFFSET 4; \
605 pushl %eax; \
606 CFI_ADJUST_CFA_OFFSET 4; \
607 lss (%esp), %esp; \
608 CFI_ADJUST_CFA_OFFSET -8;
609 #define UNWIND_ESPFIX_STACK \
610 movl %ss, %eax; \
611 /* see if on espfix stack */ \
612 cmpw $__ESPFIX_SS, %ax; \
613 jne 27f; \
614 movl $__KERNEL_DS, %eax; \
615 movl %eax, %ds; \
616 movl %eax, %es; \
617 /* switch to normal stack */ \
618 FIXUP_ESPFIX_STACK; \
619 27:;
620
621 /*
622 * Build the entry stubs and pointer table with
623 * some assembler magic.
624 */
625 .section .rodata,"a"
626 ENTRY(interrupt)
627 .text
628
629 ENTRY(irq_entries_start)
630 RING0_INT_FRAME
631 vector=0
632 .rept NR_IRQS
633 ALIGN
634 .if vector
635 CFI_ADJUST_CFA_OFFSET -4
636 .endif
637 1: pushl $~(vector)
638 CFI_ADJUST_CFA_OFFSET 4
639 jmp common_interrupt
640 .previous
641 .long 1b
642 .text
643 vector=vector+1
644 .endr
645 END(irq_entries_start)
646
647 .previous
648 END(interrupt)
649 .previous
650
651 /*
652 * the CPU automatically disables interrupts when executing an IRQ vector,
653 * so IRQ-flags tracing has to follow that:
654 */
655 ALIGN
656 common_interrupt:
657 SAVE_ALL
658 TRACE_IRQS_OFF
659 movl %esp,%eax
660 call do_IRQ
661 jmp ret_from_intr
662 ENDPROC(common_interrupt)
663 CFI_ENDPROC
664
665 #define BUILD_INTERRUPT(name, nr) \
666 ENTRY(name) \
667 RING0_INT_FRAME; \
668 pushl $~(nr); \
669 CFI_ADJUST_CFA_OFFSET 4; \
670 SAVE_ALL; \
671 TRACE_IRQS_OFF \
672 movl %esp,%eax; \
673 call smp_##name; \
674 jmp ret_from_intr; \
675 CFI_ENDPROC; \
676 ENDPROC(name)
677
678 /* The include is where all of the SMP etc. interrupts come from */
679 #include "entry_arch.h"
680
681 KPROBE_ENTRY(page_fault)
682 RING0_EC_FRAME
683 pushl $do_page_fault
684 CFI_ADJUST_CFA_OFFSET 4
685 ALIGN
686 error_code:
687 /* the function address is in %fs's slot on the stack */
688 pushl %es
689 CFI_ADJUST_CFA_OFFSET 4
690 /*CFI_REL_OFFSET es, 0*/
691 pushl %ds
692 CFI_ADJUST_CFA_OFFSET 4
693 /*CFI_REL_OFFSET ds, 0*/
694 pushl %eax
695 CFI_ADJUST_CFA_OFFSET 4
696 CFI_REL_OFFSET eax, 0
697 pushl %ebp
698 CFI_ADJUST_CFA_OFFSET 4
699 CFI_REL_OFFSET ebp, 0
700 pushl %edi
701 CFI_ADJUST_CFA_OFFSET 4
702 CFI_REL_OFFSET edi, 0
703 pushl %esi
704 CFI_ADJUST_CFA_OFFSET 4
705 CFI_REL_OFFSET esi, 0
706 pushl %edx
707 CFI_ADJUST_CFA_OFFSET 4
708 CFI_REL_OFFSET edx, 0
709 pushl %ecx
710 CFI_ADJUST_CFA_OFFSET 4
711 CFI_REL_OFFSET ecx, 0
712 pushl %ebx
713 CFI_ADJUST_CFA_OFFSET 4
714 CFI_REL_OFFSET ebx, 0
715 cld
716 pushl %fs
717 CFI_ADJUST_CFA_OFFSET 4
718 /*CFI_REL_OFFSET fs, 0*/
719 movl $(__KERNEL_PERCPU), %ecx
720 movl %ecx, %fs
721 UNWIND_ESPFIX_STACK
722 popl %ecx
723 CFI_ADJUST_CFA_OFFSET -4
724 /*CFI_REGISTER es, ecx*/
725 movl PT_FS(%esp), %edi # get the function address
726 movl PT_ORIG_EAX(%esp), %edx # get the error code
727 movl $-1, PT_ORIG_EAX(%esp) # no syscall to restart
728 mov %ecx, PT_FS(%esp)
729 /*CFI_REL_OFFSET fs, ES*/
730 movl $(__USER_DS), %ecx
731 movl %ecx, %ds
732 movl %ecx, %es
733 movl %esp,%eax # pt_regs pointer
734 call *%edi
735 jmp ret_from_exception
736 CFI_ENDPROC
737 KPROBE_END(page_fault)
738
739 ENTRY(coprocessor_error)
740 RING0_INT_FRAME
741 pushl $0
742 CFI_ADJUST_CFA_OFFSET 4
743 pushl $do_coprocessor_error
744 CFI_ADJUST_CFA_OFFSET 4
745 jmp error_code
746 CFI_ENDPROC
747 END(coprocessor_error)
748
749 ENTRY(simd_coprocessor_error)
750 RING0_INT_FRAME
751 pushl $0
752 CFI_ADJUST_CFA_OFFSET 4
753 pushl $do_simd_coprocessor_error
754 CFI_ADJUST_CFA_OFFSET 4
755 jmp error_code
756 CFI_ENDPROC
757 END(simd_coprocessor_error)
758
759 ENTRY(device_not_available)
760 RING0_INT_FRAME
761 pushl $-1 # mark this as an int
762 CFI_ADJUST_CFA_OFFSET 4
763 pushl $do_device_not_available
764 CFI_ADJUST_CFA_OFFSET 4
765 jmp error_code
766 CFI_ENDPROC
767 END(device_not_available)
768
769 /*
770 * Debug traps and NMI can happen at the one SYSENTER instruction
771 * that sets up the real kernel stack. Check here, since we can't
772 * allow the wrong stack to be used.
773 *
774 * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
775 * already pushed 3 words if it hits on the sysenter instruction:
776 * eflags, cs and eip.
777 *
778 * We just load the right stack, and push the three (known) values
779 * by hand onto the new stack - while updating the return eip past
780 * the instruction that would have done it for sysenter.
781 */
782 #define FIX_STACK(offset, ok, label) \
783 cmpw $__KERNEL_CS,4(%esp); \
784 jne ok; \
785 label: \
786 movl TSS_sysenter_sp0+offset(%esp),%esp; \
787 CFI_DEF_CFA esp, 0; \
788 CFI_UNDEFINED eip; \
789 pushfl; \
790 CFI_ADJUST_CFA_OFFSET 4; \
791 pushl $__KERNEL_CS; \
792 CFI_ADJUST_CFA_OFFSET 4; \
793 pushl $sysenter_past_esp; \
794 CFI_ADJUST_CFA_OFFSET 4; \
795 CFI_REL_OFFSET eip, 0
796
797 KPROBE_ENTRY(debug)
798 RING0_INT_FRAME
799 cmpl $ia32_sysenter_target,(%esp)
800 jne debug_stack_correct
801 FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
802 debug_stack_correct:
803 pushl $-1 # mark this as an int
804 CFI_ADJUST_CFA_OFFSET 4
805 SAVE_ALL
806 xorl %edx,%edx # error code 0
807 movl %esp,%eax # pt_regs pointer
808 call do_debug
809 jmp ret_from_exception
810 CFI_ENDPROC
811 KPROBE_END(debug)
812
813 /*
814 * NMI is doubly nasty. It can happen _while_ we're handling
815 * a debug fault, and the debug fault hasn't yet been able to
816 * clear up the stack. So we first check whether we got an
817 * NMI on the sysenter entry path, but after that we need to
818 * check whether we got an NMI on the debug path where the debug
819 * fault happened on the sysenter path.
820 */
821 KPROBE_ENTRY(nmi)
822 RING0_INT_FRAME
823 pushl %eax
824 CFI_ADJUST_CFA_OFFSET 4
825 movl %ss, %eax
826 cmpw $__ESPFIX_SS, %ax
827 popl %eax
828 CFI_ADJUST_CFA_OFFSET -4
829 je nmi_espfix_stack
830 cmpl $ia32_sysenter_target,(%esp)
831 je nmi_stack_fixup
832 pushl %eax
833 CFI_ADJUST_CFA_OFFSET 4
834 movl %esp,%eax
835 /* Do not access memory above the end of our stack page,
836 * it might not exist.
837 */
838 andl $(THREAD_SIZE-1),%eax
839 cmpl $(THREAD_SIZE-20),%eax
840 popl %eax
841 CFI_ADJUST_CFA_OFFSET -4
842 jae nmi_stack_correct
843 cmpl $ia32_sysenter_target,12(%esp)
844 je nmi_debug_stack_check
845 nmi_stack_correct:
846 /* We have a RING0_INT_FRAME here */
847 pushl %eax
848 CFI_ADJUST_CFA_OFFSET 4
849 SAVE_ALL
850 xorl %edx,%edx # zero error code
851 movl %esp,%eax # pt_regs pointer
852 call do_nmi
853 jmp restore_nocheck_notrace
854 CFI_ENDPROC
855
856 nmi_stack_fixup:
857 RING0_INT_FRAME
858 FIX_STACK(12,nmi_stack_correct, 1)
859 jmp nmi_stack_correct
860
861 nmi_debug_stack_check:
862 /* We have a RING0_INT_FRAME here */
863 cmpw $__KERNEL_CS,16(%esp)
864 jne nmi_stack_correct
865 cmpl $debug,(%esp)
866 jb nmi_stack_correct
867 cmpl $debug_esp_fix_insn,(%esp)
868 ja nmi_stack_correct
869 FIX_STACK(24,nmi_stack_correct, 1)
870 jmp nmi_stack_correct
871
872 nmi_espfix_stack:
873 /* We have a RING0_INT_FRAME here.
874 *
875 * create the pointer to lss back
876 */
877 pushl %ss
878 CFI_ADJUST_CFA_OFFSET 4
879 pushl %esp
880 CFI_ADJUST_CFA_OFFSET 4
881 addw $4, (%esp)
882 /* copy the iret frame of 12 bytes */
883 .rept 3
884 pushl 16(%esp)
885 CFI_ADJUST_CFA_OFFSET 4
886 .endr
887 pushl %eax
888 CFI_ADJUST_CFA_OFFSET 4
889 SAVE_ALL
890 FIXUP_ESPFIX_STACK # %eax == %esp
891 xorl %edx,%edx # zero error code
892 call do_nmi
893 RESTORE_REGS
894 lss 12+4(%esp), %esp # back to espfix stack
895 CFI_ADJUST_CFA_OFFSET -24
896 jmp irq_return
897 CFI_ENDPROC
898 KPROBE_END(nmi)
899
900 #ifdef CONFIG_PARAVIRT
901 ENTRY(native_iret)
902 iret
903 .section __ex_table,"a"
904 .align 4
905 .long native_iret, iret_exc
906 .previous
907 END(native_iret)
908
909 ENTRY(native_irq_enable_sysexit)
910 sti
911 sysexit
912 END(native_irq_enable_sysexit)
913 #endif
914
915 KPROBE_ENTRY(int3)
916 RING0_INT_FRAME
917 pushl $-1 # mark this as an int
918 CFI_ADJUST_CFA_OFFSET 4
919 SAVE_ALL
920 xorl %edx,%edx # zero error code
921 movl %esp,%eax # pt_regs pointer
922 call do_int3
923 jmp ret_from_exception
924 CFI_ENDPROC
925 KPROBE_END(int3)
926
927 ENTRY(overflow)
928 RING0_INT_FRAME
929 pushl $0
930 CFI_ADJUST_CFA_OFFSET 4
931 pushl $do_overflow
932 CFI_ADJUST_CFA_OFFSET 4
933 jmp error_code
934 CFI_ENDPROC
935 END(overflow)
936
937 ENTRY(bounds)
938 RING0_INT_FRAME
939 pushl $0
940 CFI_ADJUST_CFA_OFFSET 4
941 pushl $do_bounds
942 CFI_ADJUST_CFA_OFFSET 4
943 jmp error_code
944 CFI_ENDPROC
945 END(bounds)
946
947 ENTRY(invalid_op)
948 RING0_INT_FRAME
949 pushl $0
950 CFI_ADJUST_CFA_OFFSET 4
951 pushl $do_invalid_op
952 CFI_ADJUST_CFA_OFFSET 4
953 jmp error_code
954 CFI_ENDPROC
955 END(invalid_op)
956
957 ENTRY(coprocessor_segment_overrun)
958 RING0_INT_FRAME
959 pushl $0
960 CFI_ADJUST_CFA_OFFSET 4
961 pushl $do_coprocessor_segment_overrun
962 CFI_ADJUST_CFA_OFFSET 4
963 jmp error_code
964 CFI_ENDPROC
965 END(coprocessor_segment_overrun)
966
967 ENTRY(invalid_TSS)
968 RING0_EC_FRAME
969 pushl $do_invalid_TSS
970 CFI_ADJUST_CFA_OFFSET 4
971 jmp error_code
972 CFI_ENDPROC
973 END(invalid_TSS)
974
975 ENTRY(segment_not_present)
976 RING0_EC_FRAME
977 pushl $do_segment_not_present
978 CFI_ADJUST_CFA_OFFSET 4
979 jmp error_code
980 CFI_ENDPROC
981 END(segment_not_present)
982
983 ENTRY(stack_segment)
984 RING0_EC_FRAME
985 pushl $do_stack_segment
986 CFI_ADJUST_CFA_OFFSET 4
987 jmp error_code
988 CFI_ENDPROC
989 END(stack_segment)
990
991 KPROBE_ENTRY(general_protection)
992 RING0_EC_FRAME
993 pushl $do_general_protection
994 CFI_ADJUST_CFA_OFFSET 4
995 jmp error_code
996 CFI_ENDPROC
997 KPROBE_END(general_protection)
998
999 ENTRY(alignment_check)
1000 RING0_EC_FRAME
1001 pushl $do_alignment_check
1002 CFI_ADJUST_CFA_OFFSET 4
1003 jmp error_code
1004 CFI_ENDPROC
1005 END(alignment_check)
1006
1007 ENTRY(divide_error)
1008 RING0_INT_FRAME
1009 pushl $0 # no error code
1010 CFI_ADJUST_CFA_OFFSET 4
1011 pushl $do_divide_error
1012 CFI_ADJUST_CFA_OFFSET 4
1013 jmp error_code
1014 CFI_ENDPROC
1015 END(divide_error)
1016
1017 #ifdef CONFIG_X86_MCE
1018 ENTRY(machine_check)
1019 RING0_INT_FRAME
1020 pushl $0
1021 CFI_ADJUST_CFA_OFFSET 4
1022 pushl $do_machine_check
1023 CFI_ADJUST_CFA_OFFSET 4
1024 jmp error_code
1025 CFI_ENDPROC
1026 END(machine_check)
1027 #endif
1028
1029 ENTRY(spurious_interrupt_bug)
1030 RING0_INT_FRAME
1031 pushl $0
1032 CFI_ADJUST_CFA_OFFSET 4
1033 pushl $do_spurious_interrupt_bug
1034 CFI_ADJUST_CFA_OFFSET 4
1035 jmp error_code
1036 CFI_ENDPROC
1037 END(spurious_interrupt_bug)
1038
1039 ENTRY(kernel_thread_helper)
1040 pushl $0 # fake return address for unwinder
1041 CFI_STARTPROC
1042 movl %edx,%eax
1043 push %edx
1044 CFI_ADJUST_CFA_OFFSET 4
1045 call *%ebx
1046 push %eax
1047 CFI_ADJUST_CFA_OFFSET 4
1048 call do_exit
1049 CFI_ENDPROC
1050 ENDPROC(kernel_thread_helper)
1051
1052 #ifdef CONFIG_XEN
1053 /* Xen doesn't set %esp to be precisely what the normal sysenter
1054 entrypoint expects, so fix it up before using the normal path. */
1055 ENTRY(xen_sysenter_target)
1056 RING0_INT_FRAME
1057 addl $5*4, %esp /* remove xen-provided frame */
1058 CFI_ADJUST_CFA_OFFSET -5*4
1059 jmp sysenter_past_esp
1060 CFI_ENDPROC
1061
1062 ENTRY(xen_hypervisor_callback)
1063 CFI_STARTPROC
1064 pushl $0
1065 CFI_ADJUST_CFA_OFFSET 4
1066 SAVE_ALL
1067 TRACE_IRQS_OFF
1068
1069 /* Check to see if we got the event in the critical
1070 region in xen_iret_direct, after we've reenabled
1071 events and checked for pending events. This simulates
1072 iret instruction's behaviour where it delivers a
1073 pending interrupt when enabling interrupts. */
1074 movl PT_EIP(%esp),%eax
1075 cmpl $xen_iret_start_crit,%eax
1076 jb 1f
1077 cmpl $xen_iret_end_crit,%eax
1078 jae 1f
1079
1080 jmp xen_iret_crit_fixup
1081
1082 ENTRY(xen_do_upcall)
1083 1: mov %esp, %eax
1084 call xen_evtchn_do_upcall
1085 jmp ret_from_intr
1086 CFI_ENDPROC
1087 ENDPROC(xen_hypervisor_callback)
1088
1089 # Hypervisor uses this for application faults while it executes.
1090 # We get here for two reasons:
1091 # 1. Fault while reloading DS, ES, FS or GS
1092 # 2. Fault while executing IRET
1093 # Category 1 we fix up by reattempting the load, and zeroing the segment
1094 # register if the load fails.
1095 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1096 # normal Linux return path in this case because if we use the IRET hypercall
1097 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1098 # We distinguish between categories by maintaining a status value in EAX.
1099 ENTRY(xen_failsafe_callback)
1100 CFI_STARTPROC
1101 pushl %eax
1102 CFI_ADJUST_CFA_OFFSET 4
1103 movl $1,%eax
1104 1: mov 4(%esp),%ds
1105 2: mov 8(%esp),%es
1106 3: mov 12(%esp),%fs
1107 4: mov 16(%esp),%gs
1108 testl %eax,%eax
1109 popl %eax
1110 CFI_ADJUST_CFA_OFFSET -4
1111 lea 16(%esp),%esp
1112 CFI_ADJUST_CFA_OFFSET -16
1113 jz 5f
1114 addl $16,%esp
1115 jmp iret_exc # EAX != 0 => Category 2 (Bad IRET)
1116 5: pushl $0 # EAX == 0 => Category 1 (Bad segment)
1117 CFI_ADJUST_CFA_OFFSET 4
1118 SAVE_ALL
1119 jmp ret_from_exception
1120 CFI_ENDPROC
1121
1122 .section .fixup,"ax"
1123 6: xorl %eax,%eax
1124 movl %eax,4(%esp)
1125 jmp 1b
1126 7: xorl %eax,%eax
1127 movl %eax,8(%esp)
1128 jmp 2b
1129 8: xorl %eax,%eax
1130 movl %eax,12(%esp)
1131 jmp 3b
1132 9: xorl %eax,%eax
1133 movl %eax,16(%esp)
1134 jmp 4b
1135 .previous
1136 .section __ex_table,"a"
1137 .align 4
1138 .long 1b,6b
1139 .long 2b,7b
1140 .long 3b,8b
1141 .long 4b,9b
1142 .previous
1143 ENDPROC(xen_failsafe_callback)
1144
1145 #endif /* CONFIG_XEN */
1146
1147 #ifdef CONFIG_FTRACE
1148 #ifdef CONFIG_DYNAMIC_FTRACE
1149
1150 ENTRY(mcount)
1151 pushl %eax
1152 pushl %ecx
1153 pushl %edx
1154 movl 0xc(%esp), %eax
1155 subl $MCOUNT_INSN_SIZE, %eax
1156
1157 .globl mcount_call
1158 mcount_call:
1159 call ftrace_stub
1160
1161 popl %edx
1162 popl %ecx
1163 popl %eax
1164
1165 ret
1166 END(mcount)
1167
1168 ENTRY(ftrace_caller)
1169 pushl %eax
1170 pushl %ecx
1171 pushl %edx
1172 movl 0xc(%esp), %eax
1173 movl 0x4(%ebp), %edx
1174 subl $MCOUNT_INSN_SIZE, %eax
1175
1176 .globl ftrace_call
1177 ftrace_call:
1178 call ftrace_stub
1179
1180 popl %edx
1181 popl %ecx
1182 popl %eax
1183
1184 .globl ftrace_stub
1185 ftrace_stub:
1186 ret
1187 END(ftrace_caller)
1188
1189 #else /* ! CONFIG_DYNAMIC_FTRACE */
1190
1191 ENTRY(mcount)
1192 cmpl $ftrace_stub, ftrace_trace_function
1193 jnz trace
1194 .globl ftrace_stub
1195 ftrace_stub:
1196 ret
1197
1198 /* taken from glibc */
1199 trace:
1200 pushl %eax
1201 pushl %ecx
1202 pushl %edx
1203 movl 0xc(%esp), %eax
1204 movl 0x4(%ebp), %edx
1205 subl $MCOUNT_INSN_SIZE, %eax
1206
1207 call *ftrace_trace_function
1208
1209 popl %edx
1210 popl %ecx
1211 popl %eax
1212
1213 jmp ftrace_stub
1214 END(mcount)
1215 #endif /* CONFIG_DYNAMIC_FTRACE */
1216 #endif /* CONFIG_FTRACE */
1217
1218 .section .rodata,"a"
1219 #include "syscall_table_32.S"
1220
1221 syscall_table_size=(.-sys_call_table)
kernel source for telekom puls (alcatel/mediatek)