arch/x86/boot/compressed/head_64.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .code32
  25         .text
  26
  27 #include <linux/init.h>
  28 #include <linux/linkage.h>
  29 #include <asm/segment.h>
  30 #include <asm/pgtable_types.h>
  31 #include <asm/page_types.h>
  32 #include <asm/boot.h>
  33 #include <asm/msr.h>
  34 #include <asm/processor-flags.h>
  35 #include <asm/asm-offsets.h>
  36
  37 /*
  38  * Locally defined symbols should be marked hidden:
  39  */
  40         .hidden _bss
  41         .hidden _ebss
  42         .hidden _got
  43         .hidden _egot
  44
  45         __HEAD
  46         .code32
  47 ENTRY(startup_32)
  48         /*
  49          * 32bit entry is 0 and it is ABI so immutable!
  50          * If we come here directly from a bootloader,
  51          * kernel(text+data+bss+brk) ramdisk, zero_page, command line
  52          * all need to be under the 4G limit.
  53          */
  54         cld
  55         /*
  56          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
  57          * us to not reload segments
  58          */
  59         testb $(1<<6), BP_loadflags(%esi)
  60         jnz 1f
  61
  62         cli
  63         movl    $(__BOOT_DS), %eax
  64         movl    %eax, %ds
  65         movl    %eax, %es
  66         movl    %eax, %ss
  67 1:
  68
  69 /*
  70  * Calculate the delta between where we were compiled to run
  71  * at and where we were actually loaded at.  This can only be done
  72  * with a short local call on x86.  Nothing  else will tell us what
  73  * address we are running at.  The reserved chunk of the real-mode
  74  * data at 0x1e4 (defined as a scratch field) are used as the stack
  75  * for this calculation. Only 4 bytes are needed.
  76  */
  77         leal    (BP_scratch+4)(%esi), %esp
  78         call    1f
  79 1:      popl    %ebp
  80         subl    $1b, %ebp
  81
  82 /* setup a stack and make sure cpu supports long mode. */
  83         movl    $boot_stack_end, %eax
  84         addl    %ebp, %eax
  85         movl    %eax, %esp
  86
  87         call    verify_cpu
  88         testl   %eax, %eax
  89         jnz     no_longmode
  90
  91 /*
  92  * Compute the delta between where we were compiled to run at
  93  * and where the code will actually run at.
  94  *
  95  * %ebp contains the address we are loaded at by the boot loader and %ebx
  96  * contains the address where we should move the kernel image temporarily
  97  * for safe in-place decompression.
  98  */
  99
 100 #ifdef CONFIG_RELOCATABLE
 101         movl    %ebp, %ebx
 102         movl    BP_kernel_alignment(%esi), %eax
 103         decl    %eax
 104         addl    %eax, %ebx
 105         notl    %eax
 106         andl    %eax, %ebx
 107 #else
 108         movl    $LOAD_PHYSICAL_ADDR, %ebx
 109 #endif
 110
 111         /* Target address to relocate to for decompression */
 112         addl    $z_extract_offset, %ebx
 113
 114 /*
 115  * Prepare for entering 64 bit mode
 116  */
 117
 118         /* Load new GDT with the 64bit segments using 32bit descriptor */
 119         leal    gdt(%ebp), %eax
 120         movl    %eax, gdt+2(%ebp)
 121         lgdt    gdt(%ebp)
 122
 123         /* Enable PAE mode */
 124         movl    $(X86_CR4_PAE), %eax
 125         movl    %eax, %cr4
 126
 127  /*
 128   * Build early 4G boot pagetable
 129   */
 130         /* Initialize Page tables to 0 */
 131         leal    pgtable(%ebx), %edi
 132         xorl    %eax, %eax
 133         movl    $((4096*6)/4), %ecx
 134         rep     stosl
 135
 136         /* Build Level 4 */
 137         leal    pgtable + 0(%ebx), %edi
 138         leal    0x1007 (%edi), %eax
 139         movl    %eax, 0(%edi)
 140
 141         /* Build Level 3 */
 142         leal    pgtable + 0x1000(%ebx), %edi
 143         leal    0x1007(%edi), %eax
 144         movl    $4, %ecx
 145 1:      movl    %eax, 0x00(%edi)
 146         addl    $0x00001000, %eax
 147         addl    $8, %edi
 148         decl    %ecx
 149         jnz     1b
 150
 151         /* Build Level 2 */
 152         leal    pgtable + 0x2000(%ebx), %edi
 153         movl    $0x00000183, %eax
 154         movl    $2048, %ecx
 155 1:      movl    %eax, 0(%edi)
 156         addl    $0x00200000, %eax
 157         addl    $8, %edi
 158         decl    %ecx
 159         jnz     1b
 160
 161         /* Enable the boot page tables */
 162         leal    pgtable(%ebx), %eax
 163         movl    %eax, %cr3
 164
 165         /* Enable Long mode in EFER (Extended Feature Enable Register) */
 166         movl    $MSR_EFER, %ecx
 167         rdmsr
 168         btsl    $_EFER_LME, %eax
 169         wrmsr
 170
 171         /* After gdt is loaded */
 172         xorl    %eax, %eax
 173         lldt    %ax
 174         movl    $0x20, %eax
 175         ltr     %ax
 176
 177         /*
 178          * Setup for the jump to 64bit mode
 179          *
 180          * When the jump is performend we will be in long mode but
 181          * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
 182          * (and in turn EFER.LMA = 1).  To jump into 64bit mode we use
 183          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 184          * We place all of the values on our mini stack so lret can
 185          * used to perform that far jump.
 186          */
 187         pushl   $__KERNEL_CS
 188         leal    startup_64(%ebp), %eax
 189         pushl   %eax
 190
 191         /* Enter paged protected Mode, activating Long Mode */
 192         movl    $(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */
 193         movl    %eax, %cr0
 194
 195         /* Jump from 32bit compatibility mode into 64bit mode. */
 196         lret
 197 ENDPROC(startup_32)
 198
 199         .code64
 200         .org 0x200
 201 ENTRY(startup_64)
 202         /*
 203          * 64bit entry is 0x200 and it is ABI so immutable!
 204          * We come here either from startup_32 or directly from a
 205          * 64bit bootloader.
 206          * If we come here from a bootloader, kernel(text+data+bss+brk),
 207          * ramdisk, zero_page, command line could be above 4G.
 208          * We depend on an identity mapped page table being provided
 209          * that maps our entire kernel(text+data+bss+brk), zero page
 210          * and command line.
 211          */
 212 #ifdef CONFIG_EFI_STUB
 213         /*
 214          * The entry point for the PE/COFF executable is efi_pe_entry, so
 215          * only legacy boot loaders will execute this jmp.
 216          */
 217         jmp     preferred_addr
 218
 219 ENTRY(efi_pe_entry)
 220         mov     %rcx, %rdi
 221         mov     %rdx, %rsi
 222         pushq   %rdi
 223         pushq   %rsi
 224         call    make_boot_params
 225         cmpq    $0,%rax
 226         je      1f
 227         mov     %rax, %rdx
 228         leaq    startup_32(%rip), %rax
 229         movl    %eax, BP_code32_start(%rdx)
 230         popq    %rsi
 231         popq    %rdi
 232
 233 ENTRY(efi_stub_entry)
 234         call    efi_main
 235         movq    %rax,%rsi
 236         cmpq    $0,%rax
 237         jne     2f
 238 1:
 239         /* EFI init failed, so hang. */
 240         hlt
 241         jmp     1b
 242 2:
 243         movl    BP_code32_start(%esi), %eax
 244         leaq    preferred_addr(%rax), %rax
 245         jmp     *%rax
 246
 247 preferred_addr:
 248 #endif
 249
 250         /* Setup data segments. */
 251         xorl    %eax, %eax
 252         movl    %eax, %ds
 253         movl    %eax, %es
 254         movl    %eax, %ss
 255         movl    %eax, %fs
 256         movl    %eax, %gs
 257
 258         /*
 259          * Compute the decompressed kernel start address.  It is where
 260          * we were loaded at aligned to a 2M boundary. %rbp contains the
 261          * decompressed kernel start address.
 262          *
 263          * If it is a relocatable kernel then decompress and run the kernel
 264          * from load address aligned to 2MB addr, otherwise decompress and
 265          * run the kernel from LOAD_PHYSICAL_ADDR
 266          *
 267          * We cannot rely on the calculation done in 32-bit mode, since we
 268          * may have been invoked via the 64-bit entry point.
 269          */
 270
 271         /* Start with the delta to where the kernel will run at. */
 272 #ifdef CONFIG_RELOCATABLE
 273         leaq    startup_32(%rip) /* - $startup_32 */, %rbp
 274         movl    BP_kernel_alignment(%rsi), %eax
 275         decl    %eax
 276         addq    %rax, %rbp
 277         notq    %rax
 278         andq    %rax, %rbp
 279 #else
 280         movq    $LOAD_PHYSICAL_ADDR, %rbp
 281 #endif
 282
 283         /* Target address to relocate to for decompression */
 284         leaq    z_extract_offset(%rbp), %rbx
 285
 286         /* Set up the stack */
 287         leaq    boot_stack_end(%rbx), %rsp
 288
 289         /* Zero EFLAGS */
 290         pushq   $0
 291         popfq
 292
 293 /*
 294  * Copy the compressed kernel to the end of our buffer
 295  * where decompression in place becomes safe.
 296  */
 297         pushq   %rsi
 298         leaq    (_bss-8)(%rip), %rsi
 299         leaq    (_bss-8)(%rbx), %rdi
 300         movq    $_bss /* - $startup_32 */, %rcx
 301         shrq    $3, %rcx
 302         std
 303         rep     movsq
 304         cld
 305         popq    %rsi
 306
 307 /*
 308  * Jump to the relocated address.
 309  */
 310         leaq    relocated(%rbx), %rax
 311         jmp     *%rax
 312
 313         .text
 314 relocated:
 315
 316 /*
 317  * Clear BSS (stack is currently empty)
 318  */
 319         xorl    %eax, %eax
 320         leaq    _bss(%rip), %rdi
 321         leaq    _ebss(%rip), %rcx
 322         subq    %rdi, %rcx
 323         shrq    $3, %rcx
 324         rep     stosq
 325
 326 /*
 327  * Adjust our own GOT
 328  */
 329         leaq    _got(%rip), %rdx
 330         leaq    _egot(%rip), %rcx
 331 1:
 332         cmpq    %rcx, %rdx
 333         jae     2f
 334         addq    %rbx, (%rdx)
 335         addq    $8, %rdx
 336         jmp     1b
 337 2:
 338
 339 /*
 340  * Do the decompression, and jump to the new kernel..
 341  */
 342         pushq   %rsi                    /* Save the real mode argument */
 343         movq    %rsi, %rdi              /* real mode address */
 344         leaq    boot_heap(%rip), %rsi   /* malloc area for uncompression */
 345         leaq    input_data(%rip), %rdx  /* input_data */
 346         movl    $z_input_len, %ecx      /* input_len */
 347         movq    %rbp, %r8               /* output target address */
 348         call    decompress_kernel
 349         popq    %rsi
 350
 351 /*
 352  * Jump to the decompressed kernel.
 353  */
 354         jmp     *%rbp
 355
 356         .code32
 357 no_longmode:
 358         /* This isn't an x86-64 CPU so hang */
 359 1:
 360         hlt
 361         jmp     1b
 362
 363 #include "../../kernel/verify_cpu.S"
 364
 365         .data
 366 gdt:
 367         .word   gdt_end - gdt
 368         .long   gdt
 369         .word   0
 370         .quad   0x0000000000000000      /* NULL descriptor */
 371         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 372         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 373         .quad   0x0080890000000000      /* TS descriptor */
 374         .quad   0x0000000000000000      /* TS continued */
 375 gdt_end:
 376
 377 /*
 378  * Stack and heap for uncompression
 379  */
 380         .bss
 381         .balign 4
 382 boot_heap:
 383         .fill BOOT_HEAP_SIZE, 1, 0
 384 boot_stack:
 385         .fill BOOT_STACK_SIZE, 1, 0
 386 boot_stack_end:
 387
 388 /*
 389  * Space for page tables (not in .bss so not zeroed)
 390  */
 391         .section ".pgtable","a",@nobits
 392         .balign 4096
 393 pgtable:
 394         .fill 6*4096, 1, 0