projects / GitHub / LineageOS / android_kernel_samsung_universal7580.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
s390: system call path micro optimization
[GitHub/LineageOS/android_kernel_samsung_universal7580.git] / arch / s390 / kernel / entry64.S
1 /*
2 * S390 low-level entry points.
3 *
4 * Copyright IBM Corp. 1999, 2012
5 * Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
6 * Hartmut Penner (hp@de.ibm.com),
7 * Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
8 * Heiko Carstens <heiko.carstens@de.ibm.com>
9 */
10
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/processor.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21 #include <asm/sigp.h>
22
23 __PT_R0 = __PT_GPRS
24 __PT_R1 = __PT_GPRS + 8
25 __PT_R2 = __PT_GPRS + 16
26 __PT_R3 = __PT_GPRS + 24
27 __PT_R4 = __PT_GPRS + 32
28 __PT_R5 = __PT_GPRS + 40
29 __PT_R6 = __PT_GPRS + 48
30 __PT_R7 = __PT_GPRS + 56
31 __PT_R8 = __PT_GPRS + 64
32 __PT_R9 = __PT_GPRS + 72
33 __PT_R10 = __PT_GPRS + 80
34 __PT_R11 = __PT_GPRS + 88
35 __PT_R12 = __PT_GPRS + 96
36 __PT_R13 = __PT_GPRS + 104
37 __PT_R14 = __PT_GPRS + 112
38 __PT_R15 = __PT_GPRS + 120
39
40 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
41 STACK_SIZE = 1 << STACK_SHIFT
42 STACK_INIT = STACK_SIZE - STACK_FRAME_OVERHEAD - __PT_SIZE
43
44 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
45 _TIF_MCCK_PENDING | _TIF_PER_TRAP )
46 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
47 _TIF_MCCK_PENDING)
48 _TIF_TRACE = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
49 _TIF_SYSCALL_TRACEPOINT)
50 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
51
52 #define BASED(name) name-system_call(%r13)
53
54 .macro TRACE_IRQS_ON
55 #ifdef CONFIG_TRACE_IRQFLAGS
56 basr %r2,%r0
57 brasl %r14,trace_hardirqs_on_caller
58 #endif
59 .endm
60
61 .macro TRACE_IRQS_OFF
62 #ifdef CONFIG_TRACE_IRQFLAGS
63 basr %r2,%r0
64 brasl %r14,trace_hardirqs_off_caller
65 #endif
66 .endm
67
68 .macro LOCKDEP_SYS_EXIT
69 #ifdef CONFIG_LOCKDEP
70 tm __PT_PSW+1(%r11),0x01 # returning to user ?
71 jz .+10
72 brasl %r14,lockdep_sys_exit
73 #endif
74 .endm
75
76 .macro LPP newpp
77 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
78 tm __LC_MACHINE_FLAGS+6,0x20 # MACHINE_FLAG_LPP
79 jz .+8
80 .insn s,0xb2800000,\newpp
81 #endif
82 .endm
83
84 .macro HANDLE_SIE_INTERCEPT scratch,pgmcheck
85 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
86 tmhh %r8,0x0001 # interrupting from user ?
87 jnz .+42
88 lgr \scratch,%r9
89 slg \scratch,BASED(.Lsie_loop)
90 clg \scratch,BASED(.Lsie_length)
91 .if \pgmcheck
92 # Some program interrupts are suppressing (e.g. protection).
93 # We must also check the instruction after SIE in that case.
94 # do_protection_exception will rewind to rewind_pad
95 jh .+22
96 .else
97 jhe .+22
98 .endif
99 lg %r9,BASED(.Lsie_loop)
100 LPP BASED(.Lhost_id) # set host id
101 #endif
102 .endm
103
104 .macro CHECK_STACK stacksize,savearea
105 #ifdef CONFIG_CHECK_STACK
106 tml %r15,\stacksize - CONFIG_STACK_GUARD
107 lghi %r14,\savearea
108 jz stack_overflow
109 #endif
110 .endm
111
112 .macro SWITCH_ASYNC savearea,stack,shift
113 tmhh %r8,0x0001 # interrupting from user ?
114 jnz 1f
115 lgr %r14,%r9
116 slg %r14,BASED(.Lcritical_start)
117 clg %r14,BASED(.Lcritical_length)
118 jhe 0f
119 lghi %r11,\savearea # inside critical section, do cleanup
120 brasl %r14,cleanup_critical
121 tmhh %r8,0x0001 # retest problem state after cleanup
122 jnz 1f
123 0: lg %r14,\stack # are we already on the target stack?
124 slgr %r14,%r15
125 srag %r14,%r14,\shift
126 jnz 1f
127 CHECK_STACK 1<<\shift,\savearea
128 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
129 j 2f
130 1: lg %r15,\stack # load target stack
131 2: la %r11,STACK_FRAME_OVERHEAD(%r15)
132 .endm
133
134 .macro UPDATE_VTIME scratch,enter_timer
135 lg \scratch,__LC_EXIT_TIMER
136 slg \scratch,\enter_timer
137 alg \scratch,__LC_USER_TIMER
138 stg \scratch,__LC_USER_TIMER
139 lg \scratch,__LC_LAST_UPDATE_TIMER
140 slg \scratch,__LC_EXIT_TIMER
141 alg \scratch,__LC_SYSTEM_TIMER
142 stg \scratch,__LC_SYSTEM_TIMER
143 mvc __LC_LAST_UPDATE_TIMER(8),\enter_timer
144 .endm
145
146 .macro LAST_BREAK scratch
147 srag \scratch,%r10,23
148 jz .+10
149 stg %r10,__TI_last_break(%r12)
150 .endm
151
152 .macro REENABLE_IRQS
153 stg %r8,__LC_RETURN_PSW
154 ni __LC_RETURN_PSW,0xbf
155 ssm __LC_RETURN_PSW
156 .endm
157
158 .macro STCK savearea
159 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
160 .insn s,0xb27c0000,\savearea # store clock fast
161 #else
162 .insn s,0xb2050000,\savearea # store clock
163 #endif
164 .endm
165
166 .section .kprobes.text, "ax"
167
168 /*
169 * Scheduler resume function, called by switch_to
170 * gpr2 = (task_struct *) prev
171 * gpr3 = (task_struct *) next
172 * Returns:
173 * gpr2 = prev
174 */
175 ENTRY(__switch_to)
176 stmg %r6,%r15,__SF_GPRS(%r15) # store gprs of prev task
177 stg %r15,__THREAD_ksp(%r2) # store kernel stack of prev
178 lg %r4,__THREAD_info(%r2) # get thread_info of prev
179 lg %r5,__THREAD_info(%r3) # get thread_info of next
180 lgr %r15,%r5
181 aghi %r15,STACK_INIT # end of kernel stack of next
182 stg %r3,__LC_CURRENT # store task struct of next
183 stg %r5,__LC_THREAD_INFO # store thread info of next
184 stg %r15,__LC_KERNEL_STACK # store end of kernel stack
185 lctl %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
186 mvc __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
187 lg %r15,__THREAD_ksp(%r3) # load kernel stack of next
188 tm __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
189 jz 0f
190 ni __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
191 oi __TI_flags+7(%r5),_TIF_MCCK_PENDING # set it in next
192 0: lmg %r6,%r15,__SF_GPRS(%r15) # load gprs of next task
193 br %r14
194
195 __critical_start:
196 /*
197 * SVC interrupt handler routine. System calls are synchronous events and
198 * are executed with interrupts enabled.
199 */
200
201 ENTRY(system_call)
202 stpt __LC_SYNC_ENTER_TIMER
203 sysc_stmg:
204 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
205 lg %r10,__LC_LAST_BREAK
206 lg %r12,__LC_THREAD_INFO
207 sysc_per:
208 lg %r15,__LC_KERNEL_STACK
209 la %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
210 sysc_vtime:
211 UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
212 LAST_BREAK %r13
213 stmg %r0,%r7,__PT_R0(%r11)
214 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
215 mvc __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
216 mvc __PT_INT_CODE(4,%r11),__LC_SVC_ILC
217 sysc_do_svc:
218 oi __TI_flags+7(%r12),_TIF_SYSCALL
219 lg %r10,__TI_sysc_table(%r12) # address of system call table
220 llgh %r8,__PT_INT_CODE+2(%r11)
221 slag %r8,%r8,2 # shift and test for svc 0
222 jnz sysc_nr_ok
223 # svc 0: system call number in %r1
224 llgfr %r1,%r1 # clear high word in r1
225 cghi %r1,NR_syscalls
226 jnl sysc_nr_ok
227 sth %r1,__PT_INT_CODE+2(%r11)
228 slag %r8,%r1,2
229 sysc_nr_ok:
230 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
231 stg %r2,__PT_ORIG_GPR2(%r11)
232 stg %r7,STACK_FRAME_OVERHEAD(%r15)
233 lgf %r9,0(%r8,%r10) # get system call add.
234 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
235 jnz sysc_tracesys
236 basr %r14,%r9 # call sys_xxxx
237 stg %r2,__PT_R2(%r11) # store return value
238
239 sysc_return:
240 LOCKDEP_SYS_EXIT
241 sysc_tif:
242 tm __PT_PSW+1(%r11),0x01 # returning to user ?
243 jno sysc_restore
244 tm __TI_flags+7(%r12),_TIF_WORK_SVC
245 jnz sysc_work # check for work
246 ni __TI_flags+7(%r12),255-_TIF_SYSCALL
247 sysc_restore:
248 lg %r14,__LC_VDSO_PER_CPU
249 lmg %r0,%r10,__PT_R0(%r11)
250 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
251 stpt __LC_EXIT_TIMER
252 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
253 lmg %r11,%r15,__PT_R11(%r11)
254 lpswe __LC_RETURN_PSW
255 sysc_done:
256
257 #
258 # One of the work bits is on. Find out which one.
259 #
260 sysc_work:
261 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
262 jo sysc_mcck_pending
263 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
264 jo sysc_reschedule
265 tm __TI_flags+7(%r12),_TIF_PER_TRAP
266 jo sysc_singlestep
267 tm __TI_flags+7(%r12),_TIF_SIGPENDING
268 jo sysc_sigpending
269 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
270 jo sysc_notify_resume
271 j sysc_return # beware of critical section cleanup
272
273 #
274 # _TIF_NEED_RESCHED is set, call schedule
275 #
276 sysc_reschedule:
277 larl %r14,sysc_return
278 jg schedule
279
280 #
281 # _TIF_MCCK_PENDING is set, call handler
282 #
283 sysc_mcck_pending:
284 larl %r14,sysc_return
285 jg s390_handle_mcck # TIF bit will be cleared by handler
286
287 #
288 # _TIF_SIGPENDING is set, call do_signal
289 #
290 sysc_sigpending:
291 lgr %r2,%r11 # pass pointer to pt_regs
292 brasl %r14,do_signal
293 tm __TI_flags+7(%r12),_TIF_SYSCALL
294 jno sysc_return
295 lmg %r2,%r7,__PT_R2(%r11) # load svc arguments
296 lghi %r8,0 # svc 0 returns -ENOSYS
297 llgh %r1,__PT_INT_CODE+2(%r11) # load new svc number
298 cghi %r1,NR_syscalls
299 jnl sysc_nr_ok # invalid svc number -> do svc 0
300 slag %r8,%r1,2
301 j sysc_nr_ok # restart svc
302
303 #
304 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
305 #
306 sysc_notify_resume:
307 lgr %r2,%r11 # pass pointer to pt_regs
308 larl %r14,sysc_return
309 jg do_notify_resume
310
311 #
312 # _TIF_PER_TRAP is set, call do_per_trap
313 #
314 sysc_singlestep:
315 ni __TI_flags+7(%r12),255-_TIF_PER_TRAP
316 lgr %r2,%r11 # pass pointer to pt_regs
317 larl %r14,sysc_return
318 jg do_per_trap
319
320 #
321 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
322 # and after the system call
323 #
324 sysc_tracesys:
325 lgr %r2,%r11 # pass pointer to pt_regs
326 la %r3,0
327 llgh %r0,__PT_INT_CODE+2(%r11)
328 stg %r0,__PT_R2(%r11)
329 brasl %r14,do_syscall_trace_enter
330 lghi %r0,NR_syscalls
331 clgr %r0,%r2
332 jnh sysc_tracenogo
333 sllg %r8,%r2,2
334 lgf %r9,0(%r8,%r10)
335 sysc_tracego:
336 lmg %r3,%r7,__PT_R3(%r11)
337 stg %r7,STACK_FRAME_OVERHEAD(%r15)
338 lg %r2,__PT_ORIG_GPR2(%r11)
339 basr %r14,%r9 # call sys_xxx
340 stg %r2,__PT_R2(%r11) # store return value
341 sysc_tracenogo:
342 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
343 jz sysc_return
344 lgr %r2,%r11 # pass pointer to pt_regs
345 larl %r14,sysc_return
346 jg do_syscall_trace_exit
347
348 #
349 # a new process exits the kernel with ret_from_fork
350 #
351 ENTRY(ret_from_fork)
352 la %r11,STACK_FRAME_OVERHEAD(%r15)
353 lg %r12,__LC_THREAD_INFO
354 brasl %r14,schedule_tail
355 TRACE_IRQS_ON
356 ssm __LC_SVC_NEW_PSW # reenable interrupts
357 tm __PT_PSW+1(%r11),0x01 # forking a kernel thread ?
358 jne sysc_tracenogo
359 # it's a kernel thread
360 lmg %r9,%r10,__PT_R9(%r11) # load gprs
361 ENTRY(kernel_thread_starter)
362 la %r2,0(%r10)
363 basr %r14,%r9
364 j sysc_tracenogo
365
366 /*
367 * Program check handler routine
368 */
369
370 ENTRY(pgm_check_handler)
371 stpt __LC_SYNC_ENTER_TIMER
372 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
373 lg %r10,__LC_LAST_BREAK
374 lg %r12,__LC_THREAD_INFO
375 larl %r13,system_call
376 lmg %r8,%r9,__LC_PGM_OLD_PSW
377 HANDLE_SIE_INTERCEPT %r14,1
378 tmhh %r8,0x0001 # test problem state bit
379 jnz 1f # -> fault in user space
380 tmhh %r8,0x4000 # PER bit set in old PSW ?
381 jnz 0f # -> enabled, can't be a double fault
382 tm __LC_PGM_ILC+3,0x80 # check for per exception
383 jnz pgm_svcper # -> single stepped svc
384 0: CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
385 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
386 j 2f
387 1: UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
388 LAST_BREAK %r14
389 lg %r15,__LC_KERNEL_STACK
390 lg %r14,__TI_task(%r12)
391 lghi %r13,__LC_PGM_TDB
392 tm __LC_PGM_ILC+2,0x02 # check for transaction abort
393 jz 2f
394 mvc __THREAD_trap_tdb(256,%r14),0(%r13)
395 2: la %r11,STACK_FRAME_OVERHEAD(%r15)
396 stmg %r0,%r7,__PT_R0(%r11)
397 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
398 stmg %r8,%r9,__PT_PSW(%r11)
399 mvc __PT_INT_CODE(4,%r11),__LC_PGM_ILC
400 mvc __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
401 stg %r10,__PT_ARGS(%r11)
402 tm __LC_PGM_ILC+3,0x80 # check for per exception
403 jz 0f
404 tmhh %r8,0x0001 # kernel per event ?
405 jz pgm_kprobe
406 oi __TI_flags+7(%r12),_TIF_PER_TRAP
407 mvc __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
408 mvc __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
409 mvc __THREAD_per_paid(1,%r14),__LC_PER_PAID
410 0: REENABLE_IRQS
411 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
412 larl %r1,pgm_check_table
413 llgh %r10,__PT_INT_CODE+2(%r11)
414 nill %r10,0x007f
415 sll %r10,2
416 je sysc_return
417 lgf %r1,0(%r10,%r1) # load address of handler routine
418 lgr %r2,%r11 # pass pointer to pt_regs
419 basr %r14,%r1 # branch to interrupt-handler
420 j sysc_return
421
422 #
423 # PER event in supervisor state, must be kprobes
424 #
425 pgm_kprobe:
426 REENABLE_IRQS
427 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
428 lgr %r2,%r11 # pass pointer to pt_regs
429 brasl %r14,do_per_trap
430 j sysc_return
431
432 #
433 # single stepped system call
434 #
435 pgm_svcper:
436 oi __TI_flags+7(%r12),_TIF_PER_TRAP
437 mvc __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
438 larl %r14,sysc_per
439 stg %r14,__LC_RETURN_PSW+8
440 lpswe __LC_RETURN_PSW # branch to sysc_per and enable irqs
441
442 /*
443 * IO interrupt handler routine
444 */
445 ENTRY(io_int_handler)
446 STCK __LC_INT_CLOCK
447 stpt __LC_ASYNC_ENTER_TIMER
448 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
449 lg %r10,__LC_LAST_BREAK
450 lg %r12,__LC_THREAD_INFO
451 larl %r13,system_call
452 lmg %r8,%r9,__LC_IO_OLD_PSW
453 HANDLE_SIE_INTERCEPT %r14,0
454 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
455 tmhh %r8,0x0001 # interrupting from user?
456 jz io_skip
457 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
458 LAST_BREAK %r14
459 io_skip:
460 stmg %r0,%r7,__PT_R0(%r11)
461 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
462 stmg %r8,%r9,__PT_PSW(%r11)
463 TRACE_IRQS_OFF
464 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
465 lgr %r2,%r11 # pass pointer to pt_regs
466 brasl %r14,do_IRQ
467 io_return:
468 LOCKDEP_SYS_EXIT
469 TRACE_IRQS_ON
470 io_tif:
471 tm __TI_flags+7(%r12),_TIF_WORK_INT
472 jnz io_work # there is work to do (signals etc.)
473 io_restore:
474 lg %r14,__LC_VDSO_PER_CPU
475 lmg %r0,%r10,__PT_R0(%r11)
476 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
477 stpt __LC_EXIT_TIMER
478 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
479 lmg %r11,%r15,__PT_R11(%r11)
480 lpswe __LC_RETURN_PSW
481 io_done:
482
483 #
484 # There is work todo, find out in which context we have been interrupted:
485 # 1) if we return to user space we can do all _TIF_WORK_INT work
486 # 2) if we return to kernel code and kvm is enabled check if we need to
487 # modify the psw to leave SIE
488 # 3) if we return to kernel code and preemptive scheduling is enabled check
489 # the preemption counter and if it is zero call preempt_schedule_irq
490 # Before any work can be done, a switch to the kernel stack is required.
491 #
492 io_work:
493 tm __PT_PSW+1(%r11),0x01 # returning to user ?
494 jo io_work_user # yes -> do resched & signal
495 #ifdef CONFIG_PREEMPT
496 # check for preemptive scheduling
497 icm %r0,15,__TI_precount(%r12)
498 jnz io_restore # preemption is disabled
499 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
500 jno io_restore
501 # switch to kernel stack
502 lg %r1,__PT_R15(%r11)
503 aghi %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
504 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
505 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
506 la %r11,STACK_FRAME_OVERHEAD(%r1)
507 lgr %r15,%r1
508 # TRACE_IRQS_ON already done at io_return, call
509 # TRACE_IRQS_OFF to keep things symmetrical
510 TRACE_IRQS_OFF
511 brasl %r14,preempt_schedule_irq
512 j io_return
513 #else
514 j io_restore
515 #endif
516
517 #
518 # Need to do work before returning to userspace, switch to kernel stack
519 #
520 io_work_user:
521 lg %r1,__LC_KERNEL_STACK
522 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
523 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
524 la %r11,STACK_FRAME_OVERHEAD(%r1)
525 lgr %r15,%r1
526
527 #
528 # One of the work bits is on. Find out which one.
529 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
530 # and _TIF_MCCK_PENDING
531 #
532 io_work_tif:
533 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
534 jo io_mcck_pending
535 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
536 jo io_reschedule
537 tm __TI_flags+7(%r12),_TIF_SIGPENDING
538 jo io_sigpending
539 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
540 jo io_notify_resume
541 j io_return # beware of critical section cleanup
542
543 #
544 # _TIF_MCCK_PENDING is set, call handler
545 #
546 io_mcck_pending:
547 # TRACE_IRQS_ON already done at io_return
548 brasl %r14,s390_handle_mcck # TIF bit will be cleared by handler
549 TRACE_IRQS_OFF
550 j io_return
551
552 #
553 # _TIF_NEED_RESCHED is set, call schedule
554 #
555 io_reschedule:
556 # TRACE_IRQS_ON already done at io_return
557 ssm __LC_SVC_NEW_PSW # reenable interrupts
558 brasl %r14,schedule # call scheduler
559 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
560 TRACE_IRQS_OFF
561 j io_return
562
563 #
564 # _TIF_SIGPENDING or is set, call do_signal
565 #
566 io_sigpending:
567 # TRACE_IRQS_ON already done at io_return
568 ssm __LC_SVC_NEW_PSW # reenable interrupts
569 lgr %r2,%r11 # pass pointer to pt_regs
570 brasl %r14,do_signal
571 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
572 TRACE_IRQS_OFF
573 j io_return
574
575 #
576 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
577 #
578 io_notify_resume:
579 # TRACE_IRQS_ON already done at io_return
580 ssm __LC_SVC_NEW_PSW # reenable interrupts
581 lgr %r2,%r11 # pass pointer to pt_regs
582 brasl %r14,do_notify_resume
583 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
584 TRACE_IRQS_OFF
585 j io_return
586
587 /*
588 * External interrupt handler routine
589 */
590 ENTRY(ext_int_handler)
591 STCK __LC_INT_CLOCK
592 stpt __LC_ASYNC_ENTER_TIMER
593 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
594 lg %r10,__LC_LAST_BREAK
595 lg %r12,__LC_THREAD_INFO
596 larl %r13,system_call
597 lmg %r8,%r9,__LC_EXT_OLD_PSW
598 HANDLE_SIE_INTERCEPT %r14,0
599 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
600 tmhh %r8,0x0001 # interrupting from user ?
601 jz ext_skip
602 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
603 LAST_BREAK %r14
604 ext_skip:
605 stmg %r0,%r7,__PT_R0(%r11)
606 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
607 stmg %r8,%r9,__PT_PSW(%r11)
608 TRACE_IRQS_OFF
609 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
610 lghi %r1,4096
611 lgr %r2,%r11 # pass pointer to pt_regs
612 llgf %r3,__LC_EXT_CPU_ADDR # get cpu address + interruption code
613 llgf %r4,__LC_EXT_PARAMS # get external parameter
614 lg %r5,__LC_EXT_PARAMS2-4096(%r1) # get 64 bit external parameter
615 brasl %r14,do_extint
616 j io_return
617
618 /*
619 * Load idle PSW. The second "half" of this function is in cleanup_idle.
620 */
621 ENTRY(psw_idle)
622 stg %r3,__SF_EMPTY(%r15)
623 larl %r1,psw_idle_lpsw+4
624 stg %r1,__SF_EMPTY+8(%r15)
625 STCK __CLOCK_IDLE_ENTER(%r2)
626 stpt __TIMER_IDLE_ENTER(%r2)
627 psw_idle_lpsw:
628 lpswe __SF_EMPTY(%r15)
629 br %r14
630 psw_idle_end:
631
632 __critical_end:
633
634 /*
635 * Machine check handler routines
636 */
637 ENTRY(mcck_int_handler)
638 STCK __LC_MCCK_CLOCK
639 la %r1,4095 # revalidate r1
640 spt __LC_CPU_TIMER_SAVE_AREA-4095(%r1) # revalidate cpu timer
641 lmg %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
642 lg %r10,__LC_LAST_BREAK
643 lg %r12,__LC_THREAD_INFO
644 larl %r13,system_call
645 lmg %r8,%r9,__LC_MCK_OLD_PSW
646 HANDLE_SIE_INTERCEPT %r14,0
647 tm __LC_MCCK_CODE,0x80 # system damage?
648 jo mcck_panic # yes -> rest of mcck code invalid
649 lghi %r14,__LC_CPU_TIMER_SAVE_AREA
650 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
651 tm __LC_MCCK_CODE+5,0x02 # stored cpu timer value valid?
652 jo 3f
653 la %r14,__LC_SYNC_ENTER_TIMER
654 clc 0(8,%r14),__LC_ASYNC_ENTER_TIMER
655 jl 0f
656 la %r14,__LC_ASYNC_ENTER_TIMER
657 0: clc 0(8,%r14),__LC_EXIT_TIMER
658 jl 1f
659 la %r14,__LC_EXIT_TIMER
660 1: clc 0(8,%r14),__LC_LAST_UPDATE_TIMER
661 jl 2f
662 la %r14,__LC_LAST_UPDATE_TIMER
663 2: spt 0(%r14)
664 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
665 3: tm __LC_MCCK_CODE+2,0x09 # mwp + ia of old psw valid?
666 jno mcck_panic # no -> skip cleanup critical
667 SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
668 tm %r8,0x0001 # interrupting from user ?
669 jz mcck_skip
670 UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
671 LAST_BREAK %r14
672 mcck_skip:
673 lghi %r14,__LC_GPREGS_SAVE_AREA+64
674 stmg %r0,%r7,__PT_R0(%r11)
675 mvc __PT_R8(64,%r11),0(%r14)
676 stmg %r8,%r9,__PT_PSW(%r11)
677 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
678 lgr %r2,%r11 # pass pointer to pt_regs
679 brasl %r14,s390_do_machine_check
680 tm __PT_PSW+1(%r11),0x01 # returning to user ?
681 jno mcck_return
682 lg %r1,__LC_KERNEL_STACK # switch to kernel stack
683 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
684 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
685 la %r11,STACK_FRAME_OVERHEAD(%r1)
686 lgr %r15,%r1
687 ssm __LC_PGM_NEW_PSW # turn dat on, keep irqs off
688 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
689 jno mcck_return
690 TRACE_IRQS_OFF
691 brasl %r14,s390_handle_mcck
692 TRACE_IRQS_ON
693 mcck_return:
694 lg %r14,__LC_VDSO_PER_CPU
695 lmg %r0,%r10,__PT_R0(%r11)
696 mvc __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
697 tm __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
698 jno 0f
699 stpt __LC_EXIT_TIMER
700 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
701 0: lmg %r11,%r15,__PT_R11(%r11)
702 lpswe __LC_RETURN_MCCK_PSW
703
704 mcck_panic:
705 lg %r14,__LC_PANIC_STACK
706 slgr %r14,%r15
707 srag %r14,%r14,PAGE_SHIFT
708 jz 0f
709 lg %r15,__LC_PANIC_STACK
710 0: aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
711 j mcck_skip
712
713 #
714 # PSW restart interrupt handler
715 #
716 ENTRY(restart_int_handler)
717 stg %r15,__LC_SAVE_AREA_RESTART
718 lg %r15,__LC_RESTART_STACK
719 aghi %r15,-__PT_SIZE # create pt_regs on stack
720 xc 0(__PT_SIZE,%r15),0(%r15)
721 stmg %r0,%r14,__PT_R0(%r15)
722 mvc __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
723 mvc __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
724 aghi %r15,-STACK_FRAME_OVERHEAD # create stack frame on stack
725 xc 0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
726 lg %r1,__LC_RESTART_FN # load fn, parm & source cpu
727 lg %r2,__LC_RESTART_DATA
728 lg %r3,__LC_RESTART_SOURCE
729 ltgr %r3,%r3 # test source cpu address
730 jm 1f # negative -> skip source stop
731 0: sigp %r4,%r3,SIGP_SENSE # sigp sense to source cpu
732 brc 10,0b # wait for status stored
733 1: basr %r14,%r1 # call function
734 stap __SF_EMPTY(%r15) # store cpu address
735 llgh %r3,__SF_EMPTY(%r15)
736 2: sigp %r4,%r3,SIGP_STOP # sigp stop to current cpu
737 brc 2,2b
738 3: j 3b
739
740 .section .kprobes.text, "ax"
741
742 #ifdef CONFIG_CHECK_STACK
743 /*
744 * The synchronous or the asynchronous stack overflowed. We are dead.
745 * No need to properly save the registers, we are going to panic anyway.
746 * Setup a pt_regs so that show_trace can provide a good call trace.
747 */
748 stack_overflow:
749 lg %r15,__LC_PANIC_STACK # change to panic stack
750 la %r11,STACK_FRAME_OVERHEAD(%r15)
751 stmg %r0,%r7,__PT_R0(%r11)
752 stmg %r8,%r9,__PT_PSW(%r11)
753 mvc __PT_R8(64,%r11),0(%r14)
754 stg %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
755 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
756 lgr %r2,%r11 # pass pointer to pt_regs
757 jg kernel_stack_overflow
758 #endif
759
760 .align 8
761 cleanup_table:
762 .quad system_call
763 .quad sysc_do_svc
764 .quad sysc_tif
765 .quad sysc_restore
766 .quad sysc_done
767 .quad io_tif
768 .quad io_restore
769 .quad io_done
770 .quad psw_idle
771 .quad psw_idle_end
772
773 cleanup_critical:
774 clg %r9,BASED(cleanup_table) # system_call
775 jl 0f
776 clg %r9,BASED(cleanup_table+8) # sysc_do_svc
777 jl cleanup_system_call
778 clg %r9,BASED(cleanup_table+16) # sysc_tif
779 jl 0f
780 clg %r9,BASED(cleanup_table+24) # sysc_restore
781 jl cleanup_sysc_tif
782 clg %r9,BASED(cleanup_table+32) # sysc_done
783 jl cleanup_sysc_restore
784 clg %r9,BASED(cleanup_table+40) # io_tif
785 jl 0f
786 clg %r9,BASED(cleanup_table+48) # io_restore
787 jl cleanup_io_tif
788 clg %r9,BASED(cleanup_table+56) # io_done
789 jl cleanup_io_restore
790 clg %r9,BASED(cleanup_table+64) # psw_idle
791 jl 0f
792 clg %r9,BASED(cleanup_table+72) # psw_idle_end
793 jl cleanup_idle
794 0: br %r14
795
796
797 cleanup_system_call:
798 # check if stpt has been executed
799 clg %r9,BASED(cleanup_system_call_insn)
800 jh 0f
801 mvc __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
802 cghi %r11,__LC_SAVE_AREA_ASYNC
803 je 0f
804 mvc __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
805 0: # check if stmg has been executed
806 clg %r9,BASED(cleanup_system_call_insn+8)
807 jh 0f
808 mvc __LC_SAVE_AREA_SYNC(64),0(%r11)
809 0: # check if base register setup + TIF bit load has been done
810 clg %r9,BASED(cleanup_system_call_insn+16)
811 jhe 0f
812 # set up saved registers r10 and r12
813 stg %r10,16(%r11) # r10 last break
814 stg %r12,32(%r11) # r12 thread-info pointer
815 0: # check if the user time update has been done
816 clg %r9,BASED(cleanup_system_call_insn+24)
817 jh 0f
818 lg %r15,__LC_EXIT_TIMER
819 slg %r15,__LC_SYNC_ENTER_TIMER
820 alg %r15,__LC_USER_TIMER
821 stg %r15,__LC_USER_TIMER
822 0: # check if the system time update has been done
823 clg %r9,BASED(cleanup_system_call_insn+32)
824 jh 0f
825 lg %r15,__LC_LAST_UPDATE_TIMER
826 slg %r15,__LC_EXIT_TIMER
827 alg %r15,__LC_SYSTEM_TIMER
828 stg %r15,__LC_SYSTEM_TIMER
829 0: # update accounting time stamp
830 mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
831 # do LAST_BREAK
832 lg %r9,16(%r11)
833 srag %r9,%r9,23
834 jz 0f
835 mvc __TI_last_break(8,%r12),16(%r11)
836 0: # set up saved register r11
837 lg %r15,__LC_KERNEL_STACK
838 la %r9,STACK_FRAME_OVERHEAD(%r15)
839 stg %r9,24(%r11) # r11 pt_regs pointer
840 # fill pt_regs
841 mvc __PT_R8(64,%r9),__LC_SAVE_AREA_SYNC
842 stmg %r0,%r7,__PT_R0(%r9)
843 mvc __PT_PSW(16,%r9),__LC_SVC_OLD_PSW
844 mvc __PT_INT_CODE(4,%r9),__LC_SVC_ILC
845 # setup saved register r15
846 stg %r15,56(%r11) # r15 stack pointer
847 # set new psw address and exit
848 larl %r9,sysc_do_svc
849 br %r14
850 cleanup_system_call_insn:
851 .quad system_call
852 .quad sysc_stmg
853 .quad sysc_per
854 .quad sysc_vtime+18
855 .quad sysc_vtime+42
856
857 cleanup_sysc_tif:
858 larl %r9,sysc_tif
859 br %r14
860
861 cleanup_sysc_restore:
862 clg %r9,BASED(cleanup_sysc_restore_insn)
863 je 0f
864 lg %r9,24(%r11) # get saved pointer to pt_regs
865 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
866 mvc 0(64,%r11),__PT_R8(%r9)
867 lmg %r0,%r7,__PT_R0(%r9)
868 0: lmg %r8,%r9,__LC_RETURN_PSW
869 br %r14
870 cleanup_sysc_restore_insn:
871 .quad sysc_done - 4
872
873 cleanup_io_tif:
874 larl %r9,io_tif
875 br %r14
876
877 cleanup_io_restore:
878 clg %r9,BASED(cleanup_io_restore_insn)
879 je 0f
880 lg %r9,24(%r11) # get saved r11 pointer to pt_regs
881 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
882 mvc 0(64,%r11),__PT_R8(%r9)
883 lmg %r0,%r7,__PT_R0(%r9)
884 0: lmg %r8,%r9,__LC_RETURN_PSW
885 br %r14
886 cleanup_io_restore_insn:
887 .quad io_done - 4
888
889 cleanup_idle:
890 # copy interrupt clock & cpu timer
891 mvc __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
892 mvc __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
893 cghi %r11,__LC_SAVE_AREA_ASYNC
894 je 0f
895 mvc __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
896 mvc __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
897 0: # check if stck & stpt have been executed
898 clg %r9,BASED(cleanup_idle_insn)
899 jhe 1f
900 mvc __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
901 mvc __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
902 1: # account system time going idle
903 lg %r9,__LC_STEAL_TIMER
904 alg %r9,__CLOCK_IDLE_ENTER(%r2)
905 slg %r9,__LC_LAST_UPDATE_CLOCK
906 stg %r9,__LC_STEAL_TIMER
907 mvc __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
908 lg %r9,__LC_SYSTEM_TIMER
909 alg %r9,__LC_LAST_UPDATE_TIMER
910 slg %r9,__TIMER_IDLE_ENTER(%r2)
911 stg %r9,__LC_SYSTEM_TIMER
912 mvc __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
913 # prepare return psw
914 nihh %r8,0xfffd # clear wait state bit
915 lg %r9,48(%r11) # return from psw_idle
916 br %r14
917 cleanup_idle_insn:
918 .quad psw_idle_lpsw
919
920 /*
921 * Integer constants
922 */
923 .align 8
924 .Lcritical_start:
925 .quad __critical_start
926 .Lcritical_length:
927 .quad __critical_end - __critical_start
928
929
930 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
931 /*
932 * sie64a calling convention:
933 * %r2 pointer to sie control block
934 * %r3 guest register save area
935 */
936 ENTRY(sie64a)
937 stmg %r6,%r14,__SF_GPRS(%r15) # save kernel registers
938 stg %r2,__SF_EMPTY(%r15) # save control block pointer
939 stg %r3,__SF_EMPTY+8(%r15) # save guest register save area
940 xc __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
941 lmg %r0,%r13,0(%r3) # load guest gprs 0-13
942 # some program checks are suppressing. C code (e.g. do_protection_exception)
943 # will rewind the PSW by the ILC, which is 4 bytes in case of SIE. Other
944 # instructions in the sie_loop should not cause program interrupts. So
945 # lets use a nop (47 00 00 00) as a landing pad.
946 # See also HANDLE_SIE_INTERCEPT
947 rewind_pad:
948 nop 0
949 sie_loop:
950 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
951 tm __TI_flags+7(%r14),_TIF_EXIT_SIE
952 jnz sie_exit
953 lg %r14,__LC_GMAP # get gmap pointer
954 ltgr %r14,%r14
955 jz sie_gmap
956 lctlg %c1,%c1,__GMAP_ASCE(%r14) # load primary asce
957 sie_gmap:
958 lg %r14,__SF_EMPTY(%r15) # get control block pointer
959 LPP __SF_EMPTY(%r15) # set guest id
960 sie 0(%r14)
961 sie_done:
962 LPP __SF_EMPTY+16(%r15) # set host id
963 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
964 sie_exit:
965 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
966 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
967 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
968 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
969 lghi %r2,0
970 br %r14
971 sie_fault:
972 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
973 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
974 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
975 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
976 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
977 lghi %r2,-EFAULT
978 br %r14
979
980 .align 8
981 .Lsie_loop:
982 .quad sie_loop
983 .Lsie_length:
984 .quad sie_done - sie_loop
985 .Lhost_id:
986 .quad 0
987
988 EX_TABLE(rewind_pad,sie_fault)
989 EX_TABLE(sie_loop,sie_fault)
990 #endif
991
992 .section .rodata, "a"
993 #define SYSCALL(esa,esame,emu) .long esame
994 .globl sys_call_table
995 sys_call_table:
996 #include "syscalls.S"
997 #undef SYSCALL
998
999 #ifdef CONFIG_COMPAT
1000
1001 #define SYSCALL(esa,esame,emu) .long emu
1002 .globl sys_call_table_emu
1003 sys_call_table_emu:
1004 #include "syscalls.S"
1005 #undef SYSCALL
1006 #endif