[GitHub/mt8127/android_kernel_alcatel_ttab.git] / arch / x86 / kernel / trampoline_64.S

/*
 *
 *	Trampoline.S	Derived from Setup.S by Linus Torvalds
 *
 *	4 Jan 1997 Michael Chastain: changed to gnu as.
 *	15 Sept 2005 Eric Biederman: 64bit PIC support
 *
 *	Entry: CS:IP point to the start of our code, we are 
 *	in real mode with no stack, but the rest of the 
 *	trampoline page to make our stack and everything else
 *	is a mystery.
 *
 *	On entry to trampoline_data, the processor is in real mode
 *	with 16-bit addressing and 16-bit data.  CS has some value
 *	and IP is zero.  Thus, data addresses need to be absolute
 *	(no relocation) and are taken with regard to r_base.
 *
 *	With the addition of trampoline_level4_pgt this code can
 *	now enter a 64bit kernel that lives at arbitrary 64bit
 *	physical addresses.
 *
 *	If you work on this file, check the object module with objdump
 *	--full-contents --reloc to make sure there are no relocation
 *	entries.
 */

#include <linux/linkage.h>
#include <asm/pgtable_types.h>
#include <asm/page_types.h>
#include <asm/msr.h>
#include <asm/segment.h>
#include <asm/processor-flags.h>

.section .rodata, "a", @progbits

.code16

ENTRY(trampoline_data)
r_base = .
	cli			# We should be safe anyway
	wbinvd
	mov	%cs, %ax	# Code and data in the same place
	mov	%ax, %ds
	mov	%ax, %es
	mov	%ax, %ss


	movl	$0xA5A5A5A5, trampoline_data - r_base
				# write marker for master knows we're running

					# Setup stack
	movw	$(trampoline_stack_end - r_base), %sp

	call	verify_cpu		# Verify the cpu supports long mode
	testl   %eax, %eax		# Check for return code
	jnz	no_longmode

	mov	%cs, %ax
	movzx	%ax, %esi		# Find the 32bit trampoline location
	shll	$4, %esi

					# Fixup the vectors
	addl	%esi, startup_32_vector - r_base
	addl	%esi, startup_64_vector - r_base
	addl	%esi, tgdt + 2 - r_base	# Fixup the gdt pointer

	/*
	 * GDT tables in non default location kernel can be beyond 16MB and
	 * lgdt will not be able to load the address as in real mode default
	 * operand size is 16bit. Use lgdtl instead to force operand size
	 * to 32 bit.
	 */

	lidtl	tidt - r_base	# load idt with 0, 0
	lgdtl	tgdt - r_base	# load gdt with whatever is appropriate

	mov	$X86_CR0_PE, %ax	# protected mode (PE) bit
	lmsw	%ax			# into protected mode

	# flush prefetch and jump to startup_32
	ljmpl	*(startup_32_vector - r_base)

	.code32
	.balign 4
startup_32:
	movl	$__KERNEL_DS, %eax	# Initialize the %ds segment register
	movl	%eax, %ds

	movl	$X86_CR4_PAE, %eax
	movl	%eax, %cr4		# Enable PAE mode

					# Setup trampoline 4 level pagetables
	leal	(trampoline_level4_pgt - r_base)(%esi), %eax
	movl	%eax, %cr3

	movl	$MSR_EFER, %ecx
	movl	$(1 << _EFER_LME), %eax	# Enable Long Mode
	xorl	%edx, %edx
	wrmsr

	# Enable paging and in turn activate Long Mode
	# Enable protected mode
	movl	$(X86_CR0_PG | X86_CR0_PE), %eax
	movl	%eax, %cr0

	/*
	 * At this point we're in long mode but in 32bit compatibility mode
	 * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
	 * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
	 * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	 */
	ljmp	*(startup_64_vector - r_base)(%esi)

	.code64
	.balign 4
startup_64:
	# Now jump into the kernel using virtual addresses
	movq	$secondary_startup_64, %rax
	jmp	*%rax

	.code16
