arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <mach/entry-macro.S>
  14 #include <asm/unwind.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26  UNWIND(.fnstart        )
  27  UNWIND(.cantunwind     )
  28         disable_irq                             @ disable interrupts
  29         ldr     r1, [tsk, #TI_FLAGS]
  30         tst     r1, #_TIF_WORK_MASK
  31         bne     fast_work_pending
  32 #if defined(CONFIG_IRQSOFF_TRACER)
  33         asm_trace_hardirqs_on
  34 #endif
  35
  36         /* perform architecture specific actions before user return */
  37         arch_ret_to_user r1, lr
  38
  39         restore_user_regs fast = 1, offset = S_OFF
  40  UNWIND(.fnend          )
  41
  42 /*
  43  * Ok, we need to do extra processing, enter the slow path.
  44  */
  45 fast_work_pending:
  46         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  47 work_pending:
  48         tst     r1, #_TIF_NEED_RESCHED
  49         bne     work_resched
  50         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
  51         beq     no_work_pending
  52         mov     r0, sp                          @ 'regs'
  53         mov     r2, why                         @ 'syscall'
  54         tst     r1, #_TIF_SIGPENDING            @ delivering a signal?
  55         movne   why, #0                         @ prevent further restarts
  56         bl      do_notify_resume
  57         b       ret_slow_syscall                @ Check work again
  58
  59 work_resched:
  60         bl      schedule
  61 /*
  62  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  63  */
  64 ENTRY(ret_to_user)
  65 ret_slow_syscall:
  66         disable_irq                             @ disable interrupts
  67         ldr     r1, [tsk, #TI_FLAGS]
  68         tst     r1, #_TIF_WORK_MASK
  69         bne     work_pending
  70 no_work_pending:
  71 #if defined(CONFIG_IRQSOFF_TRACER)
  72         asm_trace_hardirqs_on
  73 #endif
  74         /* perform architecture specific actions before user return */
  75         arch_ret_to_user r1, lr
  76
  77         restore_user_regs fast = 0, offset = 0
  78 ENDPROC(ret_to_user)
  79
  80 /*
  81  * This is how we return from a fork.
  82  */
  83 ENTRY(ret_from_fork)
  84         bl      schedule_tail
  85         get_thread_info tsk
  86         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  87         mov     why, #1
  88         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  89         beq     ret_slow_syscall
  90         mov     r1, sp
  91         mov     r0, #1                          @ trace exit [IP = 1]
  92         bl      syscall_trace
  93         b       ret_slow_syscall
  94 ENDPROC(ret_from_fork)
  95
  96         .equ NR_syscalls,0
  97 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  98 #include "calls.S"
  99 #undef CALL
 100 #define CALL(x) .long x
 101
 102 #ifdef CONFIG_FUNCTION_TRACER
 103 /*
 104  * When compiling with -pg, gcc inserts a call to the mcount routine at the
 105  * start of every function.  In mcount, apart from the function's address (in
 106  * lr), we need to get hold of the function's caller's address.
 107  *
 108  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 109  *
 110  *      bl      mcount
 111  *
 112  * These versions have the limitation that in order for the mcount routine to
 113  * be able to determine the function's caller's address, an APCS-style frame
 114  * pointer (which is set up with something like the code below) is required.
 115  *
 116  *      mov     ip, sp
 117  *      push    {fp, ip, lr, pc}
 118  *      sub     fp, ip, #4
 119  *
 120  * With EABI, these frame pointers are not available unless -mapcs-frame is
 121  * specified, and if building as Thumb-2, not even then.
 122  *
 123  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 124  * with call sites like:
 125  *
 126  *      push    {lr}
 127  *      bl      __gnu_mcount_nc
 128  *
 129  * With these compilers, frame pointers are not necessary.
 130  *
 131  * mcount can be thought of as a function called in the middle of a subroutine
 132  * call.  As such, it needs to be transparent for both the caller and the
 133  * callee: the original lr needs to be restored when leaving mcount, and no
 134  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 135  * clobber the ip register.  This is OK because the ARM calling convention
 136  * allows it to be clobbered in subroutines and doesn't use it to hold
 137  * parameters.)
 138  *
 139  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 140  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 141  * arch/arm/kernel/ftrace.c).
 142  */
 143
 144 #ifndef CONFIG_OLD_MCOUNT
 145 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 146 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 147 #endif
 148 #endif
 149
 150 .macro __mcount suffix
 151         mcount_enter
 152         ldr     r0, =ftrace_trace_function
 153         ldr     r2, [r0]
 154         adr     r0, .Lftrace_stub
 155         cmp     r0, r2
 156         bne     1f
 157
 158 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 159         ldr     r1, =ftrace_graph_return
 160         ldr     r2, [r1]
 161         cmp     r0, r2
 162         bne     ftrace_graph_caller\suffix
 163
 164         ldr     r1, =ftrace_graph_entry
 165         ldr     r2, [r1]
 166         ldr     r0, =ftrace_graph_entry_stub
 167         cmp     r0, r2
 168         bne     ftrace_graph_caller\suffix
 169 #endif
 170
 171         mcount_exit
 172
 173 1:      mcount_get_lr   r1                      @ lr of instrumented func
 174         mov     r0, lr                          @ instrumented function
 175         sub     r0, r0, #MCOUNT_INSN_SIZE
 176         adr     lr, BSYM(2f)
 177         mov     pc, r2
 178 2:      mcount_exit
 179 .endm
 180
 181 .macro __ftrace_caller suffix
 182         mcount_enter
 183
 184         mcount_get_lr   r1                      @ lr of instrumented func
 185         mov     r0, lr                          @ instrumented function
 186         sub     r0, r0, #MCOUNT_INSN_SIZE
 187
 188         .globl ftrace_call\suffix
 189 ftrace_call\suffix:
 190         bl      ftrace_stub
 191
 192 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 193         .globl ftrace_graph_call\suffix
 194 ftrace_graph_call\suffix:
 195         mov     r0, r0
 196 #endif
 197
 198         mcount_exit
 199 .endm
 200
 201 .macro __ftrace_graph_caller
 202         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
 203 #ifdef CONFIG_DYNAMIC_FTRACE
 204         @ called from __ftrace_caller, saved in mcount_enter
 205         ldr     r1, [sp, #16]           @ instrumented routine (func)
 206 #else
 207         @ called from __mcount, untouched in lr
 208         mov     r1, lr                  @ instrumented routine (func)
 209 #endif
 210         sub     r1, r1, #MCOUNT_INSN_SIZE
 211         mov     r2, fp                  @ frame pointer
 212         bl      prepare_ftrace_return
 213         mcount_exit
 214 .endm
 215
 216 #ifdef CONFIG_OLD_MCOUNT
 217 /*
 218  * mcount
 219  */
 220
 221 .macro mcount_enter
 222         stmdb   sp!, {r0-r3, lr}
 223 .endm
 224
 225 .macro mcount_get_lr reg
 226         ldr     \reg, [fp, #-4]
 227 .endm
 228
 229 .macro mcount_exit
 230         ldr     lr, [fp, #-4]
 231         ldmia   sp!, {r0-r3, pc}
 232 .endm
 233
 234 ENTRY(mcount)
 235 #ifdef CONFIG_DYNAMIC_FTRACE
 236         stmdb   sp!, {lr}
 237         ldr     lr, [fp, #-4]
 238         ldmia   sp!, {pc}
 239 #else
 240         __mcount _old
 241 #endif
 242 ENDPROC(mcount)
 243
 244 #ifdef CONFIG_DYNAMIC_FTRACE
 245 ENTRY(ftrace_caller_old)
 246         __ftrace_caller _old
 247 ENDPROC(ftrace_caller_old)
 248 #endif
 249
 250 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 251 ENTRY(ftrace_graph_caller_old)
 252         __ftrace_graph_caller
 253 ENDPROC(ftrace_graph_caller_old)
 254 #endif
 255
 256 .purgem mcount_enter
 257 .purgem mcount_get_lr
 258 .purgem mcount_exit
 259 #endif
 260
 261 /*
 262  * __gnu_mcount_nc
 263  */
 264
 265 .macro mcount_enter
 266         stmdb   sp!, {r0-r3, lr}
 267 .endm
 268
 269 .macro mcount_get_lr reg
 270         ldr     \reg, [sp, #20]
 271 .endm
 272
 273 .macro mcount_exit
 274         ldmia   sp!, {r0-r3, ip, lr}
 275         mov     pc, ip
 276 .endm
 277
 278 ENTRY(__gnu_mcount_nc)
 279 #ifdef CONFIG_DYNAMIC_FTRACE
 280         mov     ip, lr
 281         ldmia   sp!, {lr}
 282         mov     pc, ip
 283 #else
 284         __mcount
 285 #endif
 286 ENDPROC(__gnu_mcount_nc)
 287
 288 #ifdef CONFIG_DYNAMIC_FTRACE
 289 ENTRY(ftrace_caller)
 290         __ftrace_caller
 291 ENDPROC(ftrace_caller)
 292 #endif
 293
 294 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 295 ENTRY(ftrace_graph_caller)
 296         __ftrace_graph_caller
 297 ENDPROC(ftrace_graph_caller)
 298 #endif
 299
 300 .purgem mcount_enter
 301 .purgem mcount_get_lr
 302 .purgem mcount_exit
 303
 304 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 305         .globl return_to_handler
 306 return_to_handler:
 307         stmdb   sp!, {r0-r3}
 308         mov     r0, fp                  @ frame pointer
 309         bl      ftrace_return_to_handler
 310         mov     lr, r0                  @ r0 has real ret addr
 311         ldmia   sp!, {r0-r3}
 312         mov     pc, lr
 313 #endif
 314
 315 ENTRY(ftrace_stub)
 316 .Lftrace_stub:
 317         mov     pc, lr
 318 ENDPROC(ftrace_stub)
 319
 320 #endif /* CONFIG_FUNCTION_TRACER */
 321
 322 /*=============================================================================
 323  * SWI handler
 324  *-----------------------------------------------------------------------------
 325  */
 326
 327         /* If we're optimising for StrongARM the resulting code won't
 328            run on an ARM7 and we can save a couple of instructions.
 329                                                                 --pb */
 330 #ifdef CONFIG_CPU_ARM710
 331 #define A710(code...) code
 332 .Larm710bug:
 333         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 334         mov     r0, r0
 335         add     sp, sp, #S_FRAME_SIZE
 336         subs    pc, lr, #4
 337 #else
 338 #define A710(code...)
 339 #endif
 340
 341         .align  5
 342 ENTRY(vector_swi)
 343         sub     sp, sp, #S_FRAME_SIZE
 344         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 345  ARM(   add     r8, sp, #S_PC           )
 346  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 347  THUMB( mov     r8, sp                  )
 348  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 349         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 350         str     lr, [sp, #S_PC]                 @ Save calling PC
 351         str     r8, [sp, #S_PSR]                @ Save CPSR
 352         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 353         zero_fp
 354
 355         /*
 356          * Get the system call number.
 357          */
 358
 359 #if defined(CONFIG_OABI_COMPAT)
 360
 361         /*
 362          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 363          * value to determine if it is an EABI or an old ABI call.
 364          */
 365 #ifdef CONFIG_ARM_THUMB
 366         tst     r8, #PSR_T_BIT
 367         movne   r10, #0                         @ no thumb OABI emulation
 368         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 369 #else
 370         ldr     r10, [lr, #-4]                  @ get SWI instruction
 371   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 372   A710( teq     ip, #0x0f000000                                         )
 373   A710( bne     .Larm710bug                                             )
 374 #endif
 375 #ifdef CONFIG_CPU_ENDIAN_BE8
 376         rev     r10, r10                        @ little endian instruction
 377 #endif
 378
 379 #elif defined(CONFIG_AEABI)
 380
 381         /*
 382          * Pure EABI user space always put syscall number into scno (r7).
 383          */
 384   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 385   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 386   A710( teq     ip, #0x0f000000                                         )
 387   A710( bne     .Larm710bug                                             )
 388
 389 #elif defined(CONFIG_ARM_THUMB)
 390
 391         /* Legacy ABI only, possibly thumb mode. */
 392         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 393         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 394         ldreq   scno, [lr, #-4]
 395
 396 #else
 397
 398         /* Legacy ABI only. */
 399         ldr     scno, [lr, #-4]                 @ get SWI instruction
 400   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 401   A710( teq     ip, #0x0f000000                                         )
 402   A710( bne     .Larm710bug                                             )
 403
 404 #endif
 405
 406 #ifdef CONFIG_ALIGNMENT_TRAP
 407         ldr     ip, __cr_alignment
 408         ldr     ip, [ip]
 409         mcr     p15, 0, ip, c1, c0              @ update control register
 410 #endif
 411         enable_irq
 412
 413         get_thread_info tsk
 414         adr     tbl, sys_call_table             @ load syscall table pointer
 415
 416 #if defined(CONFIG_OABI_COMPAT)
 417         /*
 418          * If the swi argument is zero, this is an EABI call and we do nothing.
 419          *
 420          * If this is an old ABI call, get the syscall number into scno and
 421          * get the old ABI syscall table address.
 422          */
 423         bics    r10, r10, #0xff000000
 424         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 425         ldrne   tbl, =sys_oabi_call_table
 426 #elif !defined(CONFIG_AEABI)
 427         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 428         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 429 #endif
 430
 431         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 432         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 433
 434 #ifdef CONFIG_SECCOMP
 435         tst     r10, #_TIF_SECCOMP
 436         beq     1f
 437         mov     r0, scno
 438         bl      __secure_computing
 439         add     r0, sp, #S_R0 + S_OFF           @ pointer to regs
 440         ldmia   r0, {r0 - r3}                   @ have to reload r0 - r3
 441 1:
 442 #endif
 443
 444         tst     r10, #_TIF_SYSCALL_TRACE                @ are we tracing syscalls?
 445         bne     __sys_trace
 446
 447         cmp     scno, #NR_syscalls              @ check upper syscall limit
 448         adr     lr, BSYM(ret_fast_syscall)      @ return address
 449         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 450
 451         add     r1, sp, #S_OFF
 452 2:      mov     why, #0                         @ no longer a real syscall
 453         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 454         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 455         bcs     arm_syscall
 456         b       sys_ni_syscall                  @ not private func
 457 ENDPROC(vector_swi)
 458
 459         /*
 460          * This is the really slow path.  We're going to be doing
 461          * context switches, and waiting for our parent to respond.
 462          */
 463 __sys_trace:
 464         mov     r2, scno
 465         add     r1, sp, #S_OFF
 466         mov     r0, #0                          @ trace entry [IP = 0]
 467         bl      syscall_trace
 468
 469         adr     lr, BSYM(__sys_trace_return)    @ return address
 470         mov     scno, r0                        @ syscall number (possibly new)
 471         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 472         cmp     scno, #NR_syscalls              @ check upper syscall limit
 473         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 474         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 475         b       2b
 476
 477 __sys_trace_return:
 478         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 479         mov     r2, scno
 480         mov     r1, sp
 481         mov     r0, #1                          @ trace exit [IP = 1]
 482         bl      syscall_trace
 483         b       ret_slow_syscall
 484
 485         .align  5
 486 #ifdef CONFIG_ALIGNMENT_TRAP
 487         .type   __cr_alignment, #object
 488 __cr_alignment:
 489         .word   cr_alignment
 490 #endif
 491         .ltorg
 492
 493 /*
 494  * This is the syscall table declaration for native ABI syscalls.
 495  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 496  */
 497 #define ABI(native, compat) native
 498 #ifdef CONFIG_AEABI
 499 #define OBSOLETE(syscall) sys_ni_syscall
 500 #else
 501 #define OBSOLETE(syscall) syscall
 502 #endif
 503
 504         .type   sys_call_table, #object
 505 ENTRY(sys_call_table)
 506 #include "calls.S"
 507 #undef ABI
 508 #undef OBSOLETE
 509
 510 /*============================================================================
 511  * Special system call wrappers
 512  */
 513 @ r0 = syscall number
 514 @ r8 = syscall table
 515 sys_syscall:
 516                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 517                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 518                 cmpne   scno, #NR_syscalls      @ check range
 519                 stmloia sp, {r5, r6}            @ shuffle args
 520                 movlo   r0, r1
 521                 movlo   r1, r2
 522                 movlo   r2, r3
 523                 movlo   r3, r4
 524                 ldrlo   pc, [tbl, scno, lsl #2]
 525                 b       sys_ni_syscall
 526 ENDPROC(sys_syscall)
 527
 528 sys_fork_wrapper:
 529                 add     r0, sp, #S_OFF
 530                 b       sys_fork
 531 ENDPROC(sys_fork_wrapper)
 532
 533 sys_vfork_wrapper:
 534                 add     r0, sp, #S_OFF
 535                 b       sys_vfork
 536 ENDPROC(sys_vfork_wrapper)
 537
 538 sys_execve_wrapper:
 539                 add     r3, sp, #S_OFF
 540                 b       sys_execve
 541 ENDPROC(sys_execve_wrapper)
 542
 543 sys_clone_wrapper:
 544                 add     ip, sp, #S_OFF
 545                 str     ip, [sp, #4]
 546                 b       sys_clone
 547 ENDPROC(sys_clone_wrapper)
 548
 549 sys_sigreturn_wrapper:
 550                 add     r0, sp, #S_OFF
 551                 mov     why, #0         @ prevent syscall restart handling
 552                 b       sys_sigreturn
 553 ENDPROC(sys_sigreturn_wrapper)
 554
 555 sys_rt_sigreturn_wrapper:
 556                 add     r0, sp, #S_OFF
 557                 mov     why, #0         @ prevent syscall restart handling
 558                 b       sys_rt_sigreturn
 559 ENDPROC(sys_rt_sigreturn_wrapper)
 560
 561 sys_sigaltstack_wrapper:
 562                 ldr     r2, [sp, #S_OFF + S_SP]
 563                 b       do_sigaltstack
 564 ENDPROC(sys_sigaltstack_wrapper)
 565
 566 sys_statfs64_wrapper:
 567                 teq     r1, #88
 568                 moveq   r1, #84
 569                 b       sys_statfs64
 570 ENDPROC(sys_statfs64_wrapper)
 571
 572 sys_fstatfs64_wrapper:
 573                 teq     r1, #88
 574                 moveq   r1, #84
 575                 b       sys_fstatfs64
 576 ENDPROC(sys_fstatfs64_wrapper)
 577
 578 /*
 579  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 580  * offset, we return EINVAL.
 581  */
 582 sys_mmap2:
 583 #if PAGE_SHIFT > 12
 584                 tst     r5, #PGOFF_MASK
 585                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 586                 streq   r5, [sp, #4]
 587                 beq     sys_mmap_pgoff
 588                 mov     r0, #-EINVAL
 589                 mov     pc, lr
 590 #else
 591                 str     r5, [sp, #4]
 592                 b       sys_mmap_pgoff
 593 #endif
 594 ENDPROC(sys_mmap2)
 595
 596 #ifdef CONFIG_OABI_COMPAT
 597
 598 /*
 599  * These are syscalls with argument register differences
 600  */
 601
 602 sys_oabi_pread64:
 603                 stmia   sp, {r3, r4}
 604                 b       sys_pread64
 605 ENDPROC(sys_oabi_pread64)
 606
 607 sys_oabi_pwrite64:
 608                 stmia   sp, {r3, r4}
 609                 b       sys_pwrite64
 610 ENDPROC(sys_oabi_pwrite64)
 611
 612 sys_oabi_truncate64:
 613                 mov     r3, r2
 614                 mov     r2, r1
 615                 b       sys_truncate64
 616 ENDPROC(sys_oabi_truncate64)
 617
 618 sys_oabi_ftruncate64:
 619                 mov     r3, r2
 620                 mov     r2, r1
 621                 b       sys_ftruncate64
 622 ENDPROC(sys_oabi_ftruncate64)
 623
 624 sys_oabi_readahead:
 625                 str     r3, [sp]
 626                 mov     r3, r2
 627                 mov     r2, r1
 628                 b       sys_readahead
 629 ENDPROC(sys_oabi_readahead)
 630
 631 /*
 632  * Let's declare a second syscall table for old ABI binaries
 633  * using the compatibility syscall entries.
 634  */
 635 #define ABI(native, compat) compat
 636 #define OBSOLETE(syscall) syscall
 637
 638         .type   sys_oabi_call_table, #object
 639 ENTRY(sys_oabi_call_table)
 640 #include "calls.S"
 641 #undef ABI
 642 #undef OBSOLETE
 643
 644 #endif
 645