arch/blackfin/lib/umodsi3.S

   1 /*
   2  * File:         arch/blackfin/lib/umodsi3.S
   3  * Based on:
   4  * Author:
   5  *
   6  * Created:
   7  * Description:  libgcc1 routines for Blackfin 5xx
   8  *
   9  * Modified:
  10  *               Copyright 2004-2006 Analog Devices Inc.
  11  *
  12  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
  13  *
  14  * This program is free software; you can redistribute it and/or modify
  15  * it under the terms of the GNU General Public License as published by
  16  * the Free Software Foundation; either version 2 of the License, or
  17  * (at your option) any later version.
  18  *
  19  * This program is distributed in the hope that it will be useful,
  20  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  21  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22  * GNU General Public License for more details.
  23  *
  24  * You should have received a copy of the GNU General Public License
  25  * along with this program; if not, see the file COPYING, or write
  26  * to the Free Software Foundation, Inc.,
  27  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  28  */
  29
  30 #ifdef CONFIG_ARITHMETIC_OPS_L1
  31 .section .l1.text
  32 #else
  33 .text
  34 #endif
  35
  36 .extern ___udivsi3;
  37 .globl  ___umodsi3
  38 ___umodsi3:
  39
  40         CC=R0==0;
  41         IF CC JUMP .LRETURN_R0;         /* Return 0, if NR == 0 */
  42         CC= R1==0;
  43         IF CC JUMP .LRETURN_ZERO_VAL;   /* Return 0, if DR == 0 */
  44         CC=R0==R1;
  45         IF CC JUMP .LRETURN_ZERO_VAL;   /* Return 0, if NR == DR */
  46         CC = R1 == 1;
  47         IF CC JUMP .LRETURN_ZERO_VAL;   /* Return 0, if  DR == 1 */
  48         CC = R0<R1 (IU);
  49         IF CC JUMP .LRETURN_R0;         /* Return dividend (R0),IF NR<DR */
  50
  51         [--SP] = (R7:6);                /* Push registers and */
  52         [--SP] = RETS;                  /* Return address */
  53         R7 = R0;                        /* Copy of R0 */
  54         R6 = R1;
  55         SP += -12;                      /* Should always provide this space */
  56         CALL ___udivsi3;                /* Compute unsigned quotient using ___udiv32()*/
  57         SP += 12;
  58         R0 *= R6;                       /* Quotient * divisor */
  59         R0 = R7 - R0;                   /* Dividend - (quotient * divisor) */
  60         RETS = [SP++];                  /* Pop return address */
  61         ( R7:6) = [SP++];               /* And registers */
  62         RTS;                            /* Return remainder */
  63 .LRETURN_ZERO_VAL:
  64         R0 = 0;
  65 .LRETURN_R0:
  66         RTS;