no_longmode:
	hlt
	jmp no_longmode
#include "verify_cpu_64.S"

	# Careful these need to be in the same 64K segment as the above;
tidt:
	.word	0			# idt limit = 0
	.word	0, 0			# idt base = 0L

	# Duplicate the global descriptor table
	# so the kernel can live anywhere
	.balign 4
tgdt:
	.short	tgdt_end - tgdt		# gdt limit
	.long	tgdt - r_base
	.short 0
	.quad	0x00cf9b000000ffff	# __KERNEL32_CS
	.quad	0x00af9b000000ffff	# __KERNEL_CS
	.quad	0x00cf93000000ffff	# __KERNEL_DS
tgdt_end:

	.balign 4
startup_32_vector:
	.long	startup_32 - r_base
	.word	__KERNEL32_CS, 0

	.balign 4
startup_64_vector:
	.long	startup_64 - r_base
	.word	__KERNEL_CS, 0

trampoline_stack:
	.org 0x1000
trampoline_stack_end:
ENTRY(trampoline_level4_pgt)
	.quad	level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.fill	510,8,0
	.quad	level3_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE

ENTRY(trampoline_end)
Commit	Line	Data
1da177e4 LT	1	/*
	2	*
	3	* Trampoline.S Derived from Setup.S by Linus Torvalds
	4	*
	5	* 4 Jan 1997 Michael Chastain: changed to gnu as.
90b1c208	6	* 15 Sept 2005 Eric Biederman: 64bit PIC support
1da177e4 LT	7	*
	8	* Entry: CS:IP point to the start of our code, we are
	9	* in real mode with no stack, but the rest of the
	10	* trampoline page to make our stack and everything else
	11	* is a mystery.
	12	*
1da177e4 LT	13	* On entry to trampoline_data, the processor is in real mode
	14	* with 16-bit addressing and 16-bit data. CS has some value
	15	* and IP is zero. Thus, data addresses need to be absolute
	16	* (no relocation) and are taken with regard to r_base.
	17	*
90b1c208 VG	18	* With the addition of trampoline_level4_pgt this code can
	19	* now enter a 64bit kernel that lives at arbitrary 64bit
	20	* physical addresses.
	21	*
1da177e4 LT	22	* If you work on this file, check the object module with objdump
1da177e4 LT	23	* --full-contents --reloc to make sure there are no relocation
90b1c208	24	* entries.
1da177e4 LT	25	*/
	26
	27	#include <linux/linkage.h>
0341c14d JF	28	#include <asm/pgtable_types.h>
0341c14d JF	29	#include <asm/page_types.h>
90b1c208 VG	30	#include <asm/msr.h>
90b1c208 VG	31	#include <asm/segment.h>
0a1e8869	32	#include <asm/processor-flags.h>
1da177e4	33
121d7bf5	34	.section .rodata, "a", @progbits
1da177e4 LT	35
	36	.code16
	37
	38	ENTRY(trampoline_data)
	39	r_base = .
90b1c208	40	cli # We should be safe anyway
0a1e8869	41	wbinvd
1da177e4 LT	42	mov %cs, %ax # Code and data in the same place
1da177e4 LT	43	mov %ax, %ds
90b1c208 VG	44	mov %ax, %es
90b1c208 VG	45	mov %ax, %ss
1da177e4	46
1da177e4 LT	47
	48	movl $0xA5A5A5A5, trampoline_data - r_base
	49	# write marker for master knows we're running
	50
90b1c208 VG	51	# Setup stack
	52	movw $(trampoline_stack_end - r_base), %sp
	53
	54	call verify_cpu # Verify the cpu supports long mode
a4831e08 VG	55	testl %eax, %eax # Check for return code
a4831e08 VG	56	jnz no_longmode
90b1c208 VG	57
	58	mov %cs, %ax
	59	movzx %ax, %esi # Find the 32bit trampoline location
	60	shll $4, %esi
	61
	62	# Fixup the vectors
	63	addl %esi, startup_32_vector - r_base
	64	addl %esi, startup_64_vector - r_base
	65	addl %esi, tgdt + 2 - r_base # Fixup the gdt pointer
	66
