projects / GitHub / LineageOS / android_kernel_samsung_universal7580.git / blob
? search:


72f230baf5d1a91665c6364b3dc619930a054fac
[GitHub/LineageOS/android_kernel_samsung_universal7580.git] / arch / s390 / kernel / entry64.S
1 /*
2 * S390 low-level entry points.
3 *
4 * Copyright IBM Corp. 1999, 2012
5 * Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
6 * Hartmut Penner (hp@de.ibm.com),
7 * Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
8 * Heiko Carstens <heiko.carstens@de.ibm.com>
9 */
10
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/processor.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21 #include <asm/sigp.h>
22
23 __PT_R0 = __PT_GPRS
24 __PT_R1 = __PT_GPRS + 8
25 __PT_R2 = __PT_GPRS + 16
26 __PT_R3 = __PT_GPRS + 24
27 __PT_R4 = __PT_GPRS + 32
28 __PT_R5 = __PT_GPRS + 40
29 __PT_R6 = __PT_GPRS + 48
30 __PT_R7 = __PT_GPRS + 56
31 __PT_R8 = __PT_GPRS + 64
32 __PT_R9 = __PT_GPRS + 72
33 __PT_R10 = __PT_GPRS + 80
34 __PT_R11 = __PT_GPRS + 88
35 __PT_R12 = __PT_GPRS + 96
36 __PT_R13 = __PT_GPRS + 104
37 __PT_R14 = __PT_GPRS + 112
38 __PT_R15 = __PT_GPRS + 120
39
40 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
41 STACK_SIZE = 1 << STACK_SHIFT
42 STACK_INIT = STACK_SIZE - STACK_FRAME_OVERHEAD - __PT_SIZE
43
44 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
45 _TIF_MCCK_PENDING | _TIF_PER_TRAP )
46 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
47 _TIF_MCCK_PENDING)
48 _TIF_TRACE = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
49 _TIF_SYSCALL_TRACEPOINT)
50 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
51
52 #define BASED(name) name-system_call(%r13)
53
54 .macro TRACE_IRQS_ON
55 #ifdef CONFIG_TRACE_IRQFLAGS
56 basr %r2,%r0
57 brasl %r14,trace_hardirqs_on_caller
58 #endif
59 .endm
60
61 .macro TRACE_IRQS_OFF
62 #ifdef CONFIG_TRACE_IRQFLAGS
63 basr %r2,%r0
64 brasl %r14,trace_hardirqs_off_caller
65 #endif
66 .endm
67
68 .macro LOCKDEP_SYS_EXIT
69 #ifdef CONFIG_LOCKDEP
70 tm __PT_PSW+1(%r11),0x01 # returning to user ?
71 jz .+10
72 brasl %r14,lockdep_sys_exit
73 #endif
74 .endm
75
76 .macro LPP newpp
77 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
78 tm __LC_MACHINE_FLAGS+6,0x20 # MACHINE_FLAG_LPP
79 jz .+8
80 .insn s,0xb2800000,\newpp
81 #endif
82 .endm
83
84 .macro HANDLE_SIE_INTERCEPT scratch,pgmcheck
85 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
86 tmhh %r8,0x0001 # interrupting from user ?
87 jnz .+42
88 lgr \scratch,%r9
89 slg \scratch,BASED(.Lsie_loop)
90 clg \scratch,BASED(.Lsie_length)
91 .if \pgmcheck
92 # Some program interrupts are suppressing (e.g. protection).
93 # We must also check the instruction after SIE in that case.
94 # do_protection_exception will rewind to rewind_pad
95 jh .+22
96 .else
97 jhe .+22
98 .endif
99 lg %r9,BASED(.Lsie_loop)
100 LPP BASED(.Lhost_id) # set host id
101 #endif
102 .endm
103
104 .macro CHECK_STACK stacksize,savearea
105 #ifdef CONFIG_CHECK_STACK
106 tml %r15,\stacksize - CONFIG_STACK_GUARD
107 lghi %r14,\savearea
108 jz stack_overflow
109 #endif
110 .endm
111
112 .macro SWITCH_ASYNC savearea,stack,shift
113 tmhh %r8,0x0001 # interrupting from user ?
114 jnz 1f
115 lgr %r14,%r9
116 slg %r14,BASED(.Lcritical_start)
117 clg %r14,BASED(.Lcritical_length)
118 jhe 0f
119 lghi %r11,\savearea # inside critical section, do cleanup
120 brasl %r14,cleanup_critical
121 tmhh %r8,0x0001 # retest problem state after cleanup
122 jnz 1f
123 0: lg %r14,\stack # are we already on the target stack?
124 slgr %r14,%r15
125 srag %r14,%r14,\shift
126 jnz 1f
127 CHECK_STACK 1<<\shift,\savearea
128 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
129 j 2f
130 1: lg %r15,\stack # load target stack
131 2: la %r11,STACK_FRAME_OVERHEAD(%r15)
132 .endm
133
134 .macro UPDATE_VTIME scratch,enter_timer
135 lg \scratch,__LC_EXIT_TIMER
136 slg \scratch,\enter_timer
137 alg \scratch,__LC_USER_TIMER
138 stg \scratch,__LC_USER_TIMER
139 lg \scratch,__LC_LAST_UPDATE_TIMER
140 slg \scratch,__LC_EXIT_TIMER
141 alg \scratch,__LC_SYSTEM_TIMER
142 stg \scratch,__LC_SYSTEM_TIMER
143 mvc __LC_LAST_UPDATE_TIMER(8),\enter_timer
144 .endm
145
146 .macro LAST_BREAK scratch
147 srag \scratch,%r10,23
148 jz .+10
149 stg %r10,__TI_last_break(%r12)
150 .endm
151
152 .macro REENABLE_IRQS
153 stg %r8,__LC_RETURN_PSW
154 ni __LC_RETURN_PSW,0xbf
155 ssm __LC_RETURN_PSW
156 .endm
157
158 .macro STCK savearea
159 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
160 .insn s,0xb27c0000,\savearea # store clock fast
161 #else
162 .insn s,0xb2050000,\savearea # store clock
163 #endif
164 .endm
165
166 .section .kprobes.text, "ax"
167
168 /*
169 * Scheduler resume function, called by switch_to
170 * gpr2 = (task_struct *) prev
171 * gpr3 = (task_struct *) next
172 * Returns:
173 * gpr2 = prev
174 */
175 ENTRY(__switch_to)
176 stmg %r6,%r15,__SF_GPRS(%r15) # store gprs of prev task
177 stg %r15,__THREAD_ksp(%r2) # store kernel stack of prev
178 lg %r4,__THREAD_info(%r2) # get thread_info of prev
179 lg %r5,__THREAD_info(%r3) # get thread_info of next
180 lgr %r15,%r5
181 aghi %r15,STACK_INIT # end of kernel stack of next
182 stg %r3,__LC_CURRENT # store task struct of next
183 stg %r5,__LC_THREAD_INFO # store thread info of next
184 stg %r15,__LC_KERNEL_STACK # store end of kernel stack
185 lctl %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
186 mvc __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
187 lg %r15,__THREAD_ksp(%r3) # load kernel stack of next
188 tm __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
189 jz 0f
190 ni __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
191 oi __TI_flags+7(%r5),_TIF_MCCK_PENDING # set it in next
192 0: lmg %r6,%r15,__SF_GPRS(%r15) # load gprs of next task
193 br %r14
194
195 __critical_start:
196 /*
197 * SVC interrupt handler routine. System calls are synchronous events and
198 * are executed with interrupts enabled.
199 */
200
201 ENTRY(system_call)
202 stpt __LC_SYNC_ENTER_TIMER
203 sysc_stmg:
204 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
205 lg %r10,__LC_LAST_BREAK
206 lg %r12,__LC_THREAD_INFO
207 sysc_per:
208 lg %r15,__LC_KERNEL_STACK
209 la %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
210 sysc_vtime:
211 UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
212 LAST_BREAK %r13
213 stmg %r0,%r7,__PT_R0(%r11)
214 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
215 mvc __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
216 mvc __PT_INT_CODE(4,%r11),__LC_SVC_ILC
217 sysc_do_svc:
218 oi __TI_flags+7(%r12),_TIF_SYSCALL
219 llgh %r8,__PT_INT_CODE+2(%r11)
220 slag %r8,%r8,2 # shift and test for svc 0
221 jnz sysc_nr_ok
222 # svc 0: system call number in %r1
223 llgfr %r1,%r1 # clear high word in r1
224 cghi %r1,NR_syscalls
225 jnl sysc_nr_ok
226 sth %r1,__PT_INT_CODE+2(%r11)
227 slag %r8,%r1,2
228 sysc_nr_ok:
229 larl %r10,sys_call_table # 64 bit system call table
230 #ifdef CONFIG_COMPAT
231 tm __TI_flags+5(%r12),(_TIF_31BIT>>16)
232 jno sysc_noemu
233 larl %r10,sys_call_table_emu # 31 bit system call table
234 sysc_noemu:
235 #endif
236 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
237 stg %r2,__PT_ORIG_GPR2(%r11)
238 stg %r7,STACK_FRAME_OVERHEAD(%r15)
239 lgf %r9,0(%r8,%r10) # get system call add.
240 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
241 jnz sysc_tracesys
242 basr %r14,%r9 # call sys_xxxx
243 stg %r2,__PT_R2(%r11) # store return value
244
245 sysc_return:
246 LOCKDEP_SYS_EXIT
247 sysc_tif:
248 tm __PT_PSW+1(%r11),0x01 # returning to user ?
249 jno sysc_restore
250 tm __TI_flags+7(%r12),_TIF_WORK_SVC
251 jnz sysc_work # check for work
252 ni __TI_flags+7(%r12),255-_TIF_SYSCALL
253 sysc_restore:
254 lg %r14,__LC_VDSO_PER_CPU
255 lmg %r0,%r10,__PT_R0(%r11)
256 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
257 stpt __LC_EXIT_TIMER
258 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
259 lmg %r11,%r15,__PT_R11(%r11)
260 lpswe __LC_RETURN_PSW
261 sysc_done:
262
263 #
264 # One of the work bits is on. Find out which one.
265 #
266 sysc_work:
267 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
268 jo sysc_mcck_pending
269 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
270 jo sysc_reschedule
271 tm __TI_flags+7(%r12),_TIF_PER_TRAP
272 jo sysc_singlestep
273 tm __TI_flags+7(%r12),_TIF_SIGPENDING
274 jo sysc_sigpending
275 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
276 jo sysc_notify_resume
277 j sysc_return # beware of critical section cleanup
278
279 #
280 # _TIF_NEED_RESCHED is set, call schedule
281 #
282 sysc_reschedule:
283 larl %r14,sysc_return
284 jg schedule
285
286 #
287 # _TIF_MCCK_PENDING is set, call handler
288 #
289 sysc_mcck_pending:
290 larl %r14,sysc_return
291 jg s390_handle_mcck # TIF bit will be cleared by handler
292
293 #
294 # _TIF_SIGPENDING is set, call do_signal
295 #
296 sysc_sigpending:
297 lgr %r2,%r11 # pass pointer to pt_regs
298 brasl %r14,do_signal
299 tm __TI_flags+7(%r12),_TIF_SYSCALL
300 jno sysc_return
301 lmg %r2,%r7,__PT_R2(%r11) # load svc arguments
302 lghi %r8,0 # svc 0 returns -ENOSYS
303 llgh %r1,__PT_INT_CODE+2(%r11) # load new svc number
304 cghi %r1,NR_syscalls
305 jnl sysc_nr_ok # invalid svc number -> do svc 0
306 slag %r8,%r1,2
307 j sysc_nr_ok # restart svc
308
309 #
310 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
311 #
312 sysc_notify_resume:
313 lgr %r2,%r11 # pass pointer to pt_regs
314 larl %r14,sysc_return
315 jg do_notify_resume
316
317 #
318 # _TIF_PER_TRAP is set, call do_per_trap
319 #
320 sysc_singlestep:
321 ni __TI_flags+7(%r12),255-_TIF_PER_TRAP
322 lgr %r2,%r11 # pass pointer to pt_regs
323 larl %r14,sysc_return
324 jg do_per_trap
325
326 #
327 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
328 # and after the system call
329 #
330 sysc_tracesys:
331 lgr %r2,%r11 # pass pointer to pt_regs
332 la %r3,0
333 llgh %r0,__PT_INT_CODE+2(%r11)
334 stg %r0,__PT_R2(%r11)
335 brasl %r14,do_syscall_trace_enter
336 lghi %r0,NR_syscalls
337 clgr %r0,%r2
338 jnh sysc_tracenogo
339 sllg %r8,%r2,2
340 lgf %r9,0(%r8,%r10)
341 sysc_tracego:
342 lmg %r3,%r7,__PT_R3(%r11)
343 stg %r7,STACK_FRAME_OVERHEAD(%r15)
344 lg %r2,__PT_ORIG_GPR2(%r11)
345 basr %r14,%r9 # call sys_xxx
346 stg %r2,__PT_R2(%r11) # store return value
347 sysc_tracenogo:
348 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
349 jz sysc_return
350 lgr %r2,%r11 # pass pointer to pt_regs
351 larl %r14,sysc_return
352 jg do_syscall_trace_exit
353
354 #
355 # a new process exits the kernel with ret_from_fork
356 #
357 ENTRY(ret_from_fork)
358 la %r11,STACK_FRAME_OVERHEAD(%r15)
359 lg %r12,__LC_THREAD_INFO
360 brasl %r14,schedule_tail
361 TRACE_IRQS_ON
362 ssm __LC_SVC_NEW_PSW # reenable interrupts
363 tm __PT_PSW+1(%r11),0x01 # forking a kernel thread ?
364 jne sysc_tracenogo
365 # it's a kernel thread
366 lmg %r9,%r10,__PT_R9(%r11) # load gprs
367 ENTRY(kernel_thread_starter)
368 la %r2,0(%r10)
369 basr %r14,%r9
370 j sysc_tracenogo
371
372 /*
373 * Program check handler routine
374 */
375
376 ENTRY(pgm_check_handler)
377 stpt __LC_SYNC_ENTER_TIMER
378 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
379 lg %r10,__LC_LAST_BREAK
380 lg %r12,__LC_THREAD_INFO
381 larl %r13,system_call
382 lmg %r8,%r9,__LC_PGM_OLD_PSW
383 HANDLE_SIE_INTERCEPT %r14,1
384 tmhh %r8,0x0001 # test problem state bit
385 jnz 1f # -> fault in user space
386 tmhh %r8,0x4000 # PER bit set in old PSW ?
387 jnz 0f # -> enabled, can't be a double fault
388 tm __LC_PGM_ILC+3,0x80 # check for per exception
389 jnz pgm_svcper # -> single stepped svc
390 0: CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
391 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
392 j 2f
393 1: UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
394 LAST_BREAK %r14
395 lg %r15,__LC_KERNEL_STACK
396 lg %r14,__TI_task(%r12)
397 lghi %r13,__LC_PGM_TDB
398 tm __LC_PGM_ILC+2,0x02 # check for transaction abort
399 jz 2f
400 mvc __THREAD_trap_tdb(256,%r14),0(%r13)
401 2: la %r11,STACK_FRAME_OVERHEAD(%r15)
402 stmg %r0,%r7,__PT_R0(%r11)
403 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
404 stmg %r8,%r9,__PT_PSW(%r11)
405 mvc __PT_INT_CODE(4,%r11),__LC_PGM_ILC
406 mvc __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
407 stg %r10,__PT_ARGS(%r11)
408 tm __LC_PGM_ILC+3,0x80 # check for per exception
409 jz 0f
410 tmhh %r8,0x0001 # kernel per event ?
411 jz pgm_kprobe
412 oi __TI_flags+7(%r12),_TIF_PER_TRAP
413 mvc __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
414 mvc __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
415 mvc __THREAD_per_paid(1,%r14),__LC_PER_PAID
416 0: REENABLE_IRQS
417 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
418 larl %r1,pgm_check_table
419 llgh %r10,__PT_INT_CODE+2(%r11)
420 nill %r10,0x007f
421 sll %r10,2
422 je sysc_return
423 lgf %r1,0(%r10,%r1) # load address of handler routine
424 lgr %r2,%r11 # pass pointer to pt_regs
425 basr %r14,%r1 # branch to interrupt-handler
426 j sysc_return
427
428 #
429 # PER event in supervisor state, must be kprobes
430 #
431 pgm_kprobe:
432 REENABLE_IRQS
433 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
434 lgr %r2,%r11 # pass pointer to pt_regs
435 brasl %r14,do_per_trap
436 j sysc_return
437
438 #
439 # single stepped system call
440 #
441 pgm_svcper:
442 oi __TI_flags+7(%r12),_TIF_PER_TRAP
443 mvc __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
444 larl %r14,sysc_per
445 stg %r14,__LC_RETURN_PSW+8
446 lpswe __LC_RETURN_PSW # branch to sysc_per and enable irqs
447
448 /*
449 * IO interrupt handler routine
450 */
451 ENTRY(io_int_handler)
452 STCK __LC_INT_CLOCK
453 stpt __LC_ASYNC_ENTER_TIMER
454 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
455 lg %r10,__LC_LAST_BREAK
456 lg %r12,__LC_THREAD_INFO
457 larl %r13,system_call
458 lmg %r8,%r9,__LC_IO_OLD_PSW
459 HANDLE_SIE_INTERCEPT %r14,0
460 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
461 tmhh %r8,0x0001 # interrupting from user?
462 jz io_skip
463 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
464 LAST_BREAK %r14
465 io_skip:
466 stmg %r0,%r7,__PT_R0(%r11)
467 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
468 stmg %r8,%r9,__PT_PSW(%r11)
469 TRACE_IRQS_OFF
470 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
471 lgr %r2,%r11 # pass pointer to pt_regs
472 brasl %r14,do_IRQ
473 io_return:
474 LOCKDEP_SYS_EXIT
475 TRACE_IRQS_ON
476 io_tif:
477 tm __TI_flags+7(%r12),_TIF_WORK_INT
478 jnz io_work # there is work to do (signals etc.)
479 io_restore:
480 lg %r14,__LC_VDSO_PER_CPU
481 lmg %r0,%r10,__PT_R0(%r11)
482 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
483 stpt __LC_EXIT_TIMER
484 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
485 lmg %r11,%r15,__PT_R11(%r11)
486 lpswe __LC_RETURN_PSW
487 io_done:
488
489 #
490 # There is work todo, find out in which context we have been interrupted:
491 # 1) if we return to user space we can do all _TIF_WORK_INT work
492 # 2) if we return to kernel code and kvm is enabled check if we need to
493 # modify the psw to leave SIE
494 # 3) if we return to kernel code and preemptive scheduling is enabled check
495 # the preemption counter and if it is zero call preempt_schedule_irq
496 # Before any work can be done, a switch to the kernel stack is required.
497 #
498 io_work:
499 tm __PT_PSW+1(%r11),0x01 # returning to user ?
500 jo io_work_user # yes -> do resched & signal
501 #ifdef CONFIG_PREEMPT
502 # check for preemptive scheduling
503 icm %r0,15,__TI_precount(%r12)
504 jnz io_restore # preemption is disabled
505 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
506 jno io_restore
507 # switch to kernel stack
508 lg %r1,__PT_R15(%r11)
509 aghi %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
510 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
511 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
512 la %r11,STACK_FRAME_OVERHEAD(%r1)
513 lgr %r15,%r1
514 # TRACE_IRQS_ON already done at io_return, call
515 # TRACE_IRQS_OFF to keep things symmetrical
516 TRACE_IRQS_OFF
517 brasl %r14,preempt_schedule_irq
518 j io_return
519 #else
520 j io_restore
521 #endif
522
523 #
524 # Need to do work before returning to userspace, switch to kernel stack
525 #
526 io_work_user:
527 lg %r1,__LC_KERNEL_STACK
528 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
529 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
530 la %r11,STACK_FRAME_OVERHEAD(%r1)
531 lgr %r15,%r1
532
533 #
534 # One of the work bits is on. Find out which one.
535 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
536 # and _TIF_MCCK_PENDING
537 #
538 io_work_tif:
539 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
540 jo io_mcck_pending
541 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
542 jo io_reschedule
543 tm __TI_flags+7(%r12),_TIF_SIGPENDING
544 jo io_sigpending
545 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
546 jo io_notify_resume
547 j io_return # beware of critical section cleanup
548
549 #
550 # _TIF_MCCK_PENDING is set, call handler
551 #
552 io_mcck_pending:
553 # TRACE_IRQS_ON already done at io_return
554 brasl %r14,s390_handle_mcck # TIF bit will be cleared by handler
555 TRACE_IRQS_OFF
556 j io_return
557
558 #
559 # _TIF_NEED_RESCHED is set, call schedule
560 #
561 io_reschedule:
562 # TRACE_IRQS_ON already done at io_return
563 ssm __LC_SVC_NEW_PSW # reenable interrupts
564 brasl %r14,schedule # call scheduler
565 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
566 TRACE_IRQS_OFF
567 j io_return
568
569 #
570 # _TIF_SIGPENDING or is set, call do_signal
571 #
572 io_sigpending:
573 # TRACE_IRQS_ON already done at io_return
574 ssm __LC_SVC_NEW_PSW # reenable interrupts
575 lgr %r2,%r11 # pass pointer to pt_regs
576 brasl %r14,do_signal
577 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
578 TRACE_IRQS_OFF
579 j io_return
580
581 #
582 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
583 #
584 io_notify_resume:
585 # TRACE_IRQS_ON already done at io_return
586 ssm __LC_SVC_NEW_PSW # reenable interrupts
587 lgr %r2,%r11 # pass pointer to pt_regs
588 brasl %r14,do_notify_resume
589 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
590 TRACE_IRQS_OFF
591 j io_return
592
593 /*
594 * External interrupt handler routine
595 */
596 ENTRY(ext_int_handler)
597 STCK __LC_INT_CLOCK
598 stpt __LC_ASYNC_ENTER_TIMER
599 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
600 lg %r10,__LC_LAST_BREAK
601 lg %r12,__LC_THREAD_INFO
602 larl %r13,system_call
603 lmg %r8,%r9,__LC_EXT_OLD_PSW
604 HANDLE_SIE_INTERCEPT %r14,0
605 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
606 tmhh %r8,0x0001 # interrupting from user ?
607 jz ext_skip
608 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
609 LAST_BREAK %r14
610 ext_skip:
611 stmg %r0,%r7,__PT_R0(%r11)
612 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
613 stmg %r8,%r9,__PT_PSW(%r11)
614 TRACE_IRQS_OFF
615 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
616 lghi %r1,4096
617 lgr %r2,%r11 # pass pointer to pt_regs
618 llgf %r3,__LC_EXT_CPU_ADDR # get cpu address + interruption code
619 llgf %r4,__LC_EXT_PARAMS # get external parameter
620 lg %r5,__LC_EXT_PARAMS2-4096(%r1) # get 64 bit external parameter
621 brasl %r14,do_extint
622 j io_return
623
624 /*
625 * Load idle PSW. The second "half" of this function is in cleanup_idle.
626 */
627 ENTRY(psw_idle)
628 stg %r3,__SF_EMPTY(%r15)
629 larl %r1,psw_idle_lpsw+4
630 stg %r1,__SF_EMPTY+8(%r15)
631 STCK __CLOCK_IDLE_ENTER(%r2)
632 stpt __TIMER_IDLE_ENTER(%r2)
633 psw_idle_lpsw:
634 lpswe __SF_EMPTY(%r15)
635 br %r14
636 psw_idle_end:
637
638 __critical_end:
639
640 /*
641 * Machine check handler routines
642 */
643 ENTRY(mcck_int_handler)
644 STCK __LC_MCCK_CLOCK
645 la %r1,4095 # revalidate r1
646 spt __LC_CPU_TIMER_SAVE_AREA-4095(%r1) # revalidate cpu timer
647 lmg %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
648 lg %r10,__LC_LAST_BREAK
649 lg %r12,__LC_THREAD_INFO
650 larl %r13,system_call
651 lmg %r8,%r9,__LC_MCK_OLD_PSW
652 HANDLE_SIE_INTERCEPT %r14,0
653 tm __LC_MCCK_CODE,0x80 # system damage?
654 jo mcck_panic # yes -> rest of mcck code invalid
655 lghi %r14,__LC_CPU_TIMER_SAVE_AREA
656 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
657 tm __LC_MCCK_CODE+5,0x02 # stored cpu timer value valid?
658 jo 3f
659 la %r14,__LC_SYNC_ENTER_TIMER
660 clc 0(8,%r14),__LC_ASYNC_ENTER_TIMER
661 jl 0f
662 la %r14,__LC_ASYNC_ENTER_TIMER
663 0: clc 0(8,%r14),__LC_EXIT_TIMER
664 jl 1f
665 la %r14,__LC_EXIT_TIMER
666 1: clc 0(8,%r14),__LC_LAST_UPDATE_TIMER
667 jl 2f
668 la %r14,__LC_LAST_UPDATE_TIMER
669 2: spt 0(%r14)
670 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
671 3: tm __LC_MCCK_CODE+2,0x09 # mwp + ia of old psw valid?
672 jno mcck_panic # no -> skip cleanup critical
673 SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
674 tm %r8,0x0001 # interrupting from user ?
675 jz mcck_skip
676 UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
677 LAST_BREAK %r14
678 mcck_skip:
679 lghi %r14,__LC_GPREGS_SAVE_AREA+64
680 stmg %r0,%r7,__PT_R0(%r11)
681 mvc __PT_R8(64,%r11),0(%r14)
682 stmg %r8,%r9,__PT_PSW(%r11)
683 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
684 lgr %r2,%r11 # pass pointer to pt_regs
685 brasl %r14,s390_do_machine_check
686 tm __PT_PSW+1(%r11),0x01 # returning to user ?
687 jno mcck_return
688 lg %r1,__LC_KERNEL_STACK # switch to kernel stack
689 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
690 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
691 la %r11,STACK_FRAME_OVERHEAD(%r1)
692 lgr %r15,%r1
693 ssm __LC_PGM_NEW_PSW # turn dat on, keep irqs off
694 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
695 jno mcck_return
696 TRACE_IRQS_OFF
697 brasl %r14,s390_handle_mcck
698 TRACE_IRQS_ON
699 mcck_return:
700 lg %r14,__LC_VDSO_PER_CPU
701 lmg %r0,%r10,__PT_R0(%r11)
702 mvc __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
703 tm __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
704 jno 0f
705 stpt __LC_EXIT_TIMER
706 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
707 0: lmg %r11,%r15,__PT_R11(%r11)
708 lpswe __LC_RETURN_MCCK_PSW
709
710 mcck_panic:
711 lg %r14,__LC_PANIC_STACK
712 slgr %r14,%r15
713 srag %r14,%r14,PAGE_SHIFT
714 jz 0f
715 lg %r15,__LC_PANIC_STACK
716 0: aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
717 j mcck_skip
718
719 #
720 # PSW restart interrupt handler
721 #
722 ENTRY(restart_int_handler)
723 stg %r15,__LC_SAVE_AREA_RESTART
724 lg %r15,__LC_RESTART_STACK
725 aghi %r15,-__PT_SIZE # create pt_regs on stack
726 xc 0(__PT_SIZE,%r15),0(%r15)
727 stmg %r0,%r14,__PT_R0(%r15)
728 mvc __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
729 mvc __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
730 aghi %r15,-STACK_FRAME_OVERHEAD # create stack frame on stack
731 xc 0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
732 lg %r1,__LC_RESTART_FN # load fn, parm & source cpu
733 lg %r2,__LC_RESTART_DATA
734 lg %r3,__LC_RESTART_SOURCE
735 ltgr %r3,%r3 # test source cpu address
736 jm 1f # negative -> skip source stop
737 0: sigp %r4,%r3,SIGP_SENSE # sigp sense to source cpu
738 brc 10,0b # wait for status stored
739 1: basr %r14,%r1 # call function
740 stap __SF_EMPTY(%r15) # store cpu address
741 llgh %r3,__SF_EMPTY(%r15)
742 2: sigp %r4,%r3,SIGP_STOP # sigp stop to current cpu
743 brc 2,2b
744 3: j 3b
745
746 .section .kprobes.text, "ax"
747
748 #ifdef CONFIG_CHECK_STACK
749 /*
750 * The synchronous or the asynchronous stack overflowed. We are dead.
751 * No need to properly save the registers, we are going to panic anyway.
752 * Setup a pt_regs so that show_trace can provide a good call trace.
753 */
754 stack_overflow:
755 lg %r15,__LC_PANIC_STACK # change to panic stack
756 la %r11,STACK_FRAME_OVERHEAD(%r15)
757 stmg %r0,%r7,__PT_R0(%r11)
758 stmg %r8,%r9,__PT_PSW(%r11)
759 mvc __PT_R8(64,%r11),0(%r14)
760 stg %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
761 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
762 lgr %r2,%r11 # pass pointer to pt_regs
763 jg kernel_stack_overflow
764 #endif
765
766 .align 8
767 cleanup_table:
768 .quad system_call
769 .quad sysc_do_svc
770 .quad sysc_tif
771 .quad sysc_restore
772 .quad sysc_done
773 .quad io_tif
774 .quad io_restore
775 .quad io_done
776 .quad psw_idle
777 .quad psw_idle_end
778
779 cleanup_critical:
780 clg %r9,BASED(cleanup_table) # system_call
781 jl 0f
782 clg %r9,BASED(cleanup_table+8) # sysc_do_svc
783 jl cleanup_system_call
784 clg %r9,BASED(cleanup_table+16) # sysc_tif
785 jl 0f
786 clg %r9,BASED(cleanup_table+24) # sysc_restore
787 jl cleanup_sysc_tif
788 clg %r9,BASED(cleanup_table+32) # sysc_done
789 jl cleanup_sysc_restore
790 clg %r9,BASED(cleanup_table+40) # io_tif
791 jl 0f
792 clg %r9,BASED(cleanup_table+48) # io_restore
793 jl cleanup_io_tif
794 clg %r9,BASED(cleanup_table+56) # io_done
795 jl cleanup_io_restore
796 clg %r9,BASED(cleanup_table+64) # psw_idle
797 jl 0f
798 clg %r9,BASED(cleanup_table+72) # psw_idle_end
799 jl cleanup_idle
800 0: br %r14
801
802
803 cleanup_system_call:
804 # check if stpt has been executed
805 clg %r9,BASED(cleanup_system_call_insn)
806 jh 0f
807 mvc __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
808 cghi %r11,__LC_SAVE_AREA_ASYNC
809 je 0f
810 mvc __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
811 0: # check if stmg has been executed
812 clg %r9,BASED(cleanup_system_call_insn+8)
813 jh 0f
814 mvc __LC_SAVE_AREA_SYNC(64),0(%r11)
815 0: # check if base register setup + TIF bit load has been done
816 clg %r9,BASED(cleanup_system_call_insn+16)
817 jhe 0f
818 # set up saved registers r10 and r12
819 stg %r10,16(%r11) # r10 last break
820 stg %r12,32(%r11) # r12 thread-info pointer
821 0: # check if the user time update has been done
822 clg %r9,BASED(cleanup_system_call_insn+24)
823 jh 0f
824 lg %r15,__LC_EXIT_TIMER
825 slg %r15,__LC_SYNC_ENTER_TIMER
826 alg %r15,__LC_USER_TIMER
827 stg %r15,__LC_USER_TIMER
828 0: # check if the system time update has been done
829 clg %r9,BASED(cleanup_system_call_insn+32)
830 jh 0f
831 lg %r15,__LC_LAST_UPDATE_TIMER
832 slg %r15,__LC_EXIT_TIMER
833 alg %r15,__LC_SYSTEM_TIMER
834 stg %r15,__LC_SYSTEM_TIMER
835 0: # update accounting time stamp
836 mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
837 # do LAST_BREAK
838 lg %r9,16(%r11)
839 srag %r9,%r9,23
840 jz 0f
841 mvc __TI_last_break(8,%r12),16(%r11)
842 0: # set up saved register r11
843 lg %r15,__LC_KERNEL_STACK
844 la %r9,STACK_FRAME_OVERHEAD(%r15)
845 stg %r9,24(%r11) # r11 pt_regs pointer
846 # fill pt_regs
847 mvc __PT_R8(64,%r9),__LC_SAVE_AREA_SYNC
848 stmg %r0,%r7,__PT_R0(%r9)
849 mvc __PT_PSW(16,%r9),__LC_SVC_OLD_PSW
850 mvc __PT_INT_CODE(4,%r9),__LC_SVC_ILC
851 # setup saved register r15
852 stg %r15,56(%r11) # r15 stack pointer
853 # set new psw address and exit
854 larl %r9,sysc_do_svc
855 br %r14
856 cleanup_system_call_insn:
857 .quad system_call
858 .quad sysc_stmg
859 .quad sysc_per
860 .quad sysc_vtime+18
861 .quad sysc_vtime+42
862
863 cleanup_sysc_tif:
864 larl %r9,sysc_tif
865 br %r14
866
867 cleanup_sysc_restore:
868 clg %r9,BASED(cleanup_sysc_restore_insn)
869 je 0f
870 lg %r9,24(%r11) # get saved pointer to pt_regs
871 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
872 mvc 0(64,%r11),__PT_R8(%r9)
873 lmg %r0,%r7,__PT_R0(%r9)
874 0: lmg %r8,%r9,__LC_RETURN_PSW
875 br %r14
876 cleanup_sysc_restore_insn:
877 .quad sysc_done - 4
878
879 cleanup_io_tif:
880 larl %r9,io_tif
881 br %r14
882
883 cleanup_io_restore:
884 clg %r9,BASED(cleanup_io_restore_insn)
885 je 0f
886 lg %r9,24(%r11) # get saved r11 pointer to pt_regs
887 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
888 mvc 0(64,%r11),__PT_R8(%r9)
889 lmg %r0,%r7,__PT_R0(%r9)
890 0: lmg %r8,%r9,__LC_RETURN_PSW
891 br %r14
892 cleanup_io_restore_insn:
893 .quad io_done - 4
894
895 cleanup_idle:
896 # copy interrupt clock & cpu timer
897 mvc __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
898 mvc __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
899 cghi %r11,__LC_SAVE_AREA_ASYNC
900 je 0f
901 mvc __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
902 mvc __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
903 0: # check if stck & stpt have been executed
904 clg %r9,BASED(cleanup_idle_insn)
905 jhe 1f
906 mvc __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
907 mvc __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
908 1: # account system time going idle
909 lg %r9,__LC_STEAL_TIMER
910 alg %r9,__CLOCK_IDLE_ENTER(%r2)
911 slg %r9,__LC_LAST_UPDATE_CLOCK
912 stg %r9,__LC_STEAL_TIMER
913 mvc __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
914 lg %r9,__LC_SYSTEM_TIMER
915 alg %r9,__LC_LAST_UPDATE_TIMER
916 slg %r9,__TIMER_IDLE_ENTER(%r2)
917 stg %r9,__LC_SYSTEM_TIMER
918 mvc __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
919 # prepare return psw
920 nihh %r8,0xfffd # clear wait state bit
921 lg %r9,48(%r11) # return from psw_idle
922 br %r14
923 cleanup_idle_insn:
924 .quad psw_idle_lpsw
925
926 /*
927 * Integer constants
928 */
929 .align 8
930 .Lcritical_start:
931 .quad __critical_start
932 .Lcritical_length:
933 .quad __critical_end - __critical_start
934
935
936 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
937 /*
938 * sie64a calling convention:
939 * %r2 pointer to sie control block
940 * %r3 guest register save area
941 */
942 ENTRY(sie64a)
943 stmg %r6,%r14,__SF_GPRS(%r15) # save kernel registers
944 stg %r2,__SF_EMPTY(%r15) # save control block pointer
945 stg %r3,__SF_EMPTY+8(%r15) # save guest register save area
946 xc __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
947 lmg %r0,%r13,0(%r3) # load guest gprs 0-13
948 # some program checks are suppressing. C code (e.g. do_protection_exception)
949 # will rewind the PSW by the ILC, which is 4 bytes in case of SIE. Other
950 # instructions in the sie_loop should not cause program interrupts. So
951 # lets use a nop (47 00 00 00) as a landing pad.
952 # See also HANDLE_SIE_INTERCEPT
953 rewind_pad:
954 nop 0
955 sie_loop:
956 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
957 tm __TI_flags+7(%r14),_TIF_EXIT_SIE
958 jnz sie_exit
959 lg %r14,__LC_GMAP # get gmap pointer
960 ltgr %r14,%r14
961 jz sie_gmap
962 lctlg %c1,%c1,__GMAP_ASCE(%r14) # load primary asce
963 sie_gmap:
964 lg %r14,__SF_EMPTY(%r15) # get control block pointer
965 LPP __SF_EMPTY(%r15) # set guest id
966 sie 0(%r14)
967 sie_done:
968 LPP __SF_EMPTY+16(%r15) # set host id
969 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
970 sie_exit:
971 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
972 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
973 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
974 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
975 lghi %r2,0
976 br %r14
977 sie_fault:
978 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
979 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
980 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
981 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
982 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
983 lghi %r2,-EFAULT
984 br %r14
985
986 .align 8
987 .Lsie_loop:
988 .quad sie_loop
989 .Lsie_length:
990 .quad sie_done - sie_loop
991 .Lhost_id:
992 .quad 0
993
994 EX_TABLE(rewind_pad,sie_fault)
995 EX_TABLE(sie_loop,sie_fault)
996 #endif
997
998 .section .rodata, "a"
999 #define SYSCALL(esa,esame,emu) .long esame
1000 .globl sys_call_table
1001 sys_call_table:
1002 #include "syscalls.S"
1003 #undef SYSCALL
1004
1005 #ifdef CONFIG_COMPAT
1006
1007 #define SYSCALL(esa,esame,emu) .long emu
1008 sys_call_table_emu:
1009 #include "syscalls.S"
1010 #undef SYSCALL
1011 #endif