projects / GitHub / mt8127 / android_kernel_alcatel_ttab.git / blame
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (incremental) | history | HEAD
c6x: switch to generic kernel_execve
[GitHub/mt8127/android_kernel_alcatel_ttab.git] / arch / c6x / kernel / entry.S
CommitLineData
e94e6682
AJ		 1;
2; Port on Texas Instruments TMS320C6x architecture
3;
4; Copyright (C) 2004-2011 Texas Instruments Incorporated
5; Author: Aurelien Jacquiot (aurelien.jacquiot@virtuallogix.com)
6; Updated for 2.6.34: Mark Salter <msalter@redhat.com>
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License version 2 as
10; published by the Free Software Foundation.
11;
12
13#include <linux/sys.h>
14#include <linux/linkage.h>
15#include <asm/thread_info.h>
16#include <asm/asm-offsets.h>
17#include <asm/unistd.h>
18#include <asm/errno.h>
19
20; Registers naming
21#define DP B14
22#define SP B15
23
24#ifndef CONFIG_PREEMPT
25#define resume_kernel restore_all
26#endif
27
28 .altmacro
29
30 .macro MASK_INT reg
31 MVC .S2 CSR,reg
32 CLR .S2 reg,0,0,reg
33 MVC .S2 reg,CSR
34 .endm
35
36 .macro UNMASK_INT reg
37 MVC .S2 CSR,reg
38 SET .S2 reg,0,0,reg
39 MVC .S2 reg,CSR
40 .endm
41
42 .macro GET_THREAD_INFO reg
43 SHR .S1X SP,THREAD_SHIFT,reg
44 SHL .S1 reg,THREAD_SHIFT,reg
45 .endm
46
47 ;;
48 ;; This defines the normal kernel pt_regs layout.
49 ;;
50 .macro SAVE_ALL __rp __tsr
51 STW .D2T2 B0,*SP--[2] ; save original B0
52 MVKL .S2 current_ksp,B0
53 MVKH .S2 current_ksp,B0
54 LDW .D2T2 *B0,B1 ; KSP
55
56 NOP 3
57 STW .D2T2 B1,*+SP[1] ; save original B1
58 XOR .D2 SP,B1,B0 ; (SP ^ KSP)
59 LDW .D2T2 *+SP[1],B1 ; restore B0/B1
60 LDW .D2T2 *++SP[2],B0
61 SHR .S2 B0,THREAD_SHIFT,B0 ; 0 if already using kstack
62 [B0] STDW .D2T2 SP:DP,*--B1[1] ; user: save user sp/dp kstack
63 [B0] MV .S2 B1,SP ; and switch to kstack
64||[!B0] STDW .D2T2 SP:DP,*--SP[1] ; kernel: save on current stack
65
66 SUBAW .D2 SP,2,SP
67
68 ADD .D1X SP,-8,A15
69 || STDW .D2T1 A15:A14,*SP--[16] ; save A15:A14
70
71 STDW .D2T2 B13:B12,*SP--[1]
72 || STDW .D1T1 A13:A12,*A15--[1]
73 || MVC .S2 __rp,B13
74
75 STDW .D2T2 B11:B10,*SP--[1]
76 || STDW .D1T1 A11:A10,*A15--[1]
77 || MVC .S2 CSR,B12
78
79 STDW .D2T2 B9:B8,*SP--[1]
80 || STDW .D1T1 A9:A8,*A15--[1]
81 || MVC .S2 RILC,B11
82 STDW .D2T2 B7:B6,*SP--[1]
83 || STDW .D1T1 A7:A6,*A15--[1]
84 || MVC .S2 ILC,B10
85
86 STDW .D2T2 B5:B4,*SP--[1]
87 || STDW .D1T1 A5:A4,*A15--[1]
88
89 STDW .D2T2 B3:B2,*SP--[1]
90 || STDW .D1T1 A3:A2,*A15--[1]
91 || MVC .S2 __tsr,B5
92
93 STDW .D2T2 B1:B0,*SP--[1]
94 || STDW .D1T1 A1:A0,*A15--[1]
95 || MV .S1X B5,A5
96
97 STDW .D2T2 B31:B30,*SP--[1]
98 || STDW .D1T1 A31:A30,*A15--[1]
99 STDW .D2T2 B29:B28,*SP--[1]
100 || STDW .D1T1 A29:A28,*A15--[1]
101 STDW .D2T2 B27:B26,*SP--[1]
102 || STDW .D1T1 A27:A26,*A15--[1]
103 STDW .D2T2 B25:B24,*SP--[1]
104 || STDW .D1T1 A25:A24,*A15--[1]
105 STDW .D2T2 B23:B22,*SP--[1]
106 || STDW .D1T1 A23:A22,*A15--[1]
107 STDW .D2T2 B21:B20,*SP--[1]
108 || STDW .D1T1 A21:A20,*A15--[1]
109 STDW .D2T2 B19:B18,*SP--[1]
110 || STDW .D1T1 A19:A18,*A15--[1]
111 STDW .D2T2 B17:B16,*SP--[1]
112 || STDW .D1T1 A17:A16,*A15--[1]
113
114 STDW .D2T2 B13:B12,*SP--[1] ; save PC and CSR
115
116 STDW .D2T2 B11:B10,*SP--[1] ; save RILC and ILC
117 STDW .D2T1 A5:A4,*SP--[1] ; save TSR and orig A4
118
119 ;; We left an unused word on the stack just above pt_regs.
120 ;; It is used to save whether or not this frame is due to
121 ;; a syscall. It is cleared here, but the syscall handler
122 ;; sets it to a non-zero value.
123 MVK .L2 0,B1
124 STW .D2T2 B1,*+SP(REGS__END+8) ; clear syscall flag
125 .endm
126
127 .macro RESTORE_ALL __rp __tsr
128 LDDW .D2T2 *++SP[1],B9:B8 ; get TSR (B9)
129 LDDW .D2T2 *++SP[1],B11:B10 ; get RILC (B11) and ILC (B10)
130 LDDW .D2T2 *++SP[1],B13:B12 ; get PC (B13) and CSR (B12)
131
132 ADDAW .D1X SP,30,A15
133
134 LDDW .D1T1 *++A15[1],A17:A16
135 || LDDW .D2T2 *++SP[1],B17:B16
136 LDDW .D1T1 *++A15[1],A19:A18
137 || LDDW .D2T2 *++SP[1],B19:B18
138 LDDW .D1T1 *++A15[1],A21:A20
139 || LDDW .D2T2 *++SP[1],B21:B20
140 LDDW .D1T1 *++A15[1],A23:A22
141 || LDDW .D2T2 *++SP[1],B23:B22
142 LDDW .D1T1 *++A15[1],A25:A24
143 || LDDW .D2T2 *++SP[1],B25:B24
144 LDDW .D1T1 *++A15[1],A27:A26
145 || LDDW .D2T2 *++SP[1],B27:B26
146 LDDW .D1T1 *++A15[1],A29:A28
147 || LDDW .D2T2 *++SP[1],B29:B28
148 LDDW .D1T1 *++A15[1],A31:A30
149 || LDDW .D2T2 *++SP[1],B31:B30
150
151 LDDW .D1T1 *++A15[1],A1:A0
152 || LDDW .D2T2 *++SP[1],B1:B0
153
154 LDDW .D1T1 *++A15[1],A3:A2
155 || LDDW .D2T2 *++SP[1],B3:B2
156 || MVC .S2 B9,__tsr
157 LDDW .D1T1 *++A15[1],A5:A4
158 || LDDW .D2T2 *++SP[1],B5:B4
159 || MVC .S2 B11,RILC
160 LDDW .D1T1 *++A15[1],A7:A6
161 || LDDW .D2T2 *++SP[1],B7:B6
162 || MVC .S2 B10,ILC
163
164 LDDW .D1T1 *++A15[1],A9:A8
165 || LDDW .D2T2 *++SP[1],B9:B8
166 || MVC .S2 B13,__rp
167
168 LDDW .D1T1 *++A15[1],A11:A10
169 || LDDW .D2T2 *++SP[1],B11:B10
170 || MVC .S2 B12,CSR
171
172 LDDW .D1T1 *++A15[1],A13:A12
173 || LDDW .D2T2 *++SP[1],B13:B12
174
175 MV .D2X A15,SP
176 || MVKL .S1 current_ksp,A15
177 MVKH .S1 current_ksp,A15
178 || ADDAW .D1X SP,6,A14
179 STW .D1T1 A14,*A15 ; save kernel stack pointer
180
181 LDDW .D2T1 *++SP[1],A15:A14
182
183 B .S2 __rp ; return from interruption
184 LDDW .D2T2 *+SP[1],SP:DP
185 NOP 4
186 .endm
187
188 .section .text
189
190 ;;
191 ;; Jump to schedule() then return to ret_from_exception
192 ;;
193_reschedule:
194#ifdef CONFIG_C6X_BIG_KERNEL
195 MVKL .S1 schedule,A0
196 MVKH .S1 schedule,A0
197 B .S2X A0
198#else
199 B .S1 schedule
200#endif
201 ADDKPC .S2 ret_from_exception,B3,4
202
203 ;;
204 ;; Called before syscall handler when process is being debugged
205 ;;
206tracesys_on:
207#ifdef CONFIG_C6X_BIG_KERNEL
208 MVKL .S1 syscall_trace_entry,A0
209 MVKH .S1 syscall_trace_entry,A0
210 B .S2X A0
211#else
212 B .S1 syscall_trace_entry
213#endif
214 ADDKPC .S2 ret_from_syscall_trace,B3,3
215 ADD .S1X 8,SP,A4
216
217ret_from_syscall_trace:
218 ;; tracing returns (possibly new) syscall number
219 MV .D2X A4,B0
220 || MVK .S2 __NR_syscalls,B1
221 CMPLTU .L2 B0,B1,B1
222
223 [!B1] BNOP .S2 ret_from_syscall_function,5
224 || MVK .S1 -ENOSYS,A4
225
226 ;; reload syscall args from (possibly modified) stack frame
227 ;; and get syscall handler addr from sys_call_table:
228 LDW .D2T2 *+SP(REGS_B4+8),B4
229 || MVKL .S2 sys_call_table,B1
230 LDW .D2T1 *+SP(REGS_A6+8),A6
231 || MVKH .S2 sys_call_table,B1
232 LDW .D2T2 *+B1[B0],B0
233 || MVKL .S2 ret_from_syscall_function,B3
234 LDW .D2T2 *+SP(REGS_B6+8),B6
235 || MVKH .S2 ret_from_syscall_function,B3
236 LDW .D2T1 *+SP(REGS_A8+8),A8
237 LDW .D2T2 *+SP(REGS_B8+8),B8
238 NOP
239 ; B0 = sys_call_table[__NR_*]
240 BNOP .S2 B0,5 ; branch to syscall handler
241 || LDW .D2T1 *+SP(REGS_ORIG_A4+8),A4
242
243syscall_exit_work:
244 AND .D1 _TIF_SYSCALL_TRACE,A2,A0
245 [!A0] BNOP .S1 work_pending,5
246 [A0] B .S2 syscall_trace_exit
247 ADDKPC .S2 resume_userspace,B3,1
248 MVC .S2 CSR,B1
249 SET .S2 B1,0,0,B1
250 MVC .S2 B1,CSR ; enable ints
251
252work_pending:
253 AND .D1 _TIF_NEED_RESCHED,A2,A0
254 [!A0] BNOP .S1 work_notifysig,5
255
256work_resched:
257#ifdef CONFIG_C6X_BIG_KERNEL
258 MVKL .S1 schedule,A1
259 MVKH .S1 schedule,A1
260 B .S2X A1
261#else
262 B .S2 schedule
263#endif
264 ADDKPC .S2 work_rescheduled,B3,4
265work_rescheduled:
266 ;; make sure we don't miss an interrupt setting need_resched or
267 ;; sigpending between sampling and the rti
268 MASK_INT B2
269 GET_THREAD_INFO A12
270 LDW .D1T1 *+A12(THREAD_INFO_FLAGS),A2
271 MVK .S1 _TIF_WORK_MASK,A1
272 MVK .S1 _TIF_NEED_RESCHED,A3
273 NOP 2
274 AND .D1 A1,A2,A0
275 || AND .S1 A3,A2,A1
276 [!A0] BNOP .S1 restore_all,5
277 [A1] BNOP .S1 work_resched,5
278
279work_notifysig:
280 B .S2 do_notify_resume
281 LDW .D2T1 *+SP(REGS__END+8),A6 ; syscall flag
282 ADDKPC .S2 resume_userspace,B3,1
283 ADD .S1X 8,SP,A4 ; pt_regs pointer is first arg
284 MV .D2X A2,B4 ; thread_info flags is second arg
285
286 ;;
287 ;; On C64x+, the return way from exception and interrupt
288 ;; is a little bit different
289 ;;
290ENTRY(ret_from_exception)
291#ifdef CONFIG_PREEMPT
292 MASK_INT B2
293#endif
294
295ENTRY(ret_from_interrupt)
296 ;;
297 ;; Check if we are comming from user mode.
298 ;;
299 LDW .D2T2 *+SP(REGS_TSR+8),B0
300 MVK .S2 0x40,B1
301 NOP 3
302 AND .D2 B0,B1,B0
303 [!B0] BNOP .S2 resume_kernel,5
304
305resume_userspace:
306 ;; make sure we don't miss an interrupt setting need_resched or
307 ;; sigpending between sampling and the rti
308 MASK_INT B2
309 GET_THREAD_INFO A12
310 LDW .D1T1 *+A12(THREAD_INFO_FLAGS),A2
311 MVK .S1 _TIF_WORK_MASK,A1
312 MVK .S1 _TIF_NEED_RESCHED,A3
313 NOP 2
314 AND .D1 A1,A2,A0
315 [A0] BNOP .S1 work_pending,5
316 BNOP .S1 restore_all,5
317
318 ;;
319 ;; System call handling
320 ;; B0 = syscall number (in sys_call_table)
321 ;; A4,B4,A6,B6,A8,B8 = arguments of the syscall function
322 ;; A4 is the return value register
323 ;;
324system_call_saved:
325 MVK .L2 1,B2
326 STW .D2T2 B2,*+SP(REGS__END+8) ; set syscall flag
327 MVC .S2 B2,ECR ; ack the software exception
328
329 UNMASK_INT B2 ; re-enable global IT
330
331system_call_saved_noack:
332 ;; Check system call number
333 MVK .S2 __NR_syscalls,B1
334#ifdef CONFIG_C6X_BIG_KERNEL
335 || MVKL .S1 sys_ni_syscall,A0
336#endif
337 CMPLTU .L2 B0,B1,B1
338#ifdef CONFIG_C6X_BIG_KERNEL
339 || MVKH .S1 sys_ni_syscall,A0
340#endif
341
342 ;; Check for ptrace
343 GET_THREAD_INFO A12
344
345#ifdef CONFIG_C6X_BIG_KERNEL
346 [!B1] B .S2X A0
347#else
348 [!B1] B .S2 sys_ni_syscall
349#endif
350 [!B1] ADDKPC .S2 ret_from_syscall_function,B3,4
351
352 ;; Get syscall handler addr from sys_call_table
353 ;; call tracesys_on or call syscall handler
354 LDW .D1T1 *+A12(THREAD_INFO_FLAGS),A2
355 || MVKL .S2 sys_call_table,B1
356 MVKH .S2 sys_call_table,B1
357 LDW .D2T2 *+B1[B0],B0
358 NOP 2
359 ; A2 = thread_info flags
360 AND .D1 _TIF_SYSCALL_TRACE,A2,A2
361 [A2] BNOP .S1 tracesys_on,5
362 ;; B0 = _sys_call_table[__NR_*]
363 B .S2 B0
364 ADDKPC .S2 ret_from_syscall_function,B3,4
365
366ret_from_syscall_function:
367 STW .D2T1 A4,*+SP(REGS_A4+8) ; save return value in A4
368 ; original A4 is in orig_A4
369syscall_exit:
370 ;; make sure we don't miss an interrupt setting need_resched or
371 ;; sigpending between sampling and the rti
372 MASK_INT B2
373 LDW .D1T1 *+A12(THREAD_INFO_FLAGS),A2
374 MVK .S1 _TIF_ALLWORK_MASK,A1
375 NOP 3
376 AND .D1 A1,A2,A2 ; check for work to do
377 [A2] BNOP .S1 syscall_exit_work,5
378
379restore_all:
380 RESTORE_ALL NRP,NTSR
381
382 ;;
383 ;; After a fork we jump here directly from resume,
384 ;; so that A4 contains the previous task structure.
385 ;;
386ENTRY(ret_from_fork)
387#ifdef CONFIG_C6X_BIG_KERNEL
388 MVKL .S1 schedule_tail,A0
389 MVKH .S1 schedule_tail,A0
390 B .S2X A0
391#else
392 B .S2 schedule_tail
393#endif
394 ADDKPC .S2 ret_from_fork_2,B3,4
395ret_from_fork_2:
396 ;; return 0 in A4 for child process
397 GET_THREAD_INFO A12
398 BNOP .S2 syscall_exit,3
399 MVK .L2 0,B0
400 STW .D2T2 B0,*+SP(REGS_A4+8)
401ENDPROC(ret_from_fork)
402
46f15067
MS		 403ENTRY(ret_from_kernel_thread)
404#ifdef CONFIG_C6X_BIG_KERNEL
405 MVKL .S1 schedule_tail,A0
406 MVKH .S1 schedule_tail,A0
407 B .S2X A0
408#else
409 B .S2 schedule_tail
410#endif
411 LDW .D2T2 *+SP(REGS_A0+8),B10 /* get fn */
412 ADDKPC .S2 0f,B3,3
4130:
414 B .S2 B10 /* call fn */
415 LDW .D2T1 *+SP(REGS_A1+8),A4 /* get arg */
416 MVKL .S2 sys_exit,B11
417 MVKH .S2 sys_exit,B11
418 ADDKPC .S2 0f,B3,1
4190:
420 BNOP .S2 B11,5 /* jump to sys_exit */
421ENDPROC(ret_from_kernel_thread)
422
39fcf440
MS		 423ENTRY(ret_from_kernel_execve)
424 GET_THREAD_INFO A12
425 BNOP .S2 syscall_exit,4
426 ADD .D2X A4,-8,SP
427ENDPROC(ret_from_kernel_execve)
428
e94e6682
AJ		 429 ;;
430 ;; These are the interrupt handlers, responsible for calling __do_IRQ()
431 ;; int6 is used for syscalls (see _system_call entry)
432 ;;
433 .macro SAVE_ALL_INT
434 SAVE_ALL IRP,ITSR
435 .endm
436
437 .macro CALL_INT int
438#ifdef CONFIG_C6X_BIG_KERNEL
439 MVKL .S1 c6x_do_IRQ,A0
440 MVKH .S1 c6x_do_IRQ,A0
441 BNOP .S2X A0,1
442 MVK .S1 int,A4
443 ADDAW .D2 SP,2,B4
444 MVKL .S2 ret_from_interrupt,B3
445 MVKH .S2 ret_from_interrupt,B3
446#else
447 CALLP .S2 c6x_do_IRQ,B3
448 || MVK .S1 int,A4
449 || ADDAW .D2 SP,2,B4
450 B .S1 ret_from_interrupt
451 NOP 5
452#endif
453 .endm
454
455ENTRY(_int4_handler)
456 SAVE_ALL_INT
457 CALL_INT 4
458ENDPROC(_int4_handler)
459
460ENTRY(_int5_handler)
461 SAVE_ALL_INT
462 CALL_INT 5
463ENDPROC(_int5_handler)
464
465ENTRY(_int6_handler)
466 SAVE_ALL_INT
467 CALL_INT 6
468ENDPROC(_int6_handler)
469
470ENTRY(_int7_handler)
471 SAVE_ALL_INT
472 CALL_INT 7
473ENDPROC(_int7_handler)
474
475ENTRY(_int8_handler)
476 SAVE_ALL_INT
477 CALL_INT 8
478ENDPROC(_int8_handler)
479
480ENTRY(_int9_handler)
481 SAVE_ALL_INT
482 CALL_INT 9
483ENDPROC(_int9_handler)
484
485ENTRY(_int10_handler)
486 SAVE_ALL_INT
487 CALL_INT 10
488ENDPROC(_int10_handler)
489
490ENTRY(_int11_handler)
491 SAVE_ALL_INT
492 CALL_INT 11
493ENDPROC(_int11_handler)
494
495ENTRY(_int12_handler)
496 SAVE_ALL_INT
497 CALL_INT 12
498ENDPROC(_int12_handler)
499
500ENTRY(_int13_handler)
501 SAVE_ALL_INT
502 CALL_INT 13
503ENDPROC(_int13_handler)
504
505ENTRY(_int14_handler)
506 SAVE_ALL_INT
507 CALL_INT 14
508ENDPROC(_int14_handler)
509
510ENTRY(_int15_handler)
511 SAVE_ALL_INT
512 CALL_INT 15
513ENDPROC(_int15_handler)
514
515 ;;
516 ;; Handler for uninitialized and spurious interrupts
517 ;;
518ENTRY(_bad_interrupt)
519 B .S2 IRP
520 NOP 5
521ENDPROC(_bad_interrupt)
522
523 ;;
524 ;; Entry for NMI/exceptions/syscall
525 ;;
526ENTRY(_nmi_handler)
527 SAVE_ALL NRP,NTSR
528
529 MVC .S2 EFR,B2
530 CMPEQ .L2 1,B2,B2
531 || MVC .S2 TSR,B1
532 CLR .S2 B1,10,10,B1
533 MVC .S2 B1,TSR
534#ifdef CONFIG_C6X_BIG_KERNEL
535 [!B2] MVKL .S1 process_exception,A0
536 [!B2] MVKH .S1 process_exception,A0
537 [!B2] B .S2X A0
538#else
539 [!B2] B .S2 process_exception
540#endif
541 [B2] B .S2 system_call_saved
542 [!B2] ADDAW .D2 SP,2,B1
543 [!B2] MV .D1X B1,A4
544 ADDKPC .S2 ret_from_trap,B3,2
545
546ret_from_trap:
547 MV .D2X A4,B0
548 [!B0] BNOP .S2 ret_from_exception,5
549
550#ifdef CONFIG_C6X_BIG_KERNEL
551 MVKL .S2 system_call_saved_noack,B3
552 MVKH .S2 system_call_saved_noack,B3
553#endif
554 LDW .D2T2 *+SP(REGS_B0+8),B0
555 LDW .D2T1 *+SP(REGS_A4+8),A4
556 LDW .D2T2 *+SP(REGS_B4+8),B4
557 LDW .D2T1 *+SP(REGS_A6+8),A6
558 LDW .D2T2 *+SP(REGS_B6+8),B6
559 LDW .D2T1 *+SP(REGS_A8+8),A8
560#ifdef CONFIG_C6X_BIG_KERNEL
561 || B .S2 B3
562#else
563 || B .S2 system_call_saved_noack
564#endif
565 LDW .D2T2 *+SP(REGS_B8+8),B8
566 NOP 4
567ENDPROC(_nmi_handler)
568
569 ;;
570 ;; Jump to schedule() then return to ret_from_isr
571 ;;
572#ifdef CONFIG_PREEMPT
573resume_kernel:
574 GET_THREAD_INFO A12
575 LDW .D1T1 *+A12(THREAD_INFO_PREEMPT_COUNT),A1
576 NOP 4
577 [A1] BNOP .S2 restore_all,5
578
579preempt_schedule:
580 GET_THREAD_INFO A2
581 LDW .D1T1 *+A2(THREAD_INFO_FLAGS),A1
582#ifdef CONFIG_C6X_BIG_KERNEL
583 MVKL .S2 preempt_schedule_irq,B0
584 MVKH .S2 preempt_schedule_irq,B0
585 NOP 2
586#else
587 NOP 4
588#endif
589 AND .D1 _TIF_NEED_RESCHED,A1,A1
590 [!A1] BNOP .S2 restore_all,5
591#ifdef CONFIG_C6X_BIG_KERNEL
592 B .S2 B0
593#else
594 B .S2 preempt_schedule_irq
595#endif
596 ADDKPC .S2 preempt_schedule,B3,4
597#endif /* CONFIG_PREEMPT */
598
599ENTRY(enable_exception)
600 DINT
601 MVC .S2 TSR,B0
602 MVC .S2 B3,NRP
603 MVK .L2 0xc,B1
604 OR .D2 B0,B1,B0
605 MVC .S2 B0,TSR ; Set GEE and XEN in TSR
606 B .S2 NRP
607 NOP 5
608ENDPROC(enable_exception)
609
610ENTRY(sys_sigaltstack)
611#ifdef CONFIG_C6X_BIG_KERNEL
612 MVKL .S1 do_sigaltstack,A0 ; branch to do_sigaltstack
613 MVKH .S1 do_sigaltstack,A0
614 B .S2X A0
615#else
616 B .S2 do_sigaltstack
617#endif
618 LDW .D2T1 *+SP(REGS_SP+8),A6
619 NOP 4
620ENDPROC(sys_sigaltstack)
621
e94e6682
AJ		 622 ;;
623 ;; Special system calls
624 ;; return address is in B3
625 ;;
626ENTRY(sys_clone)
627 ADD .D1X SP,8,A4
628#ifdef CONFIG_C6X_BIG_KERNEL
629 || MVKL .S1 sys_c6x_clone,A0
630 MVKH .S1 sys_c6x_clone,A0
631 BNOP .S2X A0,5
632#else
633 || B .S2 sys_c6x_clone
634 NOP 5
635#endif
636ENDPROC(sys_clone)
637
638ENTRY(sys_rt_sigreturn)
639 ADD .D1X SP,8,A4
640#ifdef CONFIG_C6X_BIG_KERNEL
641 || MVKL .S1 do_rt_sigreturn,A0
642 MVKH .S1 do_rt_sigreturn,A0
643 BNOP .S2X A0,5
644#else
645 || B .S2 do_rt_sigreturn
646 NOP 5
647#endif
648ENDPROC(sys_rt_sigreturn)
649
650ENTRY(sys_execve)
651 ADDAW .D2 SP,2,B6 ; put regs addr in 4th parameter
652 ; & adjust regs stack addr
653 LDW .D2T2 *+SP(REGS_B4+8),B4
654
655 ;; c6x_execve(char *name, char **argv,
656 ;; char **envp, struct pt_regs *regs)
657#ifdef CONFIG_C6X_BIG_KERNEL
658 || MVKL .S1 sys_c6x_execve,A0
659 MVKH .S1 sys_c6x_execve,A0
660 B .S2X A0
661#else
662 || B .S2 sys_c6x_execve
663#endif
664 STW .D2T2 B3,*SP--[2]
665 ADDKPC .S2 ret_from_c6x_execve,B3,3
666
667ret_from_c6x_execve:
668 LDW .D2T2 *++SP[2],B3
669 NOP 4
670 BNOP .S2 B3,5
671ENDPROC(sys_execve)
672
673ENTRY(sys_pread_c6x)
674 MV .D2X A8,B7
675#ifdef CONFIG_C6X_BIG_KERNEL
676 || MVKL .S1 sys_pread64,A0
677 MVKH .S1 sys_pread64,A0
678 BNOP .S2X A0,5
679#else
680 || B .S2 sys_pread64
681 NOP 5
682#endif
683ENDPROC(sys_pread_c6x)
684
685ENTRY(sys_pwrite_c6x)
686 MV .D2X A8,B7
687#ifdef CONFIG_C6X_BIG_KERNEL
688 || MVKL .S1 sys_pwrite64,A0
689 MVKH .S1 sys_pwrite64,A0
690 BNOP .S2X A0,5
691#else
692 || B .S2 sys_pwrite64
693 NOP 5
694#endif
695ENDPROC(sys_pwrite_c6x)
696
697;; On Entry
698;; A4 - path
699;; B4 - offset_lo (LE), offset_hi (BE)
700;; A6 - offset_lo (BE), offset_hi (LE)
701ENTRY(sys_truncate64_c6x)
702#ifdef CONFIG_CPU_BIG_ENDIAN
703 MV .S2 B4,B5
704 MV .D2X A6,B4
705#else
706 MV .D2X A6,B5
707#endif
708#ifdef CONFIG_C6X_BIG_KERNEL
709 || MVKL .S1 sys_truncate64,A0
710 MVKH .S1 sys_truncate64,A0
711 BNOP .S2X A0,5
712#else
713 || B .S2 sys_truncate64
714 NOP 5
715#endif
716ENDPROC(sys_truncate64_c6x)
717
718;; On Entry
719;; A4 - fd
720;; B4 - offset_lo (LE), offset_hi (BE)
721;; A6 - offset_lo (BE), offset_hi (LE)
722ENTRY(sys_ftruncate64_c6x)
723#ifdef CONFIG_CPU_BIG_ENDIAN
724 MV .S2 B4,B5
725 MV .D2X A6,B4
726#else
727 MV .D2X A6,B5
728#endif
729#ifdef CONFIG_C6X_BIG_KERNEL
730 || MVKL .S1 sys_ftruncate64,A0
731 MVKH .S1 sys_ftruncate64,A0
732 BNOP .S2X A0,5
733#else
734 || B .S2 sys_ftruncate64
735 NOP 5
736#endif
737ENDPROC(sys_ftruncate64_c6x)
738
e94e6682
AJ		 739;; On Entry
740;; A4 - fd
741;; B4 - offset_lo (LE), offset_hi (BE)
742;; A6 - offset_lo (BE), offset_hi (LE)
743;; B6 - len_lo (LE), len_hi (BE)
744;; A8 - len_lo (BE), len_hi (LE)
745;; B8 - advice
746ENTRY(sys_fadvise64_64_c6x)
747#ifdef CONFIG_C6X_BIG_KERNEL
748 MVKL .S1 sys_fadvise64_64,A0
749 MVKH .S1 sys_fadvise64_64,A0
750 BNOP .S2X A0,2
751#else
752 B .S2 sys_fadvise64_64
753 NOP 2
754#endif
755#ifdef CONFIG_CPU_BIG_ENDIAN
756 MV .L2 B4,B5
757 || MV .D2X A6,B4
758 MV .L1 A8,A6
759 || MV .D1X B6,A7
760#else
761 MV .D2X A6,B5
762 MV .L1 A8,A7
763 || MV .D1X B6,A6
764#endif
765 MV .L2 B8,B6
766ENDPROC(sys_fadvise64_64_c6x)
767
768;; On Entry
769;; A4 - fd
770;; B4 - mode
771;; A6 - offset_hi
772;; B6 - offset_lo
773;; A8 - len_hi
774;; B8 - len_lo
775ENTRY(sys_fallocate_c6x)
776#ifdef CONFIG_C6X_BIG_KERNEL
777 MVKL .S1 sys_fallocate,A0
778 MVKH .S1 sys_fallocate,A0
779 BNOP .S2X A0,1
780#else
781 B .S2 sys_fallocate
782 NOP
783#endif
784 MV .D1 A6,A7
785 MV .D1X B6,A6
786 MV .D2X A8,B7
787 MV .D2 B8,B6
788ENDPROC(sys_fallocate_c6x)
789
790 ;; put this in .neardata for faster access when using DSBT mode
791 .section .neardata,"aw",@progbits
792 .global current_ksp
793 .hidden current_ksp
794current_ksp:
795 .word init_thread_union + THREAD_START_SP
kernel source for telekom puls (alcatel/mediatek)