983d5dbd VG	67	/*
	68	* GDT tables in non default location kernel can be beyond 16MB and
	69	* lgdt will not be able to load the address as in real mode default
	70	* operand size is 16bit. Use lgdtl instead to force operand size
	71	* to 32 bit.
	72	*/
	73
90b1c208 VG	74	lidtl tidt - r_base # load idt with 0, 0
90b1c208 VG	75	lgdtl tgdt - r_base # load gdt with whatever is appropriate
1da177e4	76
0a1e8869 CG	77	mov $X86_CR0_PE, %ax # protected mode (PE) bit
0a1e8869 CG	78	lmsw %ax # into protected mode
90b1c208 VG	79
	80	# flush prefetch and jump to startup_32
	81	ljmpl *(startup_32_vector - r_base)
	82
	83	.code32
	84	.balign 4
	85	startup_32:
	86	movl $__KERNEL_DS, %eax # Initialize the %ds segment register
	87	movl %eax, %ds
	88
0a1e8869 CG	89	movl $X86_CR4_PAE, %eax
0a1e8869 CG	90	movl %eax, %cr4 # Enable PAE mode
90b1c208 VG	91
	92	# Setup trampoline 4 level pagetables
	93	leal (trampoline_level4_pgt - r_base)(%esi), %eax
	94	movl %eax, %cr3
	95
	96	movl $MSR_EFER, %ecx
	97	movl $(1 << _EFER_LME), %eax # Enable Long Mode
	98	xorl %edx, %edx
	99	wrmsr
	100
0a1e8869 CG	101	# Enable paging and in turn activate Long Mode
	102	# Enable protected mode
	103	movl $(X86_CR0_PG \| X86_CR0_PE), %eax
90b1c208 VG	104	movl %eax, %cr0
	105
	106	/*
	107	* At this point we're in long mode but in 32bit compatibility mode
	108	* with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
	109	* EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
	110	* the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	111	*/
	112	ljmp *(startup_64_vector - r_base)(%esi)
	113
	114	.code64
	115	.balign 4
	116	startup_64:
	117	# Now jump into the kernel using virtual addresses
	118	movq $secondary_startup_64, %rax
	119	jmp *%rax
	120
	121	.code16
90b1c208 VG	122	no_longmode:
	123	hlt
	124	jmp no_longmode
e0a84f68	125	#include "verify_cpu_64.S"
1da177e4 LT	126
1da177e4 LT	127	# Careful these need to be in the same 64K segment as the above;
90b1c208	128	tidt:
1da177e4 LT	129	.word 0 # idt limit = 0
	130	.word 0, 0 # idt base = 0L
	131
90b1c208 VG	132	# Duplicate the global descriptor table
	133	# so the kernel can live anywhere
	134	.balign 4
	135	tgdt:
	136	.short tgdt_end - tgdt # gdt limit
	137	.long tgdt - r_base
	138	.short 0
	139	.quad 0x00cf9b000000ffff # __KERNEL32_CS
	140	.quad 0x00af9b000000ffff # __KERNEL_CS
	141	.quad 0x00cf93000000ffff # __KERNEL_DS
	142	tgdt_end:
	143
	144	.balign 4
	145	startup_32_vector:
	146	.long startup_32 - r_base
	147	.word __KERNEL32_CS, 0
	148
	149	.balign 4
	150	startup_64_vector:
	151	.long startup_64 - r_base
	152	.word __KERNEL_CS, 0
	153
	154	trampoline_stack:
	155	.org 0x1000
	156	trampoline_stack_end:
	157	ENTRY(trampoline_level4_pgt)
	158	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	159	.fill 510,8,0
	160	.quad level3_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
1da177e4	161
90b1c208	162	ENTRY(trampoline_end)