arch/x86/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/irqflags.h>
  16 #include <linux/linkage.h>
  17
  18 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  19
  20         .macro IA32_ARG_FIXUP noebp=0
  21         movl    %edi,%r8d
  22         .if \noebp
  23         .else
  24         movl    %ebp,%r9d
  25         .endif
  26         xchg    %ecx,%esi
  27         movl    %ebx,%edi
  28         movl    %edx,%edx       /* zero extension */
  29         .endm
  30
  31         /* clobbers %eax */
  32         .macro  CLEAR_RREGS
  33         xorl    %eax,%eax
  34         movq    %rax,R11(%rsp)
  35         movq    %rax,R10(%rsp)
  36         movq    %rax,R9(%rsp)
  37         movq    %rax,R8(%rsp)
  38         .endm
  39
  40         .macro LOAD_ARGS32 offset
  41         movl \offset(%rsp),%r11d
  42         movl \offset+8(%rsp),%r10d
  43         movl \offset+16(%rsp),%r9d
  44         movl \offset+24(%rsp),%r8d
  45         movl \offset+40(%rsp),%ecx
  46         movl \offset+48(%rsp),%edx
  47         movl \offset+56(%rsp),%esi
  48         movl \offset+64(%rsp),%edi
  49         movl \offset+72(%rsp),%eax
  50         .endm
  51
  52         .macro CFI_STARTPROC32 simple
  53         CFI_STARTPROC   \simple
  54         CFI_UNDEFINED   r8
  55         CFI_UNDEFINED   r9
  56         CFI_UNDEFINED   r10
  57         CFI_UNDEFINED   r11
  58         CFI_UNDEFINED   r12
  59         CFI_UNDEFINED   r13
  60         CFI_UNDEFINED   r14
  61         CFI_UNDEFINED   r15
  62         .endm
  63
  64 #ifdef CONFIG_PARAVIRT
  65 ENTRY(native_usergs_sysret32)
  66         swapgs
  67         sysretl
  68 ENDPROC(native_usergs_sysret32)
  69
  70 ENTRY(native_irq_enable_sysexit)
  71         swapgs
  72         sti
  73         sysexit
  74 ENDPROC(native_irq_enable_sysexit)
  75 #endif
  76
  77 /*
  78  * 32bit SYSENTER instruction entry.
  79  *
  80  * Arguments:
  81  * %eax System call number.
  82  * %ebx Arg1
  83  * %ecx Arg2
  84  * %edx Arg3
  85  * %esi Arg4
  86  * %edi Arg5
  87  * %ebp user stack
  88  * 0(%ebp) Arg6
  89  *
  90  * Interrupts off.
  91  *
  92  * This is purely a fast path. For anything complicated we use the int 0x80
  93  * path below.  Set up a complete hardware stack frame to share code
  94  * with the int 0x80 path.
  95  */
  96 ENTRY(ia32_sysenter_target)
  97         CFI_STARTPROC32 simple
  98         CFI_SIGNAL_FRAME
  99         CFI_DEF_CFA     rsp,0
 100         CFI_REGISTER    rsp,rbp
 101         SWAPGS_UNSAFE_STACK
 102         movq    %gs:pda_kernelstack, %rsp
 103         addq    $(PDA_STACKOFFSET),%rsp
 104         /*
 105          * No need to follow this irqs on/off section: the syscall
 106          * disabled irqs, here we enable it straight after entry:
 107          */
 108         ENABLE_INTERRUPTS(CLBR_NONE)
 109         movl    %ebp,%ebp               /* zero extension */
 110         pushq   $__USER32_DS
 111         CFI_ADJUST_CFA_OFFSET 8
 112         /*CFI_REL_OFFSET ss,0*/
 113         pushq   %rbp
 114         CFI_ADJUST_CFA_OFFSET 8
 115         CFI_REL_OFFSET rsp,0
 116         pushfq
 117         CFI_ADJUST_CFA_OFFSET 8
 118         /*CFI_REL_OFFSET rflags,0*/
 119         movl    8*3-THREAD_SIZE+TI_sysenter_return(%rsp), %r10d
 120         CFI_REGISTER rip,r10
 121         pushq   $__USER32_CS
 122         CFI_ADJUST_CFA_OFFSET 8
 123         /*CFI_REL_OFFSET cs,0*/
 124         movl    %eax, %eax
 125         pushq   %r10
 126         CFI_ADJUST_CFA_OFFSET 8
 127         CFI_REL_OFFSET rip,0
 128         pushq   %rax
 129         CFI_ADJUST_CFA_OFFSET 8
 130         cld
 131         SAVE_ARGS 0,0,1
 132         /* no need to do an access_ok check here because rbp has been
 133            32bit zero extended */
 134 1:      movl    (%rbp),%r9d
 135         .section __ex_table,"a"
 136         .quad 1b,ia32_badarg
 137         .previous
 138         GET_THREAD_INFO(%r10)
 139         orl    $TS_COMPAT,TI_status(%r10)
 140         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP), \
 141                  TI_flags(%r10)
 142         CFI_REMEMBER_STATE
 143         jnz  sysenter_tracesys
 144 sysenter_do_call:
 145         cmpl    $(IA32_NR_syscalls-1),%eax
 146         ja      ia32_badsys
 147         IA32_ARG_FIXUP 1
 148         call    *ia32_sys_call_table(,%rax,8)
 149         movq    %rax,RAX-ARGOFFSET(%rsp)
 150         GET_THREAD_INFO(%r10)
 151         DISABLE_INTERRUPTS(CLBR_NONE)
 152         TRACE_IRQS_OFF
 153         testl   $_TIF_ALLWORK_MASK,TI_flags(%r10)
 154         jnz     int_ret_from_sys_call
 155         andl    $~TS_COMPAT,TI_status(%r10)
 156         /* clear IF, that popfq doesn't enable interrupts early */
 157         andl  $~0x200,EFLAGS-R11(%rsp)
 158         movl    RIP-R11(%rsp),%edx              /* User %eip */
 159         CFI_REGISTER rip,rdx
 160         RESTORE_ARGS 1,24,1,1,1,1
 161         popfq
 162         CFI_ADJUST_CFA_OFFSET -8
 163         /*CFI_RESTORE rflags*/
 164         popq    %rcx                            /* User %esp */
 165         CFI_ADJUST_CFA_OFFSET -8
 166         CFI_REGISTER rsp,rcx
 167         TRACE_IRQS_ON
 168         ENABLE_INTERRUPTS_SYSEXIT32
 169
 170 sysenter_tracesys:
 171         CFI_RESTORE_STATE
 172         xchgl   %r9d,%ebp
 173         SAVE_REST
 174         CLEAR_RREGS
 175         movq    %r9,R9(%rsp)
 176         movq    $-ENOSYS,RAX(%rsp)/* ptrace can change this for a bad syscall */
 177         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 178         call    syscall_trace_enter
 179         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 180         RESTORE_REST
 181         xchgl   %ebp,%r9d
 182         cmpl    $(IA32_NR_syscalls-1),%eax
 183         ja      int_ret_from_sys_call /* sysenter_tracesys has set RAX(%rsp) */
 184         jmp     sysenter_do_call
 185         CFI_ENDPROC
 186 ENDPROC(ia32_sysenter_target)
 187
 188 /*
 189  * 32bit SYSCALL instruction entry.
 190  *
 191  * Arguments:
 192  * %eax System call number.
 193  * %ebx Arg1
 194  * %ecx return EIP
 195  * %edx Arg3
 196  * %esi Arg4
 197  * %edi Arg5
 198  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 199  * %esp user stack
 200  * 0(%esp) Arg6
 201  *
 202  * Interrupts off.
 203  *
 204  * This is purely a fast path. For anything complicated we use the int 0x80
 205  * path below.  Set up a complete hardware stack frame to share code
 206  * with the int 0x80 path.
 207  */
 208 ENTRY(ia32_cstar_target)
 209         CFI_STARTPROC32 simple
 210         CFI_SIGNAL_FRAME
 211         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 212         CFI_REGISTER    rip,rcx
 213         /*CFI_REGISTER  rflags,r11*/
 214         SWAPGS_UNSAFE_STACK
 215         movl    %esp,%r8d
 216         CFI_REGISTER    rsp,r8
 217         movq    %gs:pda_kernelstack,%rsp
 218         /*
 219          * No need to follow this irqs on/off section: the syscall
 220          * disabled irqs and here we enable it straight after entry:
 221          */
 222         ENABLE_INTERRUPTS(CLBR_NONE)
 223         SAVE_ARGS 8,1,1
 224         movl    %eax,%eax       /* zero extension */
 225         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 226         movq    %rcx,RIP-ARGOFFSET(%rsp)
 227         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 228         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 229         movl    %ebp,%ecx
 230         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 231         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 232         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 233         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 234         movq    %r8,RSP-ARGOFFSET(%rsp)
 235         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 236         /* no need to do an access_ok check here because r8 has been
 237            32bit zero extended */
 238         /* hardware stack frame is complete now */
 239 1:      movl    (%r8),%r9d
 240         .section __ex_table,"a"
 241         .quad 1b,ia32_badarg
 242         .previous
 243         GET_THREAD_INFO(%r10)
 244         orl   $TS_COMPAT,TI_status(%r10)
 245         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP), \
 246                 TI_flags(%r10)
 247         CFI_REMEMBER_STATE
 248         jnz   cstar_tracesys
 249 cstar_do_call:
 250         cmpl $IA32_NR_syscalls-1,%eax
 251         ja  ia32_badsys
 252         IA32_ARG_FIXUP 1
 253         call *ia32_sys_call_table(,%rax,8)
 254         movq %rax,RAX-ARGOFFSET(%rsp)
 255         GET_THREAD_INFO(%r10)
 256         DISABLE_INTERRUPTS(CLBR_NONE)
 257         TRACE_IRQS_OFF
 258         testl $_TIF_ALLWORK_MASK,TI_flags(%r10)
 259         jnz  int_ret_from_sys_call
 260         andl $~TS_COMPAT,TI_status(%r10)
 261         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 262         movl RIP-ARGOFFSET(%rsp),%ecx
 263         CFI_REGISTER rip,rcx
 264         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 265         /*CFI_REGISTER rflags,r11*/
 266         TRACE_IRQS_ON
 267         movl RSP-ARGOFFSET(%rsp),%esp
 268         CFI_RESTORE rsp
 269         USERGS_SYSRET32
 270
 271 cstar_tracesys:
 272         CFI_RESTORE_STATE
 273         xchgl %r9d,%ebp
 274         SAVE_REST
 275         CLEAR_RREGS
 276         movq %r9,R9(%rsp)
 277         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 278         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 279         call syscall_trace_enter
 280         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 281         RESTORE_REST
 282         xchgl %ebp,%r9d
 283         movl RSP-ARGOFFSET(%rsp), %r8d
 284         cmpl $(IA32_NR_syscalls-1),%eax
 285         ja int_ret_from_sys_call /* cstar_tracesys has set RAX(%rsp) */
 286         jmp cstar_do_call
 287 END(ia32_cstar_target)
 288
 289 ia32_badarg:
 290         movq $-EFAULT,%rax
 291         jmp ia32_sysret
 292         CFI_ENDPROC
 293
 294 /*
 295  * Emulated IA32 system calls via int 0x80.
 296  *
 297  * Arguments:
 298  * %eax System call number.
 299  * %ebx Arg1
 300  * %ecx Arg2
 301  * %edx Arg3
 302  * %esi Arg4
 303  * %edi Arg5
 304  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 305  *
 306  * Notes:
 307  * Uses the same stack frame as the x86-64 version.
 308  * All registers except %eax must be saved (but ptrace may violate that)
 309  * Arguments are zero extended. For system calls that want sign extension and
 310  * take long arguments a wrapper is needed. Most calls can just be called
 311  * directly.
 312  * Assumes it is only called from user space and entered with interrupts off.
 313  */
 314
 315 ENTRY(ia32_syscall)
 316         CFI_STARTPROC32 simple
 317         CFI_SIGNAL_FRAME
 318         CFI_DEF_CFA     rsp,SS+8-RIP
 319         /*CFI_REL_OFFSET        ss,SS-RIP*/
 320         CFI_REL_OFFSET  rsp,RSP-RIP
 321         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 322         /*CFI_REL_OFFSET        cs,CS-RIP*/
 323         CFI_REL_OFFSET  rip,RIP-RIP
 324         PARAVIRT_ADJUST_EXCEPTION_FRAME
 325         SWAPGS
 326         /*
 327          * No need to follow this irqs on/off section: the syscall
 328          * disabled irqs and here we enable it straight after entry:
 329          */
 330         ENABLE_INTERRUPTS(CLBR_NONE)
 331         movl %eax,%eax
 332         pushq %rax
 333         CFI_ADJUST_CFA_OFFSET 8
 334         cld
 335         /* note the registers are not zero extended to the sf.
 336            this could be a problem. */
 337         SAVE_ARGS 0,0,1
 338         GET_THREAD_INFO(%r10)
 339         orl   $TS_COMPAT,TI_status(%r10)
 340         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP), \
 341                 TI_flags(%r10)
 342         jnz ia32_tracesys
 343 ia32_do_syscall:
 344         cmpl $(IA32_NR_syscalls-1),%eax
 345         ja  int_ret_from_sys_call       /* ia32_tracesys has set RAX(%rsp) */
 346         IA32_ARG_FIXUP
 347         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 348 ia32_sysret:
 349         movq %rax,RAX-ARGOFFSET(%rsp)
 350         jmp int_ret_from_sys_call
 351
 352 ia32_tracesys:
 353         SAVE_REST
 354         CLEAR_RREGS
 355         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 356         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 357         call syscall_trace_enter
 358         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 359         RESTORE_REST
 360         jmp ia32_do_syscall
 361 END(ia32_syscall)
 362
 363 ia32_badsys:
 364         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 365         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 366         jmp int_ret_from_sys_call
 367
 368 quiet_ni_syscall:
 369         movq $-ENOSYS,%rax
 370         ret
 371         CFI_ENDPROC
 372
 373         .macro PTREGSCALL label, func, arg
 374         .globl \label
 375 \label:
 376         leaq \func(%rip),%rax
 377         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 378         jmp  ia32_ptregs_common
 379         .endm
 380
 381         CFI_STARTPROC32
 382
 383         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 384         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 385         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 386         PTREGSCALL stub32_execve, sys32_execve, %rcx
 387         PTREGSCALL stub32_fork, sys_fork, %rdi
 388         PTREGSCALL stub32_clone, sys32_clone, %rdx
 389         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 390         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 391
 392 ENTRY(ia32_ptregs_common)
 393         popq %r11
 394         CFI_ENDPROC
 395         CFI_STARTPROC32 simple
 396         CFI_SIGNAL_FRAME
 397         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 398         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 399         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 400         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 401         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 402         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 403         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 404 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 405 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 406         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 407 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 408         SAVE_REST
 409         call *%rax
 410         RESTORE_REST
 411         jmp  ia32_sysret        /* misbalances the return cache */
 412         CFI_ENDPROC
 413 END(ia32_ptregs_common)
 414
 415         .section .rodata,"a"
 416         .align 8
 417 ia32_sys_call_table:
 418         .quad sys_restart_syscall
 419         .quad sys_exit
 420         .quad stub32_fork
 421         .quad sys_read
 422         .quad sys_write
 423         .quad compat_sys_open           /* 5 */
 424         .quad sys_close
 425         .quad sys32_waitpid
 426         .quad sys_creat
 427         .quad sys_link
 428         .quad sys_unlink                /* 10 */
 429         .quad stub32_execve
 430         .quad sys_chdir
 431         .quad compat_sys_time
 432         .quad sys_mknod
 433         .quad sys_chmod         /* 15 */
 434         .quad sys_lchown16
 435         .quad quiet_ni_syscall                  /* old break syscall holder */
 436         .quad sys_stat
 437         .quad sys32_lseek
 438         .quad sys_getpid                /* 20 */
 439         .quad compat_sys_mount  /* mount  */
 440         .quad sys_oldumount     /* old_umount  */
 441         .quad sys_setuid16
 442         .quad sys_getuid16
 443         .quad compat_sys_stime  /* stime */             /* 25 */
 444         .quad compat_sys_ptrace /* ptrace */
 445         .quad sys_alarm
 446         .quad sys_fstat /* (old)fstat */
 447         .quad sys_pause
 448         .quad compat_sys_utime  /* 30 */
 449         .quad quiet_ni_syscall  /* old stty syscall holder */
 450         .quad quiet_ni_syscall  /* old gtty syscall holder */
 451         .quad sys_access
 452         .quad sys_nice
 453         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 454         .quad sys_sync
 455         .quad sys32_kill
 456         .quad sys_rename
 457         .quad sys_mkdir
 458         .quad sys_rmdir         /* 40 */
 459         .quad sys_dup
 460         .quad sys32_pipe
 461         .quad compat_sys_times
 462         .quad quiet_ni_syscall                  /* old prof syscall holder */
 463         .quad sys_brk           /* 45 */
 464         .quad sys_setgid16
 465         .quad sys_getgid16
 466         .quad sys_signal
 467         .quad sys_geteuid16
 468         .quad sys_getegid16     /* 50 */
 469         .quad sys_acct
 470         .quad sys_umount                        /* new_umount */
 471         .quad quiet_ni_syscall                  /* old lock syscall holder */
 472         .quad compat_sys_ioctl
 473         .quad compat_sys_fcntl64                /* 55 */
 474         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 475         .quad sys_setpgid
 476         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 477         .quad sys32_olduname
 478         .quad sys_umask         /* 60 */
 479         .quad sys_chroot
 480         .quad sys32_ustat
 481         .quad sys_dup2
 482         .quad sys_getppid
 483         .quad sys_getpgrp               /* 65 */
 484         .quad sys_setsid
 485         .quad sys32_sigaction
 486         .quad sys_sgetmask
 487         .quad sys_ssetmask
 488         .quad sys_setreuid16    /* 70 */
 489         .quad sys_setregid16
 490         .quad sys32_sigsuspend
 491         .quad compat_sys_sigpending
 492         .quad sys_sethostname
 493         .quad compat_sys_setrlimit      /* 75 */
 494         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 495         .quad compat_sys_getrusage
 496         .quad sys32_gettimeofday
 497         .quad sys32_settimeofday
 498         .quad sys_getgroups16   /* 80 */
 499         .quad sys_setgroups16
 500         .quad sys32_old_select
 501         .quad sys_symlink
 502         .quad sys_lstat
 503         .quad sys_readlink              /* 85 */
 504         .quad sys_uselib
 505         .quad sys_swapon
 506         .quad sys_reboot
 507         .quad compat_sys_old_readdir
 508         .quad sys32_mmap                /* 90 */
 509         .quad sys_munmap
 510         .quad sys_truncate
 511         .quad sys_ftruncate
 512         .quad sys_fchmod
 513         .quad sys_fchown16              /* 95 */
 514         .quad sys_getpriority
 515         .quad sys_setpriority
 516         .quad quiet_ni_syscall                  /* old profil syscall holder */
 517         .quad compat_sys_statfs
 518         .quad compat_sys_fstatfs                /* 100 */
 519         .quad sys_ioperm
 520         .quad compat_sys_socketcall
 521         .quad sys_syslog
 522         .quad compat_sys_setitimer
 523         .quad compat_sys_getitimer      /* 105 */
 524         .quad compat_sys_newstat
 525         .quad compat_sys_newlstat
 526         .quad compat_sys_newfstat
 527         .quad sys32_uname
 528         .quad stub32_iopl               /* 110 */
 529         .quad sys_vhangup
 530         .quad quiet_ni_syscall  /* old "idle" system call */
 531         .quad sys32_vm86_warning        /* vm86old */
 532         .quad compat_sys_wait4
 533         .quad sys_swapoff               /* 115 */
 534         .quad compat_sys_sysinfo
 535         .quad sys32_ipc
 536         .quad sys_fsync
 537         .quad stub32_sigreturn
 538         .quad stub32_clone              /* 120 */
 539         .quad sys_setdomainname
 540         .quad sys_uname
 541         .quad sys_modify_ldt
 542         .quad compat_sys_adjtimex
 543         .quad sys32_mprotect            /* 125 */
 544         .quad compat_sys_sigprocmask
 545         .quad quiet_ni_syscall          /* create_module */
 546         .quad sys_init_module
 547         .quad sys_delete_module
 548         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 549         .quad sys32_quotactl
 550         .quad sys_getpgid
 551         .quad sys_fchdir
 552         .quad quiet_ni_syscall  /* bdflush */
 553         .quad sys_sysfs         /* 135 */
 554         .quad sys_personality
 555         .quad quiet_ni_syscall  /* for afs_syscall */
 556         .quad sys_setfsuid16
 557         .quad sys_setfsgid16
 558         .quad sys_llseek                /* 140 */
 559         .quad compat_sys_getdents
 560         .quad compat_sys_select
 561         .quad sys_flock
 562         .quad sys_msync
 563         .quad compat_sys_readv          /* 145 */
 564         .quad compat_sys_writev
 565         .quad sys_getsid
 566         .quad sys_fdatasync
 567         .quad sys32_sysctl      /* sysctl */
 568         .quad sys_mlock         /* 150 */
 569         .quad sys_munlock
 570         .quad sys_mlockall
 571         .quad sys_munlockall
 572         .quad sys_sched_setparam
 573         .quad sys_sched_getparam   /* 155 */
 574         .quad sys_sched_setscheduler
 575         .quad sys_sched_getscheduler
 576         .quad sys_sched_yield
 577         .quad sys_sched_get_priority_max
 578         .quad sys_sched_get_priority_min  /* 160 */
 579         .quad sys32_sched_rr_get_interval
 580         .quad compat_sys_nanosleep
 581         .quad sys_mremap
 582         .quad sys_setresuid16
 583         .quad sys_getresuid16   /* 165 */
 584         .quad sys32_vm86_warning        /* vm86 */
 585         .quad quiet_ni_syscall  /* query_module */
 586         .quad sys_poll
 587         .quad compat_sys_nfsservctl
 588         .quad sys_setresgid16   /* 170 */
 589         .quad sys_getresgid16
 590         .quad sys_prctl
 591         .quad stub32_rt_sigreturn
 592         .quad sys32_rt_sigaction
 593         .quad sys32_rt_sigprocmask      /* 175 */
 594         .quad sys32_rt_sigpending
 595         .quad compat_sys_rt_sigtimedwait
 596         .quad sys32_rt_sigqueueinfo
 597         .quad sys_rt_sigsuspend
 598         .quad sys32_pread               /* 180 */
 599         .quad sys32_pwrite
 600         .quad sys_chown16
 601         .quad sys_getcwd
 602         .quad sys_capget
 603         .quad sys_capset
 604         .quad stub32_sigaltstack
 605         .quad sys32_sendfile
 606         .quad quiet_ni_syscall          /* streams1 */
 607         .quad quiet_ni_syscall          /* streams2 */
 608         .quad stub32_vfork            /* 190 */
 609         .quad compat_sys_getrlimit
 610         .quad sys32_mmap2
 611         .quad sys32_truncate64
 612         .quad sys32_ftruncate64
 613         .quad sys32_stat64              /* 195 */
 614         .quad sys32_lstat64
 615         .quad sys32_fstat64
 616         .quad sys_lchown
 617         .quad sys_getuid
 618         .quad sys_getgid                /* 200 */
 619         .quad sys_geteuid
 620         .quad sys_getegid
 621         .quad sys_setreuid
 622         .quad sys_setregid
 623         .quad sys_getgroups     /* 205 */
 624         .quad sys_setgroups
 625         .quad sys_fchown
 626         .quad sys_setresuid
 627         .quad sys_getresuid
 628         .quad sys_setresgid     /* 210 */
 629         .quad sys_getresgid
 630         .quad sys_chown
 631         .quad sys_setuid
 632         .quad sys_setgid
 633         .quad sys_setfsuid              /* 215 */
 634         .quad sys_setfsgid
 635         .quad sys_pivot_root
 636         .quad sys_mincore
 637         .quad sys_madvise
 638         .quad compat_sys_getdents64     /* 220 getdents64 */
 639         .quad compat_sys_fcntl64
 640         .quad quiet_ni_syscall          /* tux */
 641         .quad quiet_ni_syscall          /* security */
 642         .quad sys_gettid
 643         .quad sys32_readahead   /* 225 */
 644         .quad sys_setxattr
 645         .quad sys_lsetxattr
 646         .quad sys_fsetxattr
 647         .quad sys_getxattr
 648         .quad sys_lgetxattr     /* 230 */
 649         .quad sys_fgetxattr
 650         .quad sys_listxattr
 651         .quad sys_llistxattr
 652         .quad sys_flistxattr
 653         .quad sys_removexattr   /* 235 */
 654         .quad sys_lremovexattr
 655         .quad sys_fremovexattr
 656         .quad sys_tkill
 657         .quad sys_sendfile64
 658         .quad compat_sys_futex          /* 240 */
 659         .quad compat_sys_sched_setaffinity
 660         .quad compat_sys_sched_getaffinity
 661         .quad sys_set_thread_area
 662         .quad sys_get_thread_area
 663         .quad compat_sys_io_setup       /* 245 */
 664         .quad sys_io_destroy
 665         .quad compat_sys_io_getevents
 666         .quad compat_sys_io_submit
 667         .quad sys_io_cancel
 668         .quad sys32_fadvise64           /* 250 */
 669         .quad quiet_ni_syscall  /* free_huge_pages */
 670         .quad sys_exit_group
 671         .quad sys32_lookup_dcookie
 672         .quad sys_epoll_create
 673         .quad sys_epoll_ctl             /* 255 */
 674         .quad sys_epoll_wait
 675         .quad sys_remap_file_pages
 676         .quad sys_set_tid_address
 677         .quad compat_sys_timer_create
 678         .quad compat_sys_timer_settime  /* 260 */
 679         .quad compat_sys_timer_gettime
 680         .quad sys_timer_getoverrun
 681         .quad sys_timer_delete
 682         .quad compat_sys_clock_settime
 683         .quad compat_sys_clock_gettime  /* 265 */
 684         .quad compat_sys_clock_getres
 685         .quad compat_sys_clock_nanosleep
 686         .quad compat_sys_statfs64
 687         .quad compat_sys_fstatfs64
 688         .quad sys_tgkill                /* 270 */
 689         .quad compat_sys_utimes
 690         .quad sys32_fadvise64_64
 691         .quad quiet_ni_syscall  /* sys_vserver */
 692         .quad sys_mbind
 693         .quad compat_sys_get_mempolicy  /* 275 */
 694         .quad sys_set_mempolicy
 695         .quad compat_sys_mq_open
 696         .quad sys_mq_unlink
 697         .quad compat_sys_mq_timedsend
 698         .quad compat_sys_mq_timedreceive        /* 280 */
 699         .quad compat_sys_mq_notify
 700         .quad compat_sys_mq_getsetattr
 701         .quad compat_sys_kexec_load     /* reserved for kexec */
 702         .quad compat_sys_waitid
 703         .quad quiet_ni_syscall          /* 285: sys_altroot */
 704         .quad sys_add_key
 705         .quad sys_request_key
 706         .quad sys_keyctl
 707         .quad sys_ioprio_set
 708         .quad sys_ioprio_get            /* 290 */
 709         .quad sys_inotify_init
 710         .quad sys_inotify_add_watch
 711         .quad sys_inotify_rm_watch
 712         .quad sys_migrate_pages
 713         .quad compat_sys_openat         /* 295 */
 714         .quad sys_mkdirat
 715         .quad sys_mknodat
 716         .quad sys_fchownat
 717         .quad compat_sys_futimesat
 718         .quad sys32_fstatat             /* 300 */
 719         .quad sys_unlinkat
 720         .quad sys_renameat
 721         .quad sys_linkat
 722         .quad sys_symlinkat
 723         .quad sys_readlinkat            /* 305 */
 724         .quad sys_fchmodat
 725         .quad sys_faccessat
 726         .quad compat_sys_pselect6
 727         .quad compat_sys_ppoll
 728         .quad sys_unshare               /* 310 */
 729         .quad compat_sys_set_robust_list
 730         .quad compat_sys_get_robust_list
 731         .quad sys_splice
 732         .quad sys32_sync_file_range
 733         .quad sys_tee                   /* 315 */
 734         .quad compat_sys_vmsplice
 735         .quad compat_sys_move_pages
 736         .quad sys_getcpu
 737         .quad sys_epoll_pwait
 738         .quad compat_sys_utimensat      /* 320 */
 739         .quad compat_sys_signalfd
 740         .quad sys_timerfd_create
 741         .quad sys_eventfd
 742         .quad sys32_fallocate
 743         .quad compat_sys_timerfd_settime        /* 325 */
 744         .quad compat_sys_timerfd_gettime
 745 ia32_syscall_end: