arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Return to user mode is not as complex as all this looks,
 319  * but we want the default path for a system call return to
 320  * go as quickly as possible which is why some of this is
 321  * less clear than it otherwise should be.
 322  */
 323
 324         # userspace resumption stub bypassing syscall exit tracing
 325         ALIGN
 326         RING0_PTREGS_FRAME
 327 ret_from_exception:
 328         preempt_stop(CLBR_ANY)
 329 ret_from_intr:
 330         GET_THREAD_INFO(%ebp)
 331 #ifdef CONFIG_VM86
 332         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 333         movb PT_CS(%esp), %al
 334         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 335 #else
 336         /*
 337          * We can be coming here from child spawned by kernel_thread().
 338          */
 339         movl PT_CS(%esp), %eax
 340         andl $SEGMENT_RPL_MASK, %eax
 341 #endif
 342         cmpl $USER_RPL, %eax
 343         jb resume_kernel                # not returning to v8086 or userspace
 344
 345 ENTRY(resume_userspace)
 346         LOCKDEP_SYS_EXIT
 347         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 348                                         # setting need_resched or sigpending
 349                                         # between sampling and the iret
 350         TRACE_IRQS_OFF
 351         movl TI_flags(%ebp), %ecx
 352         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 353                                         # int/exception return?
 354         jne work_pending
 355         jmp restore_all
 356 END(ret_from_exception)
 357
 358 #ifdef CONFIG_PREEMPT
 359 ENTRY(resume_kernel)
 360         DISABLE_INTERRUPTS(CLBR_ANY)
 361 need_resched:
 362         cmpl $0,PER_CPU_VAR(__preempt_count)
 363         jnz restore_all
 364         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 365         jz restore_all
 366         call preempt_schedule_irq
 367         jmp need_resched
 368 END(resume_kernel)
 369 #endif
 370         CFI_ENDPROC
 371
 372 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 373    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 374
 375         # sysenter call handler stub
 376 ENTRY(ia32_sysenter_target)
 377         CFI_STARTPROC simple
 378         CFI_SIGNAL_FRAME
 379         CFI_DEF_CFA esp, 0
 380         CFI_REGISTER esp, ebp
 381         movl TSS_sysenter_sp0(%esp),%esp
 382 sysenter_past_esp:
 383         /*
 384          * Interrupts are disabled here, but we can't trace it until
 385          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 386          * we immediately enable interrupts at that point anyway.
 387          */
 388         pushl_cfi $__USER_DS
 389         /*CFI_REL_OFFSET ss, 0*/
 390         pushl_cfi %ebp
 391         CFI_REL_OFFSET esp, 0
 392         pushfl_cfi
 393         orl $X86_EFLAGS_IF, (%esp)
 394         pushl_cfi $__USER_CS
 395         /*CFI_REL_OFFSET cs, 0*/
 396         /*
 397          * Push current_thread_info()->sysenter_return to the stack.
 398          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 399          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 400          */
 401         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 402         CFI_REL_OFFSET eip, 0
 403
 404         pushl_cfi %eax
 405         SAVE_ALL
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407
 408 /*
 409  * Load the potential sixth argument from user stack.
 410  * Careful about security.
 411  */
 412         cmpl $__PAGE_OFFSET-3,%ebp
 413         jae syscall_fault
 414         ASM_STAC
 415 1:      movl (%ebp),%ebp
 416         ASM_CLAC
 417         movl %ebp,PT_EBP(%esp)
 418         _ASM_EXTABLE(1b,syscall_fault)
 419
 420         GET_THREAD_INFO(%ebp)
 421
 422         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 423         jnz sysenter_audit
 424 sysenter_do_call:
 425         cmpl $(NR_syscalls), %eax
 426         jae sysenter_badsys
 427         call *sys_call_table(,%eax,4)
 428 sysenter_after_call:
 429         movl %eax,PT_EAX(%esp)
 430         LOCKDEP_SYS_EXIT
 431         DISABLE_INTERRUPTS(CLBR_ANY)
 432         TRACE_IRQS_OFF
 433         movl TI_flags(%ebp), %ecx
 434         testl $_TIF_ALLWORK_MASK, %ecx
 435         jne sysexit_audit
 436 sysenter_exit:
 437 /* if something modifies registers it must also disable sysexit */
 438         movl PT_EIP(%esp), %edx
 439         movl PT_OLDESP(%esp), %ecx
 440         xorl %ebp,%ebp
 441         TRACE_IRQS_ON
 442 1:      mov  PT_FS(%esp), %fs
 443         PTGS_TO_GS
 444         ENABLE_INTERRUPTS_SYSEXIT
 445
 446 #ifdef CONFIG_AUDITSYSCALL
 447 sysenter_audit:
 448         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 449         jnz syscall_trace_entry
 450         addl $4,%esp
 451         CFI_ADJUST_CFA_OFFSET -4
 452         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 453         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 454         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 455         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 456         movl %eax,%edx                  /* 2nd arg: syscall number */
 457         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 458         call __audit_syscall_entry
 459         pushl_cfi %ebx
 460         movl PT_EAX(%esp),%eax          /* reload syscall number */
 461         jmp sysenter_do_call
 462
 463 sysexit_audit:
 464         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 465         jne syscall_exit_work
 466         TRACE_IRQS_ON
 467         ENABLE_INTERRUPTS(CLBR_ANY)
 468         movl %eax,%edx          /* second arg, syscall return value */
 469         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 470         setbe %al               /* 1 if so, 0 if not */
 471         movzbl %al,%eax         /* zero-extend that */
 472         call __audit_syscall_exit
 473         DISABLE_INTERRUPTS(CLBR_ANY)
 474         TRACE_IRQS_OFF
 475         movl TI_flags(%ebp), %ecx
 476         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 477         jne syscall_exit_work
 478         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 479         jmp sysenter_exit
 480 #endif
 481
 482         CFI_ENDPROC
 483 .pushsection .fixup,"ax"
 484 2:      movl $0,PT_FS(%esp)
 485         jmp 1b
 486 .popsection
 487         _ASM_EXTABLE(1b,2b)
 488         PTGS_TO_GS_EX
 489 ENDPROC(ia32_sysenter_target)
 490
 491         # system call handler stub
 492 ENTRY(system_call)
 493         RING0_INT_FRAME                 # can't unwind into user space anyway
 494         ASM_CLAC
 495         pushl_cfi %eax                  # save orig_eax
 496         SAVE_ALL
 497         GET_THREAD_INFO(%ebp)
 498                                         # system call tracing in operation / emulation
 499         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 500         jnz syscall_trace_entry
 501         cmpl $(NR_syscalls), %eax
 502         jae syscall_badsys
 503 syscall_call:
 504         call *sys_call_table(,%eax,4)
 505 syscall_after_call:
 506         movl %eax,PT_EAX(%esp)          # store the return value
 507 syscall_exit:
 508         LOCKDEP_SYS_EXIT
 509         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 510                                         # setting need_resched or sigpending
 511                                         # between sampling and the iret
 512         TRACE_IRQS_OFF
 513         movl TI_flags(%ebp), %ecx
 514         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 515         jne syscall_exit_work
 516
 517 restore_all:
 518         TRACE_IRQS_IRET
 519 restore_all_notrace:
 520 #ifdef CONFIG_X86_ESPFIX32
 521         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 522         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 523         # are returning to the kernel.
 524         # See comments in process.c:copy_thread() for details.
 525         movb PT_OLDSS(%esp), %ah
 526         movb PT_CS(%esp), %al
 527         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 528         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 529         CFI_REMEMBER_STATE
 530         je ldt_ss                       # returning to user-space with LDT SS
 531 #endif
 532 restore_nocheck:
 533         RESTORE_REGS 4                  # skip orig_eax/error_code
 534 irq_return:
 535         INTERRUPT_RETURN
 536 .section .fixup,"ax"
 537 ENTRY(iret_exc)
 538         pushl $0                        # no error code
 539         pushl $do_iret_error
 540         jmp error_code
 541 .previous
 542         _ASM_EXTABLE(irq_return,iret_exc)
 543
 544 #ifdef CONFIG_X86_ESPFIX32
 545         CFI_RESTORE_STATE
 546 ldt_ss:
 547 #ifdef CONFIG_PARAVIRT
 548         /*
 549          * The kernel can't run on a non-flat stack if paravirt mode
 550          * is active.  Rather than try to fixup the high bits of
 551          * ESP, bypass this code entirely.  This may break DOSemu
 552          * and/or Wine support in a paravirt VM, although the option
 553          * is still available to implement the setting of the high
 554          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 555          */
 556         cmpl $0, pv_info+PARAVIRT_enabled
 557         jne restore_nocheck
 558 #endif
 559
 560 /*
 561  * Setup and switch to ESPFIX stack
 562  *
 563  * We're returning to userspace with a 16 bit stack. The CPU will not
 564  * restore the high word of ESP for us on executing iret... This is an
 565  * "official" bug of all the x86-compatible CPUs, which we can work
 566  * around to make dosemu and wine happy. We do this by preloading the
 567  * high word of ESP with the high word of the userspace ESP while
 568  * compensating for the offset by changing to the ESPFIX segment with
 569  * a base address that matches for the difference.
 570  */
 571 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 572         mov %esp, %edx                  /* load kernel esp */
 573         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 574         mov %dx, %ax                    /* eax: new kernel esp */
 575         sub %eax, %edx                  /* offset (low word is 0) */
 576         shr $16, %edx
 577         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 578         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 579         pushl_cfi $__ESPFIX_SS
 580         pushl_cfi %eax                  /* new kernel esp */
 581         /* Disable interrupts, but do not irqtrace this section: we
 582          * will soon execute iret and the tracer was already set to
 583          * the irqstate after the iret */
 584         DISABLE_INTERRUPTS(CLBR_EAX)
 585         lss (%esp), %esp                /* switch to espfix segment */
 586         CFI_ADJUST_CFA_OFFSET -8
 587         jmp restore_nocheck
 588 #endif
 589         CFI_ENDPROC
 590 ENDPROC(system_call)
 591
 592         # perform work that needs to be done immediately before resumption
 593         ALIGN
 594         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 595 work_pending:
 596         testb $_TIF_NEED_RESCHED, %cl
 597         jz work_notifysig
 598 work_resched:
 599         call schedule
 600         LOCKDEP_SYS_EXIT
 601         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 602                                         # setting need_resched or sigpending
 603                                         # between sampling and the iret
 604         TRACE_IRQS_OFF
 605         movl TI_flags(%ebp), %ecx
 606         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 607                                         # than syscall tracing?
 608         jz restore_all
 609         testb $_TIF_NEED_RESCHED, %cl
 610         jnz work_resched
 611
 612 work_notifysig:                         # deal with pending signals and
 613                                         # notify-resume requests
 614 #ifdef CONFIG_VM86
 615         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 616         movl %esp, %eax
 617         jne work_notifysig_v86          # returning to kernel-space or
 618                                         # vm86-space
 619 1:
 620 #else
 621         movl %esp, %eax
 622 #endif
 623         TRACE_IRQS_ON
 624         ENABLE_INTERRUPTS(CLBR_NONE)
 625         movb PT_CS(%esp), %bl
 626         andb $SEGMENT_RPL_MASK, %bl
 627         cmpb $USER_RPL, %bl
 628         jb resume_kernel
 629         xorl %edx, %edx
 630         call do_notify_resume
 631         jmp resume_userspace
 632
 633 #ifdef CONFIG_VM86
 634         ALIGN
 635 work_notifysig_v86:
 636         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 637         call save_v86_state             # %eax contains pt_regs pointer
 638         popl_cfi %ecx
 639         movl %eax, %esp
 640         jmp 1b
 641 #endif
 642 END(work_pending)
 643
 644         # perform syscall exit tracing
 645         ALIGN
 646 syscall_trace_entry:
 647         movl $-ENOSYS,PT_EAX(%esp)
 648         movl %esp, %eax
 649         call syscall_trace_enter
 650         /* What it returned is what we'll actually use.  */
 651         cmpl $(NR_syscalls), %eax
 652         jnae syscall_call
 653         jmp syscall_exit
 654 END(syscall_trace_entry)
 655
 656         # perform syscall exit tracing
 657         ALIGN
 658 syscall_exit_work:
 659         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 660         jz work_pending
 661         TRACE_IRQS_ON
 662         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 663                                         # schedule() instead
 664         movl %esp, %eax
 665         call syscall_trace_leave
 666         jmp resume_userspace
 667 END(syscall_exit_work)
 668         CFI_ENDPROC
 669
 670         RING0_INT_FRAME                 # can't unwind into user space anyway
 671 syscall_fault:
 672         ASM_CLAC
 673         GET_THREAD_INFO(%ebp)
 674         movl $-EFAULT,PT_EAX(%esp)
 675         jmp resume_userspace
 676 END(syscall_fault)
 677
 678 syscall_badsys:
 679         movl $-ENOSYS,%eax
 680         jmp syscall_after_call
 681 END(syscall_badsys)
 682
 683 sysenter_badsys:
 684         movl $-ENOSYS,%eax
 685         jmp sysenter_after_call
 686 END(syscall_badsys)
 687         CFI_ENDPROC
 688
 689 .macro FIXUP_ESPFIX_STACK
 690 /*
 691  * Switch back for ESPFIX stack to the normal zerobased stack
 692  *
 693  * We can't call C functions using the ESPFIX stack. This code reads
 694  * the high word of the segment base from the GDT and swiches to the
 695  * normal stack and adjusts ESP with the matching offset.
 696  */
 697 #ifdef CONFIG_X86_ESPFIX32
 698         /* fixup the stack */
 699         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 700         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 701         shl $16, %eax
 702         addl %esp, %eax                 /* the adjusted stack pointer */
 703         pushl_cfi $__KERNEL_DS
 704         pushl_cfi %eax
 705         lss (%esp), %esp                /* switch to the normal stack segment */
 706         CFI_ADJUST_CFA_OFFSET -8
 707 #endif
 708 .endm
 709 .macro UNWIND_ESPFIX_STACK
 710 #ifdef CONFIG_X86_ESPFIX32
 711         movl %ss, %eax
 712         /* see if on espfix stack */
 713         cmpw $__ESPFIX_SS, %ax
 714         jne 27f
 715         movl $__KERNEL_DS, %eax
 716         movl %eax, %ds
 717         movl %eax, %es
 718         /* switch to normal stack */
 719         FIXUP_ESPFIX_STACK
 720 27:
 721 #endif
 722 .endm
 723
 724 /*
 725  * Build the entry stubs and pointer table with some assembler magic.
 726  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 727  * single cache line on all modern x86 implementations.
 728  */
 729 .section .init.rodata,"a"
 730 ENTRY(interrupt)
 731 .section .entry.text, "ax"
 732         .p2align 5
 733         .p2align CONFIG_X86_L1_CACHE_SHIFT
 734 ENTRY(irq_entries_start)
 735         RING0_INT_FRAME
 736 vector=FIRST_EXTERNAL_VECTOR
 737 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 738         .balign 32
 739   .rept 7
 740     .if vector < NR_VECTORS
 741       .if vector <> FIRST_EXTERNAL_VECTOR
 742         CFI_ADJUST_CFA_OFFSET -4
 743       .endif
 744 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 745       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 746         jmp 2f
 747       .endif
 748       .previous
 749         .long 1b
 750       .section .entry.text, "ax"
 751 vector=vector+1
 752     .endif
 753   .endr
 754 2:      jmp common_interrupt
 755 .endr
 756 END(irq_entries_start)
 757
 758 .previous
 759 END(interrupt)
 760 .previous
 761
 762 /*
 763  * the CPU automatically disables interrupts when executing an IRQ vector,
 764  * so IRQ-flags tracing has to follow that:
 765  */
 766         .p2align CONFIG_X86_L1_CACHE_SHIFT
 767 common_interrupt:
 768         ASM_CLAC
 769         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 770         SAVE_ALL
 771         TRACE_IRQS_OFF
 772         movl %esp,%eax
 773         call do_IRQ
 774         jmp ret_from_intr
 775 ENDPROC(common_interrupt)
 776         CFI_ENDPROC
 777
 778 #define BUILD_INTERRUPT3(name, nr, fn)  \
 779 ENTRY(name)                             \
 780         RING0_INT_FRAME;                \
 781         ASM_CLAC;                       \
 782         pushl_cfi $~(nr);               \
 783         SAVE_ALL;                       \
 784         TRACE_IRQS_OFF                  \
 785         movl %esp,%eax;                 \
 786         call fn;                        \
 787         jmp ret_from_intr;              \
 788         CFI_ENDPROC;                    \
 789 ENDPROC(name)
 790
 791
 792 #ifdef CONFIG_TRACING
 793 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 794         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 795 #else
 796 #define TRACE_BUILD_INTERRUPT(name, nr)
 797 #endif
 798
 799 #define BUILD_INTERRUPT(name, nr) \
 800         BUILD_INTERRUPT3(name, nr, smp_##name); \
 801         TRACE_BUILD_INTERRUPT(name, nr)
 802
 803 /* The include is where all of the SMP etc. interrupts come from */
 804 #include <asm/entry_arch.h>
 805
 806 ENTRY(coprocessor_error)
 807         RING0_INT_FRAME
 808         ASM_CLAC
 809         pushl_cfi $0
 810         pushl_cfi $do_coprocessor_error
 811         jmp error_code
 812         CFI_ENDPROC
 813 END(coprocessor_error)
 814
 815 ENTRY(simd_coprocessor_error)
 816         RING0_INT_FRAME
 817         ASM_CLAC
 818         pushl_cfi $0
 819 #ifdef CONFIG_X86_INVD_BUG
 820         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 821 661:    pushl_cfi $do_general_protection
 822 662:
 823 .section .altinstructions,"a"
 824         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 825 .previous
 826 .section .altinstr_replacement,"ax"
 827 663:    pushl $do_simd_coprocessor_error
 828 664:
 829 .previous
 830 #else
 831         pushl_cfi $do_simd_coprocessor_error
 832 #endif
 833         jmp error_code
 834         CFI_ENDPROC
 835 END(simd_coprocessor_error)
 836
 837 ENTRY(device_not_available)
 838         RING0_INT_FRAME
 839         ASM_CLAC
 840         pushl_cfi $-1                   # mark this as an int
 841         pushl_cfi $do_device_not_available
 842         jmp error_code
 843         CFI_ENDPROC
 844 END(device_not_available)
 845
 846 #ifdef CONFIG_PARAVIRT
 847 ENTRY(native_iret)
 848         iret
 849         _ASM_EXTABLE(native_iret, iret_exc)
 850 END(native_iret)
 851
 852 ENTRY(native_irq_enable_sysexit)
 853         sti
 854         sysexit
 855 END(native_irq_enable_sysexit)
 856 #endif
 857
 858 ENTRY(overflow)
 859         RING0_INT_FRAME
 860         ASM_CLAC
 861         pushl_cfi $0
 862         pushl_cfi $do_overflow
 863         jmp error_code
 864         CFI_ENDPROC
 865 END(overflow)
 866
 867 ENTRY(bounds)
 868         RING0_INT_FRAME
 869         ASM_CLAC
 870         pushl_cfi $0
 871         pushl_cfi $do_bounds
 872         jmp error_code
 873         CFI_ENDPROC
 874 END(bounds)
 875
 876 ENTRY(invalid_op)
 877         RING0_INT_FRAME
 878         ASM_CLAC
 879         pushl_cfi $0
 880         pushl_cfi $do_invalid_op
 881         jmp error_code
 882         CFI_ENDPROC
 883 END(invalid_op)
 884
 885 ENTRY(coprocessor_segment_overrun)
 886         RING0_INT_FRAME
 887         ASM_CLAC
 888         pushl_cfi $0
 889         pushl_cfi $do_coprocessor_segment_overrun
 890         jmp error_code
 891         CFI_ENDPROC
 892 END(coprocessor_segment_overrun)
 893
 894 ENTRY(invalid_TSS)
 895         RING0_EC_FRAME
 896         ASM_CLAC
 897         pushl_cfi $do_invalid_TSS
 898         jmp error_code
 899         CFI_ENDPROC
 900 END(invalid_TSS)
 901
 902 ENTRY(segment_not_present)
 903         RING0_EC_FRAME
 904         ASM_CLAC
 905         pushl_cfi $do_segment_not_present
 906         jmp error_code
 907         CFI_ENDPROC
 908 END(segment_not_present)
 909
 910 ENTRY(stack_segment)
 911         RING0_EC_FRAME
 912         ASM_CLAC
 913         pushl_cfi $do_stack_segment
 914         jmp error_code
 915         CFI_ENDPROC
 916 END(stack_segment)
 917
 918 ENTRY(alignment_check)
 919         RING0_EC_FRAME
 920         ASM_CLAC
 921         pushl_cfi $do_alignment_check
 922         jmp error_code
 923         CFI_ENDPROC
 924 END(alignment_check)
 925
 926 ENTRY(divide_error)
 927         RING0_INT_FRAME
 928         ASM_CLAC
 929         pushl_cfi $0                    # no error code
 930         pushl_cfi $do_divide_error
 931         jmp error_code
 932         CFI_ENDPROC
 933 END(divide_error)
 934
 935 #ifdef CONFIG_X86_MCE
 936 ENTRY(machine_check)
 937         RING0_INT_FRAME
 938         ASM_CLAC
 939         pushl_cfi $0
 940         pushl_cfi machine_check_vector
 941         jmp error_code
 942         CFI_ENDPROC
 943 END(machine_check)
 944 #endif
 945
 946 ENTRY(spurious_interrupt_bug)
 947         RING0_INT_FRAME
 948         ASM_CLAC
 949         pushl_cfi $0
 950         pushl_cfi $do_spurious_interrupt_bug
 951         jmp error_code
 952         CFI_ENDPROC
 953 END(spurious_interrupt_bug)
 954
 955 #ifdef CONFIG_XEN
 956 /* Xen doesn't set %esp to be precisely what the normal sysenter
 957    entrypoint expects, so fix it up before using the normal path. */
 958 ENTRY(xen_sysenter_target)
 959         RING0_INT_FRAME
 960         addl $5*4, %esp         /* remove xen-provided frame */
 961         CFI_ADJUST_CFA_OFFSET -5*4
 962         jmp sysenter_past_esp
 963         CFI_ENDPROC
 964
 965 ENTRY(xen_hypervisor_callback)
 966         CFI_STARTPROC
 967         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 968         SAVE_ALL
 969         TRACE_IRQS_OFF
 970
 971         /* Check to see if we got the event in the critical
 972            region in xen_iret_direct, after we've reenabled
 973            events and checked for pending events.  This simulates
 974            iret instruction's behaviour where it delivers a
 975            pending interrupt when enabling interrupts. */
 976         movl PT_EIP(%esp),%eax
 977         cmpl $xen_iret_start_crit,%eax
 978         jb   1f
 979         cmpl $xen_iret_end_crit,%eax
 980         jae  1f
 981
 982         jmp  xen_iret_crit_fixup
 983
 984 ENTRY(xen_do_upcall)
 985 1:      mov %esp, %eax
 986         call xen_evtchn_do_upcall
 987         jmp  ret_from_intr
 988         CFI_ENDPROC
 989 ENDPROC(xen_hypervisor_callback)
 990
 991 # Hypervisor uses this for application faults while it executes.
 992 # We get here for two reasons:
 993 #  1. Fault while reloading DS, ES, FS or GS
 994 #  2. Fault while executing IRET
 995 # Category 1 we fix up by reattempting the load, and zeroing the segment
 996 # register if the load fails.
 997 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
 998 # normal Linux return path in this case because if we use the IRET hypercall
 999 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1000 # We distinguish between categories by maintaining a status value in EAX.
1001 ENTRY(xen_failsafe_callback)
1002         CFI_STARTPROC
1003         pushl_cfi %eax
1004         movl $1,%eax
1005 1:      mov 4(%esp),%ds
1006 2:      mov 8(%esp),%es
1007 3:      mov 12(%esp),%fs
1008 4:      mov 16(%esp),%gs
1009         /* EAX == 0 => Category 1 (Bad segment)
1010            EAX != 0 => Category 2 (Bad IRET) */
1011         testl %eax,%eax
1012         popl_cfi %eax
1013         lea 16(%esp),%esp
1014         CFI_ADJUST_CFA_OFFSET -16
1015         jz 5f
1016         jmp iret_exc
1017 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1018         SAVE_ALL
1019         jmp ret_from_exception
1020         CFI_ENDPROC
1021
1022 .section .fixup,"ax"
1023 6:      xorl %eax,%eax
1024         movl %eax,4(%esp)
1025         jmp 1b
1026 7:      xorl %eax,%eax
1027         movl %eax,8(%esp)
1028         jmp 2b
1029 8:      xorl %eax,%eax
1030         movl %eax,12(%esp)
1031         jmp 3b
1032 9:      xorl %eax,%eax
1033         movl %eax,16(%esp)
1034         jmp 4b
1035 .previous
1036         _ASM_EXTABLE(1b,6b)
1037         _ASM_EXTABLE(2b,7b)
1038         _ASM_EXTABLE(3b,8b)
1039         _ASM_EXTABLE(4b,9b)
1040 ENDPROC(xen_failsafe_callback)
1041
1042 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1043                 xen_evtchn_do_upcall)
1044
1045 #endif  /* CONFIG_XEN */
1046
1047 #if IS_ENABLED(CONFIG_HYPERV)
1048
1049 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1050         hyperv_vector_handler)
1051
1052 #endif /* CONFIG_HYPERV */
1053
1054 #ifdef CONFIG_FUNCTION_TRACER
1055 #ifdef CONFIG_DYNAMIC_FTRACE
1056
1057 ENTRY(mcount)
1058         ret
1059 END(mcount)
1060
1061 ENTRY(ftrace_caller)
1062         pushl %eax
1063         pushl %ecx
1064         pushl %edx
1065         pushl $0        /* Pass NULL as regs pointer */
1066         movl 4*4(%esp), %eax
1067         movl 0x4(%ebp), %edx
1068         movl function_trace_op, %ecx
1069         subl $MCOUNT_INSN_SIZE, %eax
1070
1071 .globl ftrace_call
1072 ftrace_call:
1073         call ftrace_stub
1074
1075         addl $4,%esp    /* skip NULL pointer */
1076         popl %edx
1077         popl %ecx
1078         popl %eax
1079 ftrace_ret:
1080 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1081 .globl ftrace_graph_call
1082 ftrace_graph_call:
1083         jmp ftrace_stub
1084 #endif
1085
1086 .globl ftrace_stub
1087 ftrace_stub:
1088         ret
1089 END(ftrace_caller)
1090
1091 ENTRY(ftrace_regs_caller)
1092         pushf   /* push flags before compare (in cs location) */
1093
1094         /*
1095          * i386 does not save SS and ESP when coming from kernel.
1096          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1097          * Unfortunately, that means eflags must be at the same location
1098          * as the current return ip is. We move the return ip into the
1099          * ip location, and move flags into the return ip location.
1100          */
1101         pushl 4(%esp)   /* save return ip into ip slot */
1102
1103         pushl $0        /* Load 0 into orig_ax */
1104         pushl %gs
1105         pushl %fs
1106         pushl %es
1107         pushl %ds
1108         pushl %eax
1109         pushl %ebp
1110         pushl %edi
1111         pushl %esi
1112         pushl %edx
1113         pushl %ecx
1114         pushl %ebx
1115
1116         movl 13*4(%esp), %eax   /* Get the saved flags */
1117         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1118                                 /* clobbering return ip */
1119         movl $__KERNEL_CS,13*4(%esp)
1120
1121         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1122         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1123         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1124         movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1125         pushl %esp              /* Save pt_regs as 4th parameter */
1126
1127 GLOBAL(ftrace_regs_call)
1128         call ftrace_stub
1129
1130         addl $4, %esp           /* Skip pt_regs */
1131         movl 14*4(%esp), %eax   /* Move flags back into cs */
1132         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1133         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1134         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1135
1136         popl %ebx
1137         popl %ecx
1138         popl %edx
1139         popl %esi
1140         popl %edi
1141         popl %ebp
1142         popl %eax
1143         popl %ds
1144         popl %es
1145         popl %fs
1146         popl %gs
1147         addl $8, %esp           /* Skip orig_ax and ip */
1148         popf                    /* Pop flags at end (no addl to corrupt flags) */
1149         jmp ftrace_ret
1150
1151         popf
1152         jmp  ftrace_stub
1153 #else /* ! CONFIG_DYNAMIC_FTRACE */
1154
1155 ENTRY(mcount)
1156         cmpl $__PAGE_OFFSET, %esp
1157         jb ftrace_stub          /* Paging not enabled yet? */
1158
1159         cmpl $ftrace_stub, ftrace_trace_function
1160         jnz trace
1161 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1162         cmpl $ftrace_stub, ftrace_graph_return
1163         jnz ftrace_graph_caller
1164
1165         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1166         jnz ftrace_graph_caller
1167 #endif
1168 .globl ftrace_stub
1169 ftrace_stub:
1170         ret
1171
1172         /* taken from glibc */
1173 trace:
1174         pushl %eax
1175         pushl %ecx
1176         pushl %edx
1177         movl 0xc(%esp), %eax
1178         movl 0x4(%ebp), %edx
1179         subl $MCOUNT_INSN_SIZE, %eax
1180
1181         call *ftrace_trace_function
1182
1183         popl %edx
1184         popl %ecx
1185         popl %eax
1186         jmp ftrace_stub
1187 END(mcount)
1188 #endif /* CONFIG_DYNAMIC_FTRACE */
1189 #endif /* CONFIG_FUNCTION_TRACER */
1190
1191 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1192 ENTRY(ftrace_graph_caller)
1193         pushl %eax
1194         pushl %ecx
1195         pushl %edx
1196         movl 0xc(%esp), %edx
1197         lea 0x4(%ebp), %eax
1198         movl (%ebp), %ecx
1199         subl $MCOUNT_INSN_SIZE, %edx
1200         call prepare_ftrace_return
1201         popl %edx
1202         popl %ecx
1203         popl %eax
1204         ret
1205 END(ftrace_graph_caller)
1206
1207 .globl return_to_handler
1208 return_to_handler:
1209         pushl %eax
1210         pushl %edx
1211         movl %ebp, %eax
1212         call ftrace_return_to_handler
1213         movl %eax, %ecx
1214         popl %edx
1215         popl %eax
1216         jmp *%ecx
1217 #endif
1218
1219 #ifdef CONFIG_TRACING
1220 ENTRY(trace_page_fault)
1221         RING0_EC_FRAME
1222         ASM_CLAC
1223         pushl_cfi $trace_do_page_fault
1224         jmp error_code
1225         CFI_ENDPROC
1226 END(trace_page_fault)
1227 #endif
1228
1229 ENTRY(page_fault)
1230         RING0_EC_FRAME
1231         ASM_CLAC
1232         pushl_cfi $do_page_fault
1233         ALIGN
1234 error_code:
1235         /* the function address is in %gs's slot on the stack */
1236         pushl_cfi %fs
1237         /*CFI_REL_OFFSET fs, 0*/
1238         pushl_cfi %es
1239         /*CFI_REL_OFFSET es, 0*/
1240         pushl_cfi %ds
1241         /*CFI_REL_OFFSET ds, 0*/
1242         pushl_cfi %eax
1243         CFI_REL_OFFSET eax, 0
1244         pushl_cfi %ebp
1245         CFI_REL_OFFSET ebp, 0
1246         pushl_cfi %edi
1247         CFI_REL_OFFSET edi, 0
1248         pushl_cfi %esi
1249         CFI_REL_OFFSET esi, 0
1250         pushl_cfi %edx
1251         CFI_REL_OFFSET edx, 0
1252         pushl_cfi %ecx
1253         CFI_REL_OFFSET ecx, 0
1254         pushl_cfi %ebx
1255         CFI_REL_OFFSET ebx, 0
1256         cld
1257         movl $(__KERNEL_PERCPU), %ecx
1258         movl %ecx, %fs
1259         UNWIND_ESPFIX_STACK
1260         GS_TO_REG %ecx
1261         movl PT_GS(%esp), %edi          # get the function address
1262         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1263         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1264         REG_TO_PTGS %ecx
1265         SET_KERNEL_GS %ecx
1266         movl $(__USER_DS), %ecx
1267         movl %ecx, %ds
1268         movl %ecx, %es
1269         TRACE_IRQS_OFF
1270         movl %esp,%eax                  # pt_regs pointer
1271         call *%edi
1272         jmp ret_from_exception
1273         CFI_ENDPROC
1274 END(page_fault)
1275
1276 /*
1277  * Debug traps and NMI can happen at the one SYSENTER instruction
1278  * that sets up the real kernel stack. Check here, since we can't
1279  * allow the wrong stack to be used.
1280  *
1281  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1282  * already pushed 3 words if it hits on the sysenter instruction:
1283  * eflags, cs and eip.
1284  *
1285  * We just load the right stack, and push the three (known) values
1286  * by hand onto the new stack - while updating the return eip past
1287  * the instruction that would have done it for sysenter.
1288  */
1289 .macro FIX_STACK offset ok label
1290         cmpw $__KERNEL_CS, 4(%esp)
1291         jne \ok
1292 \label:
1293         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1294         CFI_DEF_CFA esp, 0
1295         CFI_UNDEFINED eip
1296         pushfl_cfi
1297         pushl_cfi $__KERNEL_CS
1298         pushl_cfi $sysenter_past_esp
1299         CFI_REL_OFFSET eip, 0
1300 .endm
1301
1302 ENTRY(debug)
1303         RING0_INT_FRAME
1304         ASM_CLAC
1305         cmpl $ia32_sysenter_target,(%esp)
1306         jne debug_stack_correct
1307         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1308 debug_stack_correct:
1309         pushl_cfi $-1                   # mark this as an int
1310         SAVE_ALL
1311         TRACE_IRQS_OFF
1312         xorl %edx,%edx                  # error code 0
1313         movl %esp,%eax                  # pt_regs pointer
1314         call do_debug
1315         jmp ret_from_exception
1316         CFI_ENDPROC
1317 END(debug)
1318
1319 /*
1320  * NMI is doubly nasty. It can happen _while_ we're handling
1321  * a debug fault, and the debug fault hasn't yet been able to
1322  * clear up the stack. So we first check whether we got  an
1323  * NMI on the sysenter entry path, but after that we need to
1324  * check whether we got an NMI on the debug path where the debug
1325  * fault happened on the sysenter path.
1326  */
1327 ENTRY(nmi)
1328         RING0_INT_FRAME
1329         ASM_CLAC
1330 #ifdef CONFIG_X86_ESPFIX32
1331         pushl_cfi %eax
1332         movl %ss, %eax
1333         cmpw $__ESPFIX_SS, %ax
1334         popl_cfi %eax
1335         je nmi_espfix_stack
1336 #endif
1337         cmpl $ia32_sysenter_target,(%esp)
1338         je nmi_stack_fixup
1339         pushl_cfi %eax
1340         movl %esp,%eax
1341         /* Do not access memory above the end of our stack page,
1342          * it might not exist.
1343          */
1344         andl $(THREAD_SIZE-1),%eax
1345         cmpl $(THREAD_SIZE-20),%eax
1346         popl_cfi %eax
1347         jae nmi_stack_correct
1348         cmpl $ia32_sysenter_target,12(%esp)
1349         je nmi_debug_stack_check
1350 nmi_stack_correct:
1351         /* We have a RING0_INT_FRAME here */
1352         pushl_cfi %eax
1353         SAVE_ALL
1354         xorl %edx,%edx          # zero error code
1355         movl %esp,%eax          # pt_regs pointer
1356         call do_nmi
1357         jmp restore_all_notrace
1358         CFI_ENDPROC
1359
1360 nmi_stack_fixup:
1361         RING0_INT_FRAME
1362         FIX_STACK 12, nmi_stack_correct, 1
1363         jmp nmi_stack_correct
1364
1365 nmi_debug_stack_check:
1366         /* We have a RING0_INT_FRAME here */
1367         cmpw $__KERNEL_CS,16(%esp)
1368         jne nmi_stack_correct
1369         cmpl $debug,(%esp)
1370         jb nmi_stack_correct
1371         cmpl $debug_esp_fix_insn,(%esp)
1372         ja nmi_stack_correct
1373         FIX_STACK 24, nmi_stack_correct, 1
1374         jmp nmi_stack_correct
1375
1376 #ifdef CONFIG_X86_ESPFIX32
1377 nmi_espfix_stack:
1378         /* We have a RING0_INT_FRAME here.
1379          *
1380          * create the pointer to lss back
1381          */
1382         pushl_cfi %ss
1383         pushl_cfi %esp
1384         addl $4, (%esp)
1385         /* copy the iret frame of 12 bytes */
1386         .rept 3
1387         pushl_cfi 16(%esp)
1388         .endr
1389         pushl_cfi %eax
1390         SAVE_ALL
1391         FIXUP_ESPFIX_STACK              # %eax == %esp
1392         xorl %edx,%edx                  # zero error code
1393         call do_nmi
1394         RESTORE_REGS
1395         lss 12+4(%esp), %esp            # back to espfix stack
1396         CFI_ADJUST_CFA_OFFSET -24
1397         jmp irq_return
1398 #endif
1399         CFI_ENDPROC
1400 END(nmi)
1401
1402 ENTRY(int3)
1403         RING0_INT_FRAME
1404         ASM_CLAC
1405         pushl_cfi $-1                   # mark this as an int
1406         SAVE_ALL
1407         TRACE_IRQS_OFF
1408         xorl %edx,%edx          # zero error code
1409         movl %esp,%eax          # pt_regs pointer
1410         call do_int3
1411         jmp ret_from_exception
1412         CFI_ENDPROC
1413 END(int3)
1414
1415 ENTRY(general_protection)
1416         RING0_EC_FRAME
1417         pushl_cfi $do_general_protection
1418         jmp error_code
1419         CFI_ENDPROC
1420 END(general_protection)
1421
1422 #ifdef CONFIG_KVM_GUEST
1423 ENTRY(async_page_fault)
1424         RING0_EC_FRAME
1425         ASM_CLAC
1426         pushl_cfi $do_async_page_fault
1427         jmp error_code
1428         CFI_ENDPROC
1429 END(async_page_fault)
1430 #endif
